guix/gnu-maintenance.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2012, 2013 Nikita Karetnikov <nikita@karetnikov.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (guix gnu-maintenance)
  21   #:use-module (web uri)
  22   #:use-module (web client)
  23   #:use-module (web response)
  24   #:use-module (ice-9 regex)
  25   #:use-module (ice-9 match)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-11)
  28   #:use-module (srfi srfi-26)
  29   #:use-module (system foreign)
  30   #:use-module (guix http-client)
  31   #:use-module (guix ftp-client)
  32   #:use-module (guix utils)
  33   #:use-module (guix combinators)
  34   #:use-module (guix records)
  35   #:use-module (guix upstream)
  36   #:use-module (guix packages)
  37   #:export (gnu-package-name
  38             gnu-package-mundane-name
  39             gnu-package-copyright-holder
  40             gnu-package-savannah
  41             gnu-package-fsd
  42             gnu-package-language
  43             gnu-package-logo
  44             gnu-package-doc-category
  45             gnu-package-doc-summary
  46             gnu-package-doc-description
  47             gnu-package-doc-urls
  48             gnu-package-download-url
  49
  50             official-gnu-packages
  51             find-package
  52             gnu-package?
  53
  54             release-file?
  55             releases
  56             latest-release
  57             gnu-release-archive-types
  58             gnu-package-name->name+version
  59
  60             %gnu-updater
  61             %gnome-updater
  62             %kde-updater
  63             %xorg-updater
  64             %kernel.org-updater))
  65
  66 ;;; Commentary:
  67 ;;;
  68 ;;; Code for dealing with the maintenance of GNU packages, such as
  69 ;;; auto-updates.
  70 ;;;
  71 ;;; Code:
  72
  73 \f
  74 ;;;
  75 ;;; List of GNU packages.
  76 ;;;
  77
  78 (define %gnumaint-base-url
  79   "http://cvs.savannah.gnu.org/viewvc/*checkout*/womb/gnumaint/")
  80
  81 (define %package-list-url
  82   (string->uri
  83    (string-append %gnumaint-base-url "gnupackages.txt")))
  84
  85 (define %package-description-url
  86   ;; This file contains package descriptions in recutils format.
  87   ;; See <https://lists.gnu.org/archive/html/guix-devel/2013-10/msg00071.html>.
  88   (string->uri
  89    (string-append %gnumaint-base-url "pkgblurbs.txt")))
  90
  91 (define-record-type* <gnu-package-descriptor>
  92   gnu-package-descriptor
  93   make-gnu-package-descriptor
  94
  95   gnu-package-descriptor?
  96
  97   (name             gnu-package-name)
  98   (mundane-name     gnu-package-mundane-name)
  99   (copyright-holder gnu-package-copyright-holder)
 100   (savannah         gnu-package-savannah)
 101   (fsd              gnu-package-fsd)
 102   (language         gnu-package-language)         ; list of strings
 103   (logo             gnu-package-logo)
 104   (doc-category     gnu-package-doc-category)
 105   (doc-summary      gnu-package-doc-summary)
 106   (doc-description  gnu-package-doc-description)  ; taken from 'pkgdescr.txt'
 107   (doc-urls         gnu-package-doc-urls)         ; list of strings
 108   (download-url     gnu-package-download-url))
 109
 110 (define* (official-gnu-packages
 111           #:optional (fetch http-fetch/cached))
 112   "Return a list of records, which are GNU packages.  Use FETCH,
 113 to fetch the list of GNU packages over HTTP."
 114   (define (read-records port)
 115     ;; Return a list of alists.  Each alist contains fields of a GNU
 116     ;; package.
 117     (let loop ((alist  (recutils->alist port))
 118                (result '()))
 119       (if (null? alist)
 120           (reverse result)
 121           (loop (recutils->alist port)
 122                 (cons alist result)))))
 123
 124   (define official-description
 125     (let ((db (read-records (fetch %package-description-url #:text? #t))))
 126       (lambda (name)
 127         ;; Return the description found upstream for package NAME, or #f.
 128         (and=> (find (lambda (alist)
 129                        (equal? name (assoc-ref alist "package")))
 130                      db)
 131                (lambda (record)
 132                  (let ((field (assoc-ref record "blurb")))
 133                    ;; The upstream description file uses "redirect PACKAGE" as
 134                    ;; a blurb in cases where the description of the two
 135                    ;; packages should be considered the same (e.g., GTK+ has
 136                    ;; "redirect gnome".)  This is usually not acceptable for
 137                    ;; us because we prefer to have distinct descriptions in
 138                    ;; such cases.  Thus, ignore the 'blurb' field when that
 139                    ;; happens.
 140                    (and field
 141                         (not (string-prefix? "redirect " field))
 142                         field)))))))
 143
 144   (map (lambda (alist)
 145          (let ((name (assoc-ref alist "package")))
 146            (alist->record `(("description" . ,(official-description name))
 147                             ,@alist)
 148                           make-gnu-package-descriptor
 149                           (list "package" "mundane-name" "copyright-holder"
 150                                 "savannah" "fsd" "language" "logo"
 151                                 "doc-category" "doc-summary" "description"
 152                                 "doc-url"
 153                                 "download-url")
 154                           '("doc-url" "language"))))
 155        (let* ((port (fetch %package-list-url #:text? #t))
 156               (lst  (read-records port)))
 157          (close-port port)
 158          lst)))
 159
 160 (define (find-package name)
 161   "Find GNU package called NAME and return it.  Return #f if it was not
 162 found."
 163   (find (lambda (package)
 164           (string=? name (gnu-package-name package)))
 165         (official-gnu-packages)))
 166
 167 (define gnu-package?
 168   (memoize
 169    (let ((official-gnu-packages (memoize official-gnu-packages)))
 170      (lambda (package)
 171        "Return true if PACKAGE is a GNU package.  This procedure may access the
 172 network to check in GNU's database."
 173        (define (mirror-type url)
 174          (let ((uri (string->uri url)))
 175            (and (eq? (uri-scheme uri) 'mirror)
 176                 (cond
 177                  ((member (uri-host uri)
 178                           '("gnu" "gnupg" "gcc" "gnome"))
 179                   ;; Definitely GNU.
 180                   'gnu)
 181                  ((equal? (uri-host uri) "cran")
 182                   ;; Possibly GNU: mirror://cran could be either GNU R itself
 183                   ;; or a non-GNU package.
 184                   #f)
 185                  (else
 186                   ;; Definitely non-GNU.
 187                   'non-gnu)))))
 188
 189        (define (gnu-home-page? package)
 190          (and=> (package-home-page package)
 191                 (lambda (url)
 192                   (and=> (uri-host (string->uri url))
 193                          (lambda (host)
 194                            (member host '("www.gnu.org" "gnu.org")))))))
 195
 196        (or (gnu-home-page? package)
 197            (let ((url  (and=> (package-source package) origin-uri))
 198                  (name (package-name package)))
 199              (case (and (string? url) (mirror-type url))
 200                ((gnu) #t)
 201                ((non-gnu) #f)
 202                (else
 203                 (and (member name (map gnu-package-name (official-gnu-packages)))
 204                      #t)))))))))
 205
 206 \f
 207 ;;;
 208 ;;; Latest release.
 209 ;;;
 210
 211 (define (ftp-server/directory package)
 212   "Return the FTP server and directory where PACKAGE's tarball are stored."
 213   (values (or (assoc-ref (package-properties package) 'ftp-server)
 214               "ftp.gnu.org")
 215           (or (assoc-ref (package-properties package) 'ftp-directory)
 216               (string-append "/gnu/" (package-name package)))))
 217
 218 (define (sans-extension tarball)
 219   "Return TARBALL without its .tar.* or .zip extension."
 220   (let ((end (or (string-contains tarball ".tar")
 221                  (string-contains tarball ".zip"))))
 222     (substring tarball 0 end)))
 223
 224 (define %tarball-rx
 225   ;; The .zip extensions is notably used for freefont-ttf.
 226   ;; The "-src" pattern is for "TeXmacs-1.0.7.9-src.tar.gz".
 227   ;; The "-gnu[0-9]" pattern is for "icecat-38.4.0-gnu1.tar.bz2".
 228   (make-regexp "^([^.]+)-([0-9]|[^-])+(-(src|gnu[0-9]))?\\.(tar\\.|zip$)"))
 229
 230 (define %alpha-tarball-rx
 231   (make-regexp "^.*-.*[0-9](-|~)?(alpha|beta|rc|cvs|svn|git)-?[0-9\\.]*\\.tar\\."))
 232
 233 (define (release-file? project file)
 234   "Return #f if FILE is not a release tarball of PROJECT, otherwise return
 235 true."
 236   (and (not (string-suffix? ".sig" file))
 237        (and=> (regexp-exec %tarball-rx file)
 238               (lambda (match)
 239                 ;; Filter out unrelated files, like `guile-www-1.1.1'.
 240                 ;; Case-insensitive for things like "TeXmacs" vs. "texmacs".
 241                 ;; The "-src" suffix is for "freefont-src-20120503.tar.gz".
 242                 (and=> (match:substring match 1)
 243                        (lambda (name)
 244                          (or (string-ci=? name project)
 245                              (string-ci=? name
 246                                           (string-append project
 247                                                          "-src")))))))
 248        (not (regexp-exec %alpha-tarball-rx file))
 249        (let ((s (sans-extension file)))
 250          (regexp-exec %package-name-rx s))))
 251
 252 (define (tarball->version tarball)
 253   "Return the version TARBALL corresponds to.  TARBALL is a file name like
 254 \"coreutils-8.23.tar.xz\"."
 255   (let-values (((name version)
 256                 (gnu-package-name->name+version (sans-extension tarball))))
 257     version))
 258
 259 (define* (releases project
 260                    #:key
 261                    (server "ftp.gnu.org")
 262                    (directory (string-append "/gnu/" project)))
 263   "Return the list of <upstream-release> of PROJECT as a list of release
 264 name/directory pairs."
 265   ;; TODO: Parse something like fencepost.gnu.org:/gd/gnuorg/packages-ftp.
 266   (define conn (ftp-open server))
 267
 268   (let loop ((directories (list directory))
 269              (result      '()))
 270     (match directories
 271       (()
 272        (ftp-close conn)
 273        (coalesce-sources result))
 274       ((directory rest ...)
 275        (let* ((files   (ftp-list conn directory))
 276               (subdirs (filter-map (match-lambda
 277                                      ((name 'directory . _) name)
 278                                      (_ #f))
 279                                    files)))
 280          (define (file->url file)
 281            (string-append "ftp://" server directory "/" file))
 282
 283          (define (file->source file)
 284            (let ((url (file->url file)))
 285              (upstream-source
 286               (package project)
 287               (version (tarball->version file))
 288               (urls (list url))
 289               (signature-urls (list (string-append url ".sig"))))))
 290
 291          (loop (append (map (cut string-append directory "/" <>)
 292                             subdirs)
 293                        rest)
 294                (append
 295                 ;; Filter out signatures, deltas, and files which
 296                 ;; are potentially not releases of PROJECT--e.g.,
 297                 ;; in /gnu/guile, filter out guile-oops and
 298                 ;; guile-www; in mit-scheme, filter out binaries.
 299                 (filter-map (match-lambda
 300                               ((file 'file . _)
 301                                (and (release-file? project file)
 302                                     (file->source file)))
 303                               (_ #f))
 304                             files)
 305                 result)))))))
 306
 307 (define* (latest-ftp-release project
 308                              #:key
 309                              (server "ftp.gnu.org")
 310                              (directory (string-append "/gnu/" project))
 311                              (keep-file? (const #t))
 312                              (file->signature (cut string-append <> ".sig"))
 313                              (ftp-open ftp-open) (ftp-close ftp-close))
 314   "Return an <upstream-source> for the latest release of PROJECT on SERVER
 315 under DIRECTORY, or #f.  Use FTP-OPEN and FTP-CLOSE to open (resp. close) FTP
 316 connections; this can be useful to reuse connections.
 317
 318 KEEP-FILE? is a predicate to decide whether to enter a directory and to
 319 consider a given file (source tarball) as a valid candidate based on its name.
 320
 321 FILE->SIGNATURE must be a procedure; it is passed a source file URL and must
 322 return the corresponding signature URL, or #f it signatures are unavailable."
 323   (define (latest a b)
 324     (if (version>? a b) a b))
 325
 326   (define (latest-release a b)
 327     (if (version>? (upstream-source-version a) (upstream-source-version b))
 328         a b))
 329
 330   (define contains-digit?
 331     (cut string-any char-set:digit <>))
 332
 333   (define patch-directory-name?
 334     ;; Return #t for patch directory names such as 'bash-4.2-patches'.
 335     (cut string-suffix? "patches" <>))
 336
 337   (define conn (ftp-open server))
 338
 339   (define (file->url directory file)
 340     (string-append "ftp://" server directory "/" file))
 341
 342   (define (file->source directory file)
 343     (let ((url (file->url directory file)))
 344       (upstream-source
 345        (package project)
 346        (version (tarball->version file))
 347        (urls (list url))
 348        (signature-urls (match (file->signature url)
 349                          (#f #f)
 350                          (sig (list sig)))))))
 351
 352   (let loop ((directory directory)
 353              (result    #f))
 354     (let* ((entries (ftp-list conn directory))
 355
 356            ;; Filter out sub-directories that do not contain digits---e.g.,
 357            ;; /gnuzilla/lang and /gnupg/patches.  Filter out "w32"
 358            ;; directories as found on ftp.gnutls.org.
 359            (subdirs (filter-map (match-lambda
 360                                   (((? patch-directory-name? dir)
 361                                     'directory . _)
 362                                    #f)
 363                                   (("w32" 'directory . _)
 364                                    #f)
 365                                   (((? contains-digit? dir) 'directory . _)
 366                                    (and (keep-file? dir) dir))
 367                                   (_ #f))
 368                                 entries))
 369
 370            ;; Whether or not SUBDIRS is empty, compute the latest releases
 371            ;; for the current directory.  This is necessary for packages
 372            ;; such as 'sharutils' that have a sub-directory that contains
 373            ;; only an older release.
 374            (releases (filter-map (match-lambda
 375                                    ((file 'file . _)
 376                                     (and (release-file? project file)
 377                                          (keep-file? file)
 378                                          (file->source directory file)))
 379                                    (_ #f))
 380                                  entries)))
 381
 382       ;; Assume that SUBDIRS correspond to versions, and jump into the
 383       ;; one with the highest version number.
 384       (let* ((release  (reduce latest-release #f
 385                                (coalesce-sources releases)))
 386              (result   (if (and result release)
 387                            (latest-release release result)
 388                            (or release result)))
 389              (target   (reduce latest #f subdirs)))
 390         (if target
 391             (loop (string-append directory "/" target)
 392                   result)
 393             (begin
 394               (ftp-close conn)
 395               result))))))
 396
 397 (define* (latest-release package
 398                          #:key
 399                          (server "ftp.gnu.org")
 400                          (directory (string-append "/gnu/" package)))
 401   "Return the <upstream-source> for the latest version of PACKAGE or #f.
 402 PACKAGE must be the canonical name of a GNU package."
 403   (latest-ftp-release package
 404                       #:server server
 405                       #:directory directory))
 406
 407 (define-syntax-rule (false-if-ftp-error exp)
 408   "Return #f if an FTP error is raise while evaluating EXP; return the result
 409 of EXP otherwise."
 410   (catch 'ftp-error
 411     (lambda ()
 412       exp)
 413     (lambda (key port . rest)
 414       (if (ftp-connection? port)
 415           (ftp-close port)
 416           (close-port port))
 417       #f)))
 418
 419 (define (latest-release* package)
 420   "Like 'latest-release', but (1) take a <package> object, and (2) ignore FTP
 421 errors that might occur when PACKAGE is not actually a GNU package, or not
 422 hosted on ftp.gnu.org, or not under that name (this is the case for
 423 \"emacs-auctex\", for instance.)"
 424   (let-values (((server directory)
 425                 (ftp-server/directory package)))
 426     (let ((name (or (assoc-ref (package-properties package) 'upstream-name)
 427                     (package-name package))))
 428       (false-if-ftp-error (latest-release name
 429                                           #:server server
 430                                           #:directory directory)))))
 431
 432 (define %package-name-rx
 433   ;; Regexp for a package name, e.g., "foo-X.Y".  Since TeXmacs uses
 434   ;; "TeXmacs-X.Y-src", the `-src' suffix is allowed.
 435   (make-regexp "^(.*)-(([0-9]|\\.)+)(-src)?"))
 436
 437 (define (gnu-package-name->name+version name+version)
 438   "Return the package name and version number extracted from NAME+VERSION."
 439   (let ((match (regexp-exec %package-name-rx name+version)))
 440     (if (not match)
 441         (values name+version #f)
 442         (values (match:substring match 1) (match:substring match 2)))))
 443
 444 (define (pure-gnu-package? package)
 445   "Return true if PACKAGE is a non-Emacs and non-GNOME GNU package.  This
 446 excludes AucTeX, for instance, whose releases are now uploaded to
 447 elpa.gnu.org, and all the GNOME packages."
 448   (and (not (string-prefix? "emacs-" (package-name package)))
 449        (not (gnome-package? package))
 450        (gnu-package? package)))
 451
 452 (define (url-prefix-predicate prefix)
 453   "Return a predicate that returns true when passed a package where one of its
 454 source URLs starts with PREFIX."
 455   (lambda (package)
 456     (define matching-uri?
 457       (match-lambda
 458         ((? string? uri)
 459          (string-prefix? prefix uri))
 460         (_
 461          #f)))
 462
 463     (match (package-source package)
 464       ((? origin? origin)
 465        (match (origin-uri origin)
 466          ((? matching-uri?) #t)
 467          (_                 #f)))
 468       (_ #f))))
 469
 470 (define gnome-package?
 471   (url-prefix-predicate "mirror://gnome/"))
 472
 473 (define (latest-gnome-release package)
 474   "Return the latest release of PACKAGE, the name of a GNOME package."
 475   (define %not-dot
 476     (char-set-complement (char-set #\.)))
 477
 478   (define (even-minor-version? version)
 479     (match (string-tokenize version %not-dot)
 480       (((= string->number major) (= string->number minor) . rest)
 481        (and minor (even? minor)))
 482       (_
 483        #t)))                                      ;cross fingers
 484
 485   (define (even-numbered? file)
 486     ;; Return true if FILE somehow denotes an even-numbered file name.  The
 487     ;; trick here is that we want this to match both directories such as
 488     ;; "3.18.6" and actual file names such as "gtk+-3.18.6.tar.bz2".
 489     (let-values (((name version) (package-name->name+version file)))
 490       (even-minor-version? (or version name))))
 491
 492   (define upstream-name
 493     ;; Some packages like "NetworkManager" have camel-case names.
 494     (or (assoc-ref (package-properties package) 'upstream-name)
 495         (package-name package)))
 496
 497   (false-if-ftp-error
 498    (latest-ftp-release upstream-name
 499                        #:server "ftp.gnome.org"
 500                        #:directory (string-append "/pub/gnome/sources/"
 501                                                   upstream-name)
 502
 503
 504                        ;; <https://www.gnome.org/gnome-3/source/> explains
 505                        ;; that odd minor version numbers represent development
 506                        ;; releases, which we are usually not interested in.
 507                        #:keep-file? even-numbered?
 508
 509                        ;; ftp.gnome.org provides no signatures, only
 510                        ;; checksums.
 511                        #:file->signature (const #f))))
 512
 513
 514 (define (latest-kde-release package)
 515   "Return the latest release of PACKAGE, the name of an KDE.org package."
 516   (let ((uri (string->uri (origin-uri (package-source package)))))
 517     (false-if-ftp-error
 518      (latest-ftp-release
 519       (or (assoc-ref (package-properties package) 'upstream-name)
 520           (package-name package))
 521       #:server "mirrors.mit.edu"
 522       #:directory
 523       (string-append "/kde" (dirname (dirname (uri-path uri))))
 524       #:file->signature (const #f)))))
 525
 526 (define (latest-xorg-release package)
 527   "Return the latest release of PACKAGE, the name of an X.org package."
 528   (let ((uri (string->uri (origin-uri (package-source package)))))
 529     (false-if-ftp-error
 530      (latest-ftp-release
 531       (package-name package)
 532       #:server "ftp.freedesktop.org"
 533       #:directory
 534       (string-append "/pub/xorg/" (dirname (uri-path uri)))))))
 535
 536 (define (latest-kernel.org-release package)
 537   "Return the latest release of PACKAGE, the name of a kernel.org package."
 538   (let ((uri (string->uri (origin-uri (package-source package)))))
 539     (false-if-ftp-error
 540      (latest-ftp-release
 541       (package-name package)
 542       #:server "ftp.free.fr"                      ;a mirror reachable over FTP
 543       #:directory (string-append "/mirrors/ftp.kernel.org"
 544                                  (dirname (uri-path uri)))
 545
 546       ;; kernel.org provides "foo-x.y.tar.sign" files, which are signatures of
 547       ;; the uncompressed tarball.
 548       #:file->signature (lambda (tarball)
 549                           (string-append (file-sans-extension tarball)
 550                                          ".sign"))))))
 551
 552 (define %gnu-updater
 553   (upstream-updater
 554    (name 'gnu)
 555    (description "Updater for GNU packages")
 556    (pred pure-gnu-package?)
 557    (latest latest-release*)))
 558
 559 (define %gnome-updater
 560   (upstream-updater
 561    (name 'gnome)
 562    (description "Updater for GNOME packages")
 563    (pred gnome-package?)
 564    (latest latest-gnome-release)))
 565
 566 (define %kde-updater
 567   (upstream-updater
 568     (name 'kde)
 569     (description "Updater for KDE packages")
 570     (pred (url-prefix-predicate "mirror://kde/"))
 571     (latest latest-kde-release)))
 572
 573 (define %xorg-updater
 574   (upstream-updater
 575    (name 'xorg)
 576    (description "Updater for X.org packages")
 577    (pred (url-prefix-predicate "mirror://xorg/"))
 578    (latest latest-xorg-release)))
 579
 580 (define %kernel.org-updater
 581   (upstream-updater
 582    (name 'kernel.org)
 583    (description "Updater for packages hosted on kernel.org")
 584    (pred (url-prefix-predicate "mirror://kernel.org/"))
 585    (latest latest-kernel.org-release)))
 586
 587 ;;; gnu-maintenance.scm ends here