gnu/system/vm.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   4 ;;; Copyright © 2016, 2017 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   6 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
   7 ;;; Copyright © 2018 Chris Marusich <cmmarusich@gmail.com>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  12 ;;; under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 3 of the License, or (at
  14 ;;; your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful, but
  17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu system vm)
  25   #:use-module (guix config)
  26   #:use-module (guix store)
  27   #:use-module (guix gexp)
  28   #:use-module (guix derivations)
  29   #:use-module (guix packages)
  30   #:use-module (guix monads)
  31   #:use-module (guix records)
  32   #:use-module (guix modules)
  33   #:use-module (guix utils)
  34   #:use-module (gcrypt hash)
  35   #:use-module (guix base32)
  36   #:use-module ((guix self) #:select (make-config.scm))
  37
  38   #:use-module ((gnu build vm)
  39                 #:select (qemu-command))
  40   #:use-module (gnu packages base)
  41   #:use-module (gnu packages bootloaders)
  42   #:use-module (gnu packages cdrom)
  43   #:use-module (gnu packages compression)
  44   #:use-module (gnu packages guile)
  45   #:autoload   (gnu packages gnupg) (guile-gcrypt)
  46   #:use-module (gnu packages gawk)
  47   #:use-module (gnu packages bash)
  48   #:use-module (gnu packages less)
  49   #:use-module (gnu packages virtualization)
  50   #:use-module (gnu packages disk)
  51   #:use-module (gnu packages zile)
  52   #:use-module (gnu packages linux)
  53   #:use-module (gnu packages admin)
  54
  55   #:use-module (gnu bootloader)
  56   #:use-module (gnu bootloader grub)
  57   #:use-module (gnu system shadow)
  58   #:use-module (gnu system pam)
  59   #:use-module (gnu system linux-container)
  60   #:use-module (gnu system linux-initrd)
  61   #:use-module (gnu bootloader)
  62   #:use-module (gnu system file-systems)
  63   #:use-module (gnu system)
  64   #:use-module (gnu services)
  65   #:use-module (gnu services base)
  66   #:use-module (gnu system uuid)
  67
  68   #:use-module (srfi srfi-1)
  69   #:use-module (srfi srfi-26)
  70   #:use-module (rnrs bytevectors)
  71   #:use-module (ice-9 match)
  72
  73   #:export (expression->derivation-in-linux-vm
  74             qemu-image
  75             virtualized-operating-system
  76             system-qemu-image
  77
  78             system-qemu-image/shared-store
  79             system-qemu-image/shared-store-script
  80             system-disk-image-in-vm
  81             system-docker-image
  82
  83             virtual-machine
  84             virtual-machine?))
  85
  86 \f
  87 ;;; Commentary:
  88 ;;;
  89 ;;; Tools to evaluate build expressions within virtual machines.
  90 ;;;
  91 ;;; Code:
  92
  93 (define %linux-vm-file-systems
  94   ;; File systems mounted for 'derivation-in-linux-vm'.  These are shared with
  95   ;; the host over 9p.
  96   ;;
  97   ;; The 9p documentation says that cache=loose is "intended for exclusive,
  98   ;; read-only mounts", without additional details.  It's much faster than the
  99   ;; default cache=none, especially when copying and registering store items.
 100   ;; Thus, use cache=loose, except for /xchg where we want to ensure
 101   ;; consistency.
 102   (list (file-system
 103           (mount-point (%store-prefix))
 104           (device "store")
 105           (type "9p")
 106           (needed-for-boot? #t)
 107           (flags '(read-only))
 108           (options "trans=virtio,cache=loose")
 109           (check? #f))
 110         (file-system
 111           (mount-point "/xchg")
 112           (device "xchg")
 113           (type "9p")
 114           (needed-for-boot? #t)
 115           (options "trans=virtio")
 116           (check? #f))
 117         (file-system
 118           (mount-point "/tmp")
 119           (device "tmp")
 120           (type "9p")
 121           (needed-for-boot? #t)
 122           (options "trans=virtio,cache=loose")
 123           (check? #f))))
 124
 125 (define not-config?
 126   ;; Select (guix …) and (gnu …) modules, except (guix config).
 127   (match-lambda
 128     (('guix 'config) #f)
 129     (('guix rest ...) #t)
 130     (('gnu rest ...) #t)
 131     (rest #f)))
 132
 133 (define gcrypt-sqlite3&co
 134   ;; Guile-Gcrypt, Guile-SQLite3, and their propagated inputs.
 135   (append-map (lambda (package)
 136                 (cons package
 137                       (match (package-transitive-propagated-inputs package)
 138                         (((labels packages) ...)
 139                          packages))))
 140               (list guile-gcrypt guile-sqlite3)))
 141
 142 (define* (expression->derivation-in-linux-vm name exp
 143                                              #:key
 144                                              (system (%current-system))
 145                                              (linux linux-libre)
 146                                              initrd
 147                                              (qemu qemu-minimal)
 148                                              (env-vars '())
 149                                              (guile-for-build
 150                                               (%guile-for-build))
 151                                              (file-systems
 152                                               %linux-vm-file-systems)
 153
 154                                              (single-file-output? #f)
 155                                              (make-disk-image? #f)
 156                                              (references-graphs #f)
 157                                              (memory-size 256)
 158                                              (disk-image-format "qcow2")
 159                                              (disk-image-size 'guess)
 160
 161                                              (substitutable? #t))
 162   "Evaluate EXP in a QEMU virtual machine running LINUX with INITRD (a
 163 derivation).  The virtual machine runs with MEMORY-SIZE MiB of memory.  In the
 164 virtual machine, EXP has access to FILE-SYSTEMS, which, by default, includes a
 165 9p share of the store, the '/xchg' where EXP should put its output file(s),
 166 and a 9p share of /tmp.
 167
 168 If SINGLE-FILE-OUTPUT? is true, copy a single file from '/xchg' to OUTPUT.
 169 Otherwise, copy the contents of /xchg to a new directory OUTPUT.
 170
 171 When MAKE-DISK-IMAGE? is true, then create a QEMU disk image of type
 172 DISK-IMAGE-FORMAT (e.g., 'qcow2' or 'raw'), of DISK-IMAGE-SIZE bytes and
 173 return it.  When DISK-IMAGE-SIZE is 'guess, estimate the image size based
 174 based on the size of the closure of REFERENCES-GRAPHS.
 175
 176 When REFERENCES-GRAPHS is true, it must be a list of file name/store path
 177 pairs, as for `derivation'.  The files containing the reference graphs are
 178 made available under the /xchg CIFS share.
 179
 180 SUBSTITUTABLE? determines whether the returned derivation should be marked as
 181 substitutable."
 182   (define user-builder
 183     (program-file "builder-in-linux-vm" exp))
 184
 185   (define loader
 186     ;; Invoke USER-BUILDER instead using 'primitive-load'.  The reason for
 187     ;; this is to allow USER-BUILDER to dlopen stuff by using a full-featured
 188     ;; Guile, which it couldn't do using the statically-linked guile used in
 189     ;; the initrd.  See example at
 190     ;; <https://lists.gnu.org/archive/html/guix-devel/2017-10/msg00233.html>.
 191     (program-file "linux-vm-loader"
 192                   ;; Communicate USER-BUILDER's exit status via /xchg so that
 193                   ;; the host can distinguish between success, failure, and
 194                   ;; kernel panic.
 195                   #~(let ((status (system* #$user-builder)))
 196                       (call-with-output-file "/xchg/.exit-status"
 197                         (lambda (port)
 198                           (write status port)))
 199                       (sync)
 200                       (reboot))))
 201
 202   (define-syntax-rule (check predicate)
 203     (let-system (system target)
 204       (predicate (or target system))))
 205
 206   (let ((initrd (or initrd
 207                     (base-initrd file-systems
 208                                  #:on-error 'backtrace
 209                                  #:linux linux
 210                                  #:linux-modules %base-initrd-modules
 211                                  #:qemu-networking? #t))))
 212
 213     (define builder
 214       ;; Code that launches the VM that evaluates EXP.
 215       (with-extensions gcrypt-sqlite3&co
 216         (with-imported-modules `(,@(source-module-closure
 217                                     '((guix build utils)
 218                                       (gnu build vm))
 219                                     #:select? not-config?)
 220
 221                                  ;; For consumption by (gnu store database).
 222                                  ((guix config) => ,(make-config.scm)))
 223           #~(begin
 224               (use-modules (guix build utils)
 225                            (gnu build vm))
 226
 227               (let* ((native-inputs
 228                       '#+(list qemu (canonical-package coreutils)))
 229                      (linux   (string-append
 230                                #+linux "/"
 231                                #+(system-linux-image-file-name system)))
 232                      (initrd  #+initrd)
 233                      (loader  #+loader)
 234                      (graphs  '#$(match references-graphs
 235                                    (((graph-files . _) ...) graph-files)
 236                                    (_ #f)))
 237                      (target  #$(let-system (system target)
 238                                   (or target system)))
 239                      (size    #$(if (eq? 'guess disk-image-size)
 240                                     #~(+ (* 70 (expt 2 20)) ;ESP
 241                                          (estimated-partition-size graphs))
 242                                     disk-image-size)))
 243
 244                 (set-path-environment-variable "PATH" '("bin") native-inputs)
 245
 246                 (load-in-linux-vm loader
 247                                   #:output #$output
 248                                   #:linux linux #:initrd initrd
 249                                   #:qemu (qemu-command target)
 250                                   #:memory-size #$memory-size
 251                                   #:make-disk-image? #$make-disk-image?
 252                                   #:single-file-output? #$single-file-output?
 253                                   #:disk-image-format #$disk-image-format
 254                                   #:disk-image-size size
 255                                   #:references-graphs graphs))))))
 256
 257     (gexp->derivation name builder
 258                       ;; TODO: Require the "kvm" feature.
 259                       #:system system
 260                       #:target #f             ;EXP is always executed natively
 261                       #:env-vars env-vars
 262                       #:guile-for-build guile-for-build
 263                       #:references-graphs references-graphs
 264                       #:substitutable? substitutable?)))
 265
 266 (define (has-guix-service-type? os)
 267   "Return true if OS contains a service of the type GUIX-SERVICE-TYPE."
 268   (not (not (find (lambda (service)
 269                      (eq? (service-kind service) guix-service-type))
 270                    (operating-system-services os)))))
 271
 272 (define* (qemu-image #:key
 273                      (name "qemu-image")
 274                      (system (%current-system))
 275                      (target (%current-target-system))
 276                      (qemu qemu-minimal)
 277                      (disk-image-size 'guess)
 278                      (disk-image-format "qcow2")
 279                      (file-system-type "ext4")
 280                      (file-system-options '())
 281                      (device-nodes 'linux)
 282                      (extra-directives '())
 283                      file-system-label
 284                      file-system-uuid
 285                      os
 286                      bootcfg-drv
 287                      bootloader
 288                      (register-closures? (has-guix-service-type? os))
 289                      (inputs '())
 290                      copy-inputs?
 291                      (substitutable? #t))
 292   "Return a bootable, stand-alone QEMU image of type DISK-IMAGE-FORMAT (e.g.,
 293 'qcow2' or 'raw'), with a root partition of type FILE-SYSTEM-TYPE.
 294 Optionally, FILE-SYSTEM-LABEL can be specified as the volume name for the root
 295 partition; likewise FILE-SYSTEM-UUID, if true, specifies the UUID of the root
 296 partition (a UUID object).  FILE-SYSTEM-OPTIONS is an optional list of
 297 command-line options passed to 'mkfs.ext4' (or similar).
 298
 299 The returned image is a full disk image that runs OS-DERIVATION,
 300 with a GRUB installation that uses GRUB-CONFIGURATION as its configuration
 301 file (GRUB-CONFIGURATION must be the name of a file in the VM.)
 302
 303 INPUTS is a list of inputs (as for packages).  When COPY-INPUTS? is true, copy
 304 all of INPUTS into the image being built.  When REGISTER-CLOSURES? is true,
 305 register INPUTS in the store database of the image so that Guix can be used in
 306 the image.  By default, REGISTER-CLOSURES? is set to true only if a service of
 307 type GUIX-SERVICE-TYPE is present in the services definition of the operating
 308 system.
 309
 310 When DEVICE-NODES is 'linux, create Linux-device block and character devices
 311 under /dev.  When it is 'hurd, do Hurdish things.
 312
 313 EXTRA-DIRECTIVES is an optional list of directives to populate the root file
 314 system that is passed to 'populate-root-file-system'."
 315   (define schema
 316     (and register-closures?
 317          (local-file (search-path %load-path
 318                                   "guix/store/schema.sql"))))
 319
 320   (expression->derivation-in-linux-vm
 321    name
 322    (with-extensions gcrypt-sqlite3&co
 323      (with-imported-modules `(,@(source-module-closure '((gnu build vm)
 324                                                          (gnu build bootloader)
 325                                                          (guix store database)
 326                                                          (guix build utils))
 327                                                        #:select? not-config?)
 328                               ((guix config) => ,(make-config.scm)))
 329        #~(begin
 330            (use-modules (gnu build bootloader)
 331                         (gnu build vm)
 332                         ((gnu build linux-boot)
 333                          #:select (make-essential-device-nodes
 334                                    make-hurd-device-nodes))
 335                         (guix store database)
 336                         (guix build utils)
 337                         (srfi srfi-26)
 338                         (ice-9 binary-ports))
 339
 340            (sql-schema #$schema)
 341
 342            ;; Allow non-ASCII file names--e.g., 'nss-certs'--to be decoded.
 343            (setenv "GUIX_LOCPATH"
 344                    #+(file-append glibc-utf8-locales "/lib/locale"))
 345            (setlocale LC_ALL "en_US.utf8")
 346
 347            (let ((inputs
 348                   '#$(append (list parted e2fsprogs dosfstools)
 349                              (map canonical-package
 350                                   (list sed grep coreutils findutils gawk))))
 351
 352                  ;; This variable is unused but allows us to add INPUTS-TO-COPY
 353                  ;; as inputs.
 354                  (to-register
 355                   '#$(map (match-lambda
 356                             ((name thing) thing)
 357                             ((name thing output) `(,thing ,output)))
 358                           inputs)))
 359
 360              (set-path-environment-variable "PATH" '("bin" "sbin") inputs)
 361
 362              (let* ((graphs     '#$(match inputs
 363                                      (((names . _) ...)
 364                                       names)))
 365                     (initialize (root-partition-initializer
 366                                  #:extra-directives '#$extra-directives
 367                                  #:closures graphs
 368                                  #:copy-closures? #$copy-inputs?
 369                                  #:register-closures? #$register-closures?
 370                                  #:system-directory #$os
 371
 372                                  #:make-device-nodes
 373                                  #$(match device-nodes
 374                                      ('linux #~make-essential-device-nodes)
 375                                      ('hurd #~make-hurd-device-nodes))
 376
 377                                  ;; Disable deduplication to speed things up,
 378                                  ;; and because it doesn't help much for a
 379                                  ;; single system generation.
 380                                  #:deduplicate? #f))
 381                     (root-size  #$(if (eq? 'guess disk-image-size)
 382                                       #~(max
 383                                          ;; Minimum 20 MiB root size
 384                                          (* 20 (expt 2 20))
 385                                          (estimated-partition-size
 386                                           (map (cut string-append "/xchg/" <>)
 387                                                graphs)))
 388                                       (- disk-image-size
 389                                          (* 50 (expt 2 20)))))
 390                     (partitions
 391                      (append
 392                       (list (partition
 393                              (size root-size)
 394                              (label #$file-system-label)
 395                              (uuid #$(and=> file-system-uuid
 396                                             uuid-bytevector))
 397                              (file-system #$file-system-type)
 398                              (file-system-options '#$file-system-options)
 399                              (flags '(boot))
 400                              (initializer initialize)))
 401                       ;; Append a small EFI System Partition for use with UEFI
 402                       ;; bootloaders if we are not targeting ARM because UEFI
 403                       ;; support in U-Boot is experimental.
 404                       ;;
 405                       ;; FIXME: ‘target-arm?’ may be not operate on the right
 406                       ;; system/target values.  Rewrite using ‘let-system’ when
 407                       ;; available.
 408                       (if #$(target-arm?)
 409                           '()
 410                           (list (partition
 411                                  ;; The standalone grub image is about 10MiB, but
 412                                  ;; leave some room for custom or multiple images.
 413                                  (size (* 40 (expt 2 20)))
 414                                  (label "GNU-ESP") ;cosmetic only
 415                                  ;; Use "vfat" here since this property is used
 416                                  ;; when mounting. The actual FAT-ness is based
 417                                  ;; on file system size (16 in this case).
 418                                  (file-system "vfat")
 419                                  (flags '(esp)))))))
 420                     (grub-efi #$(and (not (target-arm?)) grub-efi)))
 421                (initialize-hard-disk "/dev/vda"
 422                                      #:partitions partitions
 423                                      #:grub-efi grub-efi
 424                                      #:bootloader-package
 425                                      #$(bootloader-package bootloader)
 426                                      #:bootcfg #$bootcfg-drv
 427                                      #:bootcfg-location
 428                                      #$(bootloader-configuration-file bootloader)
 429                                      #:bootloader-installer
 430                                      #$(bootloader-installer bootloader)))))))
 431    #:system system
 432    #:make-disk-image? #t
 433    #:disk-image-size disk-image-size
 434    #:disk-image-format disk-image-format
 435    #:references-graphs inputs
 436    #:substitutable? substitutable?))
 437
 438 (define* (system-docker-image os
 439                               #:key
 440                               (name "guix-docker-image")
 441                               (register-closures? (has-guix-service-type? os))
 442                               shared-network?)
 443   "Build a docker image.  OS is the desired <operating-system>.  NAME is the
 444 base name to use for the output file.  When SHARED-NETWORK? is true, assume
 445 that the container will share network with the host and thus doesn't need a
 446 DHCP client, nscd, and so on.
 447
 448 When REGISTER-CLOSURES? is true, register the closure of OS with Guix in the
 449 resulting Docker image.  By default, REGISTER-CLOSURES? is set to true only if
 450 a service of type GUIX-SERVICE-TYPE is present in the services definition of
 451 the operating system."
 452   (define schema
 453     (and register-closures?
 454          (local-file (search-path %load-path
 455                                   "guix/store/schema.sql"))))
 456
 457   (define boot-program
 458     ;; Program that runs the boot script of OS, which in turn starts shepherd.
 459     (program-file "boot-program"
 460                   #~(let ((system (cadr (command-line))))
 461                       (setenv "GUIX_NEW_SYSTEM" system)
 462                       (execl #$(file-append guile-2.2 "/bin/guile")
 463                              "guile" "--no-auto-compile"
 464                              (string-append system "/boot")))))
 465
 466
 467   (let ((os    (operating-system-with-gc-roots
 468                 (containerized-operating-system os '()
 469                                                 #:shared-network?
 470                                                 shared-network?)
 471                 (list boot-program)))
 472         (name  (string-append name ".tar.gz"))
 473         (graph "system-graph"))
 474     (define build
 475       (with-extensions (cons guile-json-3         ;for (guix docker)
 476                              gcrypt-sqlite3&co)   ;for (guix store database)
 477         (with-imported-modules `(,@(source-module-closure
 478                                     '((guix docker)
 479                                       (guix store database)
 480                                       (guix build utils)
 481                                       (guix build store-copy)
 482                                       (gnu build vm))
 483                                     #:select? not-config?)
 484                                  ((guix config) => ,(make-config.scm)))
 485           #~(begin
 486               (use-modules (guix docker)
 487                            (guix build utils)
 488                            (gnu build vm)
 489                            (srfi srfi-19)
 490                            (guix build store-copy)
 491                            (guix store database))
 492
 493               ;; Set the SQL schema location.
 494               (sql-schema #$schema)
 495
 496               ;; Allow non-ASCII file names--e.g., 'nss-certs'--to be decoded.
 497               (setenv "GUIX_LOCPATH"
 498                       #+(file-append glibc-utf8-locales "/lib/locale"))
 499               (setlocale LC_ALL "en_US.utf8")
 500
 501               (let* (;; This initializer requires elevated privileges that are
 502                      ;; not normally available in the build environment (e.g.,
 503                      ;; it needs to create device nodes).  In order to obtain
 504                      ;; such privileges, we run it as root in a VM.
 505                      (initialize (root-partition-initializer
 506                                   #:closures '(#$graph)
 507                                   #:register-closures? #$register-closures?
 508                                   #:system-directory #$os
 509                                   ;; De-duplication would fail due to
 510                                   ;; cross-device link errors, so don't do it.
 511                                   #:deduplicate? #f))
 512                      ;; Even as root in a VM, the initializer would fail due to
 513                      ;; lack of privileges if we use a root-directory that is on
 514                      ;; a file system that is shared with the host (e.g., /tmp).
 515                      (root-directory "/guixsd-system-root"))
 516                 (set-path-environment-variable "PATH" '("bin" "sbin") '(#+tar))
 517                 (mkdir root-directory)
 518                 (initialize root-directory)
 519                 (build-docker-image
 520                  (string-append "/xchg/" #$name) ;; The output file.
 521                  (cons* root-directory
 522                         (map store-info-item
 523                              (call-with-input-file
 524                                  (string-append "/xchg/" #$graph)
 525                                read-reference-graph)))
 526                  #$os
 527                  #:entry-point '(#$boot-program #$os)
 528                  #:compressor '(#+(file-append gzip "/bin/gzip") "-9n")
 529                  #:creation-time (make-time time-utc 0 1)
 530                  #:transformations `((,root-directory -> ""))))))))
 531
 532     (expression->derivation-in-linux-vm
 533      name build
 534      #:make-disk-image? #f
 535      #:single-file-output? #t
 536      #:references-graphs `((,graph ,os)))))
 537
 538 \f
 539 ;;;
 540 ;;; VM and disk images.
 541 ;;;
 542
 543 (define* (system-disk-image-in-vm os
 544                                   #:key
 545                                   (name "disk-image")
 546                                   (file-system-type "ext4")
 547                                   (disk-image-size (* 900 (expt 2 20)))
 548                                   (volatile? #t)
 549                                   (substitutable? #t))
 550   "Return the derivation of a disk image of DISK-IMAGE-SIZE bytes of the
 551 system described by OS.  Said image can be copied on a USB stick as is.  When
 552 VOLATILE? is true, the root file system is made volatile; this is useful
 553 to USB sticks meant to be read-only.
 554
 555 SUBSTITUTABLE? determines whether the returned derivation should be marked as
 556 substitutable."
 557   (define root-label
 558     "Guix_image")
 559
 560   (define (root-uuid os)
 561     ;; UUID of the root file system, computed in a deterministic fashion.
 562     ;; This is what we use to locate the root file system so it has to be
 563     ;; different from the user's own file system UUIDs.
 564     (operating-system-uuid os 'dce))
 565
 566   (define file-systems-to-keep
 567     (remove (lambda (fs)
 568               (string=? (file-system-mount-point fs) "/"))
 569             (operating-system-file-systems os)))
 570
 571   (let* ((os (operating-system (inherit os)
 572                ;; Since this is meant to be used on real hardware, don't
 573                ;; install QEMU networking or anything like that.  Assume USB
 574                ;; mass storage devices (usb-storage.ko) are available.
 575                (initrd (lambda (file-systems . rest)
 576                          (apply (operating-system-initrd os)
 577                                 file-systems
 578                                 #:volatile-root? volatile?
 579                                 rest)))
 580
 581                (bootloader (operating-system-bootloader os))
 582
 583                ;; Force our own root file system.  (We need a "/" file system
 584                ;; to call 'root-uuid'.)
 585                (file-systems (cons (file-system
 586                                      (mount-point "/")
 587                                      (device "/dev/placeholder")
 588                                      (type file-system-type))
 589                                    file-systems-to-keep))))
 590          (uuid (root-uuid os))
 591          (os (operating-system
 592                (inherit os)
 593                (file-systems (cons (file-system
 594                                      (mount-point "/")
 595                                      (device uuid)
 596                                      (type file-system-type))
 597                                    file-systems-to-keep))))
 598         (bootcfg (operating-system-bootcfg os)))
 599     (qemu-image #:name name
 600                 #:os os
 601                 #:bootcfg-drv bootcfg
 602                 #:bootloader (bootloader-configuration-bootloader
 603                               (operating-system-bootloader os))
 604                 #:disk-image-size disk-image-size
 605                 #:disk-image-format "raw"
 606                 #:file-system-type file-system-type
 607                 #:file-system-label root-label
 608                 #:file-system-uuid uuid
 609                 #:copy-inputs? #t
 610                 #:inputs `(("system" ,os)
 611                            ("bootcfg" ,bootcfg))
 612                 #:substitutable? substitutable?)))
 613
 614 (define* (system-qemu-image os
 615                             #:key
 616                             (file-system-type "ext4")
 617                             (disk-image-size (* 900 (expt 2 20))))
 618   "Return the derivation of a freestanding QEMU image of DISK-IMAGE-SIZE bytes
 619 of the GNU system as described by OS."
 620   (define file-systems-to-keep
 621     ;; Keep only file systems other than root and not normally bound to real
 622     ;; devices.
 623     (remove (lambda (fs)
 624               (let ((target (file-system-mount-point fs))
 625                     (source (file-system-device fs)))
 626                 (or (string=? target "/")
 627                     (string-prefix? "/dev/" source))))
 628             (operating-system-file-systems os)))
 629
 630   (define root-uuid
 631     ;; UUID of the root file system.
 632     (operating-system-uuid os
 633                            (if (string=? file-system-type "iso9660")
 634                                'iso9660
 635                                'dce)))
 636
 637
 638   (let* ((os (operating-system (inherit os)
 639                ;; Assume we have an initrd with the whole QEMU shebang.
 640
 641                ;; Force our own root file system.  Refer to it by UUID so that
 642                ;; it works regardless of how the image is used ("qemu -hda",
 643                ;; Xen, etc.).
 644                (file-systems (cons (file-system
 645                                      (mount-point "/")
 646                                      (device root-uuid)
 647                                      (type file-system-type))
 648                                    file-systems-to-keep))))
 649          (bootcfg (operating-system-bootcfg os)))
 650     (qemu-image  #:os os
 651                  #:bootcfg-drv bootcfg
 652                  #:bootloader (bootloader-configuration-bootloader
 653                                (operating-system-bootloader os))
 654                  #:disk-image-size disk-image-size
 655                  #:file-system-type file-system-type
 656                  #:file-system-uuid root-uuid
 657                  #:inputs `(("system" ,os)
 658                             ("bootcfg" ,bootcfg))
 659                  #:copy-inputs? #t)))
 660
 661 \f
 662 ;;;
 663 ;;; VMs that share file systems with the host.
 664 ;;;
 665
 666 (define (file-system->mount-tag fs)
 667   "Return a 9p mount tag for host file system FS."
 668   ;; QEMU mount tags must be ASCII, at most 31-byte long, cannot contain
 669   ;; slashes, and cannot start with '_'.  Compute an identifier that
 670   ;; corresponds to the rules.
 671   (string-append "TAG"
 672                  (string-drop (bytevector->base32-string
 673                                (sha1 (string->utf8 fs)))
 674                               4)))
 675
 676 (define (mapping->file-system mapping)
 677   "Return a 9p file system that realizes MAPPING."
 678   (match mapping
 679     (($ <file-system-mapping> source target writable?)
 680      (file-system
 681        (mount-point target)
 682        (device (file-system->mount-tag source))
 683        (type "9p")
 684        (flags (if writable? '() '(read-only)))
 685        (options "trans=virtio,cache=loose")
 686        (check? #f)
 687        (create-mount-point? #t)))))
 688
 689 (define* (virtualized-operating-system os mappings #:optional (full-boot? #f))
 690   "Return an operating system based on OS suitable for use in a virtualized
 691 environment with the store shared with the host.  MAPPINGS is a list of
 692 <file-system-mapping> to realize in the virtualized OS."
 693   (define user-file-systems
 694     ;; Remove file systems that conflict with those added below, or that are
 695     ;; normally bound to real devices.
 696     (remove (lambda (fs)
 697               (let ((target (file-system-mount-point fs))
 698                     (source (file-system-device fs)))
 699                 (or (string=? target (%store-prefix))
 700                     (string=? target "/")
 701                     (and (string? source)
 702                          (string-prefix? "/dev/" source))
 703
 704                     ;; Labels and UUIDs are necessarily invalid in the VM.
 705                     (and (file-system-mount? fs)
 706                          (or (file-system-label? source)
 707                              (uuid? source))))))
 708             (operating-system-file-systems os)))
 709
 710   (define virtual-file-systems
 711     (cons (file-system
 712             (mount-point "/")
 713             (device "/dev/vda1")
 714             (type "ext4"))
 715
 716           (append (map mapping->file-system mappings)
 717                   user-file-systems)))
 718
 719   (operating-system (inherit os)
 720
 721     ;; XXX: Until we run QEMU with UEFI support (with the OVMF firmware),
 722     ;; force the traditional i386/BIOS method.
 723     ;; See <https://bugs.gnu.org/28768>.
 724     (bootloader (bootloader-configuration
 725                   (inherit (operating-system-bootloader os))
 726                   (bootloader grub-bootloader)
 727                   (target "/dev/vda")))
 728
 729     (initrd (lambda (file-systems . rest)
 730               (apply (operating-system-initrd os)
 731                      file-systems
 732                      #:volatile-root? #t
 733                      rest)))
 734
 735     ;; Disable swap.
 736     (swap-devices '())
 737
 738     ;; XXX: When FULL-BOOT? is true, do not add a 9p mount for /gnu/store
 739     ;; since that would lead the bootloader config to look for the kernel and
 740     ;; initrd in it.
 741     (file-systems (if full-boot?
 742                       virtual-file-systems
 743                       (cons
 744                        (file-system
 745                          (inherit (mapping->file-system %store-mapping))
 746                          (needed-for-boot? #t))
 747                        virtual-file-systems)))))
 748
 749 (define* (system-qemu-image/shared-store
 750           os
 751           #:key
 752           full-boot?
 753           (disk-image-size (* (if full-boot? 500 30) (expt 2 20))))
 754   "Return a derivation that builds a QEMU image of OS that shares its store
 755 with the host.
 756
 757 When FULL-BOOT? is true, return an image that does a complete boot sequence,
 758 bootloaded included; thus, make a disk image that contains everything the
 759 bootloader refers to: OS kernel, initrd, bootloader data, etc."
 760   (define root-uuid
 761     ;; Use a fixed UUID to improve determinism.
 762     (operating-system-uuid os 'dce))
 763
 764   (define bootcfg
 765     (operating-system-bootcfg os))
 766
 767   ;; XXX: When FULL-BOOT? is true, we end up creating an image that contains
 768   ;; BOOTCFG and all its dependencies, including the output of OS.
 769   ;; This is more than needed (we only need the kernel, initrd, GRUB for its
 770   ;; font, and the background image), but it's hard to filter that.
 771   (qemu-image #:os os
 772               #:bootcfg-drv bootcfg
 773               #:bootloader (bootloader-configuration-bootloader
 774                             (operating-system-bootloader os))
 775               #:disk-image-size disk-image-size
 776               #:file-system-uuid root-uuid
 777               #:inputs (if full-boot?
 778                            `(("bootcfg" ,bootcfg))
 779                            '())
 780
 781               ;; XXX: Passing #t here is too slow, so let it off by default.
 782               #:register-closures? #f
 783               #:copy-inputs? full-boot?))
 784
 785 (define* (common-qemu-options image shared-fs)
 786   "Return the a string-value gexp with the common QEMU options to boot IMAGE,
 787 with '-virtfs' options for the host file systems listed in SHARED-FS."
 788
 789   (define (virtfs-option fs)
 790     #~(format #f "-virtfs local,path=~s,security_model=none,mount_tag=~s"
 791               #$fs #$(file-system->mount-tag fs)))
 792
 793   #~(;; Only enable kvm if we see /dev/kvm exists.
 794      ;; This allows users without hardware virtualization to still use these
 795      ;; commands.
 796      #$@(if (file-exists? "/dev/kvm")
 797             '("-enable-kvm")
 798             '())
 799
 800      "-no-reboot"
 801      "-nic" "user,model=virtio-net-pci"
 802      "-object" "rng-random,filename=/dev/urandom,id=guixsd-vm-rng"
 803      "-device" "virtio-rng-pci,rng=guixsd-vm-rng"
 804
 805      #$@(map virtfs-option shared-fs)
 806      "-vga std"
 807      (format #f "-drive file=~a,if=virtio,cache=writeback,werror=report,readonly"
 808              #$image)))
 809
 810 (define* (system-qemu-image/shared-store-script os
 811                                                 #:key
 812                                                 (qemu qemu)
 813                                                 (graphic? #t)
 814                                                 (memory-size 256)
 815                                                 (mappings '())
 816                                                 full-boot?
 817                                                 (disk-image-size
 818                                                  (* (if full-boot? 500 70)
 819                                                     (expt 2 20)))
 820                                                 (options '()))
 821   "Return a derivation that builds a script to run a virtual machine image of
 822 OS that shares its store with the host.  The virtual machine runs with
 823 MEMORY-SIZE MiB of memory.
 824
 825 MAPPINGS is a list of <file-system-mapping> specifying mapping of host file
 826 systems into the guest.
 827
 828 When FULL-BOOT? is true, the returned script runs everything starting from the
 829 bootloader; otherwise it directly starts the operating system kernel.  The
 830 DISK-IMAGE-SIZE parameter specifies the size in bytes of the root disk image;
 831 it is mostly useful when FULL-BOOT?  is true."
 832   (mlet* %store-monad ((os ->  (virtualized-operating-system os mappings full-boot?))
 833                        (image  (system-qemu-image/shared-store
 834                                 os
 835                                 #:full-boot? full-boot?
 836                                 #:disk-image-size disk-image-size)))
 837     (define kernel-arguments
 838       #~(list #$@(if graphic? #~() #~("console=ttyS0"))
 839               #+@(operating-system-kernel-arguments os "/dev/vda1")))
 840
 841     (define qemu-exec
 842       #~(list (string-append #$qemu "/bin/" #$(qemu-command (%current-system)))
 843               #$@(if full-boot?
 844                      #~()
 845                      #~("-kernel" #$(operating-system-kernel-file os)
 846                         "-initrd" #$(file-append os "/initrd")
 847                         (format #f "-append ~s"
 848                                 (string-join #$kernel-arguments " "))))
 849               #$@(common-qemu-options image
 850                                       (map file-system-mapping-source
 851                                            (cons %store-mapping mappings)))
 852               "-m " (number->string #$memory-size)
 853               #$@options))
 854
 855     (define builder
 856       #~(call-with-output-file #$output
 857           (lambda (port)
 858             (format port "#!~a~% exec ~a \"$@\"~%"
 859                     #$(file-append bash "/bin/sh")
 860                     (string-join #$qemu-exec " "))
 861             (chmod port #o555))))
 862
 863     (gexp->derivation "run-vm.sh" builder)))
 864
 865 \f
 866 ;;;
 867 ;;; High-level abstraction.
 868 ;;;
 869
 870 (define-record-type* <virtual-machine> %virtual-machine
 871   make-virtual-machine
 872   virtual-machine?
 873   (operating-system virtual-machine-operating-system) ;<operating-system>
 874   (qemu             virtual-machine-qemu              ;<package>
 875                     (default qemu))
 876   (graphic?         virtual-machine-graphic?      ;Boolean
 877                     (default #f))
 878   (memory-size      virtual-machine-memory-size   ;integer (MiB)
 879                     (default 256))
 880   (disk-image-size  virtual-machine-disk-image-size   ;integer (bytes)
 881                     (default 'guess))
 882   (port-forwardings virtual-machine-port-forwardings ;list of integer pairs
 883                     (default '())))
 884
 885 (define-syntax virtual-machine
 886   (syntax-rules ()
 887     "Declare a virtual machine running the specified OS, with the given
 888 options."
 889     ((_ os)                                       ;shortcut
 890      (%virtual-machine (operating-system os)))
 891     ((_ fields ...)
 892      (%virtual-machine fields ...))))
 893
 894 (define (port-forwardings->qemu-options forwardings)
 895   "Return the QEMU option for the given port FORWARDINGS as a string, where
 896 FORWARDINGS is a list of host-port/guest-port pairs."
 897   (string-join
 898    (map (match-lambda
 899           ((host-port . guest-port)
 900            (string-append "hostfwd=tcp::"
 901                           (number->string host-port)
 902                           "-:" (number->string guest-port))))
 903         forwardings)
 904    ","))
 905
 906 (define-gexp-compiler (virtual-machine-compiler (vm <virtual-machine>)
 907                                                 system target)
 908   ;; XXX: SYSTEM and TARGET are ignored.
 909   (match vm
 910     (($ <virtual-machine> os qemu graphic? memory-size disk-image-size ())
 911      (system-qemu-image/shared-store-script os
 912                                             #:qemu qemu
 913                                             #:graphic? graphic?
 914                                             #:memory-size memory-size
 915                                             #:disk-image-size
 916                                             disk-image-size))
 917     (($ <virtual-machine> os qemu graphic? memory-size disk-image-size
 918                           forwardings)
 919      (let ((options
 920             `("-nic" ,(string-append
 921                        "user,model=virtio-net-pci,"
 922                        (port-forwardings->qemu-options forwardings)))))
 923        (system-qemu-image/shared-store-script os
 924                                               #:qemu qemu
 925                                               #:graphic? graphic?
 926                                               #:memory-size memory-size
 927                                               #:disk-image-size
 928                                               disk-image-size
 929                                               #:options options)))))
 930
 931 ;;; vm.scm ends here