gnu/system.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015, 2016 Alex Kost <alezost@gmail.com>
   5 ;;; Copyright © 2016 Chris Marusich <cmmarusich@gmail.com>
   6 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   7 ;;;
   8 ;;; This file is part of GNU Guix.
   9 ;;;
  10 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  11 ;;; under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or (at
  13 ;;; your option) any later version.
  14 ;;;
  15 ;;; GNU Guix is distributed in the hope that it will be useful, but
  16 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 (define-module (gnu system)
  24   #:use-module (guix store)
  25   #:use-module (guix monads)
  26   #:use-module (guix gexp)
  27   #:use-module (guix records)
  28   #:use-module (guix packages)
  29   #:use-module (guix derivations)
  30   #:use-module (guix profiles)
  31   #:use-module (guix ui)
  32   #:use-module (gnu packages base)
  33   #:use-module (gnu packages bash)
  34   #:use-module (gnu packages guile)
  35   #:use-module (gnu packages admin)
  36   #:use-module (gnu packages linux)
  37   #:use-module (gnu packages pciutils)
  38   #:use-module (gnu packages package-management)
  39   #:use-module (gnu packages less)
  40   #:use-module (gnu packages zile)
  41   #:use-module (gnu packages nano)
  42   #:use-module (gnu packages gawk)
  43   #:use-module (gnu packages man)
  44   #:use-module (gnu packages texinfo)
  45   #:use-module (gnu packages compression)
  46   #:use-module (gnu packages firmware)
  47   #:use-module (gnu services)
  48   #:use-module (gnu services shepherd)
  49   #:use-module (gnu services base)
  50   #:use-module (gnu bootloader)
  51   #:use-module (gnu system shadow)
  52   #:use-module (gnu system nss)
  53   #:use-module (gnu system locale)
  54   #:use-module (gnu system pam)
  55   #:use-module (gnu system linux-initrd)
  56   #:use-module (gnu system uuid)
  57   #:use-module (gnu system file-systems)
  58   #:use-module (gnu system mapped-devices)
  59   #:use-module (ice-9 match)
  60   #:use-module (srfi srfi-1)
  61   #:use-module (srfi srfi-26)
  62   #:use-module (srfi srfi-34)
  63   #:use-module (srfi srfi-35)
  64   #:use-module (rnrs bytevectors)
  65   #:export (operating-system
  66             operating-system?
  67
  68             operating-system-bootloader
  69             operating-system-services
  70             operating-system-user-services
  71             operating-system-packages
  72             operating-system-host-name
  73             operating-system-hosts-file
  74             operating-system-kernel
  75             operating-system-kernel-file
  76             operating-system-kernel-arguments
  77             operating-system-initrd-modules
  78             operating-system-initrd
  79             operating-system-users
  80             operating-system-groups
  81             operating-system-issue
  82             operating-system-timezone
  83             operating-system-locale
  84             operating-system-locale-definitions
  85             operating-system-locale-libcs
  86             operating-system-mapped-devices
  87             operating-system-file-systems
  88             operating-system-store-file-system
  89             operating-system-user-mapped-devices
  90             operating-system-boot-mapped-devices
  91             operating-system-activation-script
  92             operating-system-user-accounts
  93             operating-system-shepherd-service-names
  94             operating-system-user-kernel-arguments
  95
  96             operating-system-derivation
  97             operating-system-profile
  98             operating-system-bootcfg
  99             operating-system-etc-directory
 100             operating-system-locale-directory
 101             operating-system-boot-script
 102
 103             system-linux-image-file-name
 104
 105             boot-parameters
 106             boot-parameters?
 107             boot-parameters-label
 108             boot-parameters-root-device
 109             boot-parameters-bootloader-name
 110             boot-parameters-store-device
 111             boot-parameters-store-mount-point
 112             boot-parameters-kernel
 113             boot-parameters-kernel-arguments
 114             boot-parameters-initrd
 115             read-boot-parameters
 116             read-boot-parameters-file
 117             boot-parameters->menu-entry
 118
 119             local-host-aliases
 120             %setuid-programs
 121             %base-packages
 122             %base-firmware))
 123
 124 ;;; Commentary:
 125 ;;;
 126 ;;; This module supports whole-system configuration.
 127 ;;;
 128 ;;; Code:
 129
 130 (define (bootable-kernel-arguments kernel-arguments system.drv root-device)
 131   "Prepend extra arguments to KERNEL-ARGUMENTS that allow SYSTEM.DRV to be
 132 booted from ROOT-DEVICE"
 133   (cons* (string-append "--root="
 134                         (cond ((uuid? root-device)
 135
 136                                ;; Note: Always use the DCE format because that's
 137                                ;; what (gnu build linux-boot) expects for the
 138                                ;; '--root' kernel command-line option.
 139                                (uuid->string (uuid-bytevector root-device)
 140                                              'dce))
 141                               ((file-system-label? root-device)
 142                                (file-system-label->string root-device))
 143                               (else root-device)))
 144          #~(string-append "--system=" #$system.drv)
 145          #~(string-append "--load=" #$system.drv "/boot")
 146          kernel-arguments))
 147
 148 ;; System-wide configuration.
 149 ;; TODO: Add per-field docstrings/stexi.
 150 (define-record-type* <operating-system> operating-system
 151   make-operating-system
 152   operating-system?
 153   (kernel operating-system-kernel                 ; package
 154           (default linux-libre))
 155   (kernel-arguments operating-system-user-kernel-arguments
 156                     (default '()))                ; list of gexps/strings
 157   (bootloader operating-system-bootloader)        ; <bootloader-configuration>
 158
 159   (initrd operating-system-initrd                 ; (list fs) -> M derivation
 160           (default base-initrd))
 161   (initrd-modules operating-system-initrd-modules ; list of strings
 162                   (thunked)                       ; it's system-dependent
 163                   (default %base-initrd-modules))
 164
 165   (firmware operating-system-firmware             ; list of packages
 166             (default %base-firmware))
 167
 168   (host-name operating-system-host-name)          ; string
 169   (hosts-file operating-system-hosts-file         ; file-like | #f
 170               (default #f))
 171
 172   (mapped-devices operating-system-mapped-devices ; list of <mapped-device>
 173                   (default '()))
 174   (file-systems operating-system-file-systems)    ; list of fs
 175   (swap-devices operating-system-swap-devices     ; list of strings
 176                 (default '()))
 177
 178   (users operating-system-users                   ; list of user accounts
 179          (default %base-user-accounts))
 180   (groups operating-system-groups                 ; list of user groups
 181           (default %base-groups))
 182
 183   (skeletons operating-system-skeletons           ; list of name/monadic value
 184              (default (default-skeletons)))
 185   (issue operating-system-issue                   ; string
 186          (default %default-issue))
 187
 188   (packages operating-system-packages             ; list of (PACKAGE OUTPUT...)
 189             (default %base-packages))             ; or just PACKAGE
 190
 191   (timezone operating-system-timezone)            ; string
 192   (locale   operating-system-locale               ; string
 193             (default "en_US.utf8"))
 194   (locale-definitions operating-system-locale-definitions ; list of <locale-definition>
 195                       (default %default-locale-definitions))
 196   (locale-libcs operating-system-locale-libcs     ; list of <packages>
 197                 (default %default-locale-libcs))
 198   (name-service-switch operating-system-name-service-switch ; <name-service-switch>
 199                        (default %default-nss))
 200
 201   (services operating-system-user-services        ; list of monadic services
 202             (default %base-services))
 203
 204   (pam-services operating-system-pam-services     ; list of PAM services
 205                 (default (base-pam-services)))
 206   (setuid-programs operating-system-setuid-programs
 207                    (default %setuid-programs))    ; list of string-valued gexps
 208
 209   (sudoers-file operating-system-sudoers-file     ; file-like
 210                 (default %sudoers-specification)))
 211
 212 (define (operating-system-kernel-arguments os system.drv root-device)
 213   "Return all the kernel arguments, including the ones not specified
 214 directly by the user."
 215   (bootable-kernel-arguments (operating-system-user-kernel-arguments os)
 216                              system.drv
 217                              root-device))
 218
 219 \f
 220 ;;;
 221 ;;; Boot parameters
 222 ;;;
 223
 224 (define-record-type* <boot-parameters>
 225   boot-parameters make-boot-parameters boot-parameters?
 226   (label            boot-parameters-label)
 227   ;; Because we will use the 'store-device' to create the GRUB search command,
 228   ;; the 'store-device' has slightly different semantics than 'root-device'.
 229   ;; The 'store-device' can be a file system uuid, a file system label, or #f,
 230   ;; but it cannot be a device path such as "/dev/sda3", since GRUB would not
 231   ;; understand that.  The 'root-device', on the other hand, corresponds
 232   ;; exactly to the device field of the <file-system> object representing the
 233   ;; OS's root file system, so it might be a device path like "/dev/sda3".
 234   (root-device      boot-parameters-root-device)
 235   (bootloader-name  boot-parameters-bootloader-name)
 236   (store-device     boot-parameters-store-device)
 237   (store-mount-point boot-parameters-store-mount-point)
 238   (kernel           boot-parameters-kernel)
 239   (kernel-arguments boot-parameters-kernel-arguments)
 240   (initrd           boot-parameters-initrd))
 241
 242 (define (ensure-not-/dev device)
 243   "If DEVICE starts with a slash, return #f.  This is meant to filter out
 244 Linux device names such as /dev/sda, and to preserve GRUB device names and
 245 file system labels."
 246   (if (and (string? device) (string-prefix? "/" device))
 247       #f
 248       device))
 249
 250 (define (read-boot-parameters port)
 251   "Read boot parameters from PORT and return the corresponding
 252 <boot-parameters> object or #f if the format is unrecognized."
 253   (define device-sexp->device
 254     (match-lambda
 255       (('uuid (? symbol? type) (? bytevector? bv))
 256        (bytevector->uuid bv type))
 257       (('file-system-label (? string? label))
 258        (file-system-label label))
 259       ((? bytevector? bv)                         ;old format
 260        (bytevector->uuid bv 'dce))
 261       ((? string? device)
 262        ;; It used to be that we would not distinguish between labels and
 263        ;; device names.  Try to infer the right thing here.
 264        (if (string-prefix? "/dev/" device)
 265            device
 266            (file-system-label device)))))
 267
 268   (match (read port)
 269     (('boot-parameters ('version 0)
 270                        ('label label) ('root-device root)
 271                        ('kernel linux)
 272                        rest ...)
 273      (boot-parameters
 274       (label label)
 275       (root-device (device-sexp->device root))
 276
 277       (bootloader-name
 278        (match (assq 'bootloader-name rest)
 279          ((_ args) args)
 280          (#f       'grub))) ; for compatibility reasons.
 281
 282       ;; In the past, we would store the directory name of the kernel instead
 283       ;; of the absolute file name of its image.  Detect that and correct it.
 284       (kernel (if (string=? linux (direct-store-path linux))
 285                   (string-append linux "/"
 286                                  (system-linux-image-file-name))
 287                   linux))
 288
 289       (kernel-arguments
 290        (match (assq 'kernel-arguments rest)
 291          ((_ args) args)
 292          (#f       '())))                         ;the old format
 293
 294       (initrd
 295        (match (assq 'initrd rest)
 296          (('initrd ('string-append directory file)) ;the old format
 297           (string-append directory file))
 298          (('initrd (? string? file))
 299           file)))
 300
 301       (store-device
 302        ;; Linux device names like "/dev/sda1" are not suitable GRUB device
 303        ;; identifiers, so we just filter them out.
 304        (ensure-not-/dev
 305         (match (assq 'store rest)
 306           (('store ('device #f) _ ...)
 307            root-device)
 308           (('store ('device device) _ ...)
 309            (device-sexp->device device))
 310           (_                                      ;the old format
 311            root-device))))
 312
 313       (store-mount-point
 314        (match (assq 'store rest)
 315          (('store ('device _) ('mount-point mount-point) _ ...)
 316           mount-point)
 317          (_                                       ;the old format
 318           "/")))))
 319     (x                                            ;unsupported format
 320      (warning (G_ "unrecognized boot parameters at '~a'~%")
 321               (port-filename port))
 322      #f)))
 323
 324 (define (read-boot-parameters-file system)
 325   "Read boot parameters from SYSTEM's (system or generation) \"parameters\"
 326 file and returns the corresponding <boot-parameters> object or #f if the
 327 format is unrecognized.
 328 The object has its kernel-arguments extended in order to make it bootable."
 329   (let* ((file (string-append system "/parameters"))
 330          (params (call-with-input-file file read-boot-parameters))
 331          (root (boot-parameters-root-device params))
 332          (kernel-arguments (boot-parameters-kernel-arguments params)))
 333     (if params
 334       (boot-parameters
 335         (inherit params)
 336         (kernel-arguments (bootable-kernel-arguments kernel-arguments
 337                                                      system root)))
 338       #f)))
 339
 340 (define (boot-parameters->menu-entry conf)
 341   (menu-entry
 342    (label (boot-parameters-label conf))
 343    (device (boot-parameters-store-device conf))
 344    (device-mount-point (boot-parameters-store-mount-point conf))
 345    (linux (boot-parameters-kernel conf))
 346    (linux-arguments (boot-parameters-kernel-arguments conf))
 347    (initrd (boot-parameters-initrd conf))))
 348
 349
 350 \f
 351 ;;;
 352 ;;; Services.
 353 ;;;
 354
 355 (define (non-boot-file-system-service os)
 356   "Return the file system service for the file systems of OS that are not
 357 marked as 'needed-for-boot'."
 358   (define file-systems
 359     (remove file-system-needed-for-boot?
 360             (operating-system-file-systems os)))
 361
 362   (define (device-mappings fs)
 363     (let ((device (file-system-device fs)))
 364       (if (string? device)                        ;title is 'device
 365           (filter (lambda (md)
 366                     (string=? (string-append "/dev/mapper/"
 367                                              (mapped-device-target md))
 368                               device))
 369                   (operating-system-mapped-devices os))
 370           '())))
 371
 372   (define (add-dependencies fs)
 373     ;; Add the dependencies due to device mappings to FS.
 374     (file-system
 375       (inherit fs)
 376       (dependencies
 377        (delete-duplicates (append (device-mappings fs)
 378                                   (file-system-dependencies fs))
 379                           eq?))))
 380
 381   (service file-system-service-type
 382            (map add-dependencies file-systems)))
 383
 384 (define (mapped-device-user device file-systems)
 385   "Return a file system among FILE-SYSTEMS that uses DEVICE, or #f."
 386   (let ((target (string-append "/dev/mapper/" (mapped-device-target device))))
 387     (find (lambda (fs)
 388             (or (member device (file-system-dependencies fs))
 389                 (and (string? (file-system-device fs))
 390                      (string=? (file-system-device fs) target))))
 391           file-systems)))
 392
 393 (define (operating-system-user-mapped-devices os)
 394   "Return the subset of mapped devices that can be installed in
 395 user-land--i.e., those not needed during boot."
 396   (let ((devices      (operating-system-mapped-devices os))
 397         (file-systems (operating-system-file-systems os)))
 398    (filter (lambda (md)
 399              (let ((user (mapped-device-user md file-systems)))
 400                (or (not user)
 401                    (not (file-system-needed-for-boot? user)))))
 402            devices)))
 403
 404 (define (operating-system-boot-mapped-devices os)
 405   "Return the subset of mapped devices that must be installed during boot,
 406 from the initrd."
 407   (let ((devices      (operating-system-mapped-devices os))
 408         (file-systems (operating-system-file-systems os)))
 409    (filter (lambda (md)
 410              (let ((user (mapped-device-user md file-systems)))
 411                (and user (file-system-needed-for-boot? user))))
 412            devices)))
 413
 414 (define (device-mapping-services os)
 415   "Return the list of device-mapping services for OS as a list."
 416   (map device-mapping-service
 417        (operating-system-user-mapped-devices os)))
 418
 419 (define (swap-services os)
 420   "Return the list of swap services for OS."
 421   (map swap-service (operating-system-swap-devices os)))
 422
 423 (define* (system-linux-image-file-name #:optional (system (%current-system)))
 424   "Return the basename of the kernel image file for SYSTEM."
 425   ;; FIXME: Evaluate the conditional based on the actual current system.
 426   (cond
 427    ((string-prefix? "arm" (%current-system)) "zImage")
 428    ((string-prefix? "mips" (%current-system)) "vmlinuz")
 429    ((string-prefix? "aarch64" (%current-system)) "Image")
 430    (else "bzImage")))
 431
 432 (define (operating-system-kernel-file os)
 433   "Return an object representing the absolute file name of the kernel image of
 434 OS."
 435   (file-append (operating-system-kernel os)
 436                "/" (system-linux-image-file-name os)))
 437
 438 (define* (operating-system-directory-base-entries os #:key container?)
 439   "Return the basic entries of the 'system' directory of OS for use as the
 440 value of the SYSTEM-SERVICE-TYPE service."
 441   (let ((locale (operating-system-locale-directory os)))
 442     (with-monad %store-monad
 443       (if container?
 444           (return `(("locale" ,locale)))
 445           (mlet %store-monad
 446               ((kernel  ->  (operating-system-kernel os))
 447                (initrd      (operating-system-initrd-file os))
 448                (params      (operating-system-boot-parameters-file os)))
 449             (return `(("kernel" ,kernel)
 450                       ("parameters" ,params)
 451                       ("initrd" ,initrd)
 452                       ("locale" ,locale))))))))   ;used by libc
 453
 454 (define* (essential-services os #:key container?)
 455   "Return the list of essential services for OS.  These are special services
 456 that implement part of what's declared in OS are responsible for low-level
 457 bookkeeping.  CONTAINER? determines whether to return the list of services for
 458 a container or that of a \"bare metal\" system."
 459   (define known-fs
 460     (map file-system-mount-point (operating-system-file-systems os)))
 461
 462   (let* ((mappings  (device-mapping-services os))
 463          (root-fs   (root-file-system-service))
 464          (other-fs  (non-boot-file-system-service os))
 465          (swaps     (swap-services os))
 466          (procs     (service user-processes-service-type))
 467          (host-name (host-name-service (operating-system-host-name os)))
 468          (entries   (operating-system-directory-base-entries
 469                      os #:container? container?)))
 470     (cons* (service system-service-type entries)
 471            %boot-service
 472
 473            ;; %SHEPHERD-ROOT-SERVICE must come first so that the gexp that
 474            ;; execs shepherd comes last in the boot script (XXX).  Likewise,
 475            ;; the cleanup service must come last so that its gexp runs before
 476            ;; activation code.
 477            %shepherd-root-service
 478            %activation-service
 479            (service cleanup-service-type #f)
 480
 481            (pam-root-service (operating-system-pam-services os))
 482            (account-service (append (operating-system-accounts os)
 483                                     (operating-system-groups os))
 484                             (operating-system-skeletons os))
 485            (operating-system-etc-service os)
 486            (service fstab-service-type '())
 487            (session-environment-service
 488             (operating-system-environment-variables os))
 489            host-name procs root-fs
 490            (service setuid-program-service-type
 491                     (operating-system-setuid-programs os))
 492            (service profile-service-type
 493                     (operating-system-packages os))
 494            other-fs
 495            (append mappings swaps
 496
 497                    ;; Add the firmware service, unless we are building for a
 498                    ;; container.
 499                    (if container?
 500                        '()
 501                        (list %linux-bare-metal-service
 502                              (service firmware-service-type
 503                                       (operating-system-firmware os))))))))
 504
 505 (define* (operating-system-services os #:key container?)
 506   "Return all the services of OS, including \"internal\" services that do not
 507 explicitly appear in OS."
 508   (instantiate-missing-services
 509    (append (operating-system-user-services os)
 510            (essential-services os #:container? container?))))
 511
 512 \f
 513 ;;;
 514 ;;; /etc.
 515 ;;;
 516
 517 (define %base-firmware
 518   ;; Firmware usable by default.
 519   (list ath9k-htc-firmware
 520         openfwwf-firmware))
 521
 522 (define %base-packages
 523   ;; Default set of packages globally visible.  It should include anything
 524   ;; required for basic administrator tasks.
 525   (cons* procps psmisc which less zile nano
 526          pciutils usbutils
 527          util-linux
 528          inetutils isc-dhcp
 529          (@ (gnu packages admin) shadow)          ;for 'passwd'
 530
 531          ;; wireless-tools is deprecated in favor of iw, but it's still what
 532          ;; many people are familiar with, so keep it around.
 533          iw wireless-tools
 534
 535          iproute
 536          net-tools                        ; XXX: remove when Inetutils suffices
 537          man-db
 538          info-reader                     ;the standalone Info reader (no Perl)
 539
 540          ;; The 'sudo' command is already in %SETUID-PROGRAMS, but we also
 541          ;; want the other commands and the man pages (notably because
 542          ;; auto-completion in Emacs shell relies on man pages.)
 543          sudo
 544
 545          ;; Get 'insmod' & co. from kmod, not module-init-tools, since udev
 546          ;; already depends on it anyway.
 547          kmod eudev
 548
 549          e2fsprogs kbd
 550
 551          bash-completion
 552
 553          ;; XXX: We don't use (canonical-package guile-2.2) here because that
 554          ;; would create a collision in the global profile between the GMP
 555          ;; variant propagated by 'guile-final' and the GMP variant propagated
 556          ;; by 'gnutls', itself propagated by 'guix'.
 557          guile-2.2
 558
 559          ;; The packages below are also in %FINAL-INPUTS, so take them from
 560          ;; there to avoid duplication.
 561          (map canonical-package
 562               (list bash coreutils findutils grep sed
 563                     diffutils patch gawk tar gzip bzip2 xz lzip))))
 564
 565 (define %default-issue
 566   ;; Default contents for /etc/issue.
 567   "
 568 This is the GNU system.  Welcome.\n")
 569
 570 (define (local-host-aliases host-name)
 571   "Return aliases for HOST-NAME, to be used in /etc/hosts."
 572   (string-append "127.0.0.1 localhost " host-name "\n"
 573                  "::1       localhost " host-name "\n"))
 574
 575 (define (default-/etc/hosts host-name)
 576   "Return the default /etc/hosts file."
 577   (plain-file "hosts" (local-host-aliases host-name)))
 578
 579 (define* (operating-system-etc-service os)
 580   "Return a <service> that builds containing the static part of the /etc
 581 directory."
 582   (let ((login.defs
 583           (plain-file "login.defs"
 584                       (string-append
 585                         "# Default paths for non-login shells started by su(1).\n"
 586                         "ENV_PATH    /run/setuid-programs:"
 587                         "/run/current-system/profile/bin:"
 588                         "/run/current-system/profile/sbin\n"
 589                         "ENV_SUPATH  /run/setuid-programs:"
 590                         "/run/current-system/profile/bin:"
 591                         "/run/current-system/profile/sbin\n")))
 592
 593         (issue      (plain-file "issue" (operating-system-issue os)))
 594         (nsswitch   (plain-file "nsswitch.conf"
 595                                 (name-service-switch->string
 596                                  (operating-system-name-service-switch os))))
 597
 598         ;; Startup file for POSIX-compliant login shells, which set system-wide
 599         ;; environment variables.
 600         (profile    (mixed-text-file "profile"  "\
 601 # Crucial variables that could be missing in the profiles' 'etc/profile'
 602 # because they would require combining both profiles.
 603 # FIXME: See <http://bugs.gnu.org/20255>.
 604 export MANPATH=$HOME/.guix-profile/share/man:/run/current-system/profile/share/man
 605 export INFOPATH=$HOME/.guix-profile/share/info:/run/current-system/profile/share/info
 606 export XDG_DATA_DIRS=$HOME/.guix-profile/share:/run/current-system/profile/share
 607 export XDG_CONFIG_DIRS=$HOME/.guix-profile/etc/xdg:/run/current-system/profile/etc/xdg
 608
 609 # Make sure libXcursor finds cursors installed into user or system profiles.  See <http://bugs.gnu.org/24445>
 610 export XCURSOR_PATH=$HOME/.icons:$HOME/.guix-profile/share/icons:/run/current-system/profile/share/icons
 611
 612 # Ignore the default value of 'PATH'.
 613 unset PATH
 614
 615 # Load the system profile's settings.
 616 GUIX_PROFILE=/run/current-system/profile ; \\
 617 . /run/current-system/profile/etc/profile
 618
 619 # Prepend setuid programs.
 620 export PATH=/run/setuid-programs:$PATH
 621
 622 # Since 'lshd' does not use pam_env, /etc/environment must be explicitly
 623 # loaded when someone logs in via SSH.  See <http://bugs.gnu.org/22175>.
 624 # We need 'PATH' to be defined here, for 'cat' and 'cut'.  Do this before
 625 # reading the user's 'etc/profile' to allow variables to be overridden.
 626 if [ -f /etc/environment -a -n \"$SSH_CLIENT\" \\
 627      -a -z \"$LINUX_MODULE_DIRECTORY\" ]
 628 then
 629   . /etc/environment
 630   export `cat /etc/environment | cut -d= -f1`
 631 fi
 632
 633 # Arrange so that ~/.config/guix/current comes first.
 634 for profile in \"$HOME/.guix-profile\" \"$HOME/.config/guix/current\"
 635 do
 636   if [ -f \"$profile/etc/profile\" ]
 637   then
 638     # Load the user profile's settings.
 639     GUIX_PROFILE=\"$profile\" ; \\
 640     . \"$profile/etc/profile\"
 641   else
 642     # At least define this one so that basic things just work
 643     # when the user installs their first package.
 644     export PATH=\"$profile/bin:$PATH\"
 645   fi
 646 done
 647
 648 # Arrange so that ~/.config/guix/current/share/info comes first.
 649 export INFOPATH=\"$HOME/.config/guix/current/share/info:$INFOPATH\"
 650
 651 # Set the umask, notably for users logging in via 'lsh'.
 652 # See <http://bugs.gnu.org/22650>.
 653 umask 022
 654
 655 # Allow Hunspell-based applications (IceCat, LibreOffice, etc.) to
 656 # find dictionaries.
 657 export DICPATH=\"$HOME/.guix-profile/share/hunspell:/run/current-system/profile/share/hunspell\"
 658
 659 # Allow GStreamer-based applications to find plugins.
 660 export GST_PLUGIN_PATH=\"$HOME/.guix-profile/lib/gstreamer-1.0\"
 661
 662 if [ -n \"$BASH_VERSION\" -a -f /etc/bashrc ]
 663 then
 664   # Load Bash-specific initialization code.
 665   . /etc/bashrc
 666 fi
 667 "))
 668
 669         (bashrc    (plain-file "bashrc" "\
 670 # Bash-specific initialization.
 671
 672 # The 'bash-completion' package.
 673 if [ -f /run/current-system/profile/etc/profile.d/bash_completion.sh ]
 674 then
 675   # Bash-completion sources ~/.bash_completion.  It installs a dynamic
 676   # completion loader that searches its own completion files as well
 677   # as those in ~/.guix-profile and /run/current-system/profile.
 678   source /run/current-system/profile/etc/profile.d/bash_completion.sh
 679 fi\n")))
 680     (etc-service
 681      `(("services" ,(file-append net-base "/etc/services"))
 682        ("protocols" ,(file-append net-base "/etc/protocols"))
 683        ("rpc" ,(file-append net-base "/etc/rpc"))
 684        ("login.defs" ,#~#$login.defs)
 685        ("issue" ,#~#$issue)
 686        ("nsswitch.conf" ,#~#$nsswitch)
 687        ("profile" ,#~#$profile)
 688        ("bashrc" ,#~#$bashrc)
 689        ("hosts" ,#~#$(or (operating-system-hosts-file os)
 690                          (default-/etc/hosts (operating-system-host-name os))))
 691        ;; Write the operating-system-host-name to /etc/hostname to prevent
 692        ;; NetworkManager from changing the system's hostname when connecting
 693        ;; to certain networks.  Some discussion at
 694        ;; https://lists.gnu.org/archive/html/help-guix/2017-09/msg00037.html
 695        ("hostname" ,(plain-file "hostname" (operating-system-host-name os)))
 696        ("localtime" ,(file-append tzdata "/share/zoneinfo/"
 697                                   (operating-system-timezone os)))
 698        ("sudoers" ,(operating-system-sudoers-file os))))))
 699
 700 (define %root-account
 701   ;; Default root account.
 702   (user-account
 703    (name "root")
 704    (password "")
 705    (uid 0) (group "root")
 706    (comment "System administrator")
 707    (home-directory "/root")))
 708
 709 (define (operating-system-accounts os)
 710   "Return the user accounts for OS, including an obligatory 'root' account,
 711 and excluding accounts requested by services."
 712   ;; Make sure there's a root account.
 713   (if (find (lambda (user)
 714               (and=> (user-account-uid user) zero?))
 715             (operating-system-users os))
 716       (operating-system-users os)
 717       (cons %root-account (operating-system-users os))))
 718
 719 (define (maybe-string->file file-name thing)
 720   "If THING is a string, return a <plain-file> with THING as its content.
 721 Otherwise just return THING.
 722
 723 This is for backward-compatibility of fields that used to be strings and are
 724 now file-like objects.."
 725   (match thing
 726     ((? string?)
 727      (warning (G_ "using a string for file '~a' is deprecated; \
 728 use 'plain-file' instead~%")
 729               file-name)
 730      (plain-file file-name thing))
 731     (x
 732      x)))
 733
 734 (define (maybe-file->monadic file-name thing)
 735   "If THING is a value in %STORE-MONAD, return it as is; otherwise return
 736 THING in the %STORE-MONAD.
 737
 738 This is for backward-compatibility of fields that used to be monadic values
 739 and are now file-like objects."
 740   (with-monad %store-monad
 741     (match thing
 742       ((? procedure?)
 743        (warning (G_ "using a monadic value for '~a' is deprecated; \
 744 use 'plain-file' instead~%")
 745                 file-name)
 746        thing)
 747       (x
 748        (return x)))))
 749
 750 (define (operating-system-etc-directory os)
 751   "Return that static part of the /etc directory of OS."
 752   (etc-directory
 753    (fold-services (operating-system-services os)
 754                   #:target-type etc-service-type)))
 755
 756 (define (operating-system-environment-variables os)
 757   "Return the environment variables of OS for
 758 @var{session-environment-service-type}, to be used in @file{/etc/environment}."
 759   `(("LANG" . ,(operating-system-locale os))
 760     ;; Note: No need to set 'TZ' since (1) we provide /etc/localtime, and (2)
 761     ;; it doesn't work for setuid binaries.  See <https://bugs.gnu.org/29212>.
 762     ("TZDIR" . ,(file-append tzdata "/share/zoneinfo"))
 763     ;; Tell 'modprobe' & co. where to look for modules.
 764     ("LINUX_MODULE_DIRECTORY" . "/run/booted-system/kernel/lib/modules")
 765     ;; These variables are honored by OpenSSL (libssl) and Git.
 766     ("SSL_CERT_DIR" . "/etc/ssl/certs")
 767     ("SSL_CERT_FILE" . "/etc/ssl/certs/ca-certificates.crt")
 768     ("GIT_SSL_CAINFO" . "/etc/ssl/certs/ca-certificates.crt")
 769
 770     ;; 'GTK_DATA_PREFIX' must name one directory where GTK+ themes are
 771     ;; searched for.
 772     ("GTK_DATA_PREFIX" . "/run/current-system/profile")
 773
 774     ;; By default, applications that use D-Bus, such as Emacs, abort at startup
 775     ;; when /etc/machine-id is missing.  Make sure these warnings are non-fatal.
 776     ("DBUS_FATAL_WARNINGS" . "0")
 777
 778     ;; XXX: Normally we wouldn't need to do this, but our glibc@2.23 package
 779     ;; used to look things up in 'PREFIX/lib/locale' instead of
 780     ;; '/run/current-system/locale' as was intended.  Keep this hack around so
 781     ;; that people who still have glibc@2.23-using packages in their profiles
 782     ;; can use them correctly.
 783     ;; TODO: Remove when glibc@2.23 is long gone.
 784     ("GUIX_LOCPATH" . "/run/current-system/locale")))
 785
 786 (define %setuid-programs
 787   ;; Default set of setuid-root programs.
 788   (let ((shadow (@ (gnu packages admin) shadow)))
 789     (list (file-append shadow "/bin/passwd")
 790           (file-append shadow "/bin/su")
 791           (file-append shadow "/bin/newuidmap")
 792           (file-append shadow "/bin/newgidmap")
 793           (file-append inetutils "/bin/ping")
 794           (file-append inetutils "/bin/ping6")
 795           (file-append sudo "/bin/sudo")
 796           (file-append fuse "/bin/fusermount"))))
 797
 798 (define %sudoers-specification
 799   ;; Default /etc/sudoers contents: 'root' and all members of the 'wheel'
 800   ;; group can do anything.  See
 801   ;; <http://www.sudo.ws/sudo/man/1.8.10/sudoers.man.html>.
 802   ;; TODO: Add a declarative API.
 803   (plain-file "sudoers" "\
 804 root ALL=(ALL) ALL
 805 %wheel ALL=(ALL) ALL\n"))
 806
 807 (define* (operating-system-activation-script os #:key container?)
 808   "Return the activation script for OS---i.e., the code that \"activates\" the
 809 stateful part of OS, including user accounts and groups, special directories,
 810 etc."
 811   (let* ((services   (operating-system-services os #:container? container?))
 812          (activation (fold-services services
 813                                     #:target-type activation-service-type)))
 814     (activation-service->script activation)))
 815
 816 (define* (operating-system-boot-script os #:key container?)
 817   "Return the boot script for OS---i.e., the code started by the initrd once
 818 we're running in the final root.  When CONTAINER? is true, skip all
 819 hardware-related operations as necessary when booting a Linux container."
 820   (let* ((services (operating-system-services os #:container? container?))
 821          (boot     (fold-services services #:target-type boot-service-type)))
 822     ;; BOOT is the script as a monadic value.
 823     (service-value boot)))
 824
 825 (define (operating-system-user-accounts os)
 826   "Return the list of user accounts of OS."
 827   (let* ((services (operating-system-services os))
 828          (account  (fold-services services
 829                                   #:target-type account-service-type)))
 830     (filter user-account?
 831             (service-value account))))
 832
 833 (define (operating-system-shepherd-service-names os)
 834   "Return the list of Shepherd service names for OS."
 835   (append-map shepherd-service-provision
 836               (service-value
 837                (fold-services (operating-system-services os)
 838                               #:target-type
 839                               shepherd-root-service-type))))
 840
 841 (define* (operating-system-derivation os #:key container?)
 842   "Return a derivation that builds OS."
 843   (let* ((services (operating-system-services os #:container? container?))
 844          (system   (fold-services services)))
 845     ;; SYSTEM contains the derivation as a monadic value.
 846     (service-value system)))
 847
 848 (define* (operating-system-profile os #:key container?)
 849   "Return a derivation that builds the system profile of OS."
 850   (mlet* %store-monad
 851       ((services -> (operating-system-services os #:container? container?))
 852        (profile (fold-services services
 853                                #:target-type profile-service-type)))
 854     (match profile
 855       (("profile" profile)
 856        (return profile)))))
 857
 858 (define (operating-system-root-file-system os)
 859   "Return the root file system of OS."
 860   (find (lambda (fs)
 861           (string=? "/" (file-system-mount-point fs)))
 862         (operating-system-file-systems os)))
 863
 864 (define (operating-system-initrd-file os)
 865   "Return a gexp denoting the initrd file of OS."
 866   (define boot-file-systems
 867     (filter file-system-needed-for-boot?
 868             (operating-system-file-systems os)))
 869
 870   (define mapped-devices
 871     (operating-system-boot-mapped-devices os))
 872
 873   (define make-initrd
 874     (operating-system-initrd os))
 875
 876   (mlet %store-monad ((initrd (make-initrd boot-file-systems
 877                                            #:linux (operating-system-kernel os)
 878                                            #:linux-modules
 879                                            (operating-system-initrd-modules os)
 880                                            #:mapped-devices mapped-devices)))
 881     (return (file-append initrd "/initrd"))))
 882
 883 (define (locale-name->definition* name)
 884   "Variant of 'locale-name->definition' that raises an error upon failure."
 885   (match (locale-name->definition name)
 886     (#f
 887      (raise (condition
 888              (&message
 889               (message (format #f (G_ "~a: invalid locale name") name))))))
 890     (def def)))
 891
 892 (define (operating-system-locale-directory os)
 893   "Return the directory containing the locales compiled for the definitions
 894 listed in OS.  The C library expects to find it under
 895 /run/current-system/locale."
 896   (define name
 897     (operating-system-locale os))
 898
 899   (define definitions
 900     ;; While we're at it, check whether NAME is defined and add it if needed.
 901     (if (member name (map locale-definition-name
 902                           (operating-system-locale-definitions os)))
 903         (operating-system-locale-definitions os)
 904         (cons (locale-name->definition* name)
 905               (operating-system-locale-definitions os))))
 906
 907   (locale-directory definitions
 908                     #:libcs (operating-system-locale-libcs os)))
 909
 910 (define (kernel->boot-label kernel)
 911   "Return a label for the bootloader menu entry that boots KERNEL."
 912   (string-append "GNU with "
 913                  (string-titlecase (package-name kernel)) " "
 914                  (package-version kernel)
 915                  " (beta)"))
 916
 917 (define (store-file-system file-systems)
 918   "Return the file system object among FILE-SYSTEMS that contains the store."
 919   (match (filter (lambda (fs)
 920                    (and (file-system-mount? fs)
 921                         (not (memq 'bind-mount (file-system-flags fs)))
 922                         (string-prefix? (file-system-mount-point fs)
 923                                         (%store-prefix))))
 924                  file-systems)
 925     ((and candidates (head . tail))
 926      (reduce (lambda (fs1 fs2)
 927                (if (> (string-length (file-system-mount-point fs1))
 928                       (string-length (file-system-mount-point fs2)))
 929                    fs1
 930                    fs2))
 931              head
 932              candidates))))
 933
 934 (define (operating-system-store-file-system os)
 935   "Return the file system that contains the store of OS."
 936   (store-file-system (operating-system-file-systems os)))
 937
 938 (define* (operating-system-bootcfg os #:optional (old-entries '()))
 939   "Return the bootloader configuration file for OS.  Use OLD-ENTRIES
 940 (which is a list of <menu-entry>) to populate the \"old entries\" menu."
 941   (mlet* %store-monad
 942       ((system      (operating-system-derivation os))
 943        (root-fs ->  (operating-system-root-file-system os))
 944        (root-device -> (file-system-device root-fs))
 945        (params (operating-system-boot-parameters os system root-device))
 946        (entry -> (boot-parameters->menu-entry params))
 947        (bootloader-conf -> (operating-system-bootloader os)))
 948     ((bootloader-configuration-file-generator
 949       (bootloader-configuration-bootloader bootloader-conf))
 950      bootloader-conf (list entry) #:old-entries old-entries)))
 951
 952 (define (operating-system-boot-parameters os system.drv root-device)
 953   "Return a monadic <boot-parameters> record that describes the boot parameters
 954 of OS.  SYSTEM.DRV is either a derivation or #f.  If it's a derivation, adds
 955 kernel arguments for that derivation to <boot-parameters>."
 956   (mlet* %store-monad
 957       ((initrd (operating-system-initrd-file os))
 958        (store -> (operating-system-store-file-system os))
 959        (bootloader  -> (bootloader-configuration-bootloader
 960                         (operating-system-bootloader os)))
 961        (bootloader-name -> (bootloader-name bootloader))
 962        (label -> (kernel->boot-label (operating-system-kernel os))))
 963     (return (boot-parameters
 964              (label label)
 965              (root-device root-device)
 966              (kernel (operating-system-kernel-file os))
 967              (kernel-arguments
 968               (if system.drv
 969                 (operating-system-kernel-arguments os system.drv root-device)
 970                 (operating-system-user-kernel-arguments os)))
 971              (initrd initrd)
 972              (bootloader-name bootloader-name)
 973              (store-device (ensure-not-/dev (file-system-device store)))
 974              (store-mount-point (file-system-mount-point store))))))
 975
 976 (define (device->sexp device)
 977   "Serialize DEVICE as an sexp (really, as an object with a read syntax.)"
 978   (match device
 979     ((? uuid? uuid)
 980      `(uuid ,(uuid-type uuid) ,(uuid-bytevector uuid)))
 981     ((? file-system-label? label)
 982      `(file-system-label ,(file-system-label->string label)))
 983     (_
 984      device)))
 985
 986 (define* (operating-system-boot-parameters-file os #:optional (system.drv #f))
 987    "Return a file that describes the boot parameters of OS.  The primary use of
 988 this file is the reconstruction of GRUB menu entries for old configurations.
 989 SYSTEM.DRV is optional.  If given, adds kernel arguments for that system to the
 990 returned file (since the returned file is then usually stored into the
 991 content-addressed \"system\" directory, it's usually not a good idea
 992 to give it because the content hash would change by the content hash
 993 being stored into the \"parameters\" file)."
 994   (mlet* %store-monad ((root -> (operating-system-root-file-system os))
 995                        (device -> (file-system-device root))
 996                        (params (operating-system-boot-parameters os
 997                                                                  system.drv
 998                                                                  device)))
 999      (gexp->file "parameters"
1000                  #~(boot-parameters
1001                     (version 0)
1002                     (label #$(boot-parameters-label params))
1003                     (root-device
1004                      #$(device->sexp
1005                         (boot-parameters-root-device params)))
1006                     (kernel #$(boot-parameters-kernel params))
1007                     (kernel-arguments
1008                      #$(boot-parameters-kernel-arguments params))
1009                     (initrd #$(boot-parameters-initrd params))
1010                     (bootloader-name #$(boot-parameters-bootloader-name params))
1011                     (store
1012                      (device
1013                       #$(device->sexp (boot-parameters-store-device params)))
1014                      (mount-point #$(boot-parameters-store-mount-point params))))
1015                  #:set-load-path? #f)))
1016
1017 (define-gexp-compiler (operating-system-compiler (os <operating-system>)
1018                                                  system target)
1019   ((store-lift
1020     (lambda (store)
1021       ;; XXX: This is not super elegant but we can't pass SYSTEM and TARGET to
1022       ;; 'operating-system-derivation'.
1023       (run-with-store store (operating-system-derivation os)
1024                       #:system system
1025                       #:target target)))))
1026
1027 ;;; system.scm ends here