gnu/packages/node.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014 Cyrill Schenkel <cyrill.schenkel@gmail.com>
   3 ;;; Copyright © 2015 Andreas Enge <andreas@enge.fr>
   4 ;;; Copyright © 2015, 2016 David Thompson <davet@gnu.org>
   5 ;;; Copyright © 2016 Ludovic Courtès <ludo@gnu.org>
   6 ;;; Copyright © 2017 Mike Gerwitz <mtg@gnu.org>
   7 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
   8 ;;; Copyright © 2018, 2019 Marius Bakke <mbakke@fastmail.com>
   9 ;;;
  10 ;;; This file is part of GNU Guix.
  11 ;;;
  12 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  13 ;;; under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 3 of the License, or (at
  15 ;;; your option) any later version.
  16 ;;;
  17 ;;; GNU Guix is distributed in the hope that it will be useful, but
  18 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 (define-module (gnu packages node)
  26   #:use-module ((guix licenses) #:select (expat))
  27   #:use-module (guix packages)
  28   #:use-module (guix derivations)
  29   #:use-module (guix download)
  30   #:use-module (guix build-system gnu)
  31   #:use-module (gnu packages)
  32   #:use-module (gnu packages adns)
  33   #:use-module (gnu packages base)
  34   #:use-module (gnu packages compression)
  35   #:use-module (gnu packages gcc)
  36   #:use-module (gnu packages icu4c)
  37   #:use-module (gnu packages libevent)
  38   #:use-module (gnu packages linux)
  39   #:use-module (gnu packages perl)
  40   #:use-module (gnu packages pkg-config)
  41   #:use-module (gnu packages python)
  42   #:use-module (gnu packages tls)
  43   #:use-module (gnu packages web))
  44
  45 (define-public node
  46   (package
  47     (name "node")
  48     (version "10.16.0")
  49     (source (origin
  50               (method url-fetch)
  51               (uri (string-append "https://nodejs.org/dist/v" version
  52                                   "/node-v" version ".tar.xz"))
  53               (sha256
  54                (base32
  55                 "0236jlb1hxhzqjlmmlxipcycrndiq92c8434iyy7zshh3n4pzqqq"))
  56               (modules '((guix build utils)))
  57               (snippet
  58                `(begin
  59                   ;; Remove bundled software.
  60                   (for-each delete-file-recursively
  61                             '("deps/cares"
  62                               "deps/http_parser"
  63                               "deps/icu-small"
  64                               "deps/nghttp2"
  65                               "deps/openssl"
  66                               "deps/uv"
  67                               "deps/zlib"))
  68                   (substitute* "Makefile"
  69                     ;; Remove references to bundled software.
  70                     (("deps/http_parser/http_parser.gyp") "")
  71                     (("deps/uv/include/\\*.h") "")
  72                     (("deps/uv/uv.gyp") "")
  73                     (("deps/zlib/zlib.gyp") ""))
  74                   #t))))
  75     (build-system gnu-build-system)
  76     (arguments
  77      ;; TODO: Purge the bundled copies from the source.
  78      '(#:configure-flags '("--shared-cares"
  79                            "--shared-http-parser"
  80                            "--shared-libuv"
  81                            "--shared-nghttp2"
  82                            "--shared-openssl"
  83                            "--shared-zlib"
  84                            "--without-snapshot"
  85                            "--with-intl=system-icu")
  86        ;; Run only the CI tests.  The default test target requires additional
  87        ;; add-ons from NPM that are not distributed with the source.
  88        #:test-target "test-ci-js"
  89        #:phases
  90        (modify-phases %standard-phases
  91          (add-before 'configure 'patch-files
  92            (lambda* (#:key inputs #:allow-other-keys)
  93              ;; Fix hardcoded /bin/sh references.
  94              (substitute* '("lib/child_process.js"
  95                             "lib/internal/v8_prof_polyfill.js"
  96                             "test/parallel/test-child-process-spawnsync-shell.js"
  97                             "test/parallel/test-stdio-closed.js"
  98                             "test/sequential/test-child-process-emfile.js")
  99                (("'/bin/sh'")
 100                 (string-append "'" (which "sh") "'")))
 101
 102              ;; Fix hardcoded /usr/bin/env references.
 103              (substitute* '("test/parallel/test-child-process-default-options.js"
 104                             "test/parallel/test-child-process-env.js"
 105                             "test/parallel/test-child-process-exec-env.js")
 106                (("'/usr/bin/env'")
 107                 (string-append "'" (which "env") "'")))
 108
 109              ;; FIXME: These tests fail in the build container, but they don't
 110              ;; seem to be indicative of real problems in practice.
 111              (for-each delete-file
 112                        '("test/parallel/test-cluster-master-error.js"
 113                          "test/parallel/test-cluster-master-kill.js"
 114                          ;; See also <https://github.com/nodejs/node/issues/25903>.
 115                          "test/sequential/test-performance.js"))
 116
 117              ;; This requires a DNS resolver.
 118              (delete-file "test/parallel/test-dns.js")
 119
 120              ;; FIXME: This test fails randomly:
 121              ;; https://github.com/nodejs/node/issues/31213
 122              (delete-file "test/parallel/test-net-listen-after-destroying-stdin.js")
 123
 124              ;; These tests have an expiry date: they depend on the validity of
 125              ;; TLS certificates that are bundled with the source.  We want this
 126              ;; package to be reproducible forever, so remove those.
 127              ;; TODO: Regenerate certs instead.
 128              (for-each delete-file
 129                        '("test/parallel/test-tls-passphrase.js"
 130                          "test/parallel/test-tls-server-verify.js"))
 131              #t))
 132          (replace 'configure
 133            ;; Node's configure script is actually a python script, so we can't
 134            ;; run it with bash.
 135            (lambda* (#:key outputs (configure-flags '()) inputs
 136                      #:allow-other-keys)
 137              (let* ((prefix (assoc-ref outputs "out"))
 138                     (flags (cons (string-append "--prefix=" prefix)
 139                                  configure-flags)))
 140                (format #t "build directory: ~s~%" (getcwd))
 141                (format #t "configure flags: ~s~%" flags)
 142                ;; Node's configure script expects the CC environment variable to
 143                ;; be set.
 144                (setenv "CC" (string-append (assoc-ref inputs "gcc") "/bin/gcc"))
 145                (apply invoke
 146                       (string-append (assoc-ref inputs "python")
 147                                      "/bin/python")
 148                       "configure" flags))))
 149          (add-after 'patch-shebangs 'patch-npm-shebang
 150            (lambda* (#:key outputs #:allow-other-keys)
 151              (let* ((bindir (string-append (assoc-ref outputs "out")
 152                                            "/bin"))
 153                     (npm    (string-append bindir "/npm"))
 154                     (target (readlink npm)))
 155                (with-directory-excursion bindir
 156                  (patch-shebang target (list bindir))
 157                  #t)))))))
 158     (native-inputs
 159      `(("python" ,python-2)
 160        ("perl" ,perl)
 161        ("pkg-config" ,pkg-config)
 162        ("procps" ,procps)
 163        ("util-linux" ,util-linux)
 164        ("which" ,which)))
 165     (native-search-paths
 166      (list (search-path-specification
 167             (variable "NODE_PATH")
 168             (files '("lib/node_modules")))))
 169     (inputs
 170      `(("c-ares" ,c-ares)
 171        ("http-parser" ,http-parser)
 172        ("icu4c" ,icu4c)
 173        ("libuv" ,libuv)
 174        ("nghttp2" ,nghttp2 "lib")
 175        ("openssl" ,openssl)
 176        ("zlib" ,zlib)))
 177     (synopsis "Evented I/O for V8 JavaScript")
 178     (description "Node.js is a platform built on Chrome's JavaScript runtime
 179 for easily building fast, scalable network applications.  Node.js uses an
 180 event-driven, non-blocking I/O model that makes it lightweight and efficient,
 181 perfect for data-intensive real-time applications that run across distributed
 182 devices.")
 183     (home-page "https://nodejs.org/")
 184     (license expat)
 185     (properties '((max-silent-time . 7200)     ;2h, needed on ARM
 186                   (timeout . 21600)))))        ;6h