gnu/packages.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2014 Eric Bavier <bavier@member.fsf.org>
   5 ;;; Copyright © 2016, 2017 Alex Kost <alezost@gmail.com>
   6 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   7 ;;;
   8 ;;; This file is part of GNU Guix.
   9 ;;;
  10 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  11 ;;; under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or (at
  13 ;;; your option) any later version.
  14 ;;;
  15 ;;; GNU Guix is distributed in the hope that it will be useful, but
  16 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 (define-module (gnu packages)
  24   #:use-module (guix packages)
  25   #:use-module (guix ui)
  26   #:use-module (guix utils)
  27   #:use-module (guix diagnostics)
  28   #:use-module (guix discovery)
  29   #:use-module (guix memoization)
  30   #:use-module ((guix build utils)
  31                 #:select ((package-name->name+version
  32                            . hyphen-separated-name->name+version)
  33                           mkdir-p))
  34   #:use-module (guix profiles)
  35   #:use-module (guix describe)
  36   #:use-module (guix deprecation)
  37   #:use-module (ice-9 vlist)
  38   #:use-module (ice-9 match)
  39   #:use-module (ice-9 binary-ports)
  40   #:autoload   (system base compile) (compile)
  41   #:use-module (srfi srfi-1)
  42   #:use-module (srfi srfi-11)
  43   #:use-module (srfi srfi-26)
  44   #:use-module (srfi srfi-34)
  45   #:use-module (srfi srfi-35)
  46   #:use-module (srfi srfi-39)
  47   #:export (search-patch
  48             search-patches
  49             search-auxiliary-file
  50             %patch-path
  51             %auxiliary-files-path
  52             %package-module-path
  53             %default-package-module-path
  54
  55             fold-packages
  56             fold-available-packages
  57
  58             find-newest-available-packages
  59             find-packages-by-name
  60             find-package-locations
  61             find-best-packages-by-name
  62
  63             specification->package
  64             specification->package+output
  65             specification->location
  66             specifications->manifest
  67
  68             generate-package-cache))
  69
  70 ;;; Commentary:
  71 ;;;
  72 ;;; General utilities for the software distribution---i.e., the modules under
  73 ;;; (gnu packages ...).
  74 ;;;
  75 ;;; Code:
  76
  77 ;; By default, we store patches and auxiliary files
  78 ;; alongside Guile modules.  This is so that these extra files can be
  79 ;; found without requiring a special setup, such as a specific
  80 ;; installation directory and an extra environment variable.  One
  81 ;; advantage of this setup is that everything just works in an
  82 ;; auto-compilation setting.
  83
  84 (define %auxiliary-files-path
  85   (make-parameter
  86    (map (cut string-append <> "/gnu/packages/aux-files")
  87         %load-path)))
  88
  89 (define (search-auxiliary-file file-name)
  90   "Search the auxiliary FILE-NAME.  Return #f if not found."
  91   (search-path (%auxiliary-files-path) file-name))
  92
  93 (define (search-patch file-name)
  94   "Search the patch FILE-NAME.  Raise an error if not found."
  95   (or (search-path (%patch-path) file-name)
  96       (raise (formatted-message (G_ "~a: patch not found")
  97                                 file-name))))
  98
  99 (define-syntax-rule (search-patches file-name ...)
 100   "Return the list of absolute file names corresponding to each
 101 FILE-NAME found in %PATCH-PATH."
 102   (list (search-patch file-name) ...))
 103
 104 (define %distro-root-directory
 105   ;; Absolute file name of the module hierarchy.  Since (gnu packages …) might
 106   ;; live in a directory different from (guix), try to get the best match.
 107   (letrec-syntax ((dirname* (syntax-rules ()
 108                               ((_ file)
 109                                (dirname file))
 110                               ((_ file head tail ...)
 111                                (dirname (dirname* file tail ...)))))
 112                   (try      (syntax-rules ()
 113                               ((_ (file things ...) rest ...)
 114                                (match (search-path %load-path file)
 115                                  (#f
 116                                   (try rest ...))
 117                                  (absolute
 118                                   (dirname* absolute things ...))))
 119                               ((_)
 120                                #f))))
 121     (try ("gnu/packages/base.scm" gnu/ packages/)
 122          ("gnu/packages.scm"      gnu/)
 123          ("guix.scm"))))
 124
 125 (define %default-package-module-path
 126   ;; Default search path for package modules.
 127   `((,%distro-root-directory . "gnu/packages")))
 128
 129 (define (cache-is-authoritative?)
 130   "Return true if the pre-computed package cache is authoritative.  It is not
 131 authoritative when entries have been added via GUIX_PACKAGE_PATH or '-L'
 132 flags."
 133   (equal? (%package-module-path)
 134           (append %default-package-module-path
 135                   (package-path-entries))))
 136
 137 (define %package-module-path
 138   ;; Search path for package modules.  Each item must be either a directory
 139   ;; name or a pair whose car is a directory and whose cdr is a sub-directory
 140   ;; to narrow the search.
 141   (let*-values (((not-colon)
 142                  (char-set-complement (char-set #\:)))
 143                 ((environment)
 144                  (string-tokenize (or (getenv "GUIX_PACKAGE_PATH") "")
 145                                   not-colon))
 146                 ((channels-scm channels-go)
 147                  (package-path-entries)))
 148     ;; Automatically add channels and items from $GUIX_PACKAGE_PATH to Guile's
 149     ;; search path.  For historical reasons, $GUIX_PACKAGE_PATH goes to the
 150     ;; front; channels go to the back so that they don't override Guix' own
 151     ;; modules.
 152     (set! %load-path
 153       (append environment %load-path channels-scm))
 154     (set! %load-compiled-path
 155       (append environment %load-compiled-path channels-go))
 156
 157     (make-parameter
 158      (append environment
 159              %default-package-module-path
 160              channels-scm))))
 161
 162 (define %patch-path
 163   ;; Define it after '%package-module-path' so that '%load-path' contains user
 164   ;; directories, allowing patches in $GUIX_PACKAGE_PATH to be found.
 165   (make-parameter
 166    (map (lambda (directory)
 167           (if (string=? directory %distro-root-directory)
 168               (string-append directory "/gnu/packages/patches")
 169               directory))
 170         %load-path)))
 171
 172 ;; This procedure is used by Emacs-Guix up to 0.5.1.1, so keep it for now.
 173 ;; See <https://github.com/alezost/guix.el/issues/30>.
 174 (define-deprecated find-newest-available-packages
 175   find-packages-by-name
 176   (mlambda ()
 177     "Return a vhash keyed by package names, and with
 178 associated values of the form
 179
 180   (newest-version newest-package ...)
 181
 182 where the preferred package is listed first."
 183     (fold-packages (lambda (p r)
 184                      (let ((name    (package-name p))
 185                            (version (package-version p)))
 186                        (match (vhash-assoc name r)
 187                          ((_ newest-so-far . pkgs)
 188                           (case (version-compare version newest-so-far)
 189                             ((>) (vhash-cons name `(,version ,p) r))
 190                             ((=) (vhash-cons name `(,version ,p ,@pkgs) r))
 191                             ((<) r)))
 192                          (#f (vhash-cons name `(,version ,p) r)))))
 193                    vlist-null)))
 194
 195 (define (fold-available-packages proc init)
 196   "Fold PROC over the list of available packages.  For each available package,
 197 PROC is called along these lines:
 198
 199   (PROC NAME VERSION RESULT
 200         #:outputs OUTPUTS
 201         #:location LOCATION
 202         …)
 203
 204 PROC can use #:allow-other-keys to ignore the bits it's not interested in.
 205 When a package cache is available, this procedure does not actually load any
 206 package module."
 207   (define cache
 208     (load-package-cache (current-profile)))
 209
 210   (if (and cache (cache-is-authoritative?))
 211       (vhash-fold (lambda (name vector result)
 212                     (match vector
 213                       (#(name version module symbol outputs
 214                               supported? deprecated?
 215                               file line column)
 216                        (proc name version result
 217                              #:outputs outputs
 218                              #:location (and file
 219                                              (location file line column))
 220                              #:supported? supported?
 221                              #:deprecated? deprecated?))))
 222                   init
 223                   cache)
 224       (fold-packages (lambda (package result)
 225                        (proc (package-name package)
 226                              (package-version package)
 227                              result
 228                              #:outputs (package-outputs package)
 229                              #:location (package-location package)
 230                              #:supported?
 231                              (->bool (supported-package? package))
 232                              #:deprecated?
 233                              (->bool
 234                               (package-superseded package))))
 235                      init)))
 236
 237 (define* (fold-packages proc init
 238                         #:optional
 239                         (modules (all-modules (%package-module-path)
 240                                               #:warn
 241                                               warn-about-load-error))
 242                         #:key (select? (negate hidden-package?)))
 243   "Call (PROC PACKAGE RESULT) for each available package defined in one of
 244 MODULES that matches SELECT?, using INIT as the initial value of RESULT.  It
 245 is guaranteed to never traverse the same package twice."
 246   (fold-module-public-variables (lambda (object result)
 247                                   (if (and (package? object) (select? object))
 248                                       (proc object result)
 249                                       result))
 250                                 init
 251                                 modules))
 252
 253 (define %package-cache-file
 254   ;; Location of the package cache.
 255   "/lib/guix/package.cache")
 256
 257 (define load-package-cache
 258   (mlambda (profile)
 259     "Attempt to load the package cache.  On success return a vhash keyed by
 260 package names.  Return #f on failure."
 261     (match profile
 262       (#f #f)
 263       (profile
 264        (catch 'system-error
 265          (lambda ()
 266            (define lst
 267              (load-compiled (string-append profile %package-cache-file)))
 268            (fold (lambda (item vhash)
 269                    (match item
 270                      (#(name version module symbol outputs
 271                              supported? deprecated?
 272                              file line column)
 273                       (vhash-cons name item vhash))))
 274                  vlist-null
 275                  lst))
 276          (lambda args
 277            (if (= ENOENT (system-error-errno args))
 278                #f
 279                (apply throw args))))))))
 280
 281 (define find-packages-by-name/direct              ;bypass the cache
 282   (let ((packages (delay
 283                     (fold-packages (lambda (p r)
 284                                      (vhash-cons (package-name p) p r))
 285                                    vlist-null)))
 286         (version>? (lambda (p1 p2)
 287                      (version>? (package-version p1) (package-version p2)))))
 288     (lambda* (name #:optional version)
 289       "Return the list of packages with the given NAME.  If VERSION is not #f,
 290 then only return packages whose version is prefixed by VERSION, sorted in
 291 decreasing version order."
 292       (let ((matching (sort (vhash-fold* cons '() name (force packages))
 293                             version>?)))
 294         (if version
 295             (filter (lambda (package)
 296                       (version-prefix? version (package-version package)))
 297                     matching)
 298             matching)))))
 299
 300 (define (cache-lookup cache name)
 301   "Lookup package NAME in CACHE.  Return a list sorted in increasing version
 302 order."
 303   (define (package-version<? v1 v2)
 304     (version>? (vector-ref v2 1) (vector-ref v1 1)))
 305
 306   (sort (vhash-fold* cons '() name cache)
 307         package-version<?))
 308
 309 (define* (find-packages-by-name name #:optional version)
 310   "Return the list of packages with the given NAME.  If VERSION is not #f,
 311 then only return packages whose version is prefixed by VERSION, sorted in
 312 decreasing version order."
 313   (define cache
 314     (load-package-cache (current-profile)))
 315
 316   (if (and (cache-is-authoritative?) cache)
 317       (match (cache-lookup cache name)
 318         (#f #f)
 319         ((#(_ versions modules symbols _ _ _ _ _ _) ...)
 320          (fold (lambda (version* module symbol result)
 321                  (if (or (not version)
 322                          (version-prefix? version version*))
 323                      (cons (module-ref (resolve-interface module)
 324                                        symbol)
 325                            result)
 326                      result))
 327                '()
 328                versions modules symbols)))
 329       (find-packages-by-name/direct name version)))
 330
 331 (define* (find-package-locations name #:optional version)
 332   "Return a list of version/location pairs corresponding to each package
 333 matching NAME and VERSION."
 334   (define cache
 335     (load-package-cache (current-profile)))
 336
 337   (if (and cache (cache-is-authoritative?))
 338       (match (cache-lookup cache name)
 339         (#f '())
 340         ((#(name versions modules symbols outputs
 341                  supported? deprecated?
 342                  files lines columns) ...)
 343          (fold (lambda (version* file line column result)
 344                  (if (and file
 345                           (or (not version)
 346                               (version-prefix? version version*)))
 347                      (alist-cons version* (location file line column)
 348                                  result)
 349                      result))
 350                '()
 351                versions files lines columns)))
 352       (map (lambda (package)
 353              (cons (package-version package) (package-location package)))
 354            (find-packages-by-name/direct name version))))
 355
 356 (define (find-best-packages-by-name name version)
 357   "If version is #f, return the list of packages named NAME with the highest
 358 version numbers; otherwise, return the list of packages named NAME and at
 359 VERSION."
 360   (if version
 361       (find-packages-by-name name version)
 362       (match (find-packages-by-name name)
 363         (()
 364          '())
 365         ((matches ...)
 366          ;; Return the subset of MATCHES with the higher version number.
 367          (let ((highest (package-version (first matches))))
 368            (take-while (lambda (p)
 369                          (string=? (package-version p) highest))
 370                        matches))))))
 371
 372 ;; Prevent Guile 3 from inlining this procedure so we can mock it in tests.
 373 (set! find-best-packages-by-name find-best-packages-by-name)
 374
 375 (define (generate-package-cache directory)
 376   "Generate under DIRECTORY a cache of all the available packages.
 377
 378 The primary purpose of the cache is to speed up package lookup by name such
 379 that we don't have to traverse and load all the package modules, thereby also
 380 reducing the memory footprint."
 381   (define cache-file
 382     (string-append directory %package-cache-file))
 383
 384   (define expand-cache
 385     (match-lambda*
 386       (((module symbol variable) (result . seen))
 387        (let ((package (variable-ref variable)))
 388          (if (or (vhash-assq package seen)
 389                  (hidden-package? package))
 390              (cons result seen)
 391              (cons (cons `#(,(package-name package)
 392                             ,(package-version package)
 393                             ,(module-name module)
 394                             ,symbol
 395                             ,(package-outputs package)
 396                             ,(->bool (supported-package? package))
 397                             ,(->bool (package-superseded package))
 398                             ,@(let ((loc (package-location package)))
 399                                 (if loc
 400                                     `(,(location-file loc)
 401                                       ,(location-line loc)
 402                                       ,(location-column loc))
 403                                     '(#f #f #f))))
 404                          result)
 405                    (vhash-consq package #t seen)))))))
 406
 407   (define entry-key
 408     (match-lambda
 409       ((module symbol variable)
 410        (let ((value (variable-ref variable)))
 411          (string-append (package-name value) (package-version value)
 412                         (object->string module)
 413                         (symbol->string symbol))))))
 414
 415   (define (entry<? a b)
 416     (string<? (entry-key a) (entry-key b)))
 417
 418   (define variables
 419     ;; First sort variables so that 'expand-cache' later dismisses
 420     ;; already-seen package objects in a deterministic fashion.
 421     (sort
 422      (fold-module-public-variables* (lambda (module symbol variable lst)
 423                                       (let ((value (false-if-exception
 424                                                     (variable-ref variable))))
 425                                         (if (package? value)
 426                                             (cons (list module symbol variable)
 427                                                   lst)
 428                                             lst)))
 429                                     '()
 430                                     (all-modules (%package-module-path)
 431                                                  #:warn
 432                                                  warn-about-load-error))
 433      entry<?))
 434
 435   (define exp
 436     (first (fold expand-cache (cons '() vlist-null) variables)))
 437
 438   (mkdir-p (dirname cache-file))
 439   (call-with-output-file cache-file
 440     (lambda (port)
 441       ;; Store the cache as a '.go' file.  This makes loading fast and reduces
 442       ;; heap usage since some of the static data is directly mmapped.
 443       (put-bytevector port
 444                       (compile `'(,@exp)
 445                                #:to 'bytecode
 446                                #:opts '(#:to-file? #t)))))
 447   cache-file)
 448
 449 \f
 450 (define %sigint-prompt
 451   ;; The prompt to jump to upon SIGINT.
 452   (make-prompt-tag "interruptible"))
 453
 454 (define (call-with-sigint-handler thunk handler)
 455   "Call THUNK and return its value.  Upon SIGINT, call HANDLER with the signal
 456 number in the context of the continuation of the call to this function, and
 457 return its return value."
 458   (call-with-prompt %sigint-prompt
 459                     (lambda ()
 460                       (sigaction SIGINT
 461                         (lambda (signum)
 462                           (sigaction SIGINT SIG_DFL)
 463                           (abort-to-prompt %sigint-prompt signum)))
 464                       (dynamic-wind
 465                         (const #t)
 466                         thunk
 467                         (cut sigaction SIGINT SIG_DFL)))
 468                     (lambda (k signum)
 469                       (handler signum))))
 470
 471 \f
 472 ;;;
 473 ;;; Package specification.
 474 ;;;
 475
 476 (define* (%find-package spec name version)
 477   (match (find-best-packages-by-name name version)
 478     ((pkg . pkg*)
 479      (unless (null? pkg*)
 480        (warning (G_ "ambiguous package specification `~a'~%") spec)
 481        (warning (G_ "choosing ~a@~a from ~a~%")
 482                 (package-name pkg) (package-version pkg)
 483                 (location->string (package-location pkg))))
 484      (match (package-superseded pkg)
 485        ((? package? new)
 486         (info (G_ "package '~a' has been superseded by '~a'~%")
 487               (package-name pkg) (package-name new))
 488         new)
 489        (#f
 490         pkg)))
 491     (x
 492      (if version
 493          (leave (G_ "~A: package not found for version ~a~%") name version)
 494          (leave (G_ "~A: unknown package~%") name)))))
 495
 496 (define (specification->package spec)
 497   "Return a package matching SPEC.  SPEC may be a package name, or a package
 498 name followed by an at-sign and a version number.  If the version number is not
 499 present, return the preferred newest version."
 500   (let-values (((name version) (package-name->name+version spec)))
 501     (%find-package spec name version)))
 502
 503 (define (specification->location spec)
 504   "Return the location of the highest-numbered package matching SPEC, a
 505 specification such as \"guile@2\" or \"emacs\"."
 506   (let-values (((name version) (package-name->name+version spec)))
 507     (match (find-package-locations name version)
 508       (()
 509        (if version
 510            (leave (G_ "~A: package not found for version ~a~%") name version)
 511            (leave (G_ "~A: unknown package~%") name)))
 512       (lst
 513        (let* ((highest   (match lst (((version . _) _ ...) version)))
 514               (locations (take-while (match-lambda
 515                                        ((version . location)
 516                                         (string=? version highest)))
 517                                      lst)))
 518          (match locations
 519            (((version . location) . rest)
 520             (unless (null? rest)
 521               (warning (G_ "ambiguous package specification `~a'~%") spec)
 522               (warning (G_ "choosing ~a@~a from ~a~%")
 523                        name version
 524                        (location->string location)))
 525             location)))))))
 526
 527 (define* (specification->package+output spec #:optional (output "out"))
 528   "Return the package and output specified by SPEC, or #f and #f; SPEC may
 529 optionally contain a version number and an output name, as in these examples:
 530
 531   guile
 532   guile@2.0.9
 533   guile:debug
 534   guile@2.0.9:debug
 535
 536 If SPEC does not specify a version number, return the preferred newest
 537 version; if SPEC does not specify an output, return OUTPUT.
 538
 539 When OUTPUT is false and SPEC does not specify any output, return #f as the
 540 output."
 541   (let-values (((name version sub-drv)
 542                 (package-specification->name+version+output spec output)))
 543     (match (%find-package spec name version)
 544       (#f
 545        (values #f #f))
 546       (package
 547        (if (or (and (not output) (not sub-drv))
 548                (member sub-drv (package-outputs package)))
 549            (values package sub-drv)
 550            (leave (G_ "package `~a' lacks output `~a'~%")
 551                   (package-full-name package)
 552                   sub-drv))))))
 553
 554 (define (specifications->manifest specs)
 555   "Given SPECS, a list of specifications such as \"emacs@25.2\" or
 556 \"guile:debug\", return a profile manifest."
 557   ;; This procedure exists mostly so users of 'guix package -m' don't have to
 558   ;; fiddle with multiple-value returns.
 559   (packages->manifest
 560    (map (compose list specification->package+output) specs)))