gnu/tests/base.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu tests base)
  21   #:use-module (gnu tests)
  22   #:use-module (gnu system)
  23   #:use-module (gnu system shadow)
  24   #:use-module (gnu system nss)
  25   #:use-module (gnu system vm)
  26   #:use-module (gnu services)
  27   #:use-module (gnu services base)
  28   #:use-module (gnu services dbus)
  29   #:use-module (gnu services avahi)
  30   #:use-module (gnu services mcron)
  31   #:use-module (gnu services shepherd)
  32   #:use-module (gnu services networking)
  33   #:use-module (gnu packages base)
  34   #:use-module (gnu packages bash)
  35   #:use-module (gnu packages imagemagick)
  36   #:use-module (gnu packages ocr)
  37   #:use-module (gnu packages package-management)
  38   #:use-module (gnu packages linux)
  39   #:use-module (gnu packages tmux)
  40   #:use-module (guix gexp)
  41   #:use-module (guix store)
  42   #:use-module (guix monads)
  43   #:use-module (guix packages)
  44   #:use-module (srfi srfi-1)
  45   #:use-module (ice-9 match)
  46   #:export (run-basic-test
  47             %test-basic-os
  48             %test-halt
  49             %test-cleanup
  50             %test-mcron
  51             %test-nss-mdns))
  52
  53 (define %simple-os
  54   (simple-operating-system))
  55
  56 \f
  57 (define* (run-basic-test os command #:optional (name "basic")
  58                          #:key initialization)
  59   "Return a derivation called NAME that tests basic features of the OS started
  60 using COMMAND, a gexp that evaluates to a list of strings.  Compare some
  61 properties of running system to what's declared in OS, an <operating-system>.
  62
  63 When INITIALIZATION is true, it must be a one-argument procedure that is
  64 passed a gexp denoting the marionette, and it must return gexp that is
  65 inserted before the first test.  This is used to introduce an extra
  66 initialization step, such as entering a LUKS passphrase."
  67   (define special-files
  68     (service-value
  69      (fold-services (operating-system-services os)
  70                     #:target-type special-files-service-type)))
  71
  72   (define guix&co
  73     (match (package-transitive-propagated-inputs guix)
  74       (((labels packages) ...)
  75        (cons guix packages))))
  76
  77   (define test
  78     (with-imported-modules '((gnu build marionette)
  79                              (guix build syscalls))
  80       #~(begin
  81           (use-modules (gnu build marionette)
  82                        (guix build syscalls)
  83                        (srfi srfi-1)
  84                        (srfi srfi-26)
  85                        (srfi srfi-64)
  86                        (ice-9 match))
  87
  88           (define marionette
  89             (make-marionette #$command))
  90
  91           (mkdir #$output)
  92           (chdir #$output)
  93
  94           (test-begin "basic")
  95
  96           #$(and initialization
  97                  (initialization #~marionette))
  98
  99           (test-assert "uname"
 100             (match (marionette-eval '(uname) marionette)
 101               (#("Linux" host-name version _ architecture)
 102                (and (string=? host-name
 103                               #$(operating-system-host-name os))
 104                     (string-prefix? #$(package-version
 105                                        (operating-system-kernel os))
 106                                     version)
 107                     (string-prefix? architecture %host-type)))))
 108
 109           ;; Shepherd reads the config file *before* binding its control
 110           ;; socket, so /var/run/shepherd/socket might not exist yet when the
 111           ;; 'marionette' service is started.
 112           (test-assert "shepherd socket ready"
 113             (marionette-eval
 114              `(begin
 115                 (use-modules (gnu services herd))
 116                 (let loop ((i 10))
 117                   (cond ((file-exists? (%shepherd-socket-file))
 118                          #t)
 119                         ((> i 0)
 120                          (sleep 1)
 121                          (loop (- i 1)))
 122                         (else
 123                          #f))))
 124              marionette))
 125
 126           (test-eq "stdin is /dev/null"
 127             'eof
 128             ;; Make sure services can no longer read from stdin once the
 129             ;; system has booted.
 130             (marionette-eval
 131              `(begin
 132                 (use-modules (gnu services herd))
 133                 (start 'user-processes)
 134                 ((@@ (gnu services herd) eval-there)
 135                  '(let ((result (read (current-input-port))))
 136                     (if (eof-object? result)
 137                         'eof
 138                         result))))
 139              marionette))
 140
 141           (test-assert "shell and user commands"
 142             ;; Is everything in $PATH?
 143             (zero? (marionette-eval '(system "
 144 . /etc/profile
 145 set -e -x
 146 guix --version
 147 ls --version
 148 grep --version
 149 info --version")
 150                                     marionette)))
 151
 152           (test-equal "special files"
 153             '#$special-files
 154             (marionette-eval
 155              '(begin
 156                 (use-modules (ice-9 match))
 157
 158                 (map (match-lambda
 159                        ((file target)
 160                         (list file (readlink file))))
 161                      '#$special-files))
 162              marionette))
 163
 164           (test-assert "accounts"
 165             (let ((users (marionette-eval '(begin
 166                                              (use-modules (ice-9 match))
 167                                              (let loop ((result '()))
 168                                                (match (getpw)
 169                                                  (#f (reverse result))
 170                                                  (x  (loop (cons x result))))))
 171                                           marionette)))
 172               (lset= equal?
 173                      (map (lambda (user)
 174                             (list (passwd:name user)
 175                                   (passwd:dir user)))
 176                           users)
 177                      (list
 178                       #$@(map (lambda (account)
 179                                 `(list ,(user-account-name account)
 180                                        ,(user-account-home-directory account)))
 181                               (operating-system-user-accounts os))))))
 182
 183           (test-assert "shepherd services"
 184             (let ((services (marionette-eval
 185                              '(begin
 186                                 (use-modules (gnu services herd))
 187
 188                                 (map (compose car live-service-provision)
 189                                      (current-services)))
 190                              marionette)))
 191               (lset= eq?
 192                      (pk 'services services)
 193                      '(root #$@(operating-system-shepherd-service-names os)))))
 194
 195           (test-assert "homes"
 196             (let ((homes
 197                    '#$(map user-account-home-directory
 198                            (filter user-account-create-home-directory?
 199                                    (operating-system-user-accounts os)))))
 200               (marionette-eval
 201                `(begin
 202                   (use-modules (gnu services herd) (srfi srfi-1))
 203
 204                   ;; Home directories are supposed to exist once 'user-homes'
 205                   ;; has been started.
 206                   (start-service 'user-homes)
 207
 208                   (every (lambda (home)
 209                            (and (file-exists? home)
 210                                 (file-is-directory? home)))
 211                          ',homes))
 212                marionette)))
 213
 214           (test-assert "skeletons in home directories"
 215             (let ((users+homes
 216                    '#$(filter-map (lambda (account)
 217                                     (and (user-account-create-home-directory?
 218                                           account)
 219                                          (not (user-account-system? account))
 220                                          (list (user-account-name account)
 221                                                (user-account-home-directory
 222                                                 account))))
 223                                   (operating-system-user-accounts os))))
 224               (marionette-eval
 225                `(begin
 226                   (use-modules (srfi srfi-1) (ice-9 ftw)
 227                                (ice-9 match))
 228
 229                   (every (match-lambda
 230                            ((user home)
 231                             ;; Make sure HOME has all the skeletons...
 232                             (and (null? (lset-difference string=?
 233                                                          (scandir "/etc/skel/")
 234                                                          (scandir home)))
 235
 236                                  ;; ... and that everything is user-owned.
 237                                  (let* ((pw  (getpwnam user))
 238                                         (uid (passwd:uid pw))
 239                                         (gid (passwd:gid pw))
 240                                         (st  (lstat home)))
 241                                    (define (user-owned? file)
 242                                      (= uid (stat:uid (lstat file))))
 243
 244                                    (and (= uid (stat:uid st))
 245                                         (eq? 'directory (stat:type st))
 246                                         (every user-owned?
 247                                                (find-files home
 248                                                            #:directories? #t)))))))
 249                          ',users+homes))
 250                marionette)))
 251
 252           (test-equal "permissions on /root"
 253             #o700
 254             (let ((root-home #$(any (lambda (account)
 255                                       (and (zero? (user-account-uid account))
 256                                            (user-account-home-directory
 257                                             account)))
 258                                     (operating-system-user-accounts os))))
 259               (stat:perms (marionette-eval `(stat ,root-home) marionette))))
 260
 261           (test-equal "ownership and permissions of /var/empty"
 262             '(0 0 #o555)
 263             (let ((st (marionette-eval `(stat "/var/empty") marionette)))
 264               (list (stat:uid st) (stat:gid st)
 265                     (stat:perms st))))
 266
 267           (test-equal "no extra home directories"
 268             '()
 269
 270             ;; Make sure the home directories that are not supposed to be
 271             ;; created are indeed not created.
 272             (let ((nonexistent
 273                    '#$(filter-map (lambda (user)
 274                                     (and (not
 275                                           (user-account-create-home-directory?
 276                                            user))
 277                                          (user-account-home-directory user)))
 278                                   (operating-system-user-accounts os))))
 279               (marionette-eval
 280                `(begin
 281                   (use-modules (srfi srfi-1))
 282
 283                   ;; Note: Do not flag "/var/empty".
 284                   (filter file-exists?
 285                           ',(remove (cut string-prefix? "/var/" <>)
 286                                     nonexistent)))
 287                marionette)))
 288
 289           (test-equal "login on tty1"
 290             "root\n"
 291             (begin
 292               (marionette-control "sendkey ctrl-alt-f1" marionette)
 293               ;; Wait for the 'term-tty1' service to be running (using
 294               ;; 'start-service' is the simplest and most reliable way to do
 295               ;; that.)
 296               (marionette-eval
 297                '(begin
 298                   (use-modules (gnu services herd))
 299                   (start-service 'term-tty1))
 300                marionette)
 301
 302               ;; Now we can type.
 303               (marionette-type "root\n\nid -un > logged-in\n" marionette)
 304
 305               ;; It can take a while before the shell commands are executed.
 306               (marionette-eval '(use-modules (rnrs io ports)) marionette)
 307               (wait-for-file "/root/logged-in" marionette
 308                              #:read 'get-string-all)))
 309
 310           ;; There should be one utmpx entry for the user logged in on tty1.
 311           (test-equal "utmpx entry"
 312             '(("root" "tty1" #f))
 313             (marionette-eval
 314              '(begin
 315                 (use-modules (guix build syscalls)
 316                              (srfi srfi-1))
 317
 318                 (filter-map (lambda (entry)
 319                               (and (equal? (login-type USER_PROCESS)
 320                                            (utmpx-login-type entry))
 321                                    (list (utmpx-user entry) (utmpx-line entry)
 322                                          (utmpx-host entry))))
 323                             (utmpx-entries)))
 324              marionette))
 325
 326           ;; Likewise for /var/log/wtmp (used by 'last').
 327           (test-assert "wtmp entry"
 328             (match (marionette-eval
 329                     '(begin
 330                        (use-modules (guix build syscalls)
 331                                     (srfi srfi-1))
 332
 333                        (define (entry->list entry)
 334                          (list (utmpx-user entry) (utmpx-line entry)
 335                                (utmpx-host entry) (utmpx-login-type entry)))
 336
 337                        (call-with-input-file "/var/log/wtmp"
 338                          (lambda (port)
 339                            (let loop ((result '()))
 340                              (if (eof-object? (peek-char port))
 341                                  (map entry->list (reverse result))
 342                                  (loop (cons (read-utmpx port) result)))))))
 343                     marionette)
 344               (((users lines hosts types) ..1)
 345                (every (lambda (type)
 346                         (eqv? type (login-type LOGIN_PROCESS)))
 347                       types))))
 348
 349           (test-assert "host name resolution"
 350             (match (marionette-eval
 351                     '(begin
 352                        ;; Wait for nscd or our requests go through it.
 353                        (use-modules (gnu services herd))
 354                        (start-service 'nscd)
 355
 356                        (list (getaddrinfo "localhost")
 357                              (getaddrinfo #$(operating-system-host-name os))))
 358                     marionette)
 359               ((((? vector?) ..1) ((? vector?) ..1))
 360                #t)
 361               (x
 362                (pk 'failure x #f))))
 363
 364           (test-equal "nscd invalidate action"
 365             '(#t)                                 ;one value, #t
 366             (marionette-eval '(with-shepherd-action 'nscd ('invalidate "hosts")
 367                                                     result
 368                                                     result)
 369                              marionette))
 370
 371           (test-equal "nscd invalidate action, wrong table"
 372             '(#f)                                 ;one value, #f
 373             (marionette-eval '(with-shepherd-action 'nscd ('invalidate "xyz")
 374                                                     result
 375                                                     result)
 376                              marionette))
 377
 378           (test-equal "host not found"
 379             #f
 380             (marionette-eval
 381              '(false-if-exception (getaddrinfo "does-not-exist"))
 382              marionette))
 383
 384           (test-equal "locale"
 385             "en_US.utf8"
 386             (marionette-eval '(let ((before (setlocale LC_ALL "en_US.utf8")))
 387                                 (setlocale LC_ALL before))
 388                              marionette))
 389
 390           (test-eq "/run/current-system is a GC root"
 391             'success!
 392             (marionette-eval '(begin
 393                                 ;; Make sure the (guix …) modules are found.
 394                                 (eval-when (expand load eval)
 395                                   (set! %load-path
 396                                     (append (map (lambda (package)
 397                                                    (string-append package
 398                                                                   "/share/guile/site/"
 399                                                                   (effective-version)))
 400                                                  '#$guix&co)
 401                                             %load-path)))
 402
 403                                 (use-modules (srfi srfi-34) (guix store))
 404
 405                                 (let ((system (readlink "/run/current-system")))
 406                                   (guard (c ((store-protocol-error? c)
 407                                              (and (file-exists? system)
 408                                                   'success!)))
 409                                     (with-store store
 410                                       (delete-paths store (list system))
 411                                       #f))))
 412                              marionette))
 413
 414           ;; This symlink is currently unused, but better have it point to the
 415           ;; right place.  See
 416           ;; <https://lists.gnu.org/archive/html/guix-devel/2016-08/msg01641.html>.
 417           (test-equal "/var/guix/gcroots/profiles is a valid symlink"
 418             "/var/guix/profiles"
 419             (marionette-eval '(readlink "/var/guix/gcroots/profiles")
 420                              marionette))
 421
 422
 423           (test-assert "screendump"
 424             (begin
 425               (marionette-control (string-append "screendump " #$output
 426                                                  "/tty1.ppm")
 427                                   marionette)
 428               (file-exists? "tty1.ppm")))
 429
 430           (test-assert "screen text"
 431             (let ((text (marionette-screen-text marionette
 432                                                 #:ocrad
 433                                                 #$(file-append ocrad
 434                                                                "/bin/ocrad"))))
 435               ;; Check whether the welcome message and shell prompt are
 436               ;; displayed.  Note: OCR confuses "y" and "V" for instance, so
 437               ;; we cannot reliably match the whole text.
 438               (and (string-contains text "This is the GNU")
 439                    (string-contains text
 440                                     (string-append
 441                                      "root@"
 442                                      #$(operating-system-host-name os))))))
 443
 444           (test-end)
 445           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 446
 447   (gexp->derivation name test))
 448
 449 (define %test-basic-os
 450   (system-test
 451    (name "basic")
 452    (description
 453     "Instrument %SIMPLE-OS, run it in a VM, and run a series of basic
 454 functionality tests.")
 455    (value
 456     (let* ((os  (marionette-operating-system
 457                  %simple-os
 458                  #:imported-modules '((gnu services herd)
 459                                       (guix combinators))))
 460            (vm  (virtual-machine os)))
 461       ;; XXX: Add call to 'virtualized-operating-system' to get the exact same
 462       ;; set of services as the OS produced by
 463       ;; 'system-qemu-image/shared-store-script'.
 464       (run-basic-test (virtualized-operating-system os '())
 465                       #~(list #$vm))))))
 466
 467 \f
 468 ;;;
 469 ;;; Halt.
 470 ;;;
 471
 472 (define (run-halt-test vm)
 473   ;; As reported in <http://bugs.gnu.org/26931>, running tmux would previously
 474   ;; lead the 'stop' method of 'user-processes' to an infinite loop, with the
 475   ;; tmux server process as a zombie that remains in the list of processes.
 476   ;; This test reproduces this scenario.
 477   (define test
 478     (with-imported-modules '((gnu build marionette))
 479       #~(begin
 480           (use-modules (gnu build marionette))
 481
 482           (define marionette
 483             (make-marionette '(#$vm)))
 484
 485           (define ocrad
 486             #$(file-append ocrad "/bin/ocrad"))
 487
 488           ;; Wait for tty1 and log in.
 489           (marionette-eval '(begin
 490                               (use-modules (gnu services herd))
 491                               (start-service 'term-tty1))
 492                            marionette)
 493           (marionette-type "root\n" marionette)
 494           (wait-for-screen-text marionette
 495                                 (lambda (text)
 496                                   (string-contains text "root@komputilo"))
 497                                 #:ocrad ocrad)
 498
 499           ;; Start tmux and wait for it to be ready.
 500           (marionette-type "tmux new-session 'echo 1 > /ready; bash'\n"
 501                            marionette)
 502           (wait-for-file "/ready" marionette)
 503
 504           ;; Make sure to stop the test after a while.
 505           (sigaction SIGALRM (lambda _
 506                                (format (current-error-port)
 507                                        "FAIL: Time is up, but VM still running.\n")
 508                                (primitive-exit 1)))
 509           (alarm 10)
 510
 511           ;; Get debugging info.
 512           (marionette-eval '(current-output-port
 513                              (open-file "/dev/console" "w0"))
 514                            marionette)
 515           (marionette-eval '(system* #$(file-append procps "/bin/ps")
 516                                      "-eo" "pid,ppid,stat,comm")
 517                            marionette)
 518
 519           ;; See if 'halt' actually works.
 520           (marionette-eval '(system* "/run/current-system/profile/sbin/halt")
 521                            marionette)
 522
 523           ;; If we reach this line, that means the VM was properly stopped in
 524           ;; a timely fashion.
 525           (alarm 0)
 526           (call-with-output-file #$output
 527             (lambda (port)
 528               (display "success!" port))))))
 529
 530   (gexp->derivation "halt" test))
 531
 532 (define %test-halt
 533   (system-test
 534    (name "halt")
 535    (description
 536     "Use the 'halt' command and make sure it succeeds and does not get stuck
 537 in a loop.  See <http://bugs.gnu.org/26931>.")
 538    (value
 539     (let ((os (marionette-operating-system
 540                (operating-system
 541                  (inherit %simple-os)
 542                  (packages (cons tmux %base-packages)))
 543                #:imported-modules '((gnu services herd)
 544                                     (guix combinators)))))
 545       (run-halt-test (virtual-machine os))))))
 546
 547 \f
 548 ;;;
 549 ;;; Cleanup of /tmp, /var/run, etc.
 550 ;;;
 551
 552 (define %cleanup-os
 553   (simple-operating-system
 554    (simple-service 'dirty-things
 555                    boot-service-type
 556                    (let ((script (plain-file
 557                                   "create-utf8-file.sh"
 558                                   (string-append
 559                                    "echo $0: dirtying /tmp...\n"
 560                                    "set -e; set -x\n"
 561                                    "touch /witness\n"
 562                                    "exec touch /tmp/λαμβδα"))))
 563                      (with-imported-modules '((guix build utils))
 564                        #~(begin
 565                            (setenv "PATH"
 566                                    #$(file-append coreutils "/bin"))
 567                            (invoke #$(file-append bash "/bin/sh")
 568                                    #$script)))))))
 569
 570 (define (run-cleanup-test name)
 571   (define os
 572     (marionette-operating-system %cleanup-os
 573                                  #:imported-modules '((gnu services herd)
 574                                                       (guix combinators))))
 575   (define test
 576     (with-imported-modules '((gnu build marionette))
 577       #~(begin
 578           (use-modules (gnu build marionette)
 579                        (srfi srfi-64)
 580                        (ice-9 match))
 581
 582           (define marionette
 583             (make-marionette (list #$(virtual-machine os))))
 584
 585           (mkdir #$output)
 586           (chdir #$output)
 587
 588           (test-begin "cleanup")
 589
 590           (test-assert "dirty service worked"
 591             (marionette-eval '(file-exists? "/witness") marionette))
 592
 593           (test-equal "/tmp cleaned up"
 594             '("." "..")
 595             (marionette-eval '(begin
 596                                 (use-modules (ice-9 ftw))
 597                                 (scandir "/tmp"))
 598                              marionette))
 599
 600           (test-end)
 601           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 602
 603   (gexp->derivation "cleanup" test))
 604
 605 (define %test-cleanup
 606   ;; See <https://bugs.gnu.org/26353>.
 607   (system-test
 608    (name "cleanup")
 609    (description "Make sure the 'cleanup' service can remove files with
 610 non-ASCII names from /tmp.")
 611    (value (run-cleanup-test name))))
 612
 613 \f
 614 ;;;
 615 ;;; Mcron.
 616 ;;;
 617
 618 (define %mcron-os
 619   ;; System with an mcron service, with one mcron job for "root" and one mcron
 620   ;; job for an unprivileged user.
 621   (let ((job1 #~(job '(next-second '(0 5 10 15 20 25 30 35 40 45 50 55))
 622                      (lambda ()
 623                        (unless (file-exists? "witness")
 624                         (call-with-output-file "witness"
 625                           (lambda (port)
 626                             (display (list (getuid) (getgid)) port)))))))
 627         (job2 #~(job next-second-from
 628                      (lambda ()
 629                        (call-with-output-file "witness"
 630                          (lambda (port)
 631                            (display (list (getuid) (getgid)) port))))
 632                      #:user "alice"))
 633         (job3 #~(job next-second-from             ;to test $PATH
 634                      "touch witness-touch")))
 635     (simple-operating-system
 636      (service mcron-service-type
 637               (mcron-configuration (jobs (list job1 job2 job3)))))))
 638
 639 (define (run-mcron-test name)
 640   (define os
 641     (marionette-operating-system
 642      %mcron-os
 643      #:imported-modules '((gnu services herd)
 644                           (guix combinators))))
 645
 646   (define test
 647     (with-imported-modules '((gnu build marionette))
 648       #~(begin
 649           (use-modules (gnu build marionette)
 650                        (srfi srfi-64)
 651                        (ice-9 match))
 652
 653           (define marionette
 654             (make-marionette (list #$(virtual-machine os))))
 655
 656           (mkdir #$output)
 657           (chdir #$output)
 658
 659           (test-begin "mcron")
 660
 661           (test-assert "service running"
 662             (marionette-eval
 663              '(begin
 664                 (use-modules (gnu services herd))
 665                 (start-service 'mcron))
 666              marionette))
 667
 668           ;; Make sure root's mcron job runs, has its cwd set to "/root", and
 669           ;; runs with the right UID/GID.
 670           (test-equal "root's job"
 671             '(0 0)
 672             (wait-for-file "/root/witness" marionette))
 673
 674           ;; Likewise for Alice's job.  We cannot know what its GID is since
 675           ;; it's chosen by 'groupadd', but it's strictly positive.
 676           (test-assert "alice's job"
 677             (match (wait-for-file "/home/alice/witness" marionette)
 678               ((1000 gid)
 679                (>= gid 100))))
 680
 681           ;; Last, the job that uses a command; allows us to test whether
 682           ;; $PATH is sane.
 683           (test-equal "root's job with command"
 684             ""
 685             (wait-for-file "/root/witness-touch" marionette
 686                            #:read '(@ (ice-9 rdelim) read-string)))
 687
 688           ;; Make sure the 'schedule' action is accepted.
 689           (test-equal "schedule action"
 690             '(#t)                                 ;one value, #t
 691             (marionette-eval '(with-shepherd-action 'mcron ('schedule) result
 692                                 result)
 693                              marionette))
 694
 695           (test-end)
 696           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 697
 698   (gexp->derivation name test))
 699
 700 (define %test-mcron
 701   (system-test
 702    (name "mcron")
 703    (description "Make sure the mcron service works as advertised.")
 704    (value (run-mcron-test name))))
 705
 706 \f
 707 ;;;
 708 ;;; Avahi and NSS-mDNS.
 709 ;;;
 710
 711 (define %avahi-os
 712   (operating-system
 713     (inherit %simple-os)
 714     (name-service-switch %mdns-host-lookup-nss)
 715     (services (cons* (service avahi-service-type
 716                               (avahi-configuration (debug? #t)))
 717                      (dbus-service)
 718                      (service dhcp-client-service-type) ;needed for multicast
 719
 720                      ;; Enable heavyweight debugging output.
 721                      (modify-services (operating-system-user-services
 722                                        %simple-os)
 723                        (nscd-service-type config
 724                                           => (nscd-configuration
 725                                               (inherit config)
 726                                               (debug-level 3)
 727                                               (log-file "/dev/console")))
 728                        (syslog-service-type config
 729                                             =>
 730                                             (syslog-configuration
 731                                              (inherit config)
 732                                              (config-file
 733                                               (plain-file
 734                                                "syslog.conf"
 735                                                "*.* /dev/console\n")))))))))
 736
 737 (define (run-nss-mdns-test)
 738   ;; Test resolution of '.local' names via libc.  Start the marionette service
 739   ;; *after* nscd.  Failing to do that, libc will try to connect to nscd,
 740   ;; fail, then never try again (see '__nss_not_use_nscd_hosts' in libc),
 741   ;; leading to '.local' resolution failures.
 742   (define os
 743     (marionette-operating-system
 744      %avahi-os
 745      #:requirements '(nscd)
 746      #:imported-modules '((gnu services herd)
 747                           (guix combinators))))
 748
 749   (define mdns-host-name
 750     (string-append (operating-system-host-name os)
 751                    ".local"))
 752
 753   (define test
 754     (with-imported-modules '((gnu build marionette))
 755       #~(begin
 756           (use-modules (gnu build marionette)
 757                        (srfi srfi-1)
 758                        (srfi srfi-64)
 759                        (ice-9 match))
 760
 761           (define marionette
 762             (make-marionette (list #$(virtual-machine os))))
 763
 764           (mkdir #$output)
 765           (chdir #$output)
 766
 767           (test-begin "avahi")
 768
 769           (test-assert "nscd PID file is created"
 770             (marionette-eval
 771              '(begin
 772                 (use-modules (gnu services herd))
 773                 (start-service 'nscd))
 774              marionette))
 775
 776           (test-assert "nscd is listening on its socket"
 777             (marionette-eval
 778              ;; XXX: Work around a race condition in nscd: nscd creates its
 779              ;; PID file before it is listening on its socket.
 780              '(let ((sock (socket PF_UNIX SOCK_STREAM 0)))
 781                 (let try ()
 782                   (catch 'system-error
 783                     (lambda ()
 784                       (connect sock AF_UNIX "/var/run/nscd/socket")
 785                       (close-port sock)
 786                       (format #t "nscd is ready~%")
 787                       #t)
 788                     (lambda args
 789                       (format #t "waiting for nscd...~%")
 790                       (usleep 500000)
 791                       (try)))))
 792              marionette))
 793
 794           (test-assert "avahi is running"
 795             (marionette-eval
 796              '(begin
 797                 (use-modules (gnu services herd))
 798                 (start-service 'avahi-daemon))
 799              marionette))
 800
 801           (test-assert "network is up"
 802             (marionette-eval
 803              '(begin
 804                 (use-modules (gnu services herd))
 805                 (start-service 'networking))
 806              marionette))
 807
 808           (test-equal "avahi-resolve-host-name"
 809             0
 810             (marionette-eval
 811              '(system*
 812                "/run/current-system/profile/bin/avahi-resolve-host-name"
 813                "-v" #$mdns-host-name)
 814              marionette))
 815
 816           (test-equal "avahi-browse"
 817             0
 818             (marionette-eval
 819              '(system* "avahi-browse" "-avt")
 820              marionette))
 821
 822           (test-assert "getaddrinfo .local"
 823             ;; Wait for the 'avahi-daemon' service and perform a resolution.
 824             (match (marionette-eval
 825                     '(getaddrinfo #$mdns-host-name)
 826                     marionette)
 827               (((? vector? addrinfos) ..1)
 828                (pk 'getaddrinfo addrinfos)
 829                (and (any (lambda (ai)
 830                            (= AF_INET (addrinfo:fam ai)))
 831                          addrinfos)
 832                     (any (lambda (ai)
 833                            (= AF_INET6 (addrinfo:fam ai)))
 834                          addrinfos)))))
 835
 836           (test-assert "gethostbyname .local"
 837             (match (pk 'gethostbyname
 838                        (marionette-eval '(gethostbyname #$mdns-host-name)
 839                                         marionette))
 840               ((? vector? result)
 841                (and (string=? (hostent:name result) #$mdns-host-name)
 842                     (= (hostent:addrtype result) AF_INET)))))
 843
 844
 845           (test-end)
 846           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 847
 848   (gexp->derivation "nss-mdns" test))
 849
 850 (define %test-nss-mdns
 851   (system-test
 852    (name "nss-mdns")
 853    (description
 854     "Test Avahi's multicast-DNS implementation, and in particular, test its
 855 glibc name service switch (NSS) module.")
 856    (value (run-nss-mdns-test))))