gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software: you can redistribute it and/or modify
   8 ;;; it under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation, either version 3 of the License, or
  10 ;;; (at your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful,
  13 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu services cuirass)
  21   #:use-module (guix gexp)
  22   #:use-module (guix records)
  23   #:use-module (gnu packages admin)
  24   #:autoload   (gnu packages ci) (cuirass)
  25   #:use-module (gnu services)
  26   #:use-module (gnu services base)
  27   #:use-module (gnu services shepherd)
  28   #:use-module (gnu system shadow)
  29   #:export (<cuirass-configuration>
  30             cuirass-configuration
  31             cuirass-configuration?
  32
  33             cuirass-service-type))
  34
  35 ;;;; Commentary:
  36 ;;;
  37 ;;; This module implements a service that to run instances of Cuirass, a
  38 ;;; continuous integration tool.
  39 ;;;
  40 ;;;; Code:
  41
  42 (define-record-type* <cuirass-configuration>
  43   cuirass-configuration make-cuirass-configuration
  44   cuirass-configuration?
  45   (cuirass          cuirass-configuration-cuirass ;package
  46                     (default cuirass))
  47   (log-file         cuirass-configuration-log-file ;string
  48                     (default "/var/log/cuirass.log"))
  49   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  50                     (default "/var/cache/cuirass"))
  51   (user             cuirass-configuration-user ;string
  52                     (default "cuirass"))
  53   (group            cuirass-configuration-group ;string
  54                     (default "cuirass"))
  55   (interval         cuirass-configuration-interval ;integer (seconds)
  56                     (default 60))
  57   (database         cuirass-configuration-database ;string (file-name)
  58                     (default "/var/run/cuirass/cuirass.db"))
  59   (specifications   cuirass-configuration-specifications)
  60                                   ;gexp that evaluates to specification-alist
  61   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
  62                     (default #f))
  63   (one-shot?        cuirass-configuration-one-shot? ;boolean
  64                     (default #f)))
  65
  66 (define (cuirass-shepherd-service config)
  67   "Return a <shepherd-service> for the Cuirass service with CONFIG."
  68   (and
  69    (cuirass-configuration? config)
  70    (let ((cuirass          (cuirass-configuration-cuirass config))
  71          (cache-directory  (cuirass-configuration-cache-directory config))
  72          (log-file         (cuirass-configuration-log-file config))
  73          (user             (cuirass-configuration-user config))
  74          (group            (cuirass-configuration-group config))
  75          (interval         (cuirass-configuration-interval config))
  76          (database         (cuirass-configuration-database config))
  77          (specs            (cuirass-configuration-specifications config))
  78          (use-substitutes? (cuirass-configuration-use-substitutes? config))
  79          (one-shot?        (cuirass-configuration-one-shot? config)))
  80      (list (shepherd-service
  81             (documentation "Run Cuirass.")
  82             (provision '(cuirass))
  83             (requirement '(guix-daemon))
  84             (start #~(make-forkexec-constructor
  85                       (list (string-append #$cuirass "/bin/cuirass")
  86                             "--cache-directory" #$cache-directory
  87                             "--specifications"
  88                             #$(scheme-file "cuirass-specs.scm" specs)
  89                             "--database" #$database
  90                             "--interval" #$(number->string interval)
  91                             #$@(if use-substitutes? '("--use-substitutes") '())
  92                             #$@(if one-shot? '("--one-shot") '()))
  93                       #:user #$user
  94                       #:group #$group
  95                       #:log-file #$log-file))
  96             (stop #~(make-kill-destructor)))))))
  97
  98 (define (cuirass-account config)
  99   "Return the user accounts and user groups for CONFIG."
 100   (let ((cuirass-user  (cuirass-configuration-user config))
 101         (cuirass-group (cuirass-configuration-group config)))
 102     (list (user-group
 103            (name cuirass-group)
 104            (system? #t))
 105           (user-account
 106            (name cuirass-user)
 107            (group cuirass-group)
 108            (system? #t)
 109            (comment "Cuirass privilege separation user")
 110            (home-directory (string-append "/var/run/" cuirass-user))
 111            (shell #~(string-append #$shadow "/sbin/nologin"))))))
 112
 113 (define (cuirass-activation config)
 114   "Return the activation code for CONFIG."
 115   (let ((cache (cuirass-configuration-cache-directory config))
 116         (db    (dirname (cuirass-configuration-database config)))
 117         (user  (cuirass-configuration-user config))
 118         (group (cuirass-configuration-group config)))
 119     (with-imported-modules '((guix build utils))
 120       #~(begin
 121           (use-modules (guix build utils))
 122
 123           (mkdir-p #$cache)
 124           (mkdir-p #$db)
 125
 126           (let ((uid (passwd:uid (getpw #$user)))
 127                 (gid (group:gid (getgr #$group))))
 128             (chown #$cache uid gid)
 129             (chown #$db uid gid))))))
 130
 131 (define cuirass-service-type
 132   (service-type
 133    (name 'cuirass)
 134    (extensions
 135     (list
 136      (service-extension profile-service-type      ;for 'info cuirass'
 137                         (compose list cuirass-configuration-cuirass))
 138      (service-extension activation-service-type cuirass-activation)
 139      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 140      (service-extension account-service-type cuirass-account)))))
 141