configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P$])
  91
  92 dnl Search for 'guile' and 'guild'.  This macro defines
  93 dnl 'GUILE_EFFECTIVE_VERSION'.
  94 GUILE_PKG([2.2 2.0])
  95 GUILE_PROGS
  96 if test "x$GUILD" = "x"; then
  97    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  98 fi
  99
 100 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
 101   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
 102 fi
 103
 104 dnl Installation directories for .scm and .go files.
 105 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 106 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 107 AC_SUBST([guilemoduledir])
 108 AC_SUBST([guileobjectdir])
 109
 110 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 111 dnl pull', among other things.
 112 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 113 if test "x$have_gnutls" != "xyes"; then
 114   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 115 fi
 116
 117 dnl Check for Guile-Git.
 118 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 119 if test "x$have_guile_git" != "xyes"; then
 120   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 121 fi
 122
 123 dnl Guile-JSON is used in various places.
 124 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 125 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 126
 127 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 128 GUIX_CHECK_GUILE_SQLITE3
 129 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 130   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 131 fi
 132
 133 GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
 134 if test "x$have_guile_gcrypt" != "xyes"; then
 135   AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
 136 fi
 137
 138 dnl Make sure we have a full-fledged Guile.
 139 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 140
 141 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 142 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 143 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 144
 145 AC_PROG_SED
 146
 147 dnl Decompressors, for use by the substituter and other modules.
 148 AC_PATH_PROG([GZIP], [gzip])
 149 AC_PATH_PROG([BZIP2], [bzip2])
 150 AC_PATH_PROG([XZ], [xz])
 151 AC_SUBST([GZIP])
 152 AC_SUBST([BZIP2])
 153 AC_SUBST([XZ])
 154
 155 AC_ARG_WITH([nix-prefix],
 156   [AS_HELP_STRING([--with-nix-prefix=DIR],
 157     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 158   [case "$withval" in
 159     yes|no) ;;
 160     *)
 161       NIX_PREFIX="$withval"
 162       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 163       AC_SUBST([NIX_PREFIX])
 164       ;;
 165    esac],
 166   [])
 167
 168 AC_PATH_PROG([NIX_HASH], [nix-hash])
 169 if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
 170    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 171 fi
 172
 173 AC_ARG_WITH([nixpkgs],
 174   [AS_HELP_STRING([--with-nixpkgs=DIR],
 175     [search for Nixpkgs in DIR (for testing purposes only)])],
 176   [case "$withval" in
 177     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 178     *)      NIXPKGS="$withval";;
 179    esac],
 180   [])
 181
 182 AC_MSG_CHECKING([for Nixpkgs source tree])
 183 if test -f "$NIXPKGS/default.nix"; then
 184    AC_MSG_RESULT([$NIXPKGS])
 185    AC_SUBST([NIXPKGS])
 186 else
 187    AC_MSG_RESULT([not found])
 188 fi
 189
 190 LIBGCRYPT="libgcrypt"
 191 LIBGCRYPT_LIBDIR="no"
 192 LIBGCRYPT_PREFIX="no"
 193
 194 AC_ARG_WITH([libgcrypt-prefix],
 195   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 196   [case "$withval" in
 197     yes|no)
 198       ;;
 199     *)
 200       LIBGCRYPT="$withval/lib/libgcrypt"
 201       LIBGCRYPT_PREFIX="$withval"
 202       LIBGCRYPT_LIBDIR="$withval/lib"
 203       ;;
 204    esac])
 205
 206 AC_ARG_WITH([libgcrypt-libdir],
 207   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 208      [search for GNU libgcrypt's shared library in DIR])],
 209   [case "$withval" in
 210     yes|no)
 211       LIBGCRYPT="libgcrypt"
 212       LIBGCRYPT_LIBDIR="no"
 213       ;;
 214     *)
 215       LIBGCRYPT="$withval/libgcrypt"
 216       LIBGCRYPT_LIBDIR="$withval"
 217       ;;
 218    esac])
 219
 220 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 221 dnl the library directory.
 222 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 223   xnono)
 224     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 225     ;;
 226 esac
 227
 228 dnl Library name suitable for `dynamic-link'.
 229 AC_MSG_CHECKING([for libgcrypt shared library name])
 230 AC_MSG_RESULT([$LIBGCRYPT])
 231 AC_SUBST([LIBGCRYPT])
 232 AC_SUBST([LIBGCRYPT_PREFIX])
 233 AC_SUBST([LIBGCRYPT_LIBDIR])
 234
 235 GUIX_ASSERT_LIBGCRYPT_USABLE
 236
 237 dnl Library name of zlib suitable for 'dynamic-link'.
 238 GUIX_LIBZ_LIBDIR([libz_libdir])
 239 if test "x$libz_libdir" = "x"; then
 240   LIBZ="libz"
 241 else
 242   LIBZ="$libz_libdir/libz"
 243 fi
 244 AC_MSG_CHECKING([for zlib's shared library name])
 245 AC_MSG_RESULT([$LIBZ])
 246 AC_SUBST([LIBZ])
 247
 248 dnl Check for Guile-SSH, for the (guix ssh) module.
 249 GUIX_CHECK_GUILE_SSH
 250 AM_CONDITIONAL([HAVE_GUILE_SSH],
 251   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 252
 253 AC_CACHE_SAVE
 254
 255 m4_include([config-daemon.ac])
 256
 257 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 258 dnl See `Building from Git' in the manual for more info.
 259 AM_MISSING_PROG([DOT], [dot])
 260
 261 dnl Manual pages.
 262 AM_MISSING_PROG([HELP2MAN], [help2man])
 263
 264 dnl Documentation translation.
 265 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 266 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 267
 268 dnl Emacs (optional), for 'etc/indent-package.el'.
 269 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 270 AC_SUBST([EMACS])
 271
 272 case "$storedir" in
 273   /gnu/store)
 274     ;;
 275   *)
 276     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 277     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 278     ;;
 279 esac
 280
 281 AC_CONFIG_FILES([Makefile
 282                  po/guix/Makefile.in
 283                  po/packages/Makefile.in
 284                  etc/guix-daemon.cil
 285                  guix/config.scm])
 286
 287 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 288 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 289   [chmod +x pre-inst-env])
 290 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 291
 292 AC_OUTPUT