gnu/system/shadow.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Alex Griffin <a@ajgrf.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu system shadow)
  21   #:use-module (guix records)
  22   #:use-module (guix gexp)
  23   #:use-module (guix store)
  24   #:use-module (guix modules)
  25   #:use-module (guix sets)
  26   #:use-module (guix ui)
  27   #:use-module (gnu services)
  28   #:use-module (gnu services shepherd)
  29   #:use-module ((gnu system file-systems)
  30                 #:select (%tty-gid))
  31   #:use-module ((gnu packages admin)
  32                 #:select (shadow))
  33   #:use-module (gnu packages bash)
  34   #:use-module (gnu packages guile-wm)
  35   #:use-module (srfi srfi-1)
  36   #:use-module (srfi srfi-26)
  37   #:use-module (srfi srfi-34)
  38   #:use-module (srfi srfi-35)
  39   #:export (user-account
  40             user-account?
  41             user-account-name
  42             user-account-password
  43             user-account-uid
  44             user-account-group
  45             user-account-supplementary-groups
  46             user-account-comment
  47             user-account-home-directory
  48             user-account-create-home-directory?
  49             user-account-shell
  50             user-account-system?
  51
  52             user-group
  53             user-group?
  54             user-group-name
  55             user-group-password
  56             user-group-id
  57             user-group-system?
  58
  59             default-skeletons
  60             skeleton-directory
  61             %base-groups
  62             %base-user-accounts
  63
  64             account-service-type
  65             account-service))
  66
  67 ;;; Commentary:
  68 ;;;
  69 ;;; Utilities for configuring the Shadow tool suite ('login', 'passwd', etc.)
  70 ;;;
  71 ;;; Code:
  72
  73 (define-record-type* <user-account>
  74   user-account make-user-account
  75   user-account?
  76   (name           user-account-name)
  77   (password       user-account-password (default #f))
  78   (uid            user-account-uid (default #f))
  79   (group          user-account-group)             ; number | string
  80   (supplementary-groups user-account-supplementary-groups
  81                         (default '()))            ; list of strings
  82   (comment        user-account-comment (default ""))
  83   (home-directory user-account-home-directory)
  84   (create-home-directory? user-account-create-home-directory? ;Boolean
  85                           (default #t))
  86   (shell          user-account-shell              ; gexp
  87                   (default (file-append bash "/bin/bash")))
  88   (system?        user-account-system?            ; Boolean
  89                   (default #f)))
  90
  91 (define-record-type* <user-group>
  92   user-group make-user-group
  93   user-group?
  94   (name           user-group-name)
  95   (password       user-group-password (default #f))
  96   (id             user-group-id (default #f))
  97   (system?        user-group-system?              ; Boolean
  98                   (default #f)))
  99
 100
 101 (define %base-groups
 102   ;; Default set of groups.
 103   (let-syntax ((system-group (syntax-rules ()
 104                                ((_ args ...)
 105                                 (user-group (system? #t) args ...)))))
 106     (list (system-group (name "root") (id 0))
 107           (system-group (name "wheel"))           ; root-like users
 108           (system-group (name "users"))           ; normal users
 109           (system-group (name "nogroup"))         ; for daemons etc.
 110
 111           ;; The following groups are conventionally used by things like udev to
 112           ;; control access to hardware devices.
 113           (system-group (name "tty") (id %tty-gid))
 114           (system-group (name "dialout"))
 115           (system-group (name "kmem"))
 116           (system-group (name "input"))           ; input devices, from udev
 117           (system-group (name "video"))
 118           (system-group (name "audio"))
 119           (system-group (name "netdev"))          ; used in avahi-dbus.conf
 120           (system-group (name "lp"))
 121           (system-group (name "disk"))
 122           (system-group (name "floppy"))
 123           (system-group (name "cdrom"))
 124           (system-group (name "tape"))
 125           (system-group (name "kvm")))))          ; for /dev/kvm
 126
 127 (define %base-user-accounts
 128   ;; List of standard user accounts.  Note that "root" is a special case, so
 129   ;; it's not listed here.
 130   (list (user-account
 131          (name "nobody")
 132          (uid 65534)
 133          (group "nogroup")
 134          (shell (file-append shadow "/sbin/nologin"))
 135          (home-directory "/nonexistent")
 136          (create-home-directory? #f)
 137          (system? #t))))
 138
 139 (define (default-skeletons)
 140   "Return the default skeleton files for /etc/skel.  These files are copied by
 141 'useradd' in the home directory of newly created user accounts."
 142   (define copy-guile-wm
 143     (with-imported-modules '((guix build utils))
 144       #~(begin
 145           (use-modules (guix build utils))
 146           (copy-file (car (find-files #+guile-wm "wm-init-sample.scm"))
 147                      #$output))))
 148
 149   (let ((profile (plain-file "bash_profile" "\
 150 # Honor per-interactive-shell startup file
 151 if [ -f ~/.bashrc ]; then . ~/.bashrc; fi\n"))
 152         (bashrc  (plain-file "bashrc" "\
 153 # Bash initialization for interactive non-login shells and
 154 # for remote shells (info \"(bash) Bash Startup Files\").
 155
 156 # Export 'SHELL' to child processes.  Programs such as 'screen'
 157 # honor it and otherwise use /bin/sh.
 158 export SHELL
 159
 160 if [[ $- != *i* ]]
 161 then
 162     # We are being invoked from a non-interactive shell.  If this
 163     # is an SSH session (as in \"ssh host command\"), source
 164     # /etc/profile so we get PATH and other essential variables.
 165     [[ -n \"$SSH_CLIENT\" ]] && source /etc/profile
 166
 167     # Don't do anything else.
 168     return
 169 fi
 170
 171 # Adjust the prompt depending on whether we're in 'guix environment'.
 172 if [ -n \"$GUIX_ENVIRONMENT\" ]
 173 then
 174     PS1='\\u@\\h \\w [env]\\$ '
 175 else
 176     PS1='\\u@\\h \\w\\$ '
 177 fi
 178 alias ls='ls -p --color'
 179 alias ll='ls -l'
 180 alias grep='grep --color'\n"))
 181         (zlogin    (plain-file "zlogin" "\
 182 # Honor system-wide environment variables
 183 source /etc/profile\n"))
 184         (guile-wm  (computed-file "guile-wm" copy-guile-wm))
 185         (xdefaults (plain-file "Xdefaults" "\
 186 XTerm*utf8: always
 187 XTerm*metaSendsEscape: true\n"))
 188         (gdbinit   (plain-file "gdbinit" "\
 189 # Tell GDB where to look for separate debugging files.
 190 set debug-file-directory ~/.guix-profile/lib/debug
 191
 192 # Authorize extensions found in the store, such as the
 193 # pretty-printers of libstdc++.
 194 set auto-load safe-path /gnu/store/*/lib\n")))
 195     `((".bash_profile" ,profile)
 196       (".bashrc" ,bashrc)
 197       (".zlogin" ,zlogin)
 198       (".Xdefaults" ,xdefaults)
 199       (".guile" ,(plain-file "dot-guile"
 200                              "(cond ((false-if-exception (resolve-interface '(ice-9 readline)))
 201        =>
 202        (lambda (module)
 203          ;; Enable completion and input history at the REPL.
 204          ((module-ref module 'activate-readline))))
 205       (else
 206        (display \"Consider installing the 'guile-readline' package for
 207 convenient interactive line editing and input history.\\n\\n\")))\n"))
 208       (".guile-wm" ,guile-wm)
 209       (".gdbinit" ,gdbinit))))
 210
 211 (define (skeleton-directory skeletons)
 212   "Return a directory containing SKELETONS, a list of name/derivation tuples."
 213   (computed-file "skel"
 214                  (with-imported-modules '((guix build utils))
 215                    #~(begin
 216                        (use-modules (ice-9 match)
 217                                     (guix build utils))
 218
 219                        (mkdir #$output)
 220                        (chdir #$output)
 221
 222                        ;; Note: copy the skeletons instead of symlinking
 223                        ;; them like 'file-union' does, because 'useradd'
 224                        ;; would just copy the symlinks as is.
 225                        (for-each (match-lambda
 226                                    ((target source)
 227                                     (copy-recursively source target)))
 228                                  '#$skeletons)
 229                        #t))))
 230
 231 (define (assert-valid-users/groups users groups)
 232   "Raise an error if USERS refer to groups not listed in GROUPS."
 233   (let ((groups (list->set (map user-group-name groups))))
 234     (define (validate-supplementary-group user group)
 235       (unless (set-contains? groups group)
 236         (raise (condition
 237                 (&message
 238                  (message
 239                   (format #f (G_ "supplementary group '~a' \
 240 of user '~a' is undeclared")
 241                           group
 242                           (user-account-name user))))))))
 243
 244     (for-each (lambda (user)
 245                 (unless (set-contains? groups (user-account-group user))
 246                   (raise (condition
 247                           (&message
 248                            (message
 249                             (format #f (G_ "primary group '~a' \
 250 of user '~a' is undeclared")
 251                                     (user-account-group user)
 252                                     (user-account-name user)))))))
 253
 254                 (for-each (cut validate-supplementary-group user <>)
 255                           (user-account-supplementary-groups user)))
 256               users)))
 257
 258 \f
 259 ;;;
 260 ;;; Service.
 261 ;;;
 262
 263 (define (user-group->gexp group)
 264   "Turn GROUP, a <user-group> object, into a list-valued gexp suitable for
 265 'active-groups'."
 266   #~(list #$(user-group-name group)
 267           #$(user-group-password group)
 268           #$(user-group-id group)
 269           #$(user-group-system? group)))
 270
 271 (define (user-account->gexp account)
 272   "Turn ACCOUNT, a <user-account> object, into a list-valued gexp suitable for
 273 'activate-users'."
 274   #~`(#$(user-account-name account)
 275       #$(user-account-uid account)
 276       #$(user-account-group account)
 277       #$(user-account-supplementary-groups account)
 278       #$(user-account-comment account)
 279       #$(user-account-home-directory account)
 280       #$(user-account-create-home-directory? account)
 281       ,#$(user-account-shell account)             ; this one is a gexp
 282       #$(user-account-password account)
 283       #$(user-account-system? account)))
 284
 285 (define (account-activation accounts+groups)
 286   "Return a gexp that activates ACCOUNTS+GROUPS, a list of <user-account> and
 287 <user-group> objects.  Raise an error if a user account refers to a undefined
 288 group."
 289   (define accounts
 290     (filter user-account? accounts+groups))
 291
 292   (define user-specs
 293     (map user-account->gexp accounts))
 294
 295   (define groups
 296     (filter user-group? accounts+groups))
 297
 298   (define group-specs
 299     (map user-group->gexp groups))
 300
 301   (assert-valid-users/groups accounts groups)
 302
 303   ;; Add users and user groups.
 304   #~(begin
 305       (setenv "PATH"
 306               (string-append #$(@ (gnu packages admin) shadow) "/sbin"))
 307       (activate-users+groups (list #$@user-specs)
 308                              (list #$@group-specs))))
 309
 310 (define (account-shepherd-service accounts+groups)
 311   "Return a Shepherd service that creates the home directories for the user
 312 accounts among ACCOUNTS+GROUPS."
 313   (define accounts
 314     (filter user-account? accounts+groups))
 315
 316   ;; Create home directories only once 'file-systems' is up.  This makes sure
 317   ;; they are created in the right place if /home lives on a separate
 318   ;; partition.
 319   ;;
 320   ;; XXX: We arrange for this service to stop right after it's done its job so
 321   ;; that 'guix system reconfigure' knows that it can reload it fearlessly
 322   ;; (and thus create new home directories).  The cost of this hack is that
 323   ;; there's a small window during which first-time logins could happen before
 324   ;; the home directory has been created.
 325   (list (shepherd-service
 326          (requirement '(file-systems))
 327          (provision '(user-homes))
 328          (modules '((gnu build activation)))
 329          (start (with-imported-modules (source-module-closure
 330                                         '((gnu build activation)))
 331                   #~(lambda ()
 332                       (activate-user-home
 333                        (list #$@(map user-account->gexp accounts)))
 334                       #f)))                       ;stop
 335          (stop #~(const #f))
 336          (respawn? #f)
 337          (documentation "Create user home directories."))))
 338
 339 (define (shells-file shells)
 340   "Return a file-like object that builds a shell list for use as /etc/shells
 341 based on SHELLS.  /etc/shells is used by xterm, polkit, and other programs."
 342   (computed-file "shells"
 343                  #~(begin
 344                      (use-modules (srfi srfi-1))
 345
 346                      (define shells
 347                        (delete-duplicates (list #$@shells)))
 348
 349                      (call-with-output-file #$output
 350                        (lambda (port)
 351                          (display "\
 352 /bin/sh
 353 /run/current-system/profile/bin/sh
 354 /run/current-system/profile/bin/bash\n" port)
 355                          (for-each (lambda (shell)
 356                                      (display shell port)
 357                                      (newline port))
 358                                    shells))))))
 359 (define (etc-files arguments)
 360   "Filter out among ARGUMENTS things corresponding to skeletons, and return
 361 the /etc/skel directory for those."
 362   (let ((skels (filter pair? arguments))
 363         (users (filter user-account? arguments)))
 364     `(("skel" ,(skeleton-directory skels))
 365       ("shells" ,(shells-file (map user-account-shell users))))))
 366
 367 (define account-service-type
 368   (service-type (name 'account)
 369
 370                 ;; Concatenate <user-account>, <user-group>, and skeleton
 371                 ;; lists.
 372                 (compose concatenate)
 373                 (extend append)
 374
 375                 (extensions
 376                  (list (service-extension activation-service-type
 377                                           account-activation)
 378                        (service-extension shepherd-root-service-type
 379                                           account-shepherd-service)
 380                        (service-extension etc-service-type
 381                                           etc-files)))))
 382
 383 (define (account-service accounts+groups skeletons)
 384   "Return a <service> that takes care of user accounts and user groups, with
 385 ACCOUNTS+GROUPS as its initial list of accounts and groups."
 386   (service account-service-type
 387            (append skeletons accounts+groups)))
 388
 389 ;;; shadow.scm ends here