gnu/services/nix.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2019, 2020 Oleg Pykhalov <go.wigust@gmail.com>
   3 ;;; Copyright © 2020 Peng Mei Yu <i@pengmeiyu.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu services nix)
  21   #:use-module (gnu packages admin)
  22   #:use-module (gnu packages package-management)
  23   #:use-module (gnu services base)
  24   #:use-module (gnu services configuration)
  25   #:use-module (gnu services shepherd)
  26   #:use-module (gnu services web)
  27   #:use-module (gnu services)
  28   #:use-module (gnu system shadow)
  29   #:use-module (guix gexp)
  30   #:use-module (guix packages)
  31   #:use-module (guix records)
  32   #:use-module (guix store)
  33   #:use-module (srfi srfi-1)
  34   #:use-module (srfi srfi-26)
  35   #:use-module (ice-9 match)
  36   #:use-module (ice-9 format)
  37   #:use-module (guix modules)
  38   #:export (nix-service-type))
  39
  40 ;;; Commentary:
  41 ;;;
  42 ;;; This module provides a service definition for the Nix daemon.
  43 ;;;
  44 ;;; Code:
  45
  46 (define-record-type* <nix-configuration>
  47   nix-configuration make-nix-configuration
  48   nix-configuration?
  49   (package             nix-configuration-package ;package
  50                        (default nix))
  51   (sandbox             nix-configuration-sandbox ;boolean
  52                        (default #t))
  53   (build-sandbox-items nix-configuration-build-sandbox-items ;list of strings
  54                        (default '()))
  55   (extra-config        nix-configuration-extra-options ;list of strings
  56                        (default '())))
  57
  58 ;; Copied from gnu/services/base.scm
  59 (define* (nix-build-accounts count #:key
  60                              (group "nixbld")
  61                              (shadow shadow))
  62   "Return a list of COUNT user accounts for Nix build users with the given
  63 GID."
  64   (unfold (cut > <> count)
  65           (lambda (n)
  66             (user-account
  67              (name (format #f "nixbld~2,'0d" n))
  68              (system? #t)
  69              (group group)
  70              (supplementary-groups (list group "kvm"))
  71              (comment (format #f "Nix Build User ~2d" n))
  72              (home-directory "/var/empty")
  73              (shell (file-append shadow "/sbin/nologin"))))
  74           1+
  75           1))
  76 (define (nix-accounts _)
  77   "Return the user accounts and user groups."
  78   (cons (user-group
  79          (name "nixbld")
  80          (system? #t)
  81
  82          ;; Use a fixed GID so that we can create the store with the right
  83          ;; owner.
  84          (id 40000))
  85         (nix-build-accounts 10 #:group "nixbld")))
  86
  87 (define nix-activation
  88   ;; Return the activation gexp.
  89   (match-lambda
  90     (($ <nix-configuration> package sandbox build-sandbox-items extra-config)
  91      (with-imported-modules (source-module-closure
  92                              '((guix build store-copy)))
  93        #~(begin
  94            (use-modules (guix build utils)
  95                         (ice-9 format)
  96                         (srfi srfi-1)
  97                         (srfi srfi-26))
  98            (for-each (cut mkdir-p <>) '("/nix/store" "/nix/var/log"
  99                                         "/nix/var/nix/gcroots/per-user"
 100                                         "/nix/var/nix/profiles/per-user"))
 101            (chown "/nix/store"
 102                   (passwd:uid (getpw "root")) (group:gid (getpw "nixbld01")))
 103            (chmod "/nix/store" #o775)
 104            (for-each (cut chmod <> #o777) '("/nix/var/nix/profiles"
 105                                             "/nix/var/nix/profiles/per-user"))
 106            (mkdir-p "/etc/nix")
 107            (with-output-to-file "/etc/nix/nix.conf"
 108              (lambda _
 109                (format #t "sandbox = ~a~%" (if #$sandbox "true" "false"))
 110                ;; config.nix captures store file names.
 111                (format #t "build-sandbox-paths = ~{~a ~}~%"
 112                        (append (append-map (cut call-with-input-file <> read)
 113                                            '#$(map references-file
 114                                                    (list package)))
 115                                '#$build-sandbox-items))
 116                (for-each (cut display <>) '#$extra-config))))))))
 117
 118 (define nix-shepherd-service
 119   ;; Return a <shepherd-service> for Nix.
 120   (match-lambda
 121     (($ <nix-configuration> package _ ...)
 122      (list
 123       (shepherd-service
 124        (provision '(nix-daemon))
 125        (documentation "Run nix-daemon.")
 126        (requirement '())
 127        (start #~(make-forkexec-constructor
 128                  (list (string-append #$package "/bin/nix-daemon"))))
 129        (respawn? #f)
 130        (stop #~(make-kill-destructor)))))))
 131
 132 (define nix-service-type
 133   (service-type
 134    (name 'nix)
 135    (extensions
 136     (list (service-extension shepherd-root-service-type nix-shepherd-service)
 137           (service-extension account-service-type nix-accounts)
 138           (service-extension activation-service-type nix-activation)
 139           (service-extension profile-service-type
 140                              (compose list nix-configuration-package))))
 141    (description "Run the Nix daemon.")
 142    (default-value (nix-configuration))))
 143
 144 ;;; nix.scm ends here