build-aux/check-final-inputs-self-contained.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;;
  20 ;;; Check whether important binaries are available at hydra.gnu.org.
  21 ;;;
  22
  23 (use-modules (guix store)
  24              (guix packages)
  25              (guix derivations)
  26              (guix ui)
  27              (gnu packages commencement)
  28              (ice-9 match)
  29              (srfi srfi-1)
  30              (srfi srfi-26))
  31
  32 (define %supported-systems
  33   '("x86_64-linux" "i686-linux"))
  34
  35 (define (final-inputs store system)
  36   "Return the list of outputs directories of the final inputs for SYSTEM."
  37   (append-map (match-lambda
  38                ((name package)
  39                 (let ((drv (package-derivation store package system)))
  40                   ;; Libc's 'debug' output refers to gcc-cross-boot0, but it's
  41                   ;; hard to avoid, so we tolerate it.  This should be the
  42                   ;; only exception.
  43                   (filter-map (match-lambda
  44                                (("debug" . directory)
  45                                 (if (string=? "glibc" (package-name package))
  46                                     #f
  47                                     directory))
  48                                ((_ . directory) directory))
  49                               (derivation->output-paths drv)))))
  50               %final-inputs))
  51
  52 (define (assert-valid-substitute substitute)
  53   "Make sure SUBSTITUTE does not refer to any bootstrap inputs, and bail out
  54 if it does."
  55   (let ((references (substitutable-references substitute)))
  56     (when (any (cut string-contains <> "boot") references)
  57       (leave (_ "'~a' refers to bootstrap inputs: ~s~%")
  58              (substitutable-path substitute) references))))
  59
  60 (define (test-final-inputs store system)
  61   "Check whether the final inputs for SYSTEM are clean---i.e., they don't
  62 refer to the bootstrap tools."
  63   (format #t "checking final inputs for '~a'...~%" system)
  64   (let* ((inputs    (final-inputs store system))
  65          (available (substitutable-path-info store inputs)))
  66     (for-each (lambda (dir)
  67                 (unless (find (lambda (substitute)
  68                                 (string=? (substitutable-path substitute)
  69                                           dir))
  70                               available)
  71                   (leave (_ "~a (system: ~a) has no substitute~%")
  72                          dir system)))
  73               inputs)
  74
  75     (for-each assert-valid-substitute available)))
  76
  77 ;; Entry point.
  78 (with-store store
  79   (set-build-options store #:use-substitutes? #t)
  80
  81   (for-each (cut test-final-inputs store <>)
  82             %supported-systems))
  83