gnu/packages/autotools.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012 Nikita Karetnikov <nikita@karetnikov.org>
   3 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2015 Mathieu Lirzin <mthl@openmailbox.org>
   5 ;;; Copyright © 2014 Manolis Fragkiskos Ragkousis <manolis837@gmail.com>
   6 ;;; Copyright © 2015, 2017, 2018 Mark H Weaver <mhw@netris.org>
   7 ;;; Copyright © 2016 David Thompson <davet@gnu.org>
   8 ;;; Copyright © 2017 ng0 <ng0@n0.is>
   9 ;;; Copyright © 2017, 2019 Efraim Flashner <efraim@flashner.co.il>
  10 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  11 ;;; Copyright © 2018 Ricardo Wurmus <rekado@elephly.net>
  12 ;;; Copyright © 2019 Pierre-Moana Levesque <pierre.moana.levesque@gmail.com>
  13 ;;;
  14 ;;; This file is part of GNU Guix.
  15 ;;;
  16 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  17 ;;; under the terms of the GNU General Public License as published by
  18 ;;; the Free Software Foundation; either version 3 of the License, or (at
  19 ;;; your option) any later version.
  20 ;;;
  21 ;;; GNU Guix is distributed in the hope that it will be useful, but
  22 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;;; GNU General Public License for more details.
  25 ;;;
  26 ;;; You should have received a copy of the GNU General Public License
  27 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 (define-module (gnu packages autotools)
  30   #:use-module (guix licenses)
  31   #:use-module (gnu packages)
  32   #:use-module (gnu packages perl)
  33   #:use-module (gnu packages python)
  34   #:use-module (gnu packages m4)
  35   #:use-module (gnu packages man)
  36   #:use-module (gnu packages bash)
  37   #:use-module (guix utils)
  38   #:use-module (guix packages)
  39   #:use-module (guix download)
  40   #:use-module (guix build-system gnu)
  41   #:use-module (guix build-system trivial)
  42   #:use-module (ice-9 match)
  43   #:export (autoconf-wrapper))
  44
  45 (define-public autoconf
  46   (package
  47     (name "autoconf")
  48     (version "2.69")
  49     (source
  50      (origin
  51       (method url-fetch)
  52       (uri (string-append "mirror://gnu/autoconf/autoconf-"
  53                           version ".tar.xz"))
  54       (sha256
  55        (base32
  56         "113nlmidxy9kjr45kg9x3ngar4951mvag1js2a3j8nxcz34wxsv4"))))
  57     (build-system gnu-build-system)
  58     (native-inputs
  59      `(("perl" ,perl)
  60        ("m4" ,m4)))
  61     ;; XXX: testsuite: 209 and 279 failed. The latter is an impurity. It
  62     ;; should use our own "cpp" instead of "/lib/cpp".
  63     (arguments `(#:tests? #f))
  64     (home-page "https://www.gnu.org/software/autoconf/")
  65     (synopsis "Create source code configuration scripts")
  66     (description
  67      "Autoconf offers the developer a robust set of M4 macros which expand
  68 into shell code to test the features of Unix-like systems and to adapt
  69 automatically their software package to these systems.  The resulting shell
  70 scripts are self-contained and portable, freeing the user from needing to
  71 know anything about Autoconf or M4.")
  72     (license gpl3+))) ; some files are under GPLv2+
  73
  74 (define-public autoconf-2.68
  75   (package (inherit autoconf)
  76     (version "2.68")
  77     (source
  78      (origin
  79       (method url-fetch)
  80       (uri (string-append "mirror://gnu/autoconf/autoconf-"
  81                           version ".tar.xz"))
  82       (sha256
  83        (base32
  84         "1fjm21k2na07f3vasf288a0zx66lbv0hd3l9bvv3q8p62s3pg569"))))))
  85
  86 (define-public autoconf-2.64
  87   ;; As of GDB 7.8, GDB is still developed using this version of Autoconf.
  88   (package (inherit autoconf)
  89     (version "2.64")
  90     (source
  91      (origin
  92       (method url-fetch)
  93       (uri (string-append "mirror://gnu/autoconf/autoconf-"
  94                           version ".tar.xz"))
  95       (sha256
  96        (base32
  97         "0j3jdjpf5ly39dlp0bg70h72nzqr059k0x8iqxvaxf106chpgn9j"))))))
  98
  99 (define-public autoconf-2.13
 100   ;; GNU IceCat 52.x requires autoconf-2.13 to build!
 101   (package (inherit autoconf)
 102     (version "2.13")
 103     (source
 104      (origin
 105       (method url-fetch)
 106       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 107                           version ".tar.gz"))
 108       (sha256
 109        (base32
 110         "07krzl4czczdsgzrrw9fiqx35xcf32naf751khg821g5pqv12qgh"))))
 111     (arguments
 112      `(#:tests? #f
 113        #:phases
 114        ;; The 'configure' script in autoconf-2.13 can't cope with "SHELL=" and
 115        ;; "CONFIG_SHELL=" arguments, so we set them as environment variables
 116        ;; and pass a simplified set of arguments.
 117        (modify-phases %standard-phases
 118          (replace 'configure
 119            (lambda* (#:key build inputs outputs #:allow-other-keys)
 120              (let ((bash (which "bash"))
 121                    (out  (assoc-ref outputs "out")))
 122                (setenv "CONFIG_SHELL" bash)
 123                (setenv "SHELL" bash)
 124                (invoke bash "./configure"
 125                        (string-append "--prefix=" out)
 126                        (string-append "--build=" build))))))))))
 127
 128
 129 (define (make-autoconf-wrapper autoconf)
 130   "Return a wrapper around AUTOCONF that generates `configure' scripts that
 131 use our own Bash instead of /bin/sh in shebangs.  For that reason, it should
 132 only be used internally---users should not end up distributing `configure'
 133 files with a system-specific shebang."
 134   (package (inherit autoconf)
 135     (name (string-append (package-name autoconf) "-wrapper"))
 136     (build-system trivial-build-system)
 137     (inputs `(("guile"
 138                ;; XXX: Kludge to hide the circular dependency.
 139                ,(module-ref (resolve-interface '(gnu packages guile))
 140                             'guile-2.0))
 141               ("autoconf" ,autoconf)
 142               ("bash" ,bash)))
 143     (arguments
 144      '(#:modules ((guix build utils))
 145        #:builder
 146        (begin
 147          (use-modules (guix build utils))
 148          (let* ((out      (assoc-ref %outputs "out"))
 149                 (bin      (string-append out "/bin"))
 150                 (autoconf (string-append
 151                            (assoc-ref %build-inputs "autoconf")
 152                            "/bin/autoconf"))
 153                 (guile    (string-append
 154                            (assoc-ref %build-inputs "guile")
 155                            "/bin/guile"))
 156                 (sh       (string-append
 157                            (assoc-ref %build-inputs "bash")
 158                            "/bin/sh"))
 159                 (modules  ((compose dirname dirname dirname)
 160                            (search-path %load-path
 161                                         "guix/build/utils.scm"))))
 162            (mkdir-p bin)
 163
 164            ;; Symlink all the binaries but `autoconf'.
 165            (with-directory-excursion bin
 166              (for-each (lambda (file)
 167                          (unless (string=? (basename file) "autoconf")
 168                            (symlink file (basename file))))
 169                        (find-files (dirname autoconf) ".*")))
 170
 171            ;; Add an `autoconf' binary that wraps the real one.
 172            (call-with-output-file (string-append bin "/autoconf")
 173              (lambda (port)
 174                ;; Shamefully, Guile can be used in shebangs only if a
 175                ;; single argument is passed (-ds); otherwise it gets
 176                ;; them all as a single argument and fails to parse them.
 177                (format port "#!~a
 178 export GUILE_LOAD_PATH=\"~a\"
 179 export GUILE_LOAD_COMPILED_PATH=\"~a\"
 180 exec ~a --no-auto-compile \"$0\" \"$@\"
 181 !#~%"
 182                        sh modules modules guile)
 183                (write
 184                 `(begin
 185                    (use-modules (guix build utils))
 186                    (let ((result (apply system* ,autoconf
 187                                         (cdr (command-line)))))
 188                      (when (and (file-exists? "configure")
 189                                 (not (file-exists? "/bin/sh")))
 190                        ;; Patch regardless of RESULT, because `autoconf
 191                        ;; -Werror' can both create a `configure' file and
 192                        ;; return a non-zero exit code.
 193                        (patch-shebang "configure"))
 194                      (exit (status:exit-val result))))
 195                 port)))
 196            (chmod (string-append bin "/autoconf") #o555)
 197            #t))))
 198
 199     ;; Do not show it in the UI since it's meant for internal use.
 200     (properties '((hidden? . #t)))))
 201
 202 (define-public autoconf-wrapper
 203   (make-autoconf-wrapper autoconf))
 204
 205 (define-public autoconf-archive
 206   (package
 207     (name "autoconf-archive")
 208     (version "2019.01.06")
 209     (source
 210      (origin
 211       (method url-fetch)
 212       (uri (string-append "mirror://gnu/autoconf-archive/autoconf-archive-"
 213                           version ".tar.xz"))
 214       (sha256
 215        (base32
 216         "0gqya7nf4j5k98dkky0c3bnr0paciya91vkqazg7knlq621mq68p"))))
 217     (build-system gnu-build-system)
 218     (home-page "https://www.gnu.org/software/autoconf-archive/")
 219     (synopsis "Collection of freely reusable Autoconf macros")
 220     (description
 221      "Autoconf Archive is a collection of over 450 new macros for Autoconf,
 222 greatly expanding the domain of its functionality.  These macros have been
 223 contributed as free software by the community.")
 224     (license gpl3+)))
 225
 226 (define-public autobuild
 227   (package
 228     (name "autobuild")
 229     (version "5.3")
 230     (source (origin
 231               (method url-fetch)
 232               (uri (string-append "mirror://savannah/autobuild/autobuild-"
 233                                   version ".tar.gz"))
 234               (sha256
 235                (base32
 236                 "0gv7g61ja9q9zg1m30k4snqwwy1kq7b4df6sb7d2qra7kbdq8af1"))))
 237     (build-system gnu-build-system)
 238     (inputs `(("perl" ,perl)))
 239     (synopsis "Process generated build logs")
 240     (description "Autobuild is a package that processes build logs generated
 241 when building software.  Autobuild is primarily focused on packages using
 242 Autoconf and Automake, but can be used with other build systems too.
 243 Autobuild generates an HTML summary file, containing links to each build log.
 244 The summary includes project name, version, build hostname, host type (cross
 245 compile aware), date of build, and indication of success or failure.  The
 246 output is indexed in many ways to simplify browsing.")
 247     (home-page "https://josefsson.org/autobuild/")
 248     (license gpl3+)))
 249
 250 (define-public automake
 251   (package
 252     (name "automake")
 253     (version "1.16.2")
 254     (source (origin
 255              (method url-fetch)
 256              (uri (string-append "mirror://gnu/automake/automake-"
 257                                  version ".tar.xz"))
 258              (sha256
 259               (base32
 260                 "1l7dkqbsmbf94ax29jj1jf6a0r6ikc8jybg1p5m0c3ki7pg5ki6c"))
 261              (patches
 262               (search-patches "automake-skip-amhello-tests.patch"))))
 263     (build-system gnu-build-system)
 264     (native-inputs
 265      `(("autoconf" ,autoconf-wrapper)
 266        ("perl" ,perl)))
 267     (native-search-paths
 268      (list (search-path-specification
 269             (variable "ACLOCAL_PATH")
 270             (files '("share/aclocal")))))
 271     (arguments
 272      '(#:modules ((guix build gnu-build-system)
 273                   (guix build utils)
 274                   (srfi srfi-1)
 275                   (srfi srfi-26)
 276                   (rnrs io ports))
 277        #:phases
 278        (modify-phases %standard-phases
 279          (add-before 'patch-source-shebangs 'patch-tests-shebangs
 280            (lambda _
 281              (let ((sh (which "sh")))
 282                (substitute* (find-files "t" "\\.(sh|tap)$")
 283                  (("#![[:blank:]]?/bin/sh")
 284                   (string-append "#!" sh)))
 285
 286                ;; Set these variables for all the `configure' runs
 287                ;; that occur during the test suite.
 288                (setenv "SHELL" sh)
 289                (setenv "CONFIG_SHELL" sh)
 290                #t)))
 291
 292            (add-before 'check 'skip-test
 293              (lambda _
 294                ;; This test requires 'etags' and fails if it's missing.
 295                ;; Skip it.
 296                (substitute* "t/tags-lisp-space.sh"
 297                  (("^required.*" all)
 298                   (string-append "exit 77\n" all "\n")))
 299                #t))
 300
 301          ;; Files like `install-sh', `mdate.sh', etc. must use
 302          ;; #!/bin/sh, otherwise users could leak erroneous shebangs
 303          ;; in the wild.  See <http://bugs.gnu.org/14201> for an
 304          ;; example.
 305          (add-after 'install 'unpatch-shebangs
 306            (lambda* (#:key outputs #:allow-other-keys)
 307              (let* ((out (assoc-ref outputs "out"))
 308                     (dir (string-append out "/share")))
 309                (define (starts-with-shebang? file)
 310                  (equal? (call-with-input-file file
 311                            (lambda (p)
 312                              (list (get-u8 p) (get-u8 p))))
 313                          (map char->integer '(#\# #\!))))
 314
 315                (for-each (lambda (file)
 316                            (when (and (starts-with-shebang? file)
 317                                       (executable-file? file))
 318                              (format #t "restoring shebang on `~a'~%"
 319                                      file)
 320                              (substitute* file
 321                                (("^#!.*/bin/sh")
 322                                 "#!/bin/sh")
 323                                (("^#!.*/bin/env(.*)$" _ args)
 324                                 (string-append "#!/usr/bin/env"
 325                                                args)))))
 326                          (find-files dir ".*"))
 327                #t))))))
 328     (home-page "https://www.gnu.org/software/automake/")
 329     (synopsis "Making GNU standards-compliant Makefiles")
 330     (description
 331      "Automake the part of the GNU build system for producing
 332 standards-compliant Makefiles.  Build requirements are entered in an
 333 intuitive format and then Automake works with Autoconf to produce a robust
 334 Makefile, simplifying the entire process for the developer.")
 335     (license gpl2+)))                      ; some files are under GPLv3+
 336
 337 (define-public libtool
 338   (package
 339     (name "libtool")
 340     (version "2.4.6")
 341     (source (origin
 342               (method url-fetch)
 343               (uri (string-append "mirror://gnu/libtool/libtool-"
 344                                   version ".tar.xz"))
 345               (sha256
 346                (base32
 347                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))
 348               (patches (search-patches "libtool-skip-tests2.patch"))))
 349     (build-system gnu-build-system)
 350     (propagated-inputs `(("m4" ,m4)))
 351     (native-inputs `(("m4" ,m4)
 352                      ("perl" ,perl)
 353                      ;; XXX: this shouldn't be necessary, but without it test
 354                      ;; 102 fails because it cannot find ltdl/libltdl.la.
 355                      ("libltdl" ,libltdl)
 356                      ("help2man" ,help2man) ;because we modify ltmain.sh
 357                      ("automake" ,automake)      ;some tests rely on 'aclocal'
 358                      ("autoconf" ,autoconf-wrapper))) ;others on 'autom4te'
 359
 360     (arguments
 361      `(;; Libltdl is provided as a separate package, so don't install it here.
 362        #:configure-flags '("--disable-ltdl-install")
 363
 364        ;; XXX: There are test failures on mips64el-linux starting from 2.4.4:
 365        ;; <http://hydra.gnu.org/build/181662>.
 366        ;; Also, do not run tests when cross compiling
 367        #:tests? ,(not (or (%current-target-system)
 368                           (string-prefix? "mips64"
 369                                           (%current-system))))
 370
 371        #:phases
 372        (modify-phases %standard-phases
 373          (add-before 'check 'pre-check
 374            (lambda* (#:key inputs native-inputs #:allow-other-keys)
 375              ;; Run the test suite in parallel, if possible.
 376              (setenv "TESTSUITEFLAGS"
 377                      (string-append
 378                       "-j"
 379                       (number->string (parallel-job-count))))
 380            ;; Patch references to /bin/sh.
 381            (let ((bash (assoc-ref (or native-inputs inputs) "bash")))
 382              (substitute* "tests/testsuite"
 383                (("/bin/sh")
 384                 (string-append bash "/bin/sh")))
 385              #t)))
 386          (add-after 'patch-source-shebangs 'restore-ltmain-shebang
 387            (lambda* (#:key inputs #:allow-other-keys)
 388              (substitute* "build-aux/ltmain.in"
 389                (("^#!.*/bin/sh$") "#!/bin/sh"))
 390              #t)))))
 391
 392     (synopsis "Generic shared library support tools")
 393     (description
 394      "GNU Libtool helps in the creation and use of shared libraries, by
 395 presenting a single consistent, portable interface that hides the usual
 396 complexity of working with shared libraries across platforms.")
 397     (license gpl3+)
 398     (home-page "https://www.gnu.org/software/libtool/")))
 399
 400 (define-public libltdl
 401   ;; This is a libltdl package separate from the libtool package.  This is
 402   ;; useful because, unlike libtool, it has zero extra dependencies (making it
 403   ;; readily usable during bootstrap), and it builds very quickly since
 404   ;; Libtool's extensive test suite isn't run.
 405   (package
 406     (name "libltdl")
 407     (version "2.4.6")
 408     (source (origin
 409               (method url-fetch)
 410               (uri (string-append "mirror://gnu/libtool/libtool-"
 411                                   version ".tar.xz"))
 412               (sha256
 413                (base32
 414                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))))
 415     (build-system gnu-build-system)
 416     (arguments
 417      '(#:configure-flags '("--enable-ltdl-install") ;really install it
 418        #:phases (modify-phases %standard-phases
 419                   (add-before 'configure 'change-directory
 420                     (lambda _ (chdir "libltdl") #t)))))
 421
 422     (synopsis "System-independent dlopen wrapper of GNU libtool")
 423     (description (package-description libtool))
 424     (home-page (package-home-page libtool))
 425     (license lgpl2.1+)))
 426
 427 (define-public pyconfigure
 428   (package
 429     (name "pyconfigure")
 430     (version "0.2.3")
 431     (source (origin
 432               (method url-fetch)
 433               (uri (string-append "mirror://gnu/pyconfigure/pyconfigure-"
 434                                   version ".tar.gz"))
 435               (sha256
 436                (base32
 437                 "0kxi9bg7l6ric39vbz9ykz4a21xlihhh2zcc3297db8amvhqwhrp"))))
 438     (build-system gnu-build-system)
 439     (arguments
 440      `(#:phases
 441        (modify-phases %standard-phases
 442          (add-before 'configure 'patch-python
 443            (lambda _
 444              (substitute* "pyconf.in"
 445                (("/usr/bin/env python") (which "python3")))
 446              #t)))))
 447     (inputs
 448      `(("python" ,python-3)))
 449     (synopsis "@command{configure} interface for Python-based packages")
 450     (description
 451      "GNU pyconfigure provides template files for easily implementing
 452 standards-compliant configure scripts and Makefiles for Python-based packages.
 453 It is designed to work alongside existing Python setup scripts, making it easy
 454 to integrate into existing projects.  Powerful and flexible Autoconf macros
 455 are available, allowing you to easily make adjustments to the installation
 456 procedure based on the capabilities of the target computer.")
 457     (home-page "https://www.gnu.org/software/pyconfigure/manual/")
 458     (license
 459      (fsf-free
 460       "https://www.gnu.org/prep/maintain/html_node/License-Notices-for-Other-Files.html"))))