configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.9.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 dnl Better be verbose.
  45 AC_MSG_CHECKING([for the store directory])
  46 AC_MSG_RESULT([$storedir])
  47
  48 AC_ARG_ENABLE([daemon],
  49   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  50   [guix_build_daemon="$enableval"],
  51   [guix_build_daemon="yes"])
  52
  53 # Prepare a version of $localstatedir & co. that does not contain references
  54 # to shell variables.
  55 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  56 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  57 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  58 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  59 AC_SUBST([guix_localstatedir])
  60 AC_SUBST([guix_sysconfdir])
  61 AC_SUBST([guix_sbindir])
  62
  63 GUIX_CHECK_FILE_NAME_LIMITS
  64
  65 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  66 dnl Make sure they are available.
  67 m4_pattern_forbid([PKG_CHECK_MODULES])
  68 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  69
  70 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  71 AC_PATH_PROG([GUILE], [guile])
  72 AC_PATH_PROG([GUILD], [guild])
  73 if test "x$GUILD" = "x"; then
  74    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  75 fi
  76
  77 dnl guile-json is used for the PyPI package importer
  78 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  79 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  80
  81 dnl Make sure we have a full-fledged Guile.
  82 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  83
  84 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  85 GUIX_CHECK_SRFI_37
  86 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  87
  88 dnl Check whether (guix build syscalls) can be built.
  89 GUIX_CHECK_LIBC_MOUNT
  90 AM_CONDITIONAL([BUILD_SYSCALLS_MODULE],
  91   [test "x$guix_cv_libc_has_mount" = "xyes"])
  92
  93 dnl Decompressors, for use by the substituter and other modules.
  94 AC_PATH_PROG([GZIP], [gzip])
  95 AC_PATH_PROG([BZIP2], [bzip2])
  96 AC_PATH_PROG([XZ], [xz])
  97 AC_SUBST([GZIP])
  98 AC_SUBST([BZIP2])
  99 AC_SUBST([XZ])
 100
 101 AC_ARG_WITH([nix-prefix],
 102   [AS_HELP_STRING([--with-nix-prefix=DIR],
 103     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 104   [case "$withval" in
 105     yes|no) ;;
 106     *)
 107       NIX_PREFIX="$withval"
 108       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 109       AC_SUBST([NIX_PREFIX])
 110       ;;
 111    esac],
 112   [])
 113
 114 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 115 AC_PATH_PROG([NIX_HASH], [nix-hash])
 116 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 117    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 118 fi
 119
 120 if test "x$NIX_INSTANTIATE" = "x"; then
 121    # This program is an optional dependency, so we just want it to be
 122    # taken from $PATH if it's not available right now.
 123    NIX_INSTANTIATE="nix-instantiate"
 124 fi
 125
 126 AC_ARG_WITH([nixpkgs],
 127   [AS_HELP_STRING([--with-nixpkgs=DIR],
 128     [search for Nixpkgs in DIR (for testing purposes only)])],
 129   [case "$withval" in
 130     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 131     *)      NIXPKGS="$withval";;
 132    esac],
 133   [])
 134
 135 AC_MSG_CHECKING([for Nixpkgs source tree])
 136 if test -f "$NIXPKGS/default.nix"; then
 137    AC_MSG_RESULT([$NIXPKGS])
 138    AC_SUBST([NIXPKGS])
 139 else
 140    AC_MSG_RESULT([not found])
 141 fi
 142
 143 LIBGCRYPT="libgcrypt"
 144 LIBGCRYPT_LIBDIR="no"
 145 LIBGCRYPT_PREFIX="no"
 146
 147 AC_ARG_WITH([libgcrypt-prefix],
 148   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 149   [case "$withval" in
 150     yes|no)
 151       ;;
 152     *)
 153       LIBGCRYPT="$withval/lib/libgcrypt"
 154       LIBGCRYPT_PREFIX="$withval"
 155       LIBGCRYPT_LIBDIR="$withval/lib"
 156       ;;
 157    esac])
 158
 159 AC_ARG_WITH([libgcrypt-libdir],
 160   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 161      [search for GNU libgcrypt's shared library in DIR])],
 162   [case "$withval" in
 163     yes|no)
 164       LIBGCRYPT="libgcrypt"
 165       LIBGCRYPT_LIBDIR="no"
 166       ;;
 167     *)
 168       LIBGCRYPT="$withval/libgcrypt"
 169       LIBGCRYPT_LIBDIR="$withval"
 170       ;;
 171    esac])
 172
 173 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 174 dnl absolute file name of libgcrypt.so.
 175 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 176   xnono)
 177     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 178     if test "x$LIBGCRYPT_LIBDIR" != x; then
 179       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 180     else
 181       dnl 'config-daemon.ac' expects "no" in this case.
 182       LIBGCRYPT_LIBDIR="no"
 183     fi
 184     ;;
 185 esac
 186
 187 dnl Library name suitable for `dynamic-link'.
 188 AC_MSG_CHECKING([for libgcrypt shared library name])
 189 AC_MSG_RESULT([$LIBGCRYPT])
 190 AC_SUBST([LIBGCRYPT])
 191 AC_SUBST([LIBGCRYPT_PREFIX])
 192 AC_SUBST([LIBGCRYPT_LIBDIR])
 193
 194 GUIX_ASSERT_LIBGCRYPT_USABLE
 195
 196 AC_CACHE_SAVE
 197
 198 m4_include([config-daemon.ac])
 199
 200 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 201 dnl See `Building from Git' in the manual for more info.
 202 AM_MISSING_PROG([DOT], [dot])
 203
 204 dnl Manual pages.
 205 AM_MISSING_PROG([HELP2MAN], [help2man])
 206
 207 AC_CONFIG_FILES([Makefile
 208                  po/guix/Makefile.in
 209                  po/packages/Makefile.in
 210                  guix/config.scm])
 211
 212 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 213 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 214 AC_CONFIG_FILES([test-env],     [chmod +x test-env])
 215
 216 dnl Emacs interface.
 217 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 218 AM_PATH_LISPDIR
 219 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 220
 221 emacsuidir="${guilemoduledir}/guix/emacs"
 222 AC_SUBST([emacsuidir])
 223 AC_CONFIG_FILES([emacs/guix-config.el
 224                  emacs/guix-helper.scm])
 225
 226 AC_OUTPUT