gnu/packages/aspell.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015, 2016 Alex Kost <alezost@gmail.com>
   4 ;;; Copyright © 2016 John Darrington <jmd@gnu.org>
   5 ;;; Copyright © 2016, 2017, 2019 Efraim Flashner <efraim@flashner.co.il>
   6 ;;; Copyright © 2016 Christopher Andersson <christopher@8bits.nu>
   7 ;;; Copyright © 2016 Theodoros Foradis <theodoros@foradis.org>
   8 ;;; Copyright © 2016, 2017, 2019 Tobias Geerinckx-Rice <me@tobias.gr>
   9 ;;; Copyright © 2019 Jens Mølgaard <jens@zete.tk>
  10 ;;; Copyright © 2020 Timotej Lazar <timotej.lazar@araneo.si>
  11 ;;;
  12 ;;; This file is part of GNU Guix.
  13 ;;;
  14 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  15 ;;; under the terms of the GNU General Public License as published by
  16 ;;; the Free Software Foundation; either version 3 of the License, or (at
  17 ;;; your option) any later version.
  18 ;;;
  19 ;;; GNU Guix is distributed in the hope that it will be useful, but
  20 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;;; GNU General Public License for more details.
  23 ;;;
  24 ;;; You should have received a copy of the GNU General Public License
  25 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 (define-module (gnu packages aspell)
  28   #:use-module (guix packages)
  29   #:use-module (guix download)
  30   #:use-module (guix build-system gnu)
  31   #:use-module (guix licenses)
  32   #:use-module (guix utils)
  33   #:use-module (gnu packages)
  34   #:use-module (gnu packages base)
  35   #:use-module (gnu packages compression)
  36   #:use-module (gnu packages perl)
  37   #:use-module (ice-9 match))
  38
  39 (define-public aspell
  40   (package
  41     (name "aspell")
  42     (version "0.60.8")
  43     (source
  44      (origin
  45       (method url-fetch)
  46       (uri (string-append "mirror://gnu/aspell/aspell-"
  47                           version ".tar.gz"))
  48       (sha256
  49        (base32
  50         "1wi60ankalmh8ds7nplz434jd7j94gdvbahdwsr539rlad8pxdzr"))
  51       (patches (search-patches "aspell-default-dict-dir.patch"))))
  52     (build-system gnu-build-system)
  53     (arguments
  54      `(#:phases
  55        (modify-phases %standard-phases
  56          (add-before 'build 'set-filter-path
  57            (lambda* (#:key outputs #:allow-other-keys)
  58              ;; Change the default value of 'filter-path' so that filters such
  59              ;; as 'tex-filter.so' can be found.  By default none of the
  60              ;; filters would be found.
  61              (let* ((out    (assoc-ref outputs "out"))
  62                     (libdir (string-append out "/lib/aspell-"
  63                                            ,(version-major+minor version))))
  64                (substitute* "common/config.cpp"
  65                  (("\"filter-path(.*)DICT_DIR" _ middle)
  66                   (string-append "\"filter-path" middle
  67                                  "\"" libdir "\"")))
  68                #t))))))
  69     (inputs `(("perl" ,perl)))
  70
  71     (native-search-paths
  72      ;; This is a Guix-specific environment variable that takes a single
  73      ;; entry, not an actual search path.
  74      (list (search-path-specification
  75             (variable "ASPELL_DICT_DIR")
  76             (separator #f)
  77             (files '("lib/aspell")))))
  78
  79     (home-page "http://aspell.net/")
  80     (synopsis "Spell checker")
  81     (description
  82      "Aspell is a spell-checker which can be used either as a library or as
  83 a standalone program.  Notable features of Aspell include its full support of
  84 documents written in the UTF-8 encoding and its ability to use multiple
  85 dictionaries, including personal ones.")
  86     (license lgpl2.1+)))
  87
  88 ;;;
  89 ;;; Dictionaries.
  90 ;;;
  91 ;;; Use 'export ASPELL_CONF="dict-dir $HOME/.guix-profile/lib/aspell"' to use
  92 ;;; them, or set the Guix-specific 'ASPELL_DICT_DIR', or just do nothing (as
  93 ;;; long as 'HOME' is set, that's fine!).
  94 ;;;
  95
  96 (define* (aspell-dictionary dict-name full-name
  97                             #:key version sha256 (prefix "aspell6-"))
  98   (package
  99     (name (string-append
 100            "aspell-dict-"
 101            ;; Downcase and replace underscore in package names
 102            ;; to follow Guix naming conventions.
 103            (string-map (match-lambda
 104                          (#\_ #\-)
 105                          (chr chr))
 106            (string-downcase dict-name))))
 107     (version version)
 108     (source (origin
 109               (method url-fetch)
 110               (uri (string-append "mirror://gnu/aspell/dict/" dict-name
 111                                   "/" prefix dict-name "-"
 112                                   version ".tar.bz2"))
 113               (sha256 sha256)))
 114     (build-system gnu-build-system)
 115     (arguments
 116      `(#:phases
 117        (modify-phases %standard-phases
 118          (replace 'configure
 119            (lambda* (#:key outputs #:allow-other-keys)
 120              (let ((out (assoc-ref outputs "out")))
 121                (invoke "./configure")))))
 122        #:make-flags
 123        (let ((out (assoc-ref %outputs "out")))
 124          (list (string-append "dictdir=" out "/lib/aspell")
 125                (string-append "datadir=" out "/lib/aspell")))
 126        #:tests? #f))
 127     (native-inputs `(("aspell" ,aspell)
 128                      ("which" ,which)))
 129     (synopsis (string-append full-name " dictionary for GNU Aspell")) ; XXX: i18n
 130     (description
 131      "This package provides a dictionary for the GNU Aspell spell checker.")
 132     (license gpl2+)
 133     (home-page "http://aspell.net/")))
 134
 135
 136 (define-public aspell-dict-ar
 137   (aspell-dictionary "ar" "Arabic"
 138                      #:version "1.2-0"
 139                      #:prefix "aspell6-"
 140                      #:sha256
 141                      (base32
 142                       "1avw40bp8yi5bnkq64ihm2rldgw34lk89yz281q9bmndh95a47h4")))
 143
 144 (define-public aspell-dict-be
 145   (aspell-dictionary "be" "Belarusian"
 146                      #:version "0.01"
 147                      #:prefix "aspell5-"
 148                      #:sha256
 149                      (base32
 150                       "1svls9p7rsfi3hs0afh0cssj006qb4v1ik2yzqgj8hm10c6as2sm")))
 151
 152 (define-public aspell-dict-ca
 153   (let ((version "2.5.0")
 154         (sha256
 155          (base32 "0kbi8fi7a1bys31kfqrlh332gyik0cfdmxgl7n15sa9c305rkgwq")))
 156     (package
 157       (inherit (aspell-dictionary "ca" "Catalan"
 158                                   #:version version
 159                                   #:sha256 sha256))
 160       (source
 161        (origin
 162          (method url-fetch)
 163          (uri (string-append "https://www.softcatala.org/pub/softcatala/aspell/"
 164                              version "/aspell6-ca-" version ".tar.bz2"))
 165          (sha256 sha256)))
 166       (home-page "https://www.softcatala.org/pub/softcatala/aspell/"))))
 167
 168 (define-public aspell-dict-de
 169   (aspell-dictionary "de" "German"
 170                      #:version "20161207-7-0"
 171                      #:sha256
 172                      (base32
 173                       "0wamclvp66xfmv5wff96v6gdlnfv4y8lx3f8wvxyzm5imwgms4n2")))
 174
 175 (define-public aspell-dict-da
 176   (aspell-dictionary "da" "Danish"
 177                      #:version "1.4.42-1"
 178                      #:prefix "aspell5-"
 179                      #:sha256
 180                      (base32
 181                       "1hfkmiyhgrx5lgrb2mffjbdn1hivrm73wcg7x0iid74p2yb0fjpp")))
 182
 183 (define-public aspell-dict-el
 184   (aspell-dictionary "el" "Greek"
 185                      #:version "0.08-0"
 186                      #:prefix "aspell6-"
 187                      #:sha256
 188                      (base32
 189                       "1ljcc30zg2v2h3w5h5jr5im41mw8jbsgvvhdd2cii2yzi8d0zxja")))
 190
 191 (define-public aspell-dict-en
 192   (aspell-dictionary "en" "English"
 193                      #:version "2019.10.06-0"
 194                      #:sha256
 195                      (base32
 196                       "1zai9wrqwgb9z9vfgb22qhrvxvg73jg0ix44j1khm2f6m96lncr4")))
 197
 198 (define-public aspell-dict-eo
 199   (aspell-dictionary "eo" "Esperanto"
 200                      #:version "2.1.20000225a-2"
 201                      #:sha256
 202                      (base32
 203                       "09vf0mbiicbmyb4bwb7v7lgpabnylg0wy7m3hlhl5rjdda6x3lj1")))
 204
 205 (define-public aspell-dict-es
 206   (aspell-dictionary "es" "Spanish"
 207                      #:version "1.11-2"
 208                      #:sha256
 209                      (base32
 210                       "1k5g328ac1hdpp6fsg57d8md6i0aqcwlszp3gbmp5706wyhpydmd")))
 211
 212 (define-public aspell-dict-fi
 213   (aspell-dictionary "fi" "Finnish"
 214                      #:version "0.7-0"
 215                      #:prefix "aspell6-"
 216                      #:sha256
 217                      (base32
 218                       "07d5s08ba4dd89cmwy9icc01i6fjdykxlb9ravmhdrhi8mxz1mzq")))
 219
 220 (define-public aspell-dict-fr
 221   (aspell-dictionary "fr" "French"
 222                      #:version "0.50-3"
 223                      #:prefix "aspell-"
 224                      #:sha256
 225                      (base32
 226                       "14ffy9mn5jqqpp437kannc3559bfdrpk7r36ljkzjalxa53i0hpr")))
 227
 228 (define-public aspell-dict-grc
 229   (aspell-dictionary "grc" "Ancient Greek"
 230                      #:version "0.02-0"
 231                      #:sha256
 232                      (base32
 233                       "1zxr8958v37v260fkqd4pg37ns5h5kyqm54hn1hg70wq5cz8h512")))
 234
 235 (define-public aspell-dict-he
 236   (aspell-dictionary "he" "Hebrew"
 237                      #:version "1.0-0"
 238                      #:sha256
 239                      (base32
 240                       "13bhbghx5b8g0119g3wxd4n8mlf707y41vlf59irxjj0kynankfn")))
 241
 242 (define-public aspell-dict-hi
 243   (aspell-dictionary "hi" "Hindi"
 244                      #:version "0.02-0"
 245                      #:prefix "aspell6-"
 246                      #:sha256
 247                      (base32
 248                       "0drs374qz4419zx1lf2k281ydxf2750jk5ailafj1x0ncz27h1ys")))
 249
 250 (define-public aspell-dict-it
 251   (let ((version "2.4-20070901-0")
 252         (sha256
 253          (base32 "0d6ypii3jblprpibazb6ypady536jz62rwxlss1x1raq07rhvvqn")))
 254     (package
 255       (inherit (aspell-dictionary "it" "Italian"
 256                                   #:version version
 257                                   #:sha256 sha256))
 258
 259       ;; The version hosted at <https://ftp.gnu.org/gnu/aspell/dict> is even
 260       ;; more out of date.
 261       (source
 262        (origin
 263          (method url-fetch)
 264          (uri (string-append "mirror://sourceforge/linguistico/"
 265                              "Dizionario%20italiano%20per%20Aspell/" version "/"
 266                              "aspell6-it-" version ".tar.bz2"))
 267          (sha256 sha256)))
 268        (home-page
 269         "http://linguistico.sourceforge.net/pages/dizionario_italiano.html"))))
 270
 271 (define-public aspell-dict-mi
 272   (aspell-dictionary "mi" "Maori"
 273                      #:version "0.50-0"
 274                      #:sha256
 275                      (base32
 276                       "12bxplpd348yx8d2q8qvahi9dlp7qf28qmanzhziwc7np8rixvmy")))
 277
 278 (define-public aspell-dict-nl
 279   (aspell-dictionary "nl" "Dutch"
 280                      #:version "0.50-2"
 281                      #:prefix "aspell-"
 282                      #:sha256
 283                      (base32
 284                       "0ffb87yjsh211hllpc4b9khqqrblial4pzi1h9r3v465z1yhn3j4")))
 285
 286 (define-public aspell-dict-nn
 287   (aspell-dictionary "nn" "Norwegian Nynorsk"
 288                      #:version "0.50.1-1"
 289                      #:sha256
 290                      (base32
 291                       "0w2k5l5rbqpliripgqwiqixz5ghnjf7i9ggbrc4ly4vy1ia10rmc")))
 292
 293 (define-public aspell-dict-pt-br
 294   (aspell-dictionary "pt_BR" "Brazilian Portuguese"
 295                      #:version "20131030-12-0"
 296                      #:sha256
 297                      (base32
 298                       "1xqlpk21s93c6blkdnpk7l62q9fxjvzdv2x86chl8p2x1gdrj3gb")))
 299
 300 (define-public aspell-dict-pt-pt
 301   (aspell-dictionary "pt_PT" "Portuguese"
 302                      #:version "20190329-1-0"
 303                      #:sha256
 304                      (base32
 305                       "0ld0d0ily4jqifjfsxfv4shbicz6ymm2gk56fq9gbzra1j4qnw75")))
 306
 307 (define-public aspell-dict-ru
 308   (aspell-dictionary "ru" "Russian"
 309                      #:version "0.99f7-1"
 310                      #:sha256
 311                      (base32
 312                       "0ip6nq43hcr7vvzbv4lwwmlwgfa60hrhsldh9xy3zg2prv6bcaaw")))
 313
 314 (define-public aspell-dict-sl
 315   (aspell-dictionary "sl" "Slovenian"
 316                      #:version "0.50-0"
 317                      #:prefix "aspell-"
 318                      #:sha256
 319                      (base32
 320                       "1l9kc5g35flq8kw9jhn2n0bjb4sipjs4qkqzgggs438kywkx2rp5")))
 321
 322 (define-public aspell-dict-sv
 323   (aspell-dictionary "sv" "Swedish"
 324                      #:version "0.51-0"
 325                      #:prefix "aspell-"
 326                      #:sha256
 327                      (base32
 328                       "02jwkjhr32kvyibnyzgx3smbnm576jwdzg3avdf6zxwckhy5fw4v")))
 329
 330 (define-public aspell-dict-uk
 331   (aspell-dictionary "uk" "Ukrainian"
 332                      #:version "1.4.0-0"
 333                      #:sha256
 334                      (base32
 335                       "137i4njvnslab6l4s291s11xijr5jsy75lbdph32f9y183lagy9m")))
 336
 337 \f
 338 ;;;
 339 ;;; Hunspell packages made from the Aspell word lists.
 340 ;;;
 341
 342 (define* (aspell-word-list language synopsis
 343                            #:optional
 344                            (nick (string-map (lambda (chr)
 345                                                (if (char=? #\_ chr)
 346                                                    #\-
 347                                                    chr))
 348                                              (string-downcase language))))
 349   (package
 350     (name (string-append "hunspell-dict-" nick))
 351     (version "2018.04.16")
 352     (source (origin
 353               (method url-fetch)
 354               (uri (string-append
 355                     "http://downloads.sourceforge.net/wordlist/scowl-"
 356                     version ".tar.gz"))
 357               (sha256
 358                (base32
 359                 "11lkrnhwrf5mvrrq45k4mads3n9aswgac8dc25ba61c75alxb5rs"))))
 360     (native-inputs
 361      `(("tar" ,tar)
 362        ("gzip" ,gzip)
 363        ("perl" ,perl)
 364        ("aspell" ,aspell)))
 365     (build-system gnu-build-system)
 366     (arguments
 367      `(#:phases
 368        (modify-phases %standard-phases
 369          (delete 'configure)
 370          (delete 'check)
 371          (replace 'build
 372            (lambda _
 373              (substitute* "speller/make-hunspell-dict"
 374                (("zip -9 .*$")
 375                 "return\n"))
 376              (mkdir "speller/hunspell")
 377
 378              ;; XXX: This actually builds all the dictionary variants.
 379              (invoke "make" "-C" "speller" "hunspell")))
 380          (replace 'install
 381            (lambda* (#:key outputs #:allow-other-keys)
 382              (let* ((out      (assoc-ref %outputs "out"))
 383                     (hunspell (string-append out "/share/hunspell"))
 384                     (myspell  (string-append out "/share/myspell"))
 385                     (doc      (string-append out "/share/doc/"
 386                                              ,name))
 387                     (dot-dic  ,(string-append "speller/" language ".dic")))
 388                (mkdir-p myspell)
 389
 390                ;; Usually there's only a 'LANGUAGE.dic' file, but for the "en"
 391                ;; dictionary, there no 'en.dic'.  Instead, there's a set of
 392                ;; 'en*.dic' files, hence the 'find-files' call below.
 393                (if (file-exists? dot-dic)
 394                    (install-file dot-dic hunspell)
 395                    (for-each (lambda (dic)
 396                                (install-file dic hunspell))
 397                              (find-files "speller"
 398                                          ,(string-append language ".*\\.dic$"))))
 399
 400                (install-file ,(string-append "speller/" language ".aff")
 401                              hunspell)
 402                (symlink hunspell (string-append myspell "/dicts"))
 403                (for-each (lambda (file)
 404                            (install-file file doc))
 405                          (find-files "."
 406                                      "^(Copyright|.*\\.(txt|org|md))$"))
 407                #t))))))
 408     (synopsis synopsis)
 409     (description
 410      "This package provides a dictionary for the Hunspell spell-checking
 411 library.")
 412     (home-page "http://wordlist.aspell.net/")
 413     (license (non-copyleft "file://Copyright"
 414                            "Word lists come from several sources, all
 415 under permissive licensing terms.  See the 'Copyright' file."))))
 416
 417 (define-syntax define-word-list-dictionary
 418   (syntax-rules (synopsis)
 419     ((_ name language (synopsis text))
 420      (define-public name
 421        (aspell-word-list language text)))
 422     ((_ name language nick (synopsis text))
 423      (define-public name
 424        (aspell-word-list language text nick)))))
 425
 426 (define-word-list-dictionary hunspell-dict-en
 427   "en"
 428   (synopsis "Hunspell dictionary for English"))
 429
 430 (define-word-list-dictionary hunspell-dict-en-au
 431   "en_AU"
 432   (synopsis "Hunspell dictionary for Australian English"))
 433
 434 (define-word-list-dictionary hunspell-dict-en-ca
 435   "en_CA"
 436   (synopsis "Hunspell dictionary for Canadian English"))
 437
 438 (define-word-list-dictionary hunspell-dict-en-gb
 439   "en_GB-ise" "en-gb"
 440   (synopsis "Hunspell dictionary for British English, with -ise endings"))
 441
 442 (define-word-list-dictionary hunspell-dict-en-gb-ize
 443   "en_GB-ize"
 444   (synopsis "Hunspell dictionary for British English, with -ize endings"))
 445
 446 (define-word-list-dictionary hunspell-dict-en-us
 447   "en_US"
 448   (synopsis "Hunspell dictionary for United States English"))