gnu/tests/base.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu tests base)
  21   #:use-module (gnu tests)
  22   #:use-module (gnu system)
  23   #:use-module (gnu system shadow)
  24   #:use-module (gnu system nss)
  25   #:use-module (gnu system vm)
  26   #:use-module (gnu services)
  27   #:use-module (gnu services base)
  28   #:use-module (gnu services dbus)
  29   #:use-module (gnu services avahi)
  30   #:use-module (gnu services mcron)
  31   #:use-module (gnu services shepherd)
  32   #:use-module (gnu services networking)
  33   #:use-module (gnu packages base)
  34   #:use-module (gnu packages bash)
  35   #:use-module (gnu packages imagemagick)
  36   #:use-module (gnu packages ocr)
  37   #:use-module (gnu packages package-management)
  38   #:use-module (gnu packages linux)
  39   #:use-module (gnu packages tmux)
  40   #:use-module (guix gexp)
  41   #:use-module (guix store)
  42   #:use-module (guix monads)
  43   #:use-module (guix packages)
  44   #:use-module (srfi srfi-1)
  45   #:export (run-basic-test
  46             %test-basic-os
  47             %test-halt
  48             %test-cleanup
  49             %test-mcron
  50             %test-nss-mdns))
  51
  52 (define %simple-os
  53   (simple-operating-system))
  54
  55 \f
  56 (define* (run-basic-test os command #:optional (name "basic")
  57                          #:key initialization)
  58   "Return a derivation called NAME that tests basic features of the OS started
  59 using COMMAND, a gexp that evaluates to a list of strings.  Compare some
  60 properties of running system to what's declared in OS, an <operating-system>.
  61
  62 When INITIALIZATION is true, it must be a one-argument procedure that is
  63 passed a gexp denoting the marionette, and it must return gexp that is
  64 inserted before the first test.  This is used to introduce an extra
  65 initialization step, such as entering a LUKS passphrase."
  66   (define special-files
  67     (service-value
  68      (fold-services (operating-system-services os)
  69                     #:target-type special-files-service-type)))
  70
  71   (define test
  72     (with-imported-modules '((gnu build marionette)
  73                              (guix build syscalls))
  74       #~(begin
  75           (use-modules (gnu build marionette)
  76                        (guix build syscalls)
  77                        (srfi srfi-1)
  78                        (srfi srfi-26)
  79                        (srfi srfi-64)
  80                        (ice-9 match))
  81
  82           (define marionette
  83             (make-marionette #$command))
  84
  85           (mkdir #$output)
  86           (chdir #$output)
  87
  88           (test-begin "basic")
  89
  90           #$(and initialization
  91                  (initialization #~marionette))
  92
  93           (test-assert "uname"
  94             (match (marionette-eval '(uname) marionette)
  95               (#("Linux" host-name version _ architecture)
  96                (and (string=? host-name
  97                               #$(operating-system-host-name os))
  98                     (string-prefix? #$(package-version
  99                                        (operating-system-kernel os))
 100                                     version)
 101                     (string-prefix? architecture %host-type)))))
 102
 103           (test-assert "shell and user commands"
 104             ;; Is everything in $PATH?
 105             (zero? (marionette-eval '(system "
 106 . /etc/profile
 107 set -e -x
 108 guix --version
 109 ls --version
 110 grep --version
 111 info --version")
 112                                     marionette)))
 113
 114           (test-equal "special files"
 115             '#$special-files
 116             (marionette-eval
 117              '(begin
 118                 (use-modules (ice-9 match))
 119
 120                 (map (match-lambda
 121                        ((file target)
 122                         (list file (readlink file))))
 123                      '#$special-files))
 124              marionette))
 125
 126           (test-assert "accounts"
 127             (let ((users (marionette-eval '(begin
 128                                              (use-modules (ice-9 match))
 129                                              (let loop ((result '()))
 130                                                (match (getpw)
 131                                                  (#f (reverse result))
 132                                                  (x  (loop (cons x result))))))
 133                                           marionette)))
 134               (lset= string=?
 135                      (map passwd:name users)
 136                      (list
 137                       #$@(map user-account-name
 138                               (operating-system-user-accounts os))))))
 139
 140           (test-assert "shepherd services"
 141             (let ((services (marionette-eval
 142                              '(begin
 143                                 (use-modules (gnu services herd))
 144
 145                                 (map (compose car live-service-provision)
 146                                      (current-services)))
 147                              marionette)))
 148               (lset= eq?
 149                      (pk 'services services)
 150                      '(root #$@(operating-system-shepherd-service-names os)))))
 151
 152           (test-assert "homes"
 153             (let ((homes
 154                    '#$(map user-account-home-directory
 155                            (filter user-account-create-home-directory?
 156                                    (operating-system-user-accounts os)))))
 157               (marionette-eval
 158                `(begin
 159                   (use-modules (gnu services herd) (srfi srfi-1))
 160
 161                   ;; Home directories are supposed to exist once 'user-homes'
 162                   ;; has been started.
 163                   (start-service 'user-homes)
 164
 165                   (every (lambda (home)
 166                            (and (file-exists? home)
 167                                 (file-is-directory? home)))
 168                          ',homes))
 169                marionette)))
 170
 171           (test-assert "skeletons in home directories"
 172             (let ((users+homes
 173                    '#$(filter-map (lambda (account)
 174                                     (and (user-account-create-home-directory?
 175                                           account)
 176                                          (not (user-account-system? account))
 177                                          (list (user-account-name account)
 178                                                (user-account-home-directory
 179                                                 account))))
 180                                   (operating-system-user-accounts os))))
 181               (marionette-eval
 182                `(begin
 183                   (use-modules (srfi srfi-1) (ice-9 ftw)
 184                                (ice-9 match))
 185
 186                   (every (match-lambda
 187                            ((user home)
 188                             ;; Make sure HOME has all the skeletons...
 189                             (and (null? (lset-difference string=?
 190                                                          (scandir "/etc/skel/")
 191                                                          (scandir home)))
 192
 193                                  ;; ... and that everything is user-owned.
 194                                  (let* ((pw  (getpwnam user))
 195                                         (uid (passwd:uid pw))
 196                                         (gid (passwd:gid pw))
 197                                         (st  (lstat home)))
 198                                    (define (user-owned? file)
 199                                      (= uid (stat:uid (lstat file))))
 200
 201                                    (and (= uid (stat:uid st))
 202                                         (eq? 'directory (stat:type st))
 203                                         (every user-owned?
 204                                                (find-files home
 205                                                            #:directories? #t)))))))
 206                          ',users+homes))
 207                marionette)))
 208
 209           (test-equal "permissions on /root"
 210             #o700
 211             (let ((root-home #$(any (lambda (account)
 212                                       (and (zero? (user-account-uid account))
 213                                            (user-account-home-directory
 214                                             account)))
 215                                     (operating-system-user-accounts os))))
 216               (stat:perms (marionette-eval `(stat ,root-home) marionette))))
 217
 218           (test-equal "no extra home directories"
 219             '()
 220
 221             ;; Make sure the home directories that are not supposed to be
 222             ;; created are indeed not created.
 223             (let ((nonexistent
 224                    '#$(filter-map (lambda (user)
 225                                     (and (not
 226                                           (user-account-create-home-directory?
 227                                            user))
 228                                          (user-account-home-directory user)))
 229                                   (operating-system-user-accounts os))))
 230               (marionette-eval
 231                `(begin
 232                   (use-modules (srfi srfi-1))
 233
 234                   ;; Note: Do not flag "/var/empty".
 235                   (filter file-exists?
 236                           ',(remove (cut string-prefix? "/var/" <>)
 237                                     nonexistent)))
 238                marionette)))
 239
 240           (test-equal "login on tty1"
 241             "root\n"
 242             (begin
 243               (marionette-control "sendkey ctrl-alt-f1" marionette)
 244               ;; Wait for the 'term-tty1' service to be running (using
 245               ;; 'start-service' is the simplest and most reliable way to do
 246               ;; that.)
 247               (marionette-eval
 248                '(begin
 249                   (use-modules (gnu services herd))
 250                   (start-service 'term-tty1))
 251                marionette)
 252
 253               ;; Now we can type.
 254               (marionette-type "root\n\nid -un > logged-in\n" marionette)
 255
 256               ;; It can take a while before the shell commands are executed.
 257               (marionette-eval '(use-modules (rnrs io ports)) marionette)
 258               (wait-for-file "/root/logged-in" marionette
 259                              #:read 'get-string-all)))
 260
 261           ;; There should be one utmpx entry for the user logged in on tty1.
 262           (test-equal "utmpx entry"
 263             '(("root" "tty1" #f))
 264             (marionette-eval
 265              '(begin
 266                 (use-modules (guix build syscalls)
 267                              (srfi srfi-1))
 268
 269                 (filter-map (lambda (entry)
 270                               (and (equal? (login-type USER_PROCESS)
 271                                            (utmpx-login-type entry))
 272                                    (list (utmpx-user entry) (utmpx-line entry)
 273                                          (utmpx-host entry))))
 274                             (utmpx-entries)))
 275              marionette))
 276
 277           ;; Likewise for /var/log/wtmp (used by 'last').
 278           (test-assert "wtmp entry"
 279             (match (marionette-eval
 280                     '(begin
 281                        (use-modules (guix build syscalls)
 282                                     (srfi srfi-1))
 283
 284                        (define (entry->list entry)
 285                          (list (utmpx-user entry) (utmpx-line entry)
 286                                (utmpx-host entry) (utmpx-login-type entry)))
 287
 288                        (call-with-input-file "/var/log/wtmp"
 289                          (lambda (port)
 290                            (let loop ((result '()))
 291                              (if (eof-object? (peek-char port))
 292                                  (map entry->list (reverse result))
 293                                  (loop (cons (read-utmpx port) result)))))))
 294                     marionette)
 295               (((users lines hosts types) ..1)
 296                (every (lambda (type)
 297                         (eqv? type (login-type LOGIN_PROCESS)))
 298                       types))))
 299
 300           (test-assert "host name resolution"
 301             (match (marionette-eval
 302                     '(begin
 303                        ;; Wait for nscd or our requests go through it.
 304                        (use-modules (gnu services herd))
 305                        (start-service 'nscd)
 306
 307                        (list (getaddrinfo "localhost")
 308                              (getaddrinfo #$(operating-system-host-name os))))
 309                     marionette)
 310               ((((? vector?) ..1) ((? vector?) ..1))
 311                #t)
 312               (x
 313                (pk 'failure x #f))))
 314
 315           (test-equal "host not found"
 316             #f
 317             (marionette-eval
 318              '(false-if-exception (getaddrinfo "does-not-exist"))
 319              marionette))
 320
 321           (test-equal "locale"
 322             "en_US.utf8"
 323             (marionette-eval '(let ((before (setlocale LC_ALL "en_US.utf8")))
 324                                 (setlocale LC_ALL before))
 325                              marionette))
 326
 327           (test-eq "/run/current-system is a GC root"
 328             'success!
 329             (marionette-eval '(begin
 330                                 ;; Make sure the (guix …) modules are found.
 331                                 (add-to-load-path
 332                                  #+(file-append guix "/share/guile/site/2.2"))
 333
 334                                 (use-modules (srfi srfi-34) (guix store))
 335
 336                                 (let ((system (readlink "/run/current-system")))
 337                                   (guard (c ((nix-protocol-error? c)
 338                                              (and (file-exists? system)
 339                                                   'success!)))
 340                                     (with-store store
 341                                       (delete-paths store (list system))
 342                                       #f))))
 343                              marionette))
 344
 345           ;; This symlink is currently unused, but better have it point to the
 346           ;; right place.  See
 347           ;; <https://lists.gnu.org/archive/html/guix-devel/2016-08/msg01641.html>.
 348           (test-equal "/var/guix/gcroots/profiles is a valid symlink"
 349             "/var/guix/profiles"
 350             (marionette-eval '(readlink "/var/guix/gcroots/profiles")
 351                              marionette))
 352
 353
 354           (test-assert "screendump"
 355             (begin
 356               (marionette-control (string-append "screendump " #$output
 357                                                  "/tty1.ppm")
 358                                   marionette)
 359               (file-exists? "tty1.ppm")))
 360
 361           (test-assert "screen text"
 362             (let ((text (marionette-screen-text marionette
 363                                                 #:ocrad
 364                                                 #$(file-append ocrad
 365                                                                "/bin/ocrad"))))
 366               ;; Check whether the welcome message and shell prompt are
 367               ;; displayed.  Note: OCR confuses "y" and "V" for instance, so
 368               ;; we cannot reliably match the whole text.
 369               (and (string-contains text "This is the GNU")
 370                    (string-contains text
 371                                     (string-append
 372                                      "root@"
 373                                      #$(operating-system-host-name os))))))
 374
 375           (test-end)
 376           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 377
 378   (gexp->derivation name test))
 379
 380 (define %test-basic-os
 381   (system-test
 382    (name "basic")
 383    (description
 384     "Instrument %SIMPLE-OS, run it in a VM, and run a series of basic
 385 functionality tests.")
 386    (value
 387     (let* ((os  (marionette-operating-system
 388                  %simple-os
 389                  #:imported-modules '((gnu services herd)
 390                                       (guix combinators))))
 391            (vm  (virtual-machine os)))
 392       ;; XXX: Add call to 'virtualized-operating-system' to get the exact same
 393       ;; set of services as the OS produced by
 394       ;; 'system-qemu-image/shared-store-script'.
 395       (run-basic-test (virtualized-operating-system os '())
 396                       #~(list #$vm))))))
 397
 398 \f
 399 ;;;
 400 ;;; Halt.
 401 ;;;
 402
 403 (define (run-halt-test vm)
 404   ;; As reported in <http://bugs.gnu.org/26931>, running tmux would previously
 405   ;; lead the 'stop' method of 'user-processes' to an infinite loop, with the
 406   ;; tmux server process as a zombie that remains in the list of processes.
 407   ;; This test reproduces this scenario.
 408   (define test
 409     (with-imported-modules '((gnu build marionette))
 410       #~(begin
 411           (use-modules (gnu build marionette))
 412
 413           (define marionette
 414             (make-marionette '(#$vm)))
 415
 416           (define ocrad
 417             #$(file-append ocrad "/bin/ocrad"))
 418
 419           ;; Wait for tty1 and log in.
 420           (marionette-eval '(begin
 421                               (use-modules (gnu services herd))
 422                               (start-service 'term-tty1))
 423                            marionette)
 424           (marionette-type "root\n" marionette)
 425           (wait-for-screen-text marionette
 426                                 (lambda (text)
 427                                   (string-contains text "root@komputilo"))
 428                                 #:ocrad ocrad)
 429
 430           ;; Start tmux and wait for it to be ready.
 431           (marionette-type "tmux new-session 'echo 1 > /ready; bash'\n"
 432                            marionette)
 433           (wait-for-file "/ready" marionette)
 434
 435           ;; Make sure to stop the test after a while.
 436           (sigaction SIGALRM (lambda _
 437                                (format (current-error-port)
 438                                        "FAIL: Time is up, but VM still running.\n")
 439                                (primitive-exit 1)))
 440           (alarm 10)
 441
 442           ;; Get debugging info.
 443           (marionette-eval '(current-output-port
 444                              (open-file "/dev/console" "w0"))
 445                            marionette)
 446           (marionette-eval '(system* #$(file-append procps "/bin/ps")
 447                                      "-eo" "pid,ppid,stat,comm")
 448                            marionette)
 449
 450           ;; See if 'halt' actually works.
 451           (marionette-eval '(system* "/run/current-system/profile/sbin/halt")
 452                            marionette)
 453
 454           ;; If we reach this line, that means the VM was properly stopped in
 455           ;; a timely fashion.
 456           (alarm 0)
 457           (call-with-output-file #$output
 458             (lambda (port)
 459               (display "success!" port))))))
 460
 461   (gexp->derivation "halt" test))
 462
 463 (define %test-halt
 464   (system-test
 465    (name "halt")
 466    (description
 467     "Use the 'halt' command and make sure it succeeds and does not get stuck
 468 in a loop.  See <http://bugs.gnu.org/26931>.")
 469    (value
 470     (let ((os (marionette-operating-system
 471                (operating-system
 472                  (inherit %simple-os)
 473                  (packages (cons tmux %base-packages)))
 474                #:imported-modules '((gnu services herd)
 475                                     (guix combinators)))))
 476       (run-halt-test (virtual-machine os))))))
 477
 478 \f
 479 ;;;
 480 ;;; Cleanup of /tmp, /var/run, etc.
 481 ;;;
 482
 483 (define %cleanup-os
 484   (simple-operating-system
 485    (simple-service 'dirty-things
 486                    boot-service-type
 487                    (let ((script (plain-file
 488                                   "create-utf8-file.sh"
 489                                   (string-append
 490                                    "echo $0: dirtying /tmp...\n"
 491                                    "set -e; set -x\n"
 492                                    "touch /witness\n"
 493                                    "exec touch /tmp/λαμβδα"))))
 494                      (with-imported-modules '((guix build utils))
 495                        #~(begin
 496                            (setenv "PATH"
 497                                    #$(file-append coreutils "/bin"))
 498                            (invoke #$(file-append bash "/bin/sh")
 499                                    #$script)))))))
 500
 501 (define (run-cleanup-test name)
 502   (define os
 503     (marionette-operating-system %cleanup-os
 504                                  #:imported-modules '((gnu services herd)
 505                                                       (guix combinators))))
 506   (define test
 507     (with-imported-modules '((gnu build marionette))
 508       #~(begin
 509           (use-modules (gnu build marionette)
 510                        (srfi srfi-64)
 511                        (ice-9 match))
 512
 513           (define marionette
 514             (make-marionette (list #$(virtual-machine os))))
 515
 516           (mkdir #$output)
 517           (chdir #$output)
 518
 519           (test-begin "cleanup")
 520
 521           (test-assert "dirty service worked"
 522             (marionette-eval '(file-exists? "/witness") marionette))
 523
 524           (test-equal "/tmp cleaned up"
 525             '("." "..")
 526             (marionette-eval '(begin
 527                                 (use-modules (ice-9 ftw))
 528                                 (scandir "/tmp"))
 529                              marionette))
 530
 531           (test-end)
 532           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 533
 534   (gexp->derivation "cleanup" test))
 535
 536 (define %test-cleanup
 537   ;; See <https://bugs.gnu.org/26353>.
 538   (system-test
 539    (name "cleanup")
 540    (description "Make sure the 'cleanup' service can remove files with
 541 non-ASCII names from /tmp.")
 542    (value (run-cleanup-test name))))
 543
 544 \f
 545 ;;;
 546 ;;; Mcron.
 547 ;;;
 548
 549 (define %mcron-os
 550   ;; System with an mcron service, with one mcron job for "root" and one mcron
 551   ;; job for an unprivileged user.
 552   (let ((job1 #~(job '(next-second '(0 5 10 15 20 25 30 35 40 45 50 55))
 553                      (lambda ()
 554                        (unless (file-exists? "witness")
 555                         (call-with-output-file "witness"
 556                           (lambda (port)
 557                             (display (list (getuid) (getgid)) port)))))))
 558         (job2 #~(job next-second-from
 559                      (lambda ()
 560                        (call-with-output-file "witness"
 561                          (lambda (port)
 562                            (display (list (getuid) (getgid)) port))))
 563                      #:user "alice"))
 564         (job3 #~(job next-second-from             ;to test $PATH
 565                      "touch witness-touch")))
 566     (simple-operating-system
 567      (mcron-service (list job1 job2 job3)))))
 568
 569 (define (run-mcron-test name)
 570   (define os
 571     (marionette-operating-system
 572      %mcron-os
 573      #:imported-modules '((gnu services herd)
 574                           (guix combinators))))
 575
 576   (define test
 577     (with-imported-modules '((gnu build marionette))
 578       #~(begin
 579           (use-modules (gnu build marionette)
 580                        (srfi srfi-64)
 581                        (ice-9 match))
 582
 583           (define marionette
 584             (make-marionette (list #$(virtual-machine os))))
 585
 586           (mkdir #$output)
 587           (chdir #$output)
 588
 589           (test-begin "mcron")
 590
 591           (test-assert "service running"
 592             (marionette-eval
 593              '(begin
 594                 (use-modules (gnu services herd))
 595                 (start-service 'mcron))
 596              marionette))
 597
 598           ;; Make sure root's mcron job runs, has its cwd set to "/root", and
 599           ;; runs with the right UID/GID.
 600           (test-equal "root's job"
 601             '(0 0)
 602             (wait-for-file "/root/witness" marionette))
 603
 604           ;; Likewise for Alice's job.  We cannot know what its GID is since
 605           ;; it's chosen by 'groupadd', but it's strictly positive.
 606           (test-assert "alice's job"
 607             (match (wait-for-file "/home/alice/witness" marionette)
 608               ((1000 gid)
 609                (>= gid 100))))
 610
 611           ;; Last, the job that uses a command; allows us to test whether
 612           ;; $PATH is sane.
 613           (test-equal "root's job with command"
 614             ""
 615             (wait-for-file "/root/witness-touch" marionette
 616                            #:read '(@ (ice-9 rdelim) read-string)))
 617
 618           (test-end)
 619           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 620
 621   (gexp->derivation name test))
 622
 623 (define %test-mcron
 624   (system-test
 625    (name "mcron")
 626    (description "Make sure the mcron service works as advertised.")
 627    (value (run-mcron-test name))))
 628
 629 \f
 630 ;;;
 631 ;;; Avahi and NSS-mDNS.
 632 ;;;
 633
 634 (define %avahi-os
 635   (operating-system
 636     (inherit %simple-os)
 637     (name-service-switch %mdns-host-lookup-nss)
 638     (services (cons* (avahi-service #:debug? #t)
 639                      (dbus-service)
 640                      (dhcp-client-service)        ;needed for multicast
 641
 642                      ;; Enable heavyweight debugging output.
 643                      (modify-services (operating-system-user-services
 644                                        %simple-os)
 645                        (nscd-service-type config
 646                                           => (nscd-configuration
 647                                               (inherit config)
 648                                               (debug-level 3)
 649                                               (log-file "/dev/console")))
 650                        (syslog-service-type config
 651                                             =>
 652                                             (syslog-configuration
 653                                              (inherit config)
 654                                              (config-file
 655                                               (plain-file
 656                                                "syslog.conf"
 657                                                "*.* /dev/console\n")))))))))
 658
 659 (define (run-nss-mdns-test)
 660   ;; Test resolution of '.local' names via libc.  Start the marionette service
 661   ;; *after* nscd.  Failing to do that, libc will try to connect to nscd,
 662   ;; fail, then never try again (see '__nss_not_use_nscd_hosts' in libc),
 663   ;; leading to '.local' resolution failures.
 664   (define os
 665     (marionette-operating-system
 666      %avahi-os
 667      #:requirements '(nscd)
 668      #:imported-modules '((gnu services herd)
 669                           (guix combinators))))
 670
 671   (define mdns-host-name
 672     (string-append (operating-system-host-name os)
 673                    ".local"))
 674
 675   (define test
 676     (with-imported-modules '((gnu build marionette))
 677       #~(begin
 678           (use-modules (gnu build marionette)
 679                        (srfi srfi-1)
 680                        (srfi srfi-64)
 681                        (ice-9 match))
 682
 683           (define marionette
 684             (make-marionette (list #$(virtual-machine os))))
 685
 686           (mkdir #$output)
 687           (chdir #$output)
 688
 689           (test-begin "avahi")
 690
 691           (test-assert "nscd PID file is created"
 692             (marionette-eval
 693              '(begin
 694                 (use-modules (gnu services herd))
 695                 (start-service 'nscd))
 696              marionette))
 697
 698           (test-assert "nscd is listening on its socket"
 699             (marionette-eval
 700              ;; XXX: Work around a race condition in nscd: nscd creates its
 701              ;; PID file before it is listening on its socket.
 702              '(let ((sock (socket PF_UNIX SOCK_STREAM 0)))
 703                 (let try ()
 704                   (catch 'system-error
 705                     (lambda ()
 706                       (connect sock AF_UNIX "/var/run/nscd/socket")
 707                       (close-port sock)
 708                       (format #t "nscd is ready~%")
 709                       #t)
 710                     (lambda args
 711                       (format #t "waiting for nscd...~%")
 712                       (usleep 500000)
 713                       (try)))))
 714              marionette))
 715
 716           (test-assert "avahi is running"
 717             (marionette-eval
 718              '(begin
 719                 (use-modules (gnu services herd))
 720                 (start-service 'avahi-daemon))
 721              marionette))
 722
 723           (test-assert "network is up"
 724             (marionette-eval
 725              '(begin
 726                 (use-modules (gnu services herd))
 727                 (start-service 'networking))
 728              marionette))
 729
 730           (test-equal "avahi-resolve-host-name"
 731             0
 732             (marionette-eval
 733              '(system*
 734                "/run/current-system/profile/bin/avahi-resolve-host-name"
 735                "-v" #$mdns-host-name)
 736              marionette))
 737
 738           (test-equal "avahi-browse"
 739             0
 740             (marionette-eval
 741              '(system* "avahi-browse" "-avt")
 742              marionette))
 743
 744           (test-assert "getaddrinfo .local"
 745             ;; Wait for the 'avahi-daemon' service and perform a resolution.
 746             (match (marionette-eval
 747                     '(getaddrinfo #$mdns-host-name)
 748                     marionette)
 749               (((? vector? addrinfos) ..1)
 750                (pk 'getaddrinfo addrinfos)
 751                (and (any (lambda (ai)
 752                            (= AF_INET (addrinfo:fam ai)))
 753                          addrinfos)
 754                     (any (lambda (ai)
 755                            (= AF_INET6 (addrinfo:fam ai)))
 756                          addrinfos)))))
 757
 758           (test-assert "gethostbyname .local"
 759             (match (pk 'gethostbyname
 760                        (marionette-eval '(gethostbyname #$mdns-host-name)
 761                                         marionette))
 762               ((? vector? result)
 763                (and (string=? (hostent:name result) #$mdns-host-name)
 764                     (= (hostent:addrtype result) AF_INET)))))
 765
 766
 767           (test-end)
 768           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 769
 770   (gexp->derivation "nss-mdns" test))
 771
 772 (define %test-nss-mdns
 773   (system-test
 774    (name "nss-mdns")
 775    (description
 776     "Test Avahi's multicast-DNS implementation, and in particular, test its
 777 glibc name service switch (NSS) module.")
 778    (value (run-nss-mdns-test))))