gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018, 2019 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (gnu packages admin)
  28   #:use-module (gnu packages ci)
  29   #:use-module (gnu packages version-control)
  30   #:use-module (gnu services)
  31   #:use-module (gnu services base)
  32   #:use-module (gnu services shepherd)
  33   #:use-module (gnu services admin)
  34   #:use-module (gnu system shadow)
  35   #:export (<cuirass-configuration>
  36             cuirass-configuration
  37             cuirass-configuration?
  38
  39             cuirass-service-type))
  40
  41 ;;;; Commentary:
  42 ;;;
  43 ;;; This module implements a service that to run instances of Cuirass, a
  44 ;;; continuous integration tool.
  45 ;;;
  46 ;;;; Code:
  47
  48 (define-record-type* <cuirass-configuration>
  49   cuirass-configuration make-cuirass-configuration
  50   cuirass-configuration?
  51   (cuirass          cuirass-configuration-cuirass ;package
  52                     (default cuirass))
  53   (log-file         cuirass-configuration-log-file ;string
  54                     (default "/var/log/cuirass.log"))
  55   (web-log-file     cuirass-configuration-web-log-file ;string
  56                     (default "/var/log/cuirass-web.log"))
  57   (queries-log-file cuirass-configuration-queries-log-file ;string
  58                     (default #f))
  59   (web-queries-log-file
  60                     cuirass-configuration-web-queries-log-file ;string
  61                     (default #f))
  62   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  63                     (default "/var/cache/cuirass"))
  64   (ttl              cuirass-configuration-ttl     ;integer
  65                     (default (* 30 24 3600)))
  66   (user             cuirass-configuration-user ;string
  67                     (default "cuirass"))
  68   (group            cuirass-configuration-group ;string
  69                     (default "cuirass"))
  70   (interval         cuirass-configuration-interval ;integer (seconds)
  71                     (default 60))
  72   (queue-size       cuirass-configuration-queue-size
  73                     (default 1))
  74   (database         cuirass-configuration-database ;string (file-name)
  75                     (default "/var/lib/cuirass/cuirass.db"))
  76   (port             cuirass-configuration-port ;integer (port)
  77                     (default 8081))
  78   (host             cuirass-configuration-host ;string
  79                     (default "localhost"))
  80   (specifications   cuirass-configuration-specifications)
  81                                   ;gexp that evaluates to specification-alist
  82   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
  83                     (default #f))
  84   (one-shot?        cuirass-configuration-one-shot? ;boolean
  85                     (default #f))
  86   (fallback?        cuirass-configuration-fallback? ;boolean
  87                     (default #f))
  88   (extra-options    cuirass-configuration-extra-options
  89                     (default '())))
  90
  91 (define (cuirass-shepherd-service config)
  92   "Return a <shepherd-service> for the Cuirass service with CONFIG."
  93   (let ((cuirass          (cuirass-configuration-cuirass config))
  94         (cache-directory  (cuirass-configuration-cache-directory config))
  95         (web-log-file     (cuirass-configuration-web-log-file config))
  96         (log-file         (cuirass-configuration-log-file config))
  97         (queries-log-file (cuirass-configuration-queries-log-file config))
  98         (web-queries-log-file
  99                           (cuirass-configuration-web-queries-log-file config))
 100         (user             (cuirass-configuration-user config))
 101         (group            (cuirass-configuration-group config))
 102         (interval         (cuirass-configuration-interval config))
 103         (queue-size       (cuirass-configuration-queue-size config))
 104         (database         (cuirass-configuration-database config))
 105         (ttl              (cuirass-configuration-ttl config))
 106         (port             (cuirass-configuration-port config))
 107         (host             (cuirass-configuration-host config))
 108         (specs            (cuirass-configuration-specifications config))
 109         (use-substitutes? (cuirass-configuration-use-substitutes? config))
 110         (one-shot?        (cuirass-configuration-one-shot? config))
 111         (fallback?        (cuirass-configuration-fallback? config))
 112         (extra-options    (cuirass-configuration-extra-options config)))
 113     (list (shepherd-service
 114            (documentation "Run Cuirass.")
 115            (provision '(cuirass))
 116            (requirement '(guix-daemon networking))
 117            (start #~(make-forkexec-constructor
 118                      (list (string-append #$cuirass "/bin/cuirass")
 119                            "--cache-directory" #$cache-directory
 120                            "--specifications"
 121                            #$(scheme-file "cuirass-specs.scm" specs)
 122                            "--database" #$database
 123                            "--ttl" #$(string-append (number->string ttl) "s")
 124                            "--interval" #$(number->string interval)
 125                            "--queue-size" #$(number->string queue-size)
 126                            #$@(if queries-log-file
 127                                   (list (string-append "--log-queries="
 128                                                        queries-log-file))
 129                                   '())
 130                            #$@(if use-substitutes? '("--use-substitutes") '())
 131                            #$@(if one-shot? '("--one-shot") '())
 132                            #$@(if fallback? '("--fallback") '())
 133                            #$@extra-options)
 134
 135                      #:environment-variables
 136                      (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 137                            (string-append "GIT_EXEC_PATH=" #$git
 138                                           "/libexec/git-core"))
 139
 140                      #:user #$user
 141                      #:group #$group
 142                      #:log-file #$log-file))
 143            (stop #~(make-kill-destructor)))
 144           (shepherd-service
 145            (documentation "Run Cuirass web interface.")
 146            (provision '(cuirass-web))
 147            (requirement '(guix-daemon networking))
 148            (start #~(make-forkexec-constructor
 149                      (list (string-append #$cuirass "/bin/cuirass")
 150                            "--cache-directory" #$cache-directory
 151                            "--specifications"
 152                            #$(scheme-file "cuirass-specs.scm" specs)
 153                            "--database" #$database
 154                            "--ttl" #$(string-append (number->string ttl) "s")
 155                            "--web"
 156                            "--port" #$(number->string port)
 157                            "--listen" #$host
 158                            "--interval" #$(number->string interval)
 159                            #$@(if web-queries-log-file
 160                                   (list (string-append "--log-queries="
 161                                                        web-queries-log-file))
 162                                   '())
 163                            #$@(if use-substitutes? '("--use-substitutes") '())
 164                            #$@(if fallback? '("--fallback") '())
 165                            #$@extra-options)
 166
 167                      #:user #$user
 168                      #:group #$group
 169                      #:log-file #$web-log-file))
 170            (stop #~(make-kill-destructor))))))
 171
 172 (define (cuirass-account config)
 173   "Return the user accounts and user groups for CONFIG."
 174   (let ((cuirass-user  (cuirass-configuration-user config))
 175         (cuirass-group (cuirass-configuration-group config)))
 176     (list (user-group
 177            (name cuirass-group)
 178            (system? #t))
 179           (user-account
 180            (name cuirass-user)
 181            (group cuirass-group)
 182            (system? #t)
 183            (comment "Cuirass privilege separation user")
 184            (home-directory (string-append "/var/lib/" cuirass-user))
 185            (shell (file-append shadow "/sbin/nologin"))))))
 186
 187 (define (cuirass-activation config)
 188   "Return the activation code for CONFIG."
 189   (let ((cache (cuirass-configuration-cache-directory config))
 190         (db    (dirname (cuirass-configuration-database config)))
 191         (user  (cuirass-configuration-user config))
 192         (log   "/var/log/cuirass")
 193         (queries-log-file (cuirass-configuration-queries-log-file config))
 194         (web-queries-log-file
 195          (cuirass-configuration-web-queries-log-file config))
 196         (group (cuirass-configuration-group config)))
 197     (with-imported-modules '((guix build utils))
 198       #~(begin
 199           (use-modules (guix build utils))
 200
 201           (mkdir-p #$cache)
 202           (mkdir-p #$db)
 203           (mkdir-p #$log)
 204
 205           (let ((uid (passwd:uid (getpw #$user)))
 206                 (gid (group:gid (getgr #$group))))
 207             (chown #$cache uid gid)
 208             (chown #$db uid gid)
 209             (chown #$log uid gid)
 210
 211             (let ((queries-log-file #$queries-log-file))
 212               (when queries-log-file
 213                 (call-with-output-file queries-log-file (const #t))
 214                 (chown #$queries-log-file uid gid)))
 215
 216             (let ((web-queries-log-file #$web-queries-log-file))
 217               (when web-queries-log-file
 218                 (call-with-output-file web-queries-log-file (const #t))
 219                 (chown web-queries-log-file uid gid))))))))
 220
 221 (define (cuirass-log-rotations config)
 222   "Return the list of log rotations that corresponds to CONFIG."
 223   (let ((queries-log-file (cuirass-configuration-queries-log-file config))
 224         (web-queries-log-file
 225          (cuirass-configuration-web-queries-log-file config)))
 226     (list (log-rotation
 227            (files `(,(cuirass-configuration-log-file config)
 228                     ,@(if queries-log-file
 229                           (list queries-log-file)
 230                           '())
 231                     ,@(if web-queries-log-file
 232                           (list web-queries-log-file)
 233                           '())))
 234            (frequency 'weekly)
 235            (options '("rotate 40"))))))              ;worth keeping
 236
 237 (define cuirass-service-type
 238   (service-type
 239    (name 'cuirass)
 240    (extensions
 241     (list
 242      (service-extension profile-service-type      ;for 'info cuirass'
 243                         (compose list cuirass-configuration-cuirass))
 244      (service-extension rottlog-service-type cuirass-log-rotations)
 245      (service-extension activation-service-type cuirass-activation)
 246      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 247      (service-extension account-service-type cuirass-account)))
 248    (description
 249     "Run the Cuirass continuous integration service.")))
 250