2 # Process this file with autoconf to produce a configure script.
6 [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
7 [bug-guix@gnu.org], [guix],
8 [https://www.gnu.org/software/guix/])
9 AC_CONFIG_AUX_DIR([build-aux])
11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
12 color-tests parallel-tests -Woverride -Wno-portability])
14 # Enable silent rules by default.
15 AM_SILENT_RULES([yes])
17 AC_CONFIG_SRCDIR([guix.scm])
18 AC_CONFIG_MACRO_DIR([m4])
20 dnl For the C++ code. This must be used early.
21 AC_USE_SYSTEM_EXTENSIONS
23 AM_GNU_GETTEXT([external])
24 AM_GNU_GETTEXT_VERSION([0.18.1])
27 GUIX_ASSERT_SUPPORTED_SYSTEM
29 AC_ARG_WITH(store-dir,
30 AC_HELP_STRING([--with-store-dir=PATH],
31 [file name of the store (defaults to /gnu/store)]),
32 [storedir="$withval"],
33 [storedir="/gnu/store"])
36 AC_ARG_WITH([bash-completion-dir],
37 AC_HELP_STRING([--with-bash-completion-dir=DIR],
38 [name of the Bash completion directory]),
39 [bashcompletiondir="$withval"],
40 [bashcompletiondir='${sysconfdir}/bash_completion.d'])
41 AC_SUBST([bashcompletiondir])
43 AC_ARG_WITH([zsh-completion-dir],
44 AC_HELP_STRING([--with-zsh-completion-dir=DIR],
45 [name of the Zsh completion directory]),
46 [zshcompletiondir="$withval"],
47 [zshcompletiondir='${datadir}/zsh/site-functions'])
48 AC_SUBST([zshcompletiondir])
50 dnl Better be verbose.
51 AC_MSG_CHECKING([for the store directory])
52 AC_MSG_RESULT([$storedir])
54 AC_ARG_ENABLE([daemon],
55 [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
56 [guix_build_daemon="$enableval"],
57 [guix_build_daemon="yes"])
59 # Prepare a version of $localstatedir & co. that does not contain references
61 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
62 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
63 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
64 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
65 AC_SUBST([guix_localstatedir])
66 AC_SUBST([guix_sysconfdir])
67 AC_SUBST([guix_sbindir])
69 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
70 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
72 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
73 dnl Make sure they are available.
74 m4_pattern_forbid([PKG_CHECK_MODULES])
75 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
76 m4_pattern_forbid([^GUILE_P$])
78 dnl Search for 'guile' and 'guild'. This macro defines
79 dnl 'GUILE_EFFECTIVE_VERSION'.
82 if test "x$GUILD" = "x"; then
83 AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
86 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
87 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.9])
90 dnl Installation directories for .scm and .go files.
91 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
92 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
93 AC_SUBST([guilemoduledir])
94 AC_SUBST([guileobjectdir])
96 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
97 dnl pull', among other things.
98 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
99 if test "x$have_gnutls" != "xyes"; then
100 AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
103 dnl Check for Guile-Git.
104 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
105 if test "x$have_guile_git" != "xyes"; then
106 AC_MSG_ERROR([Guile-Git is missing; please install it.])
109 dnl Guile-JSON is used in various places.
110 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
111 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
113 dnl Make sure we have a full-fledged Guile.
114 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
116 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
117 dnl found in 2.2.1. See <https://bugs.gnu.org/29903>.
118 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
120 dnl Decompressors, for use by the substituter and other modules.
121 AC_PATH_PROG([GZIP], [gzip])
122 AC_PATH_PROG([BZIP2], [bzip2])
123 AC_PATH_PROG([XZ], [xz])
128 AC_ARG_WITH([nix-prefix],
129 [AS_HELP_STRING([--with-nix-prefix=DIR],
130 [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
134 NIX_PREFIX="$withval"
135 PATH="$NIX_PREFIX/bin:$PATH"; export PATH
136 AC_SUBST([NIX_PREFIX])
141 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
142 AC_PATH_PROG([NIX_HASH], [nix-hash])
143 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
144 AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
147 if test "x$NIX_INSTANTIATE" = "x"; then
148 # This program is an optional dependency, so we just want it to be
149 # taken from $PATH if it's not available right now.
150 NIX_INSTANTIATE="nix-instantiate"
153 AC_ARG_WITH([nixpkgs],
154 [AS_HELP_STRING([--with-nixpkgs=DIR],
155 [search for Nixpkgs in DIR (for testing purposes only)])],
157 yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
158 *) NIXPKGS="$withval";;
162 AC_MSG_CHECKING([for Nixpkgs source tree])
163 if test -f "$NIXPKGS/default.nix"; then
164 AC_MSG_RESULT([$NIXPKGS])
167 AC_MSG_RESULT([not found])
170 LIBGCRYPT="libgcrypt"
171 LIBGCRYPT_LIBDIR="no"
172 LIBGCRYPT_PREFIX="no"
174 AC_ARG_WITH([libgcrypt-prefix],
175 [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
180 LIBGCRYPT="$withval/lib/libgcrypt"
181 LIBGCRYPT_PREFIX="$withval"
182 LIBGCRYPT_LIBDIR="$withval/lib"
186 AC_ARG_WITH([libgcrypt-libdir],
187 [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
188 [search for GNU libgcrypt's shared library in DIR])],
191 LIBGCRYPT="libgcrypt"
192 LIBGCRYPT_LIBDIR="no"
195 LIBGCRYPT="$withval/libgcrypt"
196 LIBGCRYPT_LIBDIR="$withval"
200 dnl If none of the --with-libgcrypt-* options was used, try to determine the
201 dnl absolute file name of libgcrypt.so.
202 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
204 GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
205 if test "x$LIBGCRYPT_LIBDIR" != x; then
206 LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
208 dnl 'config-daemon.ac' expects "no" in this case.
209 LIBGCRYPT_LIBDIR="no"
214 dnl Library name suitable for `dynamic-link'.
215 AC_MSG_CHECKING([for libgcrypt shared library name])
216 AC_MSG_RESULT([$LIBGCRYPT])
217 AC_SUBST([LIBGCRYPT])
218 AC_SUBST([LIBGCRYPT_PREFIX])
219 AC_SUBST([LIBGCRYPT_LIBDIR])
221 GUIX_ASSERT_LIBGCRYPT_USABLE
223 dnl Library name of zlib suitable for 'dynamic-link'.
224 GUIX_LIBZ_LIBDIR([libz_libdir])
225 if test "x$libz_libdir" = "x"; then
228 LIBZ="$libz_libdir/libz"
230 AC_MSG_CHECKING([for zlib's shared library name])
231 AC_MSG_RESULT([$LIBZ])
234 dnl Check for Guile-SSH, for the (guix ssh) module.
236 AM_CONDITIONAL([HAVE_GUILE_SSH],
237 [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
241 m4_include([config-daemon.ac])
243 dnl `dot' (from the Graphviz package) is only needed for maintainers.
244 dnl See `Building from Git' in the manual for more info.
245 AM_MISSING_PROG([DOT], [dot])
248 AM_MISSING_PROG([HELP2MAN], [help2man])
250 dnl Emacs (optional), for 'etc/indent-package.el'.
251 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
258 AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
259 AC_MSG_WARN([from downloading substitutes from gnu.org.])
263 AC_CONFIG_FILES([Makefile
265 po/packages/Makefile.in
268 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
269 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
270 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
271 [chmod +x pre-inst-env])
272 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])