gnu/packages/scheme.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (gnu packages scheme)
  20   #:use-module (gnu packages)
  21   #:use-module (guix licenses)
  22   #:use-module (guix packages)
  23   #:use-module (guix download)
  24   #:use-module (guix build-system gnu)
  25   #:use-module (gnu packages m4)
  26   #:use-module (gnu packages multiprecision)
  27   #:use-module (gnu packages emacs)
  28   #:use-module (gnu packages texinfo)
  29   #:use-module (gnu packages elf)
  30   #:use-module (gnu packages which)
  31   #:use-module (gnu packages pkg-config)
  32   #:use-module (gnu packages avahi)
  33   #:use-module (gnu packages libphidget)
  34   #:use-module (gnu packages glib)
  35   #:use-module (gnu packages gtk)
  36   #:use-module (gnu packages libffi)
  37   #:use-module (gnu packages libjpeg)
  38   #:use-module (ice-9 match))
  39
  40 (define-public mit-scheme
  41   (package
  42     (name "mit-scheme")
  43     (version "9.1.1")
  44     (source #f)                                   ; see below
  45     (build-system gnu-build-system)
  46     (arguments
  47      `(#:tests? #f                                ; no "check" target
  48        #:phases
  49        (alist-replace
  50         'unpack
  51         (lambda* (#:key inputs #:allow-other-keys)
  52           (and (zero? (system* "tar" "xzvf"
  53                                (assoc-ref inputs "source")))
  54                (chdir ,(string-append name "-" version))
  55                (begin
  56                  ;; Delete these dangling symlinks since they break
  57                  ;; `patch-shebangs'.
  58                  (for-each delete-file
  59                            (append (find-files "src/lib/lib" "\\.so$")
  60                                    (find-files "src/lib" "^ffi-test")))
  61                  (chdir "src")
  62                  #t)))
  63         (alist-replace
  64          'build
  65          (lambda* (#:key system outputs #:allow-other-keys)
  66            (let ((out (assoc-ref outputs "out")))
  67              (if (or (string-prefix? "x86_64" system)
  68                      (string-prefix? "i686" system))
  69                  (zero? (system* "make" "compile-microcode"))
  70                  (zero? (system* "./etc/make-liarc.sh"
  71                                  (string-append "--prefix=" out))))))
  72          %standard-phases))))
  73     (inputs
  74      `(;; TODO: Build doc when TeX Live is available.
  75        ;; ("automake" ,automake)
  76        ;; ("texlive-core" ,texlive-core)
  77        ("texinfo" ,texinfo)
  78        ("m4" ,m4)
  79
  80        ("source"
  81
  82         ;; MIT/GNU Scheme is not bootstrappable, so it's recommended to
  83         ;; compile from the architecture-specific tarballs, which contain
  84         ;; pre-built binaries.  It leads to more efficient code than when
  85         ;; building the tarball that contains generated C code instead of
  86         ;; those binaries.
  87         ,(origin
  88           (method url-fetch)
  89           (uri (string-append "mirror://gnu/mit-scheme/stable.pkg/"
  90                               version "/mit-scheme-"
  91                               version "-"
  92                               (match (%current-system)
  93                                 ("x86_64-linux" "x86-64")
  94                                 ("i686-linux" "i386")
  95                                 (_ "c"))
  96                               ".tar.gz"))
  97           (sha256
  98            (match (%current-system)
  99              ("x86_64-linux"
 100               (base32
 101                "1wcxm9hyfc53myvlcn93fyqrnnn4scwkknl9hkbp1cphc6mp291x"))
 102              ("i686-linux"
 103               (base32
 104                "0vi760fy550d9db538m0vzbq1mpdncvw9g8bk4lswk0kcdira55z"))
 105              (_
 106               (base32
 107                "0pclakzwxbqgy6wqwvs6ml62wgby8ba8xzmwzdwhx1v8wv05yw1j"))))))))
 108     (home-page "http://www.gnu.org/software/mit-scheme/")
 109     (synopsis "Scheme implementation with integrated editor and debugger")
 110     (description
 111      "GNU/MIT Scheme is an implementation of the Scheme programming
 112 language.  It provides an interpreter, a compiler and a debugger.  It also
 113 features an integrated Emacs-like editor and a large runtime library.")
 114     (license gpl2+)))
 115
 116 (define-public bigloo
 117   (package
 118     (name "bigloo")
 119     (version "4.1a")
 120     (source (origin
 121              (method url-fetch)
 122              (uri (string-append "ftp://ftp-sop.inria.fr/indes/fp/Bigloo/bigloo"
 123                                  version ".tar.gz"))
 124              (sha256
 125               (base32
 126                "170q7nh08n4v20xl81fxb0xcdxphqqacfa643hsa8i2ar6pki04c"))
 127              (patches (list (search-patch "bigloo-gc-shebangs.patch")))))
 128     (build-system gnu-build-system)
 129     (arguments
 130      `(#:test-target "test"
 131        #:phases (alist-replace
 132                  'configure
 133                  (lambda* (#:key outputs #:allow-other-keys)
 134
 135                    (substitute* "configure"
 136                      (("^shell=.*$")
 137                       (string-append "shell=" (which "bash") "\n")))
 138
 139                    ;; Since libgc's pthread redirects are used, we end up
 140                    ;; using libgc symbols, so we must link against it.
 141                    ;; Reported on 2013-06-25.
 142                    (substitute* "api/pthread/src/Makefile"
 143                      (("^EXTRALIBS[[:blank:]]*=(.*)$" _ value)
 144                       (string-append "EXTRALIBS = "
 145                                      (string-trim-right value)
 146                                      " -l$(GCLIB)_fth-$(RELEASE)"
 147                                      " -Wl,-rpath=" (assoc-ref outputs "out")
 148                                      "/lib/bigloo/" ,version)))
 149
 150                    ;; Those variables are used by libgc's `configure'.
 151                    (setenv "SHELL" (which "sh"))
 152                    (setenv "CONFIG_SHELL" (which "sh"))
 153
 154                    ;; ... but they turned out to be overridden later, so work
 155                    ;; around that.
 156                    (substitute* (find-files "gc" "^configure-gc")
 157                      (("sh=/bin/sh")
 158                       (string-append "sh=" (which "sh"))))
 159
 160                    ;; The `configure' script doesn't understand options
 161                    ;; of those of Autoconf.
 162                    (let ((out (assoc-ref outputs "out")))
 163                      (zero?
 164                       (system* "./configure"
 165                                (string-append "--prefix=" out)
 166                                ;; FIXME: Currently fails, see
 167                                ;; <http://article.gmane.org/gmane.lisp.scheme.bigloo/6126>.
 168                                ;; "--customgc=no" ; use our libgc
 169                                (string-append"--mv=" (which "mv"))
 170                                (string-append "--rm=" (which "rm"))))))
 171                  (alist-cons-after
 172                   'install 'install-emacs-modes
 173                   (lambda* (#:key outputs #:allow-other-keys)
 174                     (let* ((out (assoc-ref outputs "out"))
 175                            (dir (string-append out "/share/emacs/site-lisp")))
 176                       (zero? (system* "make" "-C" "bmacs" "all" "install"
 177                                       (string-append "EMACSBRAND=emacs24")
 178                                       (string-append "EMACSDIR=" dir)))))
 179                   %standard-phases))))
 180     (inputs
 181      `(("emacs" ,emacs)
 182
 183        ;; Optional APIs for which Bigloo has bindings.
 184        ("avahi" ,avahi)
 185        ("libphidget" ,libphidget)))
 186     (native-inputs
 187      `(("pkg-config" ,pkg-config)))
 188     (propagated-inputs
 189      `(("gmp" ,gmp)))                             ; bigloo.h refers to gmp.h
 190     (home-page "http://www-sop.inria.fr/indes/fp/Bigloo/")
 191     (synopsis "Bigloo, an efficient Scheme compiler")
 192     (description
 193      "Bigloo is a Scheme implementation devoted to one goal: enabling
 194 Scheme based programming style where C(++) is usually
 195 required.  Bigloo attempts to make Scheme practical by offering
 196 features usually presented by traditional programming languages
 197 but not offered by Scheme and functional programming.  Bigloo
 198 compiles Scheme modules.  It delivers small and fast stand alone
 199 binary executables.  Bigloo enables full connections between
 200 Scheme and C programs, between Scheme and Java programs, and
 201 between Scheme and C# programs.")
 202     (license gpl2+)))
 203
 204 (define-public hop
 205   (package
 206     (name "hop")
 207     (version "2.4.0")
 208     (source (origin
 209              (method url-fetch)
 210              (uri (string-append "ftp://ftp-sop.inria.fr/indes/fp/Hop/hop-"
 211                                  version ".tar.gz"))
 212              (sha256
 213               (base32
 214                "1v2r4ga58kk1sx0frn8qa8ccmjpic9csqzpk499wc95y9c4b1wy3"))
 215              (patches (list (search-patch "hop-bigloo-4.0b.patch")))))
 216     (build-system gnu-build-system)
 217     (arguments
 218      '(#:phases
 219        (alist-replace
 220         'configure
 221         (lambda* (#:key inputs outputs #:allow-other-keys)
 222           (let ((out (assoc-ref outputs "out")))
 223             (zero?
 224              (system* "./configure"
 225                       (string-append"--prefix=" out)))))
 226         (alist-cons-after
 227          'strip 'patch-rpath
 228          (lambda* (#:key outputs #:allow-other-keys)
 229            ;; Patch the RPATH of every installed library to point to $out/lib
 230            ;; instead of $TMPDIR.  Note that "patchelf --set-rpath" produces
 231            ;; invalid binaries when used before stripping.
 232            (let ((out    (assoc-ref outputs "out"))
 233                  (tmpdir (getcwd)))
 234              (every (lambda (lib)
 235                       (let* ((in    (open-pipe* OPEN_READ "patchelf"
 236                                                 "--print-rpath" lib))
 237                              (rpath (read-line in)))
 238                         (and (zero? (close-pipe in))
 239                              (let ((rpath* (regexp-substitute/global
 240                                             #f (regexp-quote tmpdir) rpath
 241                                             'pre out 'post)))
 242                                (or (equal? rpath rpath*)
 243                                    (begin
 244                                      (format #t "~a: changing RPATH from `~a' to `~a'~%"
 245                                              lib rpath rpath*)
 246                                      (zero?
 247                                       (system* "patchelf" "--set-rpath"
 248                                                rpath* lib))))))))
 249                     (append (find-files (string-append out "/bin")
 250                                         ".*")
 251                             (find-files (string-append out "/lib")
 252                                         "\\.so$")))))
 253          %standard-phases))
 254        #:tests? #f                                ; no test suite
 255        #:modules ((guix build gnu-build-system)
 256                   (guix build utils)
 257                   (ice-9 popen)
 258                   (ice-9 regex)
 259                   (ice-9 rdelim)
 260                   (srfi srfi-1))))
 261     (inputs `(("bigloo" ,bigloo)
 262               ("which" ,which)
 263               ("patchelf" ,patchelf)))
 264     (home-page "http://hop.inria.fr/")
 265     (synopsis "A multi-tier programming language for the Web 2.0")
 266     (description
 267      "HOP is a multi-tier programming language for the Web 2.0 and the
 268 so-called diffuse Web.  It is designed for programming interactive web
 269 applications in many fields such as multimedia (web galleries, music players,
 270 ...), ubiquitous and house automation (SmartPhones, personal appliance),
 271 mashups, office (web agendas, mail clients, ...), etc.")
 272     (license gpl2+)))
 273
 274 (define-public chicken
 275   (package
 276     (name "chicken")
 277     (version "4.8.0.3")
 278     (source (origin
 279              (method url-fetch)
 280              (uri (string-append "http://code.call-cc.org/releases/4.8.0/chicken-"
 281                                  version ".tar.gz"))
 282              (sha256
 283               (base32
 284                "1hwrnc2dhgbnz3mlpcb4qvg76kwsfzqylw24gxyy91jmygk1853a"))))
 285     (build-system gnu-build-system)
 286     (arguments
 287      `(#:modules ((guix build gnu-build-system)
 288                   (guix build utils)
 289                   (srfi srfi-1))
 290
 291        ;; No `configure' script; run "make check" after "make install" as
 292        ;; prescribed by README.
 293        #:phases (alist-cons-after
 294                  'install 'check
 295                  (assoc-ref %standard-phases 'check)
 296                  (fold alist-delete %standard-phases
 297                        '(configure check)))
 298
 299        #:make-flags (let ((out (assoc-ref %outputs "out")))
 300                       (list "PLATFORM=linux"
 301                             (string-append "PREFIX=" out)
 302                             (string-append "VARDIR=" out "/var/lib")))
 303
 304        ;; Parallel builds are not supported, as noted in README.
 305        #:parallel-build? #f))
 306     (home-page "http://www.call-cc.org/")
 307     (synopsis "R5RS Scheme implementation that compiles native code via C")
 308     (description
 309      "CHICKEN is a compiler for the Scheme programming language.  CHICKEN
 310 produces portable and efficient C, supports almost all of the R5RS Scheme
 311 language standard, and includes many enhancements and extensions.")
 312     (license bsd-3)))
 313
 314 (define-public scheme48
 315   (package
 316     (name "scheme48")
 317     (version "1.9")
 318     (source (origin
 319              (method url-fetch)
 320              (uri (string-append "http://s48.org/" version
 321                                  "/scheme48-" version ".tgz"))
 322              (sha256
 323               (base32
 324                "0rw2lz5xgld0klvld292ds6hvfk5l12vskzgf1hhwjdpa38r3fnw"))
 325              (patches (list (search-patch "scheme48-tests.patch")))))
 326     (build-system gnu-build-system)
 327     (home-page "http://s48.org/")
 328     (synopsis "Scheme implementation using a bytecode interpreter")
 329     (description
 330      "Scheme 48 is an implementation of Scheme based on a byte-code
 331 interpreter and is designed to be used as a testbed for experiments in
 332 implementation techniques and as an expository tool.")
 333
 334     ;; Most files are BSD-3; see COPYING for the few exceptions.
 335     (license bsd-3)))
 336
 337 (define-public racket
 338   (package
 339     (name "racket")
 340     (version "5.3.4")
 341     (source (origin
 342              (method url-fetch)
 343              (uri (list (string-append "http://download.racket-lang.org/installers/"
 344                                        version "/racket/racket-" version
 345                                        "-src-unix.tgz")
 346                         (string-append
 347                          "http://mirror.informatik.uni-tuebingen.de/mirror/racket/"
 348                          version "/racket/racket-" version "-src-unix.tgz")))
 349              (sha256
 350               ;; XXX: Used to be 1xhnx3yd74zrvn6sfcqmk57kxj51cwvm660dwiaxr1qxnm5lq0v7.
 351               (base32 "0yrdmpdvzf092869y6zjjjxl6j2kypgiv7qrfkv7lj8w01pbh7sd"))))
 352     (build-system gnu-build-system)
 353     (arguments
 354      '(#:phases
 355        (let* ((gui-libs
 356                (lambda (inputs)
 357                  (define (lib input)
 358                    (string-append (assoc-ref inputs input) "/lib"))
 359
 360                  (list (lib "glib")
 361                        (lib "cairo")
 362                        (lib "pango")
 363                        (lib "libjpeg")
 364                        (lib "gtk")
 365                        (lib "gdk-pixbuf")))))
 366          (alist-cons-before
 367           'configure 'pre-configure
 368           (lambda* (#:key inputs #:allow-other-keys)
 369             (chdir "src")
 370
 371             ;; The GUI libs are dynamically opened through the FFI, so they
 372             ;; must be in the loader's search path.
 373             (setenv "LD_LIBRARY_PATH" (string-join (gui-libs inputs) ":")))
 374           (alist-cons-after
 375            'unpack 'patch-/bin/sh
 376            (lambda _
 377              (substitute* "collects/racket/system.rkt"
 378                (("/bin/sh") (which "sh"))))
 379            (alist-cons-after
 380             'install 'wrap-programs
 381             (lambda* (#:key inputs outputs #:allow-other-keys)
 382               (let ((out (assoc-ref outputs "out")))
 383                 (define (wrap prog)
 384                   (wrap-program prog
 385                                 `("LD_LIBRARY_PATH" ":" prefix
 386                                   ,(gui-libs inputs))))
 387
 388                 (with-directory-excursion (string-append out "/bin")
 389                   (for-each wrap
 390                             (list "gracket" "drracket" "slideshow" "mred"))
 391                   #t)))
 392             %standard-phases))))
 393        #:tests? #f                                ; XXX: how to run them?
 394        ))
 395     (inputs `(("libffi" ,libffi)
 396               ("glib" ,glib)                      ; for DrRacket
 397               ("cairo" ,cairo)
 398               ("pango" ,pango)
 399               ("libjpeg" ,libjpeg-8)
 400               ("gdk-pixbuf" ,gdk-pixbuf)
 401               ("gtk" ,gtk+-2)))
 402     (home-page "http://racket-lang.org")
 403     (synopsis "Implementation of Scheme and related languages")
 404     (description
 405      "Racket is an implementation of the Scheme programming language (R5RS and
 406 R6RS) and related languages, such as Typed Racket.  It features a compiler and
 407 a virtual machine with just-in-time native compilation, as well as a large set
 408 of libraries.")
 409     (license lgpl2.0+)))