configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28 GUIX_CHANNEL_METADATA
  29
  30 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = "xyes"])
  31
  32 AC_ARG_WITH(store-dir,
  33   AS_HELP_STRING([--with-store-dir=PATH],
  34     [file name of the store (defaults to /gnu/store)]),
  35   [storedir="$withval"],
  36   [storedir="/gnu/store"])
  37 AC_SUBST(storedir)
  38
  39 AC_ARG_WITH([bash-completion-dir],
  40   AS_HELP_STRING([--with-bash-completion-dir=DIR],
  41     [name of the Bash completion directory]),
  42   [bashcompletiondir="$withval"],
  43   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  44 AC_SUBST([bashcompletiondir])
  45
  46 AC_ARG_WITH([zsh-completion-dir],
  47   AS_HELP_STRING([--with-zsh-completion-dir=DIR],
  48     [name of the Zsh completion directory]),
  49   [zshcompletiondir="$withval"],
  50   [zshcompletiondir='${datadir}/zsh/site-functions'])
  51 AC_SUBST([zshcompletiondir])
  52
  53 AC_ARG_WITH([fish-completion-dir],
  54   AS_HELP_STRING([--with-fish-completion-dir=DIR],
  55     [name of the Fish completion directory]),
  56   [fishcompletiondir="$withval"],
  57   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  58 AC_SUBST([fishcompletiondir])
  59
  60 AC_ARG_WITH([selinux-policy-dir],
  61   AS_HELP_STRING([--with-selinux-policy-dir=DIR],
  62     [name of the SELinux policy directory]),
  63   [selinux_policydir="$withval"],
  64   [selinux_policydir='${datadir}/selinux/'])
  65 AC_SUBST([selinux_policydir])
  66
  67 dnl Better be verbose.
  68 AC_MSG_CHECKING([for the store directory])
  69 AC_MSG_RESULT([$storedir])
  70
  71 AC_ARG_ENABLE([daemon],
  72   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  73   [guix_build_daemon="$enableval"],
  74   [guix_build_daemon="yes"])
  75
  76 # Prepare a version of $localstatedir & co. that does not contain references
  77 # to shell variables.
  78 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  79 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  80 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  81 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  82 AC_SUBST([guix_localstatedir])
  83 AC_SUBST([guix_sysconfdir])
  84 AC_SUBST([guix_sbindir])
  85
  86 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  87 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  88
  89 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  90 dnl Make sure they are available.
  91 m4_pattern_forbid([PKG_CHECK_MODULES])
  92 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  93 m4_pattern_forbid([^GUILE_P])
  94 m4_pattern_allow([^GUILE_PKG_ERRORS])
  95 m4_pattern_forbid([^GUIX_])
  96
  97 dnl Search for 'guile' and 'guild'.  This macro defines
  98 dnl 'GUILE_EFFECTIVE_VERSION'.
  99 GUILE_PKG([3.0 2.2])
 100 GUILE_PROGS
 101 if test "x$GUILD" = "x"; then
 102    AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
 103 fi
 104
 105 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.2"; then
 106   PKG_CHECK_MODULES([GUILE], [guile-2.2 >= 2.2.6])
 107 fi
 108
 109 dnl Get CFLAGS and LDFLAGS for libguile.
 110 GUILE_FLAGS
 111
 112 dnl Installation directories for .scm and .go files.
 113 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 114 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 115 AC_SUBST([guilemoduledir])
 116 AC_SUBST([guileobjectdir])
 117
 118 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 119 dnl pull', among other things.
 120 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 121 if test "x$have_gnutls" != "xyes"; then
 122   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 123 fi
 124
 125 dnl Check for Guile-Git.
 126 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 127 if test "x$have_guile_git" != "xyes"; then
 128   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 129 fi
 130
 131 dnl Check for Guile-JSON.
 132 GUIX_CHECK_GUILE_JSON
 133 if test "x$guix_cv_have_recent_guile_json" != "xyes"; then
 134   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 135 fi
 136
 137 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 138 GUIX_CHECK_GUILE_SQLITE3
 139 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 140   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 141 fi
 142
 143 GUIX_CHECK_GUILE_GCRYPT
 144 if test "x$guix_cv_have_recent_guile_gcrypt" != "xyes"; then
 145   AC_MSG_ERROR([A recent Guile-Gcrypt could not be found; please install it.])
 146 fi
 147
 148 GUIX_CHECK_GUILE_GIT
 149 if test "x$guix_cv_have_recent_guile_git" != "xyes"; then
 150   AC_MSG_ERROR([A recent Guile-Git could not be found; please install it.])
 151 fi
 152
 153 dnl Check for Guile-zlib.
 154 GUIX_CHECK_GUILE_ZLIB
 155 if test "x$guix_cv_have_recent_guile_zlib" != "xyes"; then
 156   AC_MSG_ERROR([A recent Guile-zlib could not be found; please install it.])
 157 fi
 158
 159 dnl Check for Guile-lzlib.
 160 GUILE_MODULE_AVAILABLE([have_guile_lzlib], [(lzlib)])
 161 if test "x$have_guile_lzlib" != "xyes"; then
 162   AC_MSG_ERROR([Guile-lzlib is missing; please install it.])
 163 fi
 164
 165 dnl Check for Guile-Avahi.
 166 GUILE_MODULE_AVAILABLE([have_guile_avahi], [(avahi)])
 167 AM_CONDITIONAL([HAVE_GUILE_AVAHI],
 168   [test "x$have_guile_avahi" = "xyes"])
 169
 170 dnl Guile-newt is used by the graphical installer.
 171 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
 172
 173 AC_ARG_ENABLE([installer],
 174     AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
 175
 176 AS_IF([test "x$enable_installer" = "xyes"], [
 177 if test "x$have_guile_newt" != "xyes"; then
 178   AC_MSG_ERROR([Guile-newt could not be found; please install it.])
 179 fi
 180 ])
 181
 182 AM_CONDITIONAL([ENABLE_INSTALLER],
 183   [test "x$enable_installer" = "xyes"])
 184
 185 dnl Make sure we have a full-fledged Guile.
 186 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 187
 188 AC_PROG_SED
 189
 190 dnl Decompressors, for use by the substituter and other modules.
 191 AC_PATH_PROG([GZIP], [gzip])
 192 AC_PATH_PROG([BZIP2], [bzip2])
 193 AC_PATH_PROG([XZ], [xz])
 194 AC_SUBST([GZIP])
 195 AC_SUBST([BZIP2])
 196 AC_SUBST([XZ])
 197
 198 LIBGCRYPT_LIBDIR="no"
 199 LIBGCRYPT_PREFIX="no"
 200
 201 AC_ARG_WITH([libgcrypt-prefix],
 202   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 203   [case "$withval" in
 204     yes|no)
 205       ;;
 206     *)
 207       LIBGCRYPT_PREFIX="$withval"
 208       LIBGCRYPT_LIBDIR="$withval/lib"
 209       ;;
 210    esac])
 211
 212 AC_ARG_WITH([libgcrypt-libdir],
 213   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 214      [search for GNU libgcrypt's shared library in DIR])],
 215   [case "$withval" in
 216     yes|no)
 217       LIBGCRYPT_LIBDIR="no"
 218       ;;
 219     *)
 220       LIBGCRYPT_LIBDIR="$withval"
 221       ;;
 222    esac])
 223
 224 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 225 dnl the library directory.
 226 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 227   xnono)
 228     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 229     ;;
 230 esac
 231
 232 AC_SUBST([LIBGCRYPT_PREFIX])
 233 AC_SUBST([LIBGCRYPT_LIBDIR])
 234
 235 dnl Check for Guile-SSH, for the (guix ssh) module.
 236 GUIX_CHECK_GUILE_SSH
 237 AM_CONDITIONAL([HAVE_GUILE_SSH],
 238   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 239
 240 AC_CACHE_SAVE
 241
 242 m4_include([config-daemon.ac])
 243
 244 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 245 dnl See `Building from Git' in the manual for more info.
 246 AM_MISSING_PROG([DOT], [dot])
 247
 248 dnl Manual pages.
 249 AM_MISSING_PROG([HELP2MAN], [help2man])
 250
 251 dnl Documentation translation.
 252 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 253 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 254
 255 case "$storedir" in
 256   /gnu/store)
 257     ;;
 258   *)
 259     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 260     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 261     ;;
 262 esac
 263
 264 AC_CONFIG_FILES([Makefile
 265                  po/guix/Makefile.in
 266                  po/packages/Makefile.in
 267                  etc/guix-daemon.cil
 268                  guix/config.scm])
 269
 270 AC_CONFIG_FILES([etc/committer.scm], [chmod +x etc/committer.scm])
 271 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 272 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 273   [chmod +x pre-inst-env])
 274
 275 AC_OUTPUT