gnu/packages/ssh.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013, 2014 Andreas Enge <andreas@enge.fr>
   4 ;;; Copyright © 2014, 2015, 2016 Mark H Weaver <mhw@netris.org>
   5 ;;; Copyright © 2015, 2016 Efraim Flashner <efraim@flashner.co.il>
   6 ;;; Copyright © 2016 Leo Famulari <leo@famulari.name>
   7 ;;; Copyright © 2016 Nicolas Goaziou <mail@nicolasgoaziou.fr>
   8 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   9 ;;; Copyright © 2017 Tobias Geerinckx-Rice <me@tobias.gr>
  10 ;;; Copyright © 2017 Stefan Reichör <stefan@xsteve.at>
  11 ;;; Copyright © 2017 Ricardo Wurmus <rekado@elephly.net>
  12 ;;; Copyright © 2017 ng0 <ng0@n0.is>
  13 ;;;
  14 ;;; This file is part of GNU Guix.
  15 ;;;
  16 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  17 ;;; under the terms of the GNU General Public License as published by
  18 ;;; the Free Software Foundation; either version 3 of the License, or (at
  19 ;;; your option) any later version.
  20 ;;;
  21 ;;; GNU Guix is distributed in the hope that it will be useful, but
  22 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;;; GNU General Public License for more details.
  25 ;;;
  26 ;;; You should have received a copy of the GNU General Public License
  27 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 (define-module (gnu packages ssh)
  30   #:use-module (gnu packages)
  31   #:use-module (gnu packages autotools)
  32   #:use-module (gnu packages base)
  33   #:autoload   (gnu packages boost) (boost)
  34   #:use-module (gnu packages compression)
  35   #:use-module (gnu packages crypto)
  36   #:use-module (gnu packages elf)
  37   #:use-module (gnu packages gnupg)
  38   #:use-module (gnu packages gperf)
  39   #:use-module (gnu packages groff)
  40   #:use-module (gnu packages guile)
  41   #:use-module (gnu packages linux)
  42   #:use-module (gnu packages logging)
  43   #:use-module (gnu packages m4)
  44   #:use-module (gnu packages multiprecision)
  45   #:use-module (gnu packages ncurses)
  46   #:use-module (gnu packages nettle)
  47   #:use-module (gnu packages kerberos)
  48   #:use-module (gnu packages perl)
  49   #:use-module (gnu packages pkg-config)
  50   #:use-module (gnu packages popt)
  51   #:autoload   (gnu packages protobuf) (protobuf)
  52   #:use-module (gnu packages readline)
  53   #:use-module (gnu packages texinfo)
  54   #:use-module (gnu packages tls)
  55   #:use-module (gnu packages xorg)
  56   #:use-module (guix build-system cmake)
  57   #:use-module (guix build-system gnu)
  58   #:use-module (guix download)
  59   #:use-module (guix git-download)
  60   #:use-module ((guix licenses) #:prefix license:)
  61   #:use-module (guix packages)
  62   #:use-module (srfi srfi-1))
  63
  64 (define-public libssh
  65   (package
  66     (name "libssh")
  67     (version "0.7.5")
  68     (source (origin
  69               (method url-fetch)
  70               (uri (string-append
  71                     "https://red.libssh.org/attachments/download/218/libssh-"
  72                     version ".tar.xz"))
  73               (sha256
  74                (base32
  75                 "15bh6dm9c50ndddzh3gqcgw7axp3ghrspjpkb1z3dr90vkanvs2l"))
  76               (patches (search-patches "libssh-hostname-parser-bug.patch"))))
  77     (build-system cmake-build-system)
  78     (outputs '("out" "debug"))
  79     (arguments
  80      '(#:configure-flags '("-DWITH_GCRYPT=ON")
  81
  82        ;; TODO: Add 'CMockery' and '-DWITH_TESTING=ON' for the test suite.
  83        #:tests? #f))
  84     (inputs `(("zlib" ,zlib)
  85               ("libgcrypt" ,libgcrypt)))
  86     (synopsis "SSH client library")
  87     (description
  88      "libssh is a C library implementing the SSHv2 and SSHv1 protocol for
  89 client and server implementations.  With libssh, you can remotely execute
  90 programs, transfer files, and use a secure and transparent tunnel for your
  91 remote applications.")
  92     (home-page "https://www.libssh.org")
  93     (license license:lgpl2.1+)))
  94
  95 (define-public libssh2
  96   (package
  97    (name "libssh2")
  98    (version "1.8.0")
  99    (source (origin
 100             (method url-fetch)
 101             (uri (string-append
 102                    "https://www.libssh2.org/download/libssh2-"
 103                    version ".tar.gz"))
 104             (sha256
 105              (base32
 106               "1m3n8spv79qhjq4yi0wgly5s5rc8783jb1pyra9bkx1md0plxwrr"))
 107             (patches
 108              (search-patches "libssh2-fix-build-failure-with-gcrypt.patch"))))
 109    (build-system gnu-build-system)
 110    ;; The installed libssh2.pc file does not include paths to libgcrypt and
 111    ;; zlib libraries, so we need to propagate the inputs.
 112    (propagated-inputs `(("libgcrypt" ,libgcrypt)
 113                         ("zlib" ,zlib)))
 114    (arguments '(#:configure-flags `("--with-libgcrypt")
 115                 #:phases (modify-phases %standard-phases
 116                            (add-before 'configure 'autoreconf
 117                              (lambda _
 118                                (zero? (system* "autoreconf" "-v")))))))
 119    (native-inputs `(("autoconf" ,autoconf)
 120                     ("automake" ,automake)))
 121    (synopsis "Client-side C library implementing the SSH2 protocol")
 122    (description
 123     "libssh2 is a library intended to allow software developers access to
 124 the SSH-2 protocol in an easy-to-use self-contained package.  It can be built
 125 into an application to perform many different tasks when communicating with
 126 a server that supports the SSH-2 protocol.")
 127    (license license:bsd-3)
 128    (home-page "http://www.libssh2.org/")))
 129
 130 (define-public openssh
 131   (package
 132    (name "openssh")
 133    (version "7.6p1")
 134    (source (origin
 135              (method url-fetch)
 136              (uri (string-append "mirror://openbsd/OpenSSH/portable/"
 137                                  name "-" version ".tar.gz"))
 138              (sha256
 139               (base32
 140                "08qpsb8mrzcx8wgvz9insiyvq7sbg26yj5nvl2m5n57yvppcl8x3"))))
 141    (build-system gnu-build-system)
 142    (native-inputs `(("groff" ,groff)))
 143    (inputs `(("openssl" ,openssl)
 144              ("pam" ,linux-pam)
 145              ("mit-krb5" ,mit-krb5)
 146              ("zlib" ,zlib)
 147              ("xauth" ,xauth)))                   ;for 'ssh -X' and 'ssh -Y'
 148    (arguments
 149     `(#:test-target "tests"
 150       #:configure-flags  `("--sysconfdir=/etc/ssh"
 151
 152                            ;; Default value of 'PATH' used by sshd.
 153                           "--with-default-path=/run/current-system/profile/bin"
 154
 155                           ;; configure needs to find krb5-config
 156                           ,(string-append "--with-kerberos5="
 157                                           (assoc-ref %build-inputs "mit-krb5")
 158                                           "/bin")
 159
 160                           ;; Enable PAM support in sshd.
 161                           "--with-pam")
 162
 163       #:phases
 164       (modify-phases %standard-phases
 165         (add-after 'configure 'reset-/var/empty
 166          (lambda* (#:key outputs #:allow-other-keys)
 167            (let ((out (assoc-ref outputs "out")))
 168              (substitute* "Makefile"
 169                (("PRIVSEP_PATH=/var/empty")
 170                 (string-append "PRIVSEP_PATH=" out "/var/empty")))
 171              #t)))
 172         (add-before 'check 'patch-tests
 173          (lambda _
 174            ;; remove 't-exec' regress target which requires user 'sshd'
 175            (substitute* "regress/Makefile"
 176              (("^(REGRESS_TARGETS=.*) t-exec(.*)" all pre post)
 177               (string-append pre post)))
 178            #t))
 179         (replace 'install
 180          (lambda* (#:key outputs (make-flags '()) #:allow-other-keys)
 181            ;; install without host keys and system configuration files
 182            (and (zero? (apply system* "make" "install-nosysconf" make-flags))
 183                 (begin
 184                   (install-file "contrib/ssh-copy-id"
 185                                 (string-append (assoc-ref outputs "out")
 186                                                "/bin/"))
 187                   (chmod (string-append (assoc-ref outputs "out")
 188                                         "/bin/ssh-copy-id") #o555)
 189                   (install-file "contrib/ssh-copy-id.1"
 190                                 (string-append (assoc-ref outputs "out")
 191                                                "/share/man/man1/"))
 192                   #t)))))))
 193    (synopsis "Client and server for the secure shell (ssh) protocol")
 194    (description
 195     "The SSH2 protocol implemented in OpenSSH is standardised by the
 196 IETF secsh working group and is specified in several RFCs and drafts.
 197 It is composed of three layered components:
 198
 199 The transport layer provides algorithm negotiation and a key exchange.
 200 The key exchange includes server authentication and results in a
 201 cryptographically secured connection: it provides integrity, confidentiality
 202 and optional compression.
 203
 204 The user authentication layer uses the established connection and relies on
 205 the services provided by the transport layer.  It provides several mechanisms
 206 for user authentication.  These include traditional password authentication
 207 as well as public-key or host-based authentication mechanisms.
 208
 209 The connection layer multiplexes many different concurrent channels over the
 210 authenticated connection and allows tunneling of login sessions and
 211 TCP-forwarding.  It provides a flow control service for these channels.
 212 Additionally, various channel-specific options can be negotiated.")
 213    (license (license:non-copyleft "file://LICENSE"
 214                                "See LICENSE in the distribution."))
 215    (home-page "http://www.openssh.org/")))
 216
 217 (define-public guile-ssh
 218   (package
 219     (name "guile-ssh")
 220     (version "0.11.2")
 221     (home-page "https://github.com/artyom-poptsov/guile-ssh")
 222     (source (origin
 223               ;; ftp://memory-heap.org/software/guile-ssh/guile-ssh-VERSION.tar.gz
 224               ;; exists, but the server appears to be too slow and unreliable.
 225               ;; Also, using this URL allows the GitHub updater to work.
 226               (method url-fetch)
 227               (uri (string-append home-page "/archive/v"
 228                                   version ".tar.gz"))
 229               (file-name (string-append name "-" version ".tar.gz"))
 230               (sha256
 231                (base32
 232                 "1w0k5s09xj5xycb7lbp5b7rm0xncclms3jwl98lwj8fxwngi1s90"))))
 233     (build-system gnu-build-system)
 234     (outputs '("out" "debug"))
 235     (arguments
 236      '(#:phases (modify-phases %standard-phases
 237                   (add-after 'unpack 'autoreconf
 238                     (lambda* (#:key inputs #:allow-other-keys)
 239                       (zero? (system* "autoreconf" "-vfi"))))
 240                   (add-before 'build 'fix-libguile-ssh-file-name
 241                     (lambda* (#:key outputs #:allow-other-keys)
 242                       ;; Build and install libguile-ssh.so so that we can use
 243                       ;; its absolute file name in .scm files, before we build
 244                       ;; the .go files.
 245                       (and (zero? (system* "make" "install"
 246                                            "-C" "libguile-ssh"
 247                                            "-j" (number->string
 248                                                  (parallel-job-count))))
 249                            (let* ((out      (assoc-ref outputs "out"))
 250                                   (libdir   (string-append out "/lib")))
 251                              (substitute* (find-files "." "\\.scm$")
 252                                (("\"libguile-ssh\"")
 253                                 (string-append "\"" libdir "/libguile-ssh\"")))
 254                              #t)))))
 255
 256        ;; Tests are not parallel-safe.
 257        #:parallel-tests? #f))
 258     (native-inputs `(("autoconf" ,autoconf)
 259                      ("automake" ,automake)
 260                      ("libtool" ,libtool)
 261                      ("texinfo" ,texinfo)
 262                      ("pkg-config" ,pkg-config)
 263                      ("which" ,which)))
 264     (inputs `(("guile" ,guile-2.2)
 265               ("libssh" ,libssh)
 266               ("libgcrypt" ,libgcrypt)))
 267     (synopsis "Guile bindings to libssh")
 268     (description
 269      "Guile-SSH is a library that provides access to the SSH protocol for
 270 programs written in GNU Guile interpreter.  It is a wrapper to the underlying
 271 libssh library.")
 272     (license license:gpl3+)))
 273
 274 (define-public guile2.2-ssh
 275   (deprecated-package "guile2.2-ssh" guile-ssh))
 276
 277 (define-public guile2.0-ssh
 278   (package
 279     (inherit guile-ssh)
 280     (name "guile2.0-ssh")
 281     (inputs `(("guile" ,guile-2.0)
 282               ,@(alist-delete "guile" (package-inputs guile-ssh))))))
 283
 284 (define-public corkscrew
 285   (package
 286     (name "corkscrew")
 287     (version "2.0")
 288     (source
 289      (origin
 290        (method url-fetch)
 291        ;; The agroman.net domain name expired on 2017-03-23, and the original
 292        ;; "http://www.agroman.net/corkscrew/corkscrew-2.0.tar.gz" now returns
 293        ;; bogus HTML.  Perhaps it will yet return.  Until then, use a mirror.
 294        (uri (string-append "https://downloads.openwrt.org/sources/"
 295                            "corkscrew-" version ".tar.gz"))
 296        (sha256 (base32
 297                 "1gmhas4va6gd70i2x2mpxpwpgww6413mji29mg282jms3jscn3qd"))))
 298     (build-system gnu-build-system)
 299     (arguments
 300      ;; Replace configure phase as the ./configure script does not link
 301      ;; CONFIG_SHELL and SHELL passed as parameters
 302      '(#:phases
 303        (modify-phases %standard-phases
 304          (replace 'configure
 305            (lambda* (#:key outputs inputs system build target
 306                            #:allow-other-keys #:rest args)
 307              (let* ((configure (assoc-ref %standard-phases 'configure))
 308                     (prefix (assoc-ref outputs "out"))
 309                     (bash   (which "bash"))
 310                     ;; Set --build and --host flags as the provided config.guess
 311                     ;; is not able to detect them
 312                     (flags `(,(string-append "--prefix=" prefix)
 313                              ,(string-append "--build=" build)
 314                              ,(string-append "--host=" (or target build)))))
 315                (setenv "CONFIG_SHELL" bash)
 316                (zero? (apply system* bash
 317                              (string-append "." "/configure")
 318                              flags)))))
 319          (add-after 'install 'install-documentation
 320            (lambda* (#:key outputs #:allow-other-keys)
 321              (let* ((out (assoc-ref outputs "out"))
 322                     (doc (string-append out "/share/doc/corkscrew")))
 323                (install-file "README" doc)
 324                #t))))))
 325     (home-page "http://www.agroman.net/corkscrew")
 326     (synopsis "SSH tunneling through HTTP(S) proxies")
 327     (description
 328      "Corkscrew tunnels SSH connections through most HTTP and HTTPS proxies.
 329 Proxy authentication is only supported through the plain-text HTTP basic
 330 authentication scheme.")
 331     (license license:gpl2+)))
 332
 333 (define-public mosh
 334   (package
 335     (name "mosh")
 336     (version "1.3.2")
 337     (source (origin
 338               (method url-fetch)
 339               (uri (string-append "https://mosh.org/mosh-" version ".tar.gz"))
 340               (sha256
 341                (base32
 342                 "05hjhlp6lk8yjcy59zywpf0r6s0h0b9zxq0lw66dh9x8vxrhaq6s"))))
 343     (build-system gnu-build-system)
 344     (arguments
 345      '(#:phases
 346        (modify-phases %standard-phases
 347          (add-after 'install 'wrap
 348            (lambda* (#:key outputs #:allow-other-keys)
 349              ;; Make sure 'mosh' can find 'mosh-client' and
 350              ;; 'mosh-server'.
 351              (let* ((out (assoc-ref outputs "out"))
 352                     (bin (string-append out "/bin")))
 353                (wrap-program (string-append bin "/mosh")
 354                              `("PATH" ":" prefix (,bin)))))))))
 355     (native-inputs
 356      `(("pkg-config" ,pkg-config)))
 357     (inputs
 358      `(("openssl" ,openssl)
 359        ("perl" ,perl)
 360        ("perl-io-tty" ,perl-io-tty)
 361        ("zlib" ,zlib)
 362        ("ncurses" ,ncurses)
 363        ("protobuf" ,protobuf)
 364        ("boost-headers" ,boost)))
 365     (home-page "https://mosh.org/")
 366     (synopsis "Remote shell tolerant to intermittent connectivity")
 367     (description
 368      "Remote terminal application that allows roaming, supports intermittent
 369 connectivity, and provides intelligent local echo and line editing of user
 370 keystrokes.  Mosh is a replacement for SSH.  It's more robust and responsive,
 371 especially over Wi-Fi, cellular, and long-distance links.")
 372     (license license:gpl3+)))
 373
 374 (define-public et
 375   (package
 376     (name "et")
 377     (version "3.1.0")
 378     (source
 379      (origin
 380        (method url-fetch)
 381        (uri (string-append
 382              "https://github.com/MisterTea/EternalTCP/archive/et-v"
 383              version ".tar.gz"))
 384        (sha256
 385         (base32 "1n2w2kqbshdmbb0gz4yizyw9gqfls6qm2dnwx1d9c2hz7hmi7521"))))
 386     (build-system cmake-build-system)
 387     (arguments `(#:tests? #f))
 388     (native-inputs
 389      `(("pkg-config" ,pkg-config)))
 390     (inputs `(("glog" ,glog)
 391               ("gflags" ,gflags)
 392               ("libsodium" ,libsodium)
 393               ("protobuf" ,protobuf)))
 394     (synopsis "Remote shell that automatically reconnects")
 395     (description
 396      "Eternal Terminal (ET) is a remote shell that automatically reconnects
 397 without interrupting the session.  Unlike SSH sessions, ET sessions will
 398 survive even network outages and IP changes.  ET uses a custom protocol over
 399 TCP, not the SSH protocol.")
 400     (home-page "https://mistertea.github.io/EternalTCP/")
 401     (license license:asl2.0)))
 402
 403 (define-public dropbear
 404   (package
 405     (name "dropbear")
 406     (version "2017.75")
 407     (source (origin
 408               (method url-fetch)
 409               (uri (string-append
 410                     "https://matt.ucc.asn.au/" name "/releases/"
 411                     name "-" version ".tar.bz2"))
 412               (sha256
 413                (base32
 414                 "1309cm2aw62n9m3h38prvgsqr8bj85hfasgnvwkd42cp3k5ivg3c"))))
 415     (build-system gnu-build-system)
 416     (arguments  `(#:tests? #f)) ; There is no "make check" or anything similar
 417     (inputs `(("zlib" ,zlib)))
 418     (synopsis "Small SSH server and client")
 419     (description "Dropbear is a relatively small SSH server and
 420 client.  It runs on a variety of POSIX-based platforms.  Dropbear is
 421 particularly useful for embedded systems, such as wireless routers.")
 422     (home-page "https://matt.ucc.asn.au/dropbear/dropbear.html")
 423     (license (license:x11-style "" "See file LICENSE."))))
 424
 425 (define-public liboop
 426   (package
 427     (name "liboop")
 428     (version "1.0")
 429     (source
 430      (origin
 431       (method url-fetch)
 432       (uri (string-append "http://download.ofb.net/liboop/liboop-"
 433                           version ".tar.gz"))
 434       (sha256
 435        (base32
 436         "0z6rlalhvfca64jpvksppc9bdhs7jwhiw4y35g5ibvh91xp3rn1l"))
 437       (patches (search-patches "liboop-mips64-deplibs-fix.patch"))))
 438     (build-system gnu-build-system)
 439     (home-page "http://www.lysator.liu.se/liboop/")
 440     (synopsis "Event loop library")
 441     (description "Liboop is a low-level event loop management library for
 442 POSIX-based operating systems.  It supports the development of modular,
 443 multiplexed applications which may respond to events from several sources.  It
 444 replaces the \"select() loop\" and allows the registration of event handlers
 445 for file and network I/O, timers and signals.  Since processes use these
 446 mechanisms for almost all external communication, liboop can be used as the
 447 basis for almost any application.")
 448     (license license:lgpl2.1+)))
 449
 450 (define-public lsh
 451   (package
 452     (name "lsh")
 453     (version "2.1")
 454     (source (origin
 455               (method url-fetch)
 456               (uri (string-append "mirror://gnu/lsh/lsh-"
 457                                   version ".tar.gz"))
 458               (sha256
 459                (base32
 460                 "1qqjy9zfzgny0rkb27c8c7dfsylvb6n0ld8h3an2r83pmaqr9gwb"))
 461               (modules '((guix build utils)))
 462               (snippet
 463                '(begin
 464                   (substitute* "src/testsuite/functions.sh"
 465                     (("localhost")
 466                      ;; Avoid host name lookups since they don't work in
 467                      ;; chroot builds.
 468                      "127.0.0.1")
 469                     (("set -e")
 470                      ;; Make tests more verbose.
 471                      "set -e\nset -x"))
 472
 473                   (substitute* (find-files "src/testsuite" "-test$")
 474                     (("localhost") "127.0.0.1"))
 475
 476                   (substitute* "src/testsuite/login-auth-test"
 477                     (("/bin/cat") "cat"))))))
 478     (build-system gnu-build-system)
 479     (native-inputs
 480      `(("m4" ,m4)
 481        ("guile" ,guile-2.0)
 482        ("gperf" ,gperf)
 483        ("psmisc" ,psmisc)))                       ; for `killall'
 484     (inputs
 485      `(("nettle" ,nettle-2)
 486        ("linux-pam" ,linux-pam)
 487
 488        ;; 'rl.c' uses the 'CPPFunction' type, which is no longer in
 489        ;; Readline 6.3.
 490        ("readline" ,readline-6.2)
 491
 492        ("liboop" ,liboop)
 493        ("zlib" ,zlib)
 494        ("gmp" ,gmp)
 495
 496        ;; The server (lshd) invokes xauth when X11 forwarding is requested.
 497        ;; This adds 24 MiB (or 27%) to the closure of lsh.
 498        ("xauth" ,xauth)))
 499     (arguments
 500      '(;; Skip the `configure' test that checks whether /dev/ptmx &
 501        ;; co. work as expected, because it relies on impurities (for
 502        ;; instance, /dev/pts may be unavailable in chroots.)
 503        #:configure-flags '("lsh_cv_sys_unix98_ptys=yes"
 504
 505                            ;; Use glibc's argp rather than the bundled one.
 506                            "--with-system-argp"
 507
 508                            ;; 'lsh_argp.h' checks HAVE_ARGP_PARSE but nothing
 509                            ;; defines it.
 510                            "CPPFLAGS=-DHAVE_ARGP_PARSE")
 511
 512        ;; FIXME: Tests won't run in a chroot, presumably because
 513        ;; /etc/profile is missing, and thus clients get an empty $PATH
 514        ;; and nothing works.
 515        #:tests? #f
 516
 517        #:phases
 518        (modify-phases %standard-phases
 519          (add-before 'configure 'pre-configure
 520            (lambda* (#:key inputs #:allow-other-keys)
 521              (let* ((nettle    (assoc-ref inputs "nettle"))
 522                     (sexp-conv (string-append nettle "/bin/sexp-conv")))
 523                ;; Remove argp from the list of sub-directories; we don't want
 524                ;; to build it, really.
 525                (substitute* "src/Makefile.in"
 526                  (("^SUBDIRS = argp")
 527                   "SUBDIRS ="))
 528
 529                ;; Make sure 'lsh' and 'lshd' pick 'sexp-conv' in the right place
 530                ;; by default.
 531                (substitute* "src/environ.h.in"
 532                  (("^#define PATH_SEXP_CONV.*")
 533                   (string-append "#define PATH_SEXP_CONV \""
 534                                  sexp-conv "\"\n")))
 535
 536                ;; Same for the 'lsh-authorize' script.
 537                (substitute* "src/lsh-authorize"
 538                  (("=sexp-conv")
 539                   (string-append "=" sexp-conv)))
 540
 541                ;; Tell lshd where 'xauth' lives.  Another option would be to
 542                ;; hardcode "/run/current-system/profile/bin/xauth", thereby
 543                ;; reducing the closure size, but that wouldn't work on foreign
 544                ;; distros.
 545                (with-fluids ((%default-port-encoding "ISO-8859-1"))
 546                  (substitute* "src/server_x11.c"
 547                    (("define XAUTH_PROGRAM.*")
 548                     (string-append "define XAUTH_PROGRAM \""
 549                                    (assoc-ref inputs "xauth")
 550                                    "/bin/xauth\"\n")))))
 551
 552              ;; Tests rely on $USER being set.
 553              (setenv "USER" "guix"))))))
 554     (home-page "http://www.lysator.liu.se/~nisse/lsh/")
 555     (synopsis "GNU implementation of the Secure Shell (ssh) protocols")
 556     (description
 557      "GNU lsh is a free implementation of the SSH version 2 protocol.  It is
 558 used to create a secure line of communication between two computers,
 559 providing shell access to the server system from the client.  It provides
 560 both the server daemon and the client application, as well as tools for
 561 manipulating key files.")
 562     (license license:gpl2+)))
 563
 564 (define-public sshpass
 565   (package
 566     (name "sshpass")
 567     (version "1.06")
 568     (synopsis "Non-interactive password authentication with SSH")
 569     (home-page "https://sourceforge.net/projects/sshpass/")
 570     (source
 571      (origin
 572        (method url-fetch)
 573        (uri (string-append "mirror://sourceforge/sshpass/sshpass/"
 574                            version "/sshpass-" version ".tar.gz"))
 575        (sha256
 576         (base32
 577          "0q7fblaczb7kwbsz0gdy9267z0sllzgmf0c7z5c9mf88wv74ycn6"))))
 578     (build-system gnu-build-system)
 579     (description "sshpass is a tool for non-interactivly performing password
 580 authentication with SSH's so-called @dfn{interactive keyboard password
 581 authentication}.")
 582     (license license:gpl2+)))
 583
 584 (define-public autossh
 585   (package
 586     (name "autossh")
 587     (version "1.4e")
 588     (source
 589      (origin
 590        (method url-fetch)
 591        (uri (string-append
 592              "http://www.harding.motd.ca/autossh/autossh-"
 593              version ".tgz"))
 594        (sha256
 595         (base32 "0mlicw28vq2jxa0jf0dys5ja75v0fxpjavlq9dpif6bnknji13ly"))))
 596     (build-system gnu-build-system)
 597     (arguments `(#:tests? #f)) ; There is no "make check" or anything similar
 598     (inputs `(("openssh" ,openssh)))
 599     (synopsis "Automatically restart SSH sessions and tunnels")
 600     (description "autossh is a program to start a copy of @command{ssh} and
 601 monitor it, restarting it as necessary should it die or stop passing traffic.")
 602     (home-page "http://www.harding.motd.ca/autossh/")
 603     (license
 604      ;; Why point to a source file?  Well, all the individual files have a
 605      ;; copy of this license in their headers, but there's no separate file
 606      ;; with that information.
 607      (license:non-copyleft "file://autossh.c"))))
 608
 609 (define-public pdsh
 610   (package
 611     (name "pdsh")
 612     (version "2.33")
 613     (source
 614      (origin
 615        (method url-fetch)
 616        (uri (string-append "https://github.com/chaos/pdsh/"
 617                            "releases/download/pdsh-" version
 618                            "/pdsh-" version ".tar.gz"))
 619        (file-name (string-append name "-" version ".tar.gz"))
 620        (sha256
 621         (base32 "0bwlkl9inj66iwvafg00pi3sk9n673phdi0kcc59y9nn55s0hs3k"))))
 622     (build-system gnu-build-system)
 623     (arguments
 624      `(#:configure-flags
 625        (list "--with-ssh")
 626        #:phases
 627        (modify-phases %standard-phases
 628          (add-after 'unpack 'patch-/bin/sh
 629            (lambda _
 630              (substitute* '("tests/t0006-pdcp.sh"
 631                             "tests/t0004-module-loading.sh"
 632                             "tests/t2001-ssh.sh"
 633                             "tests/t1003-slurm.sh"
 634                             "tests/t6036-long-output-lines.sh"
 635                             "tests/aggregate-results.sh"
 636                             "tests/t2000-exec.sh"
 637                             "tests/t0002-internal.sh"
 638                             "tests/t1002-dshgroup.sh"
 639                             "tests/t5000-dshbak.sh"
 640                             "tests/t0001-basic.sh"
 641                             "tests/t0005-rcmd_type-and-user.sh"
 642                             "tests/test-lib.sh"
 643                             "tests/t2002-mrsh.sh"
 644                             "tests/t0003-wcoll.sh"
 645                             "tests/test-modules/pcptest.c")
 646                (("/bin/sh") (which "bash")))
 647              #t))
 648          (add-after 'unpack 'patch-tests
 649            (lambda _
 650              (substitute* "tests/t6036-long-output-lines.sh"
 651                (("which") (which "which")))
 652              #t)))))
 653     (inputs
 654      `(("openssh" ,openssh)
 655        ("mit-krb5" ,mit-krb5)
 656        ("perl" ,perl)))
 657     (native-inputs
 658      `(("which" ,which)))
 659     (home-page "https://github.com/chaos/pdsh")
 660     (synopsis "Parallel distributed shell")
 661     (description "Pdsh is a an efficient, multithreaded remote shell client
 662 which executes commands on multiple remote hosts in parallel.  Pdsh implements
 663 dynamically loadable modules for extended functionality such as new remote
 664 shell services and remote host selection.")
 665     (license license:gpl2+)))