gnu/packages/chez.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Federico Beffa <beffa@fbengineering.ch>
   3 ;;; Copyright © 2016 Efraim Flashner <efraim@flashner.co.il>
   4 ;;; Copyright © 2017 Tobias Geerinckx-Rice <me@tobias.gr>
   5 ;;;
   6 ;;; This file is part of GNU Guix.
   7 ;;;
   8 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   9 ;;; under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 3 of the License, or (at
  11 ;;; your option) any later version.
  12 ;;;
  13 ;;; GNU Guix is distributed in the hope that it will be useful, but
  14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU General Public License
  19 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 (define-module (gnu packages chez)
  22   #:use-module (gnu packages)
  23   #:use-module ((guix licenses)
  24                 #:select (gpl2+ gpl3+ lgpl2.0+ lgpl2.1+ asl2.0 bsd-3 expat
  25                           public-domain))
  26   #:use-module (guix packages)
  27   #:use-module (guix download)
  28   #:use-module (guix git-download)
  29   #:use-module (guix utils)
  30   #:use-module (guix build-system gnu)
  31   #:use-module (gnu packages compression)
  32   #:use-module (gnu packages ncurses)
  33   #:use-module (gnu packages ghostscript)
  34   #:use-module (gnu packages netpbm)
  35   #:use-module (gnu packages tex)
  36   #:use-module (gnu packages compression)
  37   #:use-module (gnu packages image)
  38   #:use-module (gnu packages xorg)
  39   #:use-module (ice-9 match)
  40   #:use-module (srfi srfi-1))
  41
  42 (define nanopass
  43   (let ((version "1.9"))
  44     (origin
  45       (method url-fetch)
  46       (uri (string-append
  47             "https://github.com/nanopass/nanopass-framework-scheme/archive"
  48             "/v" version ".tar.gz"))
  49       (sha256 (base32 "11pwyy4jiwhcl2am3a4ciczacjbjkyvdizqzdglb3l1hj2gj6nv2"))
  50       (file-name (string-append "nanopass-" version ".tar.gz")))))
  51
  52 (define stex
  53   (let ((version "1.2.1"))
  54     (origin
  55       (method url-fetch)
  56       (uri (string-append
  57             "https://github.com/dybvig/stex/archive"
  58             "/v" version ".tar.gz"))
  59       (sha256 (base32 "03pl3f668h24dn51vccr1sj5lsba9zq3j37bnxjvdadcdaj4qy5z"))
  60       (file-name (string-append "stex-" version ".tar.gz")))))
  61
  62 (define-public chez-scheme
  63   (package
  64     (name "chez-scheme")
  65     (version "9.5")
  66     (source
  67      (origin
  68        (method url-fetch)
  69        (uri (string-append "https://github.com/cisco/ChezScheme/archive/"
  70                            "v" version ".tar.gz"))
  71        (sha256
  72         (base32 "135991hspq0grf26pvl2lkwhp92yz204h6rgiwyym0x6v0xzknd1"))
  73        (file-name (string-append "chez-scheme-" version ".tar.gz"))
  74        (modules '((guix build utils)))
  75        (snippet
  76         ;; Fix compilation with glibc >= 2.26, which removed xlocale.h.
  77         '(begin
  78            (substitute* "c/expeditor.c"
  79              (("xlocale\\.h") "locale.h"))
  80            #t))))
  81     (build-system gnu-build-system)
  82     (inputs
  83      `(("ncurses" ,ncurses)
  84        ("libx11" ,libx11)
  85        ("xorg-rgb" ,xorg-rgb)
  86        ("nanopass" ,nanopass)
  87        ("zlib" ,zlib)
  88        ("zlib:static" ,zlib "static")
  89        ("stex" ,stex)))
  90     (native-inputs
  91      `(("texlive" ,(texlive-union (list texlive-latex-oberdiek
  92                                         texlive-generic-epsf)))
  93        ("ghostscript" ,ghostscript)
  94        ("netpbm" ,netpbm)))
  95     (native-search-paths
  96      (list (search-path-specification
  97             (variable "CHEZSCHEMELIBDIRS")
  98             (files (list (string-append "lib/csv" version "-site"))))))
  99     (outputs '("out" "doc"))
 100     (arguments
 101      `(#:modules ((guix build gnu-build-system)
 102                   (guix build utils)
 103                   (ice-9 match))
 104        #:test-target "test"
 105        #:configure-flags
 106        (list ,(match (or (%current-target-system) (%current-system))
 107                 ("x86_64-linux" '(list "--machine=ta6le"))
 108                 ("i686-linux" '(list "--machine=ti3le"))
 109                 ;; Let autodetection have its attempt on other architectures.
 110                 (_
 111                  '())))
 112        #:phases
 113        (modify-phases %standard-phases
 114          (add-after 'unpack 'patch-processor-detection
 115            (lambda _ (substitute* "configure"
 116                        (("uname -a") "uname -m"))
 117                    #t))
 118          (add-after 'unpack 'patch-broken-documentation
 119            (lambda _
 120              ;; Work around an oversight in the 9.5 release tarball that causes
 121              ;; building the documentation to fail. This should be fixed in the
 122              ;; next one; see <https://github.com/cisco/ChezScheme/issues/209>.
 123              (substitute* "csug/copyright.stex"
 124                (("\\\\INSERTREVISIONMONTHSPACEYEAR" )
 125                 "October 2017"))))     ; tarball release date
 126          ;; Adapt the custom 'configure' script.
 127          (replace 'configure
 128            (lambda* (#:key inputs outputs #:allow-other-keys)
 129              (let ((out (assoc-ref outputs "out"))
 130                    (nanopass (assoc-ref inputs "nanopass"))
 131                    (stex (assoc-ref inputs "stex"))
 132                    (zlib (assoc-ref inputs "zlib"))
 133                    (zlib-static (assoc-ref inputs "zlib:static"))
 134                    (unpack (assoc-ref %standard-phases 'unpack))
 135                    (patch-source-shebangs
 136                     (assoc-ref %standard-phases 'patch-source-shebangs)))
 137                (map (match-lambda
 138                       ((src orig-name new-name)
 139                        (with-directory-excursion "."
 140                          (apply unpack (list #:source src))
 141                          (apply patch-source-shebangs (list #:source src)))
 142                        (delete-file-recursively new-name)
 143                        (system* "mv" orig-name new-name)))
 144                     `((,nanopass "nanopass-framework-scheme-1.9" "nanopass")
 145                       (,stex "stex-1.2.1" "stex")))
 146                ;; The Makefile wants to download and compile "zlib".  We patch
 147                ;; it to use the one from our 'zlib' package.
 148                (substitute* "configure"
 149                  (("rmdir zlib .*$") "echo \"using system zlib\"\n"))
 150                (substitute* (find-files "./c" "Mf-[a-zA-Z0-9.]+")
 151                  (("\\$\\{Kernel\\}: \\$\\{kernelobj\\} \\.\\./zlib/libz\\.a")
 152                   "${Kernel}: ${kernelobj}")
 153                  (("ld ([-a-zA-Z0-9_${} ]+) \\.\\./zlib/libz\\.a" all args)
 154                   (string-append "ld " args " " zlib-static "/lib/libz.a"))
 155                  (("\\(cd \\.\\./zlib; ([-a-zA-Z0-9=./ ]+))")
 156                   (which "true")))
 157                (substitute* (find-files "mats" "Mf-.*")
 158                  (("^[[:space:]]+(cc ) *") "\tgcc "))
 159                (substitute*
 160                    (find-files "." (string-append
 161                                     "("
 162                                     "Mf-[a-zA-Z0-9.]+"
 163                                     "|Makefile[a-zA-Z0-9.]*"
 164                                     "|checkin"
 165                                     "|stex\\.stex"
 166                                     "|newrelease"
 167                                     "|workarea"
 168                                     ;;"|[a-zA-Z0-9.]+\\.ms" ; guile can't read
 169                                     ")"))
 170                  (("/bin/rm") (which "rm"))
 171                  (("/bin/ln") (which "ln"))
 172                  (("/bin/cp") (which "cp")))
 173                (substitute* "makefiles/installsh"
 174                  (("/bin/true") (which "true")))
 175                (substitute* "stex/Makefile"
 176                  (("PREFIX=/usr") (string-append "PREFIX=" out)))
 177                (zero? (system* "./configure" "--threads"
 178                                (string-append "--installprefix=" out))))))
 179          ;; Installation of the documentation requires a running "chez".
 180          (add-after 'install 'install-doc
 181            (lambda* (#:key inputs outputs #:allow-other-keys)
 182              (let ((bin (string-append (assoc-ref outputs "out") "/bin"))
 183                    (doc (string-append (assoc-ref outputs "doc")
 184                                        "/share/doc/" ,name "-" ,version)))
 185                (setenv "HOME" (getcwd))
 186                (setenv "PATH" (string-append (getenv "PATH") ":" bin))
 187                (with-directory-excursion "stex"
 188                  (system* "make" (string-append "BIN=" bin)))
 189                (system* "make" "docs")
 190                (with-directory-excursion "csug"
 191                  (substitute* "Makefile"
 192                    (("/tmp/csug9") doc))
 193                  (system* "make" "install")
 194                  (install-file "csug.pdf" doc))
 195                (with-directory-excursion "release_notes"
 196                  (install-file "release_notes.pdf" doc))
 197                #t)))
 198          ;; The binary file name is called "scheme" as the one from MIT/GNU
 199          ;; Scheme.  We add a symlink to use in case both are installed.
 200          (add-after 'install 'install-symlink
 201            (lambda* (#:key outputs #:allow-other-keys)
 202              (let* ((out (assoc-ref outputs "out"))
 203                     (bin (string-append out "/bin"))
 204                     (lib (string-append out "/lib"))
 205                     (name "chez-scheme"))
 206                (symlink (string-append bin "/scheme")
 207                         (string-append bin "/" name))
 208                (map (lambda (file)
 209                       (symlink file (string-append (dirname file)
 210                                                    "/" name ".boot")))
 211                     (find-files lib "scheme.boot"))
 212                #t)))
 213          (add-before 'reset-gzip-timestamps 'make-manpages-writable
 214            (lambda* (#:key outputs #:allow-other-keys)
 215              (map (lambda (file)
 216                     (make-file-writable file))
 217                   (find-files (string-append (assoc-ref outputs "out")
 218                                              "/share/man")
 219                               ".*\\.gz$"))
 220              #t)))))
 221     ;; According to the documentation MIPS is not supported.
 222     ;; Cross-compiling for the Raspberry Pi is supported, but not native ARM.
 223     (supported-systems (fold delete %supported-systems
 224                              '("mips64el-linux" "armhf-linux")))
 225     (home-page "http://www.scheme.com")
 226     (synopsis "R6RS Scheme compiler and run-time")
 227     (description
 228      "Chez Scheme is a compiler and run-time system for the language of the
 229 Revised^6 Report on Scheme (R6RS), with numerous extensions.  The compiler
 230 generates native code for each target processor, with support for x86, x86_64,
 231 and 32-bit PowerPC architectures.")
 232     (license asl2.0)))
 233
 234 (define-public chez-srfi
 235   (package
 236     (name "chez-srfi")
 237     (version "1.0")
 238     (source
 239      (origin
 240        (method url-fetch)
 241        (uri (string-append
 242              "https://github.com/fedeinthemix/chez-srfi/archive"
 243              "/v" version ".tar.gz"))
 244        (sha256
 245         (base32 "17i4wly7bcr5kb5hf04ljpbvv4r5hsr9xsmw650fj43z9jr303gs"))
 246        (file-name (string-append name "-" version ".tar.gz"))))
 247     (build-system gnu-build-system)
 248     (native-inputs
 249      `(("chez-scheme" ,chez-scheme)))
 250     (arguments
 251      `(#:make-flags (let ((out (assoc-ref %outputs "out")))
 252                       (list (string-append "PREFIX=" out)))
 253        #:test-target "test"
 254        #:phases (modify-phases %standard-phases
 255                   (delete 'configure))))
 256     (home-page "https://github.com/fedeinthemix/chez-srfi")
 257     (synopsis "SRFI libraries for Chez Scheme")
 258     (description
 259      "This package provides a collection of SRFI libraries for Chez Scheme.")
 260     (license expat)))
 261
 262 (define-public chez-web
 263   (let ((commit "5fd177fe53f31f466bf88720d03c95a3711a8bea")
 264         (revision "1"))
 265     (package
 266       (name "chez-web")
 267       ;; release 2.0 is different and doesn't work.
 268       (version (string-append "2.0-" revision "."
 269                               (string-take commit 7)))
 270       (source
 271        (origin
 272          (method git-fetch)
 273          (uri (git-reference
 274                (url "https://github.com/arcfide/ChezWEB.git")
 275                (commit commit)))
 276          (file-name (string-append name "-" version "-checkout"))
 277          (sha256
 278           (base32 "1dq25qygyncbfq4kwwqqgyyakfqjwhp5q23vrf3bff1p66nyfl3b"))))
 279       (build-system gnu-build-system)
 280       (native-inputs
 281        `(("chez-scheme" ,chez-scheme)
 282          ("ghostscript" ,ghostscript)
 283          ("texlive" ,(texlive-union (list texlive-latex-oberdiek
 284                                           texlive-generic-epsf
 285                                           texlive-metapost
 286                                           texlive-fonts-charter
 287                                           texlive-generic-pdftex
 288                                           texlive-context-base
 289                                           texlive-fonts-cm
 290                                           texlive-tex-plain)))))
 291       (arguments
 292        `(#:make-flags (list (string-append "PREFIX=" %output)
 293                             (string-append "DOCDIR=" %output "/share/doc/"
 294                                            ,name "-" ,version)
 295                             (string-append "LIBDIR=" %output "/lib/chezweb")
 296                             (string-append "TEXDIR=" %output "/share/texmf-local"))
 297                       #:tests? #f        ; no tests
 298                       #:phases
 299                       (modify-phases %standard-phases
 300                         (add-before 'build 'set-HOME
 301                           (lambda _
 302                             ;; FIXME: texlive-union does not find the built
 303                             ;; metafonts, so it tries to generate them in HOME.
 304                             (setenv "HOME" "/tmp")
 305                             #t))
 306                         ;; This package has a custom "bootstrap" script that
 307                         ;; is meant to be run from the Makefile.
 308                         (delete 'bootstrap)
 309                         (replace 'configure
 310                           (lambda* _
 311                             (copy-file "config.mk.template" "config.mk")
 312                             (substitute* "tangleit"
 313                               (("\\./cheztangle\\.ss" all)
 314                                (string-append "chez-scheme --program " all)))
 315                             (substitute* "weaveit"
 316                               (("mpost chezweb\\.mp")
 317                                "mpost --tex=tex chezweb.mp")
 318                               (("\\./chezweave" all)
 319                                (string-append "chez-scheme --program " all)))
 320                             (substitute* "installit"
 321                               (("-g \\$GROUP -o \\$OWNER") "")))))))
 322       (home-page "https://github.com/arcfide/ChezWEB")
 323       (synopsis "Hygienic Literate Programming for Chez Scheme")
 324       (description "ChezWEB is a system for doing Knuthian style WEB
 325 programming in Scheme.")
 326       (license expat))))
 327
 328 (define-public chez-sockets
 329   (let ((commit "bce96881c06bd69a6757a6bff139744153924140")
 330         (revision "1"))
 331     (package
 332       (name "chez-sockets")
 333       (version (string-append "0.0-" revision "."
 334                               (string-take commit 7)))
 335       (source
 336        (origin
 337          (method git-fetch)
 338          (uri (git-reference
 339                (url "https://github.com/arcfide/chez-sockets.git")
 340                (commit commit)))
 341          (file-name (string-append name "-" version "-checkout"))
 342          (sha256
 343           (base32 "1n5fbwwz51fdzvjackgmnsgh363g9inyxv7kmzi0469cwavwcx5m"))))
 344       (build-system gnu-build-system)
 345       (native-inputs
 346        `(("chez-scheme" ,chez-scheme)
 347          ("chez-web" ,chez-web)
 348          ("texlive" ,texlive)))
 349       (arguments
 350        `(#:tests? #f              ; no tests
 351          #:phases
 352          (modify-phases %standard-phases
 353            (replace 'configure
 354              (lambda* (#:key outputs inputs #:allow-other-keys)
 355                (let* ((out (assoc-ref outputs "out"))
 356                       (chez-web (assoc-ref inputs "chez-web"))
 357                       (chez (assoc-ref inputs "chez-scheme"))
 358                       (chez-h (dirname (car (find-files chez "scheme\\.h")))))
 359                  (substitute* "Makefile"
 360                    (("(SCHEMEH=).*$" all var)
 361                     (string-append var chez-h)))
 362                  #t)))
 363            (add-before 'build 'tangle
 364              (lambda _
 365                ;; just using "make" tries to build the .c files before
 366                ;; they are created.
 367                (and (zero? (system* "make" "sockets"))
 368                     (zero? (system* "make")))))
 369            (replace 'build
 370              (lambda* (#:key outputs inputs #:allow-other-keys)
 371                (let* ((out (assoc-ref outputs "out"))
 372                       (chez-site (string-append out "/lib/csv"
 373                                                 ,(package-version chez-scheme)
 374                                                 "-site/arcfide")))
 375                  ;; make sure Chez Scheme can find the shared libraries.
 376                  (substitute* "sockets.ss"
 377                    (("(load-shared-object) \"(socket-ffi-values\\.[sd][oy].*)\""
 378                      all cmd so)
 379                     (string-append cmd " \"" chez-site "/" so "\""))
 380                    (("sockets-stub\\.[sd][oy].*" all)
 381                     (string-append chez-site "/" all)))
 382                  ;; to compile chez-sockets, the .so files must be
 383                  ;; installed (because of the absolute path we
 384                  ;; inserted above).
 385                  (for-each (lambda (f d) (install-file f d))
 386                            '("socket-ffi-values.so" "sockets-stub.so")
 387                            (list chez-site chez-site))
 388                  (zero? (system "echo '(compile-file \"sockets.sls\")' | scheme -q")))))
 389            (replace 'install
 390              (lambda* (#:key outputs inputs #:allow-other-keys)
 391                (let* ((out (assoc-ref outputs "out"))
 392                       (lib (string-append out "/lib/chez-sockets"))
 393                       (doc (string-append out "/share/doc/" ,name "-" ,version))
 394                       (chez-site (string-append out "/lib/csv"
 395                                                 ,(package-version chez-scheme)
 396                                                 "-site/arcfide")))
 397                  (for-each (lambda (f d) (install-file f d))
 398                            '("sockets.pdf" "sockets.so")
 399                            (list doc chez-site))
 400                  #t))))))
 401       (home-page "https://github.com/arcfide/chez-sockets")
 402       (synopsis "Extensible sockets library for Chez Scheme")
 403       (description "Chez-sockets is an extensible sockets library for
 404 Chez Scheme.")
 405       (license expat))))
 406
 407 ;; Help function for Chez Scheme to add the current path to
 408 ;; CHEZSCHEMELIBDIRS.
 409 (define chez-configure
 410   '(lambda _
 411      (let ((chez-env (getenv "CHEZSCHEMELIBDIRS")))
 412        (setenv "CHEZSCHEMELIBDIRS"
 413                (if chez-env
 414                    (string-append ".:" chez-env)
 415                    "."))
 416        #t)))
 417
 418 ;; Help function to define make flags for some Chez Scheme custom make
 419 ;; files.
 420 (define (chez-make-flags name version)
 421   `(let ((out (assoc-ref %outputs "out")))
 422      (list (string-append "PREFIX=" out)
 423            (string-append "DOCDIR=" out "/share/doc/"
 424                           ,name "-" ,version))))
 425
 426 (define-public chez-matchable
 427   (package
 428     (name "chez-matchable")
 429     (version "20160306")
 430     (home-page "https://github.com/fedeinthemix/chez-matchable")
 431     (source
 432      (origin
 433        (method url-fetch)
 434        (uri (string-append home-page "/archive" "/v" version ".tar.gz"))
 435        (sha256
 436         (base32 "0cl4vc6487pikjq159pj4n5ghyaax31nywb5n4yn1682h3ir1hs0"))
 437        (file-name (string-append name "-" version ".tar.gz"))))
 438     (build-system gnu-build-system)
 439     (inputs
 440      `(("chez-srfi" ,chez-srfi))) ; for tests
 441     (native-inputs
 442      `(("chez-scheme" ,chez-scheme)))
 443     (arguments
 444      `(#:make-flags ,(chez-make-flags name version)
 445        #:test-target "test"
 446        #:phases (modify-phases %standard-phases
 447                   (replace 'configure ,chez-configure))))
 448     (synopsis "Portable hygienic pattern matcher for Scheme")
 449     (description "This package provides a superset of the popular Scheme
 450 @code{match} package by Andrew Wright, written in fully portable
 451 @code{syntax-rules} and thus preserving hygiene.")
 452     (license public-domain)))
 453
 454 (define-public chez-irregex
 455   (package
 456     (name "chez-irregex")
 457     (version "0.9.4")
 458     (source
 459      (origin
 460        (method url-fetch)
 461        (uri (string-append
 462              "https://github.com/fedeinthemix/chez-irregex/archive"
 463              "/v" version ".tar.gz"))
 464        (sha256
 465         (base32 "0ywy5syaw549a58viz68dmgnv756ic705rcnlqxgjq27lnaim53b"))
 466        (file-name (string-append name "-" version ".tar.gz"))))
 467     (build-system gnu-build-system)
 468     (inputs
 469      `(("chez-matchable" ,chez-matchable))) ; for tests
 470     (propagated-inputs
 471      `(("chez-srfi" ,chez-srfi))) ; for irregex-utils
 472     (native-inputs
 473      `(("chez-scheme" ,chez-scheme)))
 474     (arguments
 475      `(#:make-flags ,(chez-make-flags name version)
 476        #:test-target "test"
 477        #:phases (modify-phases %standard-phases
 478                   (replace 'configure ,chez-configure))))
 479     (home-page "https://github.com/fedeinthemix/chez-irregex")
 480     (synopsis "Portable regular expression library for Scheme")
 481     (description "This package provides a portable and efficient
 482 R[4567]RS implementation of regular expressions, supporting both POSIX
 483 syntax with various (irregular) PCRE extensions, as well as SCSH's SRE
 484 syntax, with various aliases for commonly used patterns.")
 485     (license bsd-3)))
 486
 487 (define-public chez-fmt
 488   (package
 489     (name "chez-fmt")
 490     (version "0.8.11")
 491     (source
 492      (origin
 493        (method url-fetch)
 494        (uri (string-append
 495              "http://synthcode.com/scheme/fmt/fmt-" version ".tar.gz"))
 496        (sha256
 497         (base32 "1zxqlw1jyg85yzclylh8bp2b3fwcy3l3xal68jw837n5illvsjcl"))
 498        (file-name (string-append name "-" version ".tar.gz"))))
 499     (build-system gnu-build-system)
 500     (propagated-inputs
 501      `(("chez-srfi" ,chez-srfi))) ; for irregex-utils
 502     (native-inputs
 503      `(("chez-scheme" ,chez-scheme)))
 504     (arguments
 505      `(#:make-flags ,(chez-make-flags name version)
 506        #:test-target "chez-check"
 507        #:phases
 508        (modify-phases %standard-phases
 509          (replace 'configure ,chez-configure)
 510          (replace 'build
 511            (lambda* (#:key (make-flags '()) #:allow-other-keys)
 512              (zero? (apply system* "make" "chez-build" make-flags))))
 513          (replace 'install
 514            (lambda* (#:key (make-flags '()) #:allow-other-keys)
 515              (zero? (apply system* "make" "chez-install" make-flags)))))))
 516     (home-page "http://synthcode.com/scheme/fmt")
 517     (synopsis "Combinator formatting library for Chez Scheme")
 518     (description "This package provides a library of procedures for
 519 formatting Scheme objects to text in various ways, and for easily
 520 concatenating, composing and extending these formatters efficiently
 521 without resorting to capturing and manipulating intermediate
 522 strings.")
 523     (license bsd-3)))
 524
 525 (define-public chez-mit
 526   (package
 527     (name "chez-mit")
 528     (version "0.1")
 529     (home-page "https://github.com/fedeinthemix/chez-mit")
 530     (source
 531      (origin
 532        (method url-fetch)
 533        (uri (string-append home-page "/archive/v" version ".tar.gz"))
 534        (sha256
 535         (base32 "1p11q061znwxzxrxg3vw4dbsnpv1dav12hjhnkrjnzyyjvvdm2kn"))
 536        (file-name (string-append name "-" version ".tar.gz"))))
 537     (build-system gnu-build-system)
 538     (inputs
 539      `(("chez-srfi" ,chez-srfi))) ; for tests
 540     (native-inputs
 541      `(("chez-scheme" ,chez-scheme)))
 542     (arguments
 543      `(#:make-flags ,(chez-make-flags name version)
 544        #:test-target "test"
 545        #:phases (modify-phases %standard-phases
 546                   (replace 'configure ,chez-configure))))
 547     (synopsis "MIT/GNU Scheme compatibility library for Chez Scheme")
 548     (description "This package provides a set of MIT/GNU Scheme compatibility
 549 libraries for Chez Scheme.  The main goal was to provide the functionality
 550 required to port the program 'Scmutils' to Chez Scheme.")
 551     (license gpl3+)))
 552
 553 (define-public chez-scmutils
 554   (package
 555     (name "chez-scmutils")
 556     (version "0.1")
 557     (home-page "https://github.com/fedeinthemix/chez-scmutils")
 558     (source
 559      (origin
 560        (method url-fetch)
 561        (uri (string-append home-page "/archive/v" version ".tar.gz"))
 562        (sha256
 563         (base32 "1a5j61pggaiwl1gl6m038rcy5n8r2sj5nyjmz86jydx97mm5i8hj"))
 564        (file-name (string-append name "-" version ".tar.gz"))))
 565     (build-system gnu-build-system)
 566     (inputs
 567      `(("chez-srfi" ,chez-srfi)))      ; for tests
 568     (native-inputs
 569      `(("chez-scheme" ,chez-scheme)))
 570     (propagated-inputs
 571      `(("chez-mit" ,chez-mit)
 572        ("chez-srfi" ,chez-srfi)))
 573     (arguments
 574      `(#:make-flags ,(chez-make-flags name version)
 575        #:tests? #f ; no test suite
 576        #:phases
 577        (modify-phases %standard-phases
 578          (replace 'configure ,chez-configure)
 579          ;; Since the documentation is lacking, we install the source
 580          ;; code.  For things to work correctly we have to replace
 581          ;; relative paths by absolute ones in 'include' forms.  This
 582          ;; in turn requires us to compile the files in the final
 583          ;; destination.
 584          (delete 'build)
 585          (add-after 'install 'install-src
 586            (lambda* (#:key (make-flags '()) #:allow-other-keys)
 587              (zero? (apply system* "make" "install-src" make-flags))))
 588          (add-after 'install-src 'absolute-path-in-scm-files
 589            (lambda* (#:key outputs #:allow-other-keys)
 590              (let ((out (assoc-ref outputs "out")))
 591                (for-each (lambda (file)
 592                            (substitute* file
 593                              (("include +\"\\./scmutils")
 594                               (string-append "include \"" (dirname file)))))
 595                          (find-files out "\\.sls"))
 596                (for-each (lambda (file)
 597                            (substitute* file
 598                              (("include +\"\\./scmutils/simplify")
 599                               (string-append "include \"" (dirname file)))))
 600                          (find-files out "fbe-syntax\\.scm"))
 601                #t)))
 602          (add-after 'absolute-path-in-scm-files 'build
 603            (lambda* (#:key outputs (make-flags '()) #:allow-other-keys)
 604              (let* ((out (assoc-ref outputs "out"))
 605                     (mk-file (car (find-files out "Makefile"))))
 606                (with-directory-excursion (dirname mk-file)
 607                  (zero? (apply system* "make" "build" make-flags))))))
 608          (add-after 'build 'clean-up
 609            (lambda* (#:key outputs #:allow-other-keys)
 610              (let* ((out (assoc-ref outputs "out")))
 611                (for-each delete-file
 612                          (find-files out "Makefile|compile-all\\.ss"))))))))
 613     (synopsis "Port of MIT/GNU Scheme Scmutils to Chez Scheme")
 614     (description "This package provides a port of the MIT/GNU Scheme
 615 Scmutils program to Chez Scheme.  The port consists of a set of
 616 libraries providing most of the functionality of the original.")
 617     (license gpl3+)))