gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017, 2020 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018, 2019 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (gnu packages admin)
  28   #:use-module (gnu packages ci)
  29   #:use-module (gnu packages version-control)
  30   #:use-module (gnu services)
  31   #:use-module (gnu services base)
  32   #:use-module (gnu services databases)
  33   #:use-module (gnu services shepherd)
  34   #:use-module (gnu services admin)
  35   #:use-module (gnu system shadow)
  36   #:export (<cuirass-remote-server-configuration>
  37             cuirass-remote-server-configuration
  38             cuirass-remote-server-configuration?
  39
  40             <cuirass-configuration>
  41             cuirass-configuration
  42             cuirass-configuration?
  43             cuirass-service-type
  44
  45             <cuirass-remote-worker-configuration>
  46             cuirass-remote-worker-configuration
  47             cuirass-remote-worker-configuration?
  48             cuirass-remote-worker-service-type))
  49
  50 ;;;; Commentary:
  51 ;;;
  52 ;;; This module implements a service that to run instances of Cuirass, a
  53 ;;; continuous integration tool.
  54 ;;;
  55 ;;;; Code:
  56
  57 (define %cuirass-default-database
  58   "dbname=cuirass host=/var/run/postgresql")
  59
  60 (define-record-type* <cuirass-remote-server-configuration>
  61   cuirass-remote-server-configuration make-cuirass-remote-server-configuration
  62   cuirass-remote-server-configuration?
  63   (backend-port     cuirass-remote-server-configuration-backend-port ;int
  64                     (default #f))
  65   (publish-port     cuirass-remote-server-configuration-publish-port ;int
  66                     (default #f))
  67   (log-file         cuirass-remote-server-log-file ;string
  68                     (default "/var/log/cuirass-remote-server.log"))
  69   (cache            cuirass-remote-server-configuration-cache ;string
  70                     (default "/var/cache/cuirass/remote/"))
  71   (trigger-url      cuirass-remote-server-trigger-url ;string
  72                     (default #f))
  73   (public-key       cuirass-remote-server-configuration-public-key ;string
  74                     (default #f))
  75   (private-key      cuirass-remote-server-configuration-private-key ;string
  76                     (default #f)))
  77
  78 (define-record-type* <cuirass-configuration>
  79   cuirass-configuration make-cuirass-configuration
  80   cuirass-configuration?
  81   (cuirass          cuirass-configuration-cuirass ;package
  82                     (default cuirass))
  83   (log-file         cuirass-configuration-log-file ;string
  84                     (default "/var/log/cuirass.log"))
  85   (web-log-file     cuirass-configuration-web-log-file ;string
  86                     (default "/var/log/cuirass-web.log"))
  87   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  88                     (default "/var/cache/cuirass"))
  89   (user             cuirass-configuration-user ;string
  90                     (default "cuirass"))
  91   (group            cuirass-configuration-group ;string
  92                     (default "cuirass"))
  93   (interval         cuirass-configuration-interval ;integer (seconds)
  94                     (default 60))
  95   (remote-server    cuirass-configuration-remote-server
  96                     (default #f))
  97   (database         cuirass-configuration-database ;string
  98                     (default %cuirass-default-database))
  99   (port             cuirass-configuration-port ;integer (port)
 100                     (default 8081))
 101   (host             cuirass-configuration-host ;string
 102                     (default "localhost"))
 103   (specifications   cuirass-configuration-specifications)
 104                                   ;gexp that evaluates to specification-alist
 105   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
 106                     (default #f))
 107   (one-shot?        cuirass-configuration-one-shot? ;boolean
 108                     (default #f))
 109   (fallback?        cuirass-configuration-fallback? ;boolean
 110                     (default #f))
 111   (extra-options    cuirass-configuration-extra-options
 112                     (default '())))
 113
 114 (define (cuirass-shepherd-service config)
 115   "Return a <shepherd-service> for the Cuirass service with CONFIG."
 116   (let ((cuirass          (cuirass-configuration-cuirass config))
 117         (cache-directory  (cuirass-configuration-cache-directory config))
 118         (web-log-file     (cuirass-configuration-web-log-file config))
 119         (log-file         (cuirass-configuration-log-file config))
 120         (user             (cuirass-configuration-user config))
 121         (group            (cuirass-configuration-group config))
 122         (interval         (cuirass-configuration-interval config))
 123         (remote-server    (cuirass-configuration-remote-server config))
 124         (database         (cuirass-configuration-database config))
 125         (port             (cuirass-configuration-port config))
 126         (host             (cuirass-configuration-host config))
 127         (specs            (cuirass-configuration-specifications config))
 128         (use-substitutes? (cuirass-configuration-use-substitutes? config))
 129         (one-shot?        (cuirass-configuration-one-shot? config))
 130         (fallback?        (cuirass-configuration-fallback? config))
 131         (extra-options    (cuirass-configuration-extra-options config)))
 132     `(,(shepherd-service
 133         (documentation "Run Cuirass.")
 134         (provision '(cuirass))
 135         (requirement '(guix-daemon postgres networking))
 136         (start #~(make-forkexec-constructor
 137                   (list (string-append #$cuirass "/bin/cuirass")
 138                         "--cache-directory" #$cache-directory
 139                         "--specifications"
 140                         #$(scheme-file "cuirass-specs.scm" specs)
 141                         "--database" #$database
 142                         "--interval" #$(number->string interval)
 143                         #$@(if remote-server '("--build-remote") '())
 144                         #$@(if use-substitutes? '("--use-substitutes") '())
 145                         #$@(if one-shot? '("--one-shot") '())
 146                         #$@(if fallback? '("--fallback") '())
 147                         #$@extra-options)
 148
 149                   #:environment-variables
 150                   (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 151                         (string-append "GIT_EXEC_PATH=" #$git
 152                                        "/libexec/git-core"))
 153
 154                   #:user #$user
 155                   #:group #$group
 156                   #:log-file #$log-file))
 157         (stop #~(make-kill-destructor)))
 158       ,(shepherd-service
 159         (documentation "Run Cuirass web interface.")
 160         (provision '(cuirass-web))
 161         (requirement '(guix-daemon postgres networking))
 162         (start #~(make-forkexec-constructor
 163                   (list (string-append #$cuirass "/bin/cuirass")
 164                         "--cache-directory" #$cache-directory
 165                         "--database" #$database
 166                         "--web"
 167                         "--port" #$(number->string port)
 168                         "--listen" #$host
 169                         "--interval" #$(number->string interval)
 170                         #$@(if use-substitutes? '("--use-substitutes") '())
 171                         #$@(if fallback? '("--fallback") '())
 172                         #$@extra-options)
 173
 174                   #:user #$user
 175                   #:group #$group
 176                   #:log-file #$web-log-file))
 177         (stop #~(make-kill-destructor)))
 178       ,@(if remote-server
 179             (match-record remote-server <cuirass-remote-server-configuration>
 180               (backend-port publish-port log-file cache trigger-url
 181                             public-key private-key)
 182               (list
 183                (shepherd-service
 184                 (documentation "Run Cuirass remote build server.")
 185                 (provision '(cuirass-remote-server))
 186                 (requirement '(avahi-daemon cuirass guix-daemon networking))
 187                 (start #~(make-forkexec-constructor
 188                           (list (string-append #$cuirass "/bin/remote-server")
 189                                 (string-append "--database=" #$database)
 190                                 (string-append "--cache=" #$cache)
 191                                 (string-append "--user=" #$user)
 192                                 #$@(if backend-port
 193                                        (list (string-append
 194                                               "--backend-port="
 195                                               (number->string backend-port)))
 196                                        '())
 197                                 #$@(if publish-port
 198                                        (list (string-append
 199                                               "--publish-port="
 200                                               (number->string publish-port)))
 201                                        '())
 202                                 #$@(if trigger-url
 203                                        (list
 204                                         (string-append
 205                                          "--trigger-substitute-url="
 206                                          trigger-url))
 207                                        '())
 208                                 #$@(if public-key
 209                                        (list
 210                                         (string-append "--public-key="
 211                                                        public-key))
 212                                        '())
 213                                 #$@(if private-key
 214                                        (list
 215                                         (string-append "--private-key="
 216                                                        private-key))
 217                                        '()))
 218                           #:log-file #$log-file))
 219                 (stop #~(make-kill-destructor)))))
 220             '()))))
 221
 222 (define (cuirass-account config)
 223   "Return the user accounts and user groups for CONFIG."
 224   (let ((cuirass-user  (cuirass-configuration-user config))
 225         (cuirass-group (cuirass-configuration-group config)))
 226     (list (user-group
 227            (name cuirass-group)
 228            (system? #t))
 229           (user-account
 230            (name cuirass-user)
 231            (group cuirass-group)
 232            (system? #t)
 233            (comment "Cuirass privilege separation user")
 234            (home-directory (string-append "/var/lib/" cuirass-user))
 235            (shell (file-append shadow "/sbin/nologin"))))))
 236
 237 (define (cuirass-postgresql-role config)
 238   (let ((user (cuirass-configuration-user config)))
 239     (list (postgresql-role
 240            (name user)
 241            (create-database? #t)))))
 242
 243 (define (cuirass-activation config)
 244   "Return the activation code for CONFIG."
 245   (let ((cache (cuirass-configuration-cache-directory config))
 246         (db    (dirname (cuirass-configuration-database config)))
 247         (user  (cuirass-configuration-user config))
 248         (log   "/var/log/cuirass")
 249         (group (cuirass-configuration-group config)))
 250     (with-imported-modules '((guix build utils))
 251       #~(begin
 252           (use-modules (guix build utils))
 253
 254           (mkdir-p #$cache)
 255           (mkdir-p #$db)
 256           (mkdir-p #$log)
 257
 258           (let ((uid (passwd:uid (getpw #$user)))
 259                 (gid (group:gid (getgr #$group))))
 260             (chown #$cache uid gid)
 261             (chown #$db uid gid)
 262             (chown #$log uid gid))))))
 263
 264 (define (cuirass-log-rotations config)
 265   "Return the list of log rotations that corresponds to CONFIG."
 266   (list (log-rotation
 267          (files (list (cuirass-configuration-log-file config)))
 268          (frequency 'weekly)
 269          (options '("rotate 40")))))              ;worth keeping
 270
 271 (define cuirass-service-type
 272   (service-type
 273    (name 'cuirass)
 274    (extensions
 275     (list
 276      (service-extension profile-service-type      ;for 'info cuirass'
 277                         (compose list cuirass-configuration-cuirass))
 278      (service-extension rottlog-service-type cuirass-log-rotations)
 279      (service-extension activation-service-type cuirass-activation)
 280      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 281      (service-extension account-service-type cuirass-account)
 282      (service-extension postgresql-role-service-type
 283                         cuirass-postgresql-role)))
 284    (description
 285     "Run the Cuirass continuous integration service.")))
 286
 287 (define-record-type* <cuirass-remote-worker-configuration>
 288   cuirass-remote-worker-configuration make-cuirass-remote-worker-configuration
 289   cuirass-remote-worker-configuration?
 290   (cuirass          cuirass-remote-worker-configuration-cuirass ;package
 291                     (default cuirass))
 292   (workers          cuirass-remote-worker-workers ;int
 293                     (default 1))
 294   (systems          cuirass-remote-worker-systems ;list
 295                     (list (%current-system)))
 296   (log-file         cuirass-remote-worker-log-file ;string
 297                     (default "/var/log/cuirass-remote-worker.log"))
 298   (publish-port     cuirass-remote-worker-configuration-publish-port ;int
 299                     (default #f))
 300   (public-key       cuirass-remote-worker-configuration-public-key ;string
 301                     (default #f))
 302   (private-key      cuirass-remote-worker-configuration-private-key ;string
 303                     (default #f)))
 304
 305 (define (cuirass-remote-worker-shepherd-service config)
 306   "Return a <shepherd-service> for the Cuirass remote worker service with
 307 CONFIG."
 308   (match-record config <cuirass-remote-worker-configuration>
 309     (cuirass workers systems log-file publish-port public-key private-key)
 310     (list (shepherd-service
 311            (documentation "Run Cuirass remote build worker.")
 312            (provision '(cuirass-remote-worker))
 313            (requirement '(avahi-daemon guix-daemon networking))
 314            (start #~(make-forkexec-constructor
 315                      (list (string-append #$cuirass "/bin/remote-worker")
 316                            (string-append "--workers="
 317                                           #$(number->string workers))
 318                            #$@(if systems
 319                                   (list (string-append
 320                                          "--systems="
 321                                          (string-join systems ",")))
 322                                   '())
 323                            #$@(if publish-port
 324                                   (list (string-append
 325                                          "--publish-port="
 326                                          (number->string publish-port)))
 327                                   '())
 328                            #$@(if public-key
 329                                   (list
 330                                    (string-append "--public-key="
 331                                                   public-key))
 332                                   '())
 333                            #$@(if private-key
 334                                   (list
 335                                    (string-append "--private-key="
 336                                                   private-key))
 337                                   '()))
 338                     #:log-file #$log-file))
 339            (stop #~(make-kill-destructor))))))
 340
 341 (define cuirass-remote-worker-service-type
 342   (service-type
 343    (name 'cuirass-remote-worker)
 344    (extensions
 345     (list
 346      (service-extension shepherd-root-service-type
 347                         cuirass-remote-worker-shepherd-service)))
 348    (description
 349     "Run the Cuirass remote build worker service.")))