emacs/guix-prettify.el

   1 ;;; guix-prettify.el --- Prettify Guix store file names
   2
   3 ;; Copyright © 2014, 2015 Alex Kost <alezost@gmail.com>
   4
   5 ;; This file is part of GNU Guix.
   6
   7 ;; GNU Guix is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; GNU Guix is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; This package provides minor-mode for prettifying Guix store file
  23 ;; names — i.e., after enabling `guix-prettify-mode',
  24 ;; '/gnu/store/72f54nfp6g1hz873w8z3gfcah0h4nl9p-foo-0.1' names will be
  25 ;; replaced with '/gnu/store/…-foo-0.1' in the current buffer.  There is
  26 ;; also `global-guix-prettify-mode' for global prettifying.
  27
  28 ;; To install, add the following to your emacs init file:
  29 ;;
  30 ;;   (add-to-list 'load-path "/path/to/dir-with-guix-prettify")
  31 ;;   (autoload 'guix-prettify-mode "guix-prettify" nil t)
  32 ;;   (autoload 'global-guix-prettify-mode "guix-prettify" nil t)
  33
  34 ;; If you want to enable/disable composition after "M-x font-lock-mode",
  35 ;; use the following setting:
  36 ;;
  37 ;;   (setq font-lock-extra-managed-props
  38 ;;         (cons 'composition font-lock-extra-managed-props))
  39
  40 ;; Credits:
  41 ;;
  42 ;; Thanks to Ludovic Courtès for the idea of this package.
  43 ;;
  44 ;; Thanks to the authors of `prettify-symbols-mode' (part of Emacs 24.4)
  45 ;; and "pretty-symbols.el" <http://github.com/drothlis/pretty-symbols>
  46 ;; for the code.  It helped to write this package.
  47
  48 ;;; Code:
  49
  50 (require 'guix-utils)
  51
  52 (defgroup guix-prettify nil
  53   "Prettify Guix store file names."
  54   :prefix "guix-prettify-"
  55   :group 'guix
  56   :group 'font-lock
  57   :group 'convenience)
  58
  59 (defcustom guix-prettify-char ?…
  60   "Character used for prettifying."
  61   :type 'character
  62   :group 'guix-prettify)
  63
  64 (defcustom guix-prettify-decompose-force nil
  65   "If non-nil, remove any composition.
  66
  67 By default, after disabling `guix-prettify-mode',
  68 compositions (prettifying names with `guix-prettify-char') are
  69 removed only from strings matching `guix-prettify-regexp', so
  70 that compositions created by other modes are left untouched.
  71
  72 Set this variable to non-nil, if you want to remove any
  73 composition unconditionally (like `prettify-symbols-mode' does).
  74 Most likely it will do no harm and will make the process of
  75 disabling `guix-prettify-mode' a little faster."
  76   :type 'boolean
  77   :group 'guix-prettify)
  78
  79 (defcustom guix-prettify-regexp
  80   (rx "/"
  81       (or "nix" "gnu")
  82       "/store/"
  83       ;; Hash-parts do not include "e", "o", "u" and "t".  See base32Chars
  84       ;; at <https://github.com/NixOS/nix/blob/master/src/libutil/hash.cc>
  85       (group (= 32 (any "0-9" "a-d" "f-n" "p-s" "v-z"))))
  86   "Regexp matching file names for prettifying.
  87
  88 Disable `guix-prettify-mode' before modifying this variable and
  89 make sure to modify `guix-prettify-regexp-group' if needed.
  90
  91 Example of a \"deeper\" prettifying:
  92
  93   (setq guix-prettify-regexp \"store/[[:alnum:]]\\\\\\={32\\\\}\"
  94         guix-prettify-regexp-group 0)
  95
  96 This will transform
  97 '/gnu/store/72f54nfp6g1hz873w8z3gfcah0h4nl9p-foo-0.1' into
  98 '/gnu/…-foo-0.1'"
  99   :type 'regexp
 100   :group 'guix-prettify)
 101
 102 (defcustom guix-prettify-regexp-group 1
 103   "Regexp group in `guix-prettify-regexp' for prettifying."
 104   :type 'integer
 105   :group 'guix-prettify)
 106
 107 (defvar guix-prettify-special-modes
 108   '(guix-info-mode ibuffer-mode)
 109   "List of special modes that support font-locking.
 110
 111 By default, \\[global-guix-prettify-mode] enables prettifying in
 112 all buffers except the ones where `font-lock-defaults' is
 113 nil (see Info node `(elisp) Font Lock Basics'), because it may
 114 break the existing highlighting.
 115
 116 Modes from this list and all derived modes are exceptions
 117 \(`global-guix-prettify-mode' enables prettifying there).")
 118
 119 (defvar guix-prettify-flush-function
 120   (cond ((fboundp 'font-lock-flush) #'font-lock-flush)
 121         ((fboundp 'jit-lock-refontify) #'jit-lock-refontify))
 122   "Function used to refontify buffer.
 123 This function is called without arguments after
 124 enabling/disabling `guix-prettify-mode'.  If nil, do nothing.")
 125
 126 (defun guix-prettify-compose ()
 127   "Compose matching region in the current buffer."
 128   (let ((beg (match-beginning guix-prettify-regexp-group))
 129         (end (match-end       guix-prettify-regexp-group)))
 130     (compose-region beg end guix-prettify-char 'decompose-region))
 131   ;; Return nil because we're not adding any face property.
 132   nil)
 133
 134 (defun guix-prettify-decompose-buffer ()
 135   "Remove file names compositions from the current buffer."
 136   (with-silent-modifications
 137     (let ((inhibit-read-only t))
 138       (if guix-prettify-decompose-force
 139           (remove-text-properties (point-min)
 140                                   (point-max)
 141                                   '(composition nil))
 142         (guix-while-search guix-prettify-regexp
 143           (remove-text-properties
 144            (match-beginning guix-prettify-regexp-group)
 145            (match-end       guix-prettify-regexp-group)
 146            '(composition nil)))))))
 147
 148 ;;;###autoload
 149 (define-minor-mode guix-prettify-mode
 150   "Toggle Guix Prettify mode.
 151
 152 With a prefix argument ARG, enable Guix Prettify mode if ARG is
 153 positive, and disable it otherwise.  If called from Lisp, enable
 154 the mode if ARG is omitted or nil.
 155
 156 When Guix Prettify mode is enabled, hash-parts of the Guix store
 157 file names (see `guix-prettify-regexp') are prettified,
 158 i.e. displayed as `guix-prettify-char' character.  This mode can
 159 be enabled programmatically using hooks:
 160
 161   (add-hook 'shell-mode-hook 'guix-prettify-mode)
 162
 163 It is possible to enable the mode in any buffer, however not any
 164 buffer's highlighting may survive after adding new elements to
 165 `font-lock-keywords' (see `guix-prettify-special-modes' for
 166 details).
 167
 168 Also you can use `global-guix-prettify-mode' to enable Guix
 169 Prettify mode for all modes that support font-locking."
 170   :init-value nil
 171   :lighter " …"
 172   (let ((keywords `((,guix-prettify-regexp
 173                      (,guix-prettify-regexp-group
 174                       (guix-prettify-compose))))))
 175     (if guix-prettify-mode
 176         ;; Turn on.
 177         (font-lock-add-keywords nil keywords)
 178       ;; Turn off.
 179       (font-lock-remove-keywords nil keywords)
 180       (guix-prettify-decompose-buffer))
 181     (and guix-prettify-flush-function
 182          (funcall guix-prettify-flush-function))))
 183
 184 (defun guix-prettify-supported-p ()
 185   "Return non-nil, if the mode can be harmlessly enabled in current buffer."
 186   (or font-lock-defaults
 187       (apply #'derived-mode-p guix-prettify-special-modes)))
 188
 189 (defun guix-prettify-turn-on ()
 190   "Enable `guix-prettify-mode' in the current buffer if needed.
 191 See `guix-prettify-special-modes' for details."
 192   (and (not guix-prettify-mode)
 193        (guix-prettify-supported-p)
 194        (guix-prettify-mode)))
 195
 196 ;;;###autoload
 197 (define-globalized-minor-mode global-guix-prettify-mode
 198   guix-prettify-mode guix-prettify-turn-on)
 199
 200 ;;;###autoload
 201 (defalias 'guix-prettify-global-mode 'global-guix-prettify-mode)
 202
 203 (provide 'guix-prettify)
 204
 205 ;;; guix-prettify.el ends here