gnu/packages/ncurses.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014 Mark H Weaver <mhw@netris.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu packages ncurses)
  21   #:use-module (guix licenses)
  22   #:use-module (guix packages)
  23   #:use-module (guix download)
  24   #:use-module (guix build-system gnu))
  25
  26 (define-public ncurses
  27   (let ((patch-makefile-phase
  28          '(lambda _
  29             (for-each patch-makefile-SHELL
  30                       (find-files "." "Makefile.in"))))
  31         (configure-phase
  32          '(lambda* (#:key inputs outputs configure-flags
  33                     #:allow-other-keys)
  34             ;; The `ncursesw5-config' has a #!/bin/sh.  We want to patch
  35             ;; it to point to libc's embedded Bash, to avoid retaining a
  36             ;; reference to the bootstrap Bash.
  37             (let* ((libc (assoc-ref inputs "libc"))
  38                    (bash (string-append libc "/bin/bash"))
  39                    (out  (assoc-ref outputs "out")))
  40               (format #t "configure flags: ~s~%" configure-flags)
  41               (zero? (apply system* bash "./configure"
  42                             (string-append "SHELL=" bash)
  43                             (string-append "CONFIG_SHELL=" bash)
  44                             (string-append "--prefix=" out)
  45                             configure-flags)))))
  46         (post-install-phase
  47          '(lambda* (#:key outputs #:allow-other-keys)
  48             (let ((out (assoc-ref outputs "out")))
  49               ;; When building a wide-character (Unicode) build, create backward
  50               ;; compatibility links from the the "normal" libraries to the
  51               ;; wide-character libraries (e.g. libncurses.so to libncursesw.so).
  52               (with-directory-excursion (string-append out "/lib")
  53                 (for-each (lambda (lib)
  54                             (define libw.a
  55                               (string-append "lib" lib "w.a"))
  56                             (define lib.a
  57                               (string-append "lib" lib ".a"))
  58                             (define libw.so.x
  59                               (string-append "lib" lib "w.so.5"))
  60                             (define lib.so.x
  61                               (string-append "lib" lib ".so.5"))
  62                             (define lib.so
  63                               (string-append "lib" lib ".so"))
  64
  65                             (when (file-exists? libw.a)
  66                               (format #t "creating symlinks for `lib~a'~%" lib)
  67                               (symlink libw.a lib.a)
  68                               (symlink libw.so.x lib.so.x)
  69                               (false-if-exception (delete-file lib.so))
  70                               (call-with-output-file lib.so
  71                                 (lambda (p)
  72                                   (format p "INPUT (-l~aw)~%" lib)))))
  73                           '("curses" "ncurses" "form" "panel" "menu")))))))
  74     (package
  75      (name "ncurses")
  76      (version "5.9")
  77      (source (origin
  78               (method url-fetch)
  79               (uri (string-append "mirror://gnu/ncurses/ncurses-"
  80                                   version ".tar.gz"))
  81               (sha256
  82                (base32
  83                 "0fsn7xis81za62afan0vvm38bvgzg5wfmv1m86flqcj0nj7jjilh"))))
  84      (build-system gnu-build-system)
  85      (arguments
  86       `(#:configure-flags
  87         `("--with-shared" "--without-debug" "--enable-widec"
  88
  89           ;; By default headers land in an `ncursesw' subdir, which is not
  90           ;; what users expect.
  91           ,(string-append "--includedir=" (assoc-ref %outputs "out")
  92                           "/include")
  93
  94           ;; Make sure programs like 'tic', 'reset', and 'clear' have a
  95           ;; correct RUNPATH.
  96           ,(string-append "LDFLAGS=-Wl,-rpath=" (assoc-ref %outputs "out")
  97                           "/lib")
  98
  99           ;; C++ bindings fail to build on
 100           ;; `i386-pc-solaris2.11' with GCC 3.4.3:
 101           ;; <http://bugs.opensolaris.org/bugdatabase/view_bug.do?bug_id=6395191>.
 102           ,,@(if (string=? (%current-system) "i686-solaris")
 103                  '("--without-cxx-binding")
 104                  '()))
 105         #:tests? #f                               ; no "check" target
 106         #:phases ,(if (%current-target-system)
 107
 108                       `(alist-cons-before         ; cross build
 109                         'configure 'patch-makefile-SHELL
 110                         ,patch-makefile-phase
 111                         (alist-cons-after
 112                          'install 'post-install ,post-install-phase
 113                          %standard-phases))
 114
 115                       `(alist-cons-after          ; native build
 116                         'install 'post-install ,post-install-phase
 117                         (alist-cons-before
 118                          'configure 'patch-makefile-SHELL
 119                          ,patch-makefile-phase
 120                          (alist-replace
 121                           'configure
 122                           ,configure-phase
 123                           %standard-phases))))))
 124      (self-native-input? #t)                      ; for `tic'
 125      (synopsis "Terminal emulation (termcap, terminfo) library")
 126      (description
 127       "GNU Ncurses is a library which provides capabilities to write text to
 128 a terminal in a terminal-independent manner.  It supports pads and color as
 129 well as multiple highlights and forms characters.  It is typically used to
 130 implement user interfaces for command-line applications.  The accompanying
 131 ncursesw library provides wide character support.")
 132      (license x11)
 133      (home-page "http://www.gnu.org/software/ncurses/"))))