configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.11.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 AC_ARG_WITH([zsh-completion-dir],
  45   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  46     [name of the Zsh completion directory]),
  47   [zshcompletiondir="$withval"],
  48   [zshcompletiondir='${datadir}/zsh/site-functions'])
  49 AC_SUBST([zshcompletiondir])
  50
  51 dnl Better be verbose.
  52 AC_MSG_CHECKING([for the store directory])
  53 AC_MSG_RESULT([$storedir])
  54
  55 AC_ARG_ENABLE([daemon],
  56   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  57   [guix_build_daemon="$enableval"],
  58   [guix_build_daemon="yes"])
  59
  60 # Prepare a version of $localstatedir & co. that does not contain references
  61 # to shell variables.
  62 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  63 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  64 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  65 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  66 AC_SUBST([guix_localstatedir])
  67 AC_SUBST([guix_sysconfdir])
  68 AC_SUBST([guix_sbindir])
  69
  70 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  71 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  72
  73 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  74 dnl Make sure they are available.
  75 m4_pattern_forbid([PKG_CHECK_MODULES])
  76 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  77 m4_pattern_forbid([^GUILE_P$])
  78
  79 dnl Search for 'guile' and 'guild'.  Prefer 2.0 until the 2.2 upgrade is
  80 dnl complete.
  81 GUILE_PKG([2.0 2.2])
  82 GUILE_PROGS
  83 if test "x$GUILD" = "x"; then
  84    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  85 fi
  86
  87 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  88   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  89 else
  90   AC_MSG_WARN([Guile $GUILE_EFFECTIVE_VERSION is not fully supported!])
  91 fi
  92
  93 dnl guile-json is used for the PyPI package importer
  94 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  95 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  96
  97 dnl Make sure we have a full-fledged Guile.
  98 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  99
 100 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
 101 GUIX_CHECK_SRFI_37
 102 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
 103
 104 dnl Decompressors, for use by the substituter and other modules.
 105 AC_PATH_PROG([GZIP], [gzip])
 106 AC_PATH_PROG([BZIP2], [bzip2])
 107 AC_PATH_PROG([XZ], [xz])
 108 AC_SUBST([GZIP])
 109 AC_SUBST([BZIP2])
 110 AC_SUBST([XZ])
 111
 112 AC_ARG_WITH([nix-prefix],
 113   [AS_HELP_STRING([--with-nix-prefix=DIR],
 114     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 115   [case "$withval" in
 116     yes|no) ;;
 117     *)
 118       NIX_PREFIX="$withval"
 119       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 120       AC_SUBST([NIX_PREFIX])
 121       ;;
 122    esac],
 123   [])
 124
 125 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 126 AC_PATH_PROG([NIX_HASH], [nix-hash])
 127 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 128    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 129 fi
 130
 131 if test "x$NIX_INSTANTIATE" = "x"; then
 132    # This program is an optional dependency, so we just want it to be
 133    # taken from $PATH if it's not available right now.
 134    NIX_INSTANTIATE="nix-instantiate"
 135 fi
 136
 137 AC_ARG_WITH([nixpkgs],
 138   [AS_HELP_STRING([--with-nixpkgs=DIR],
 139     [search for Nixpkgs in DIR (for testing purposes only)])],
 140   [case "$withval" in
 141     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 142     *)      NIXPKGS="$withval";;
 143    esac],
 144   [])
 145
 146 AC_MSG_CHECKING([for Nixpkgs source tree])
 147 if test -f "$NIXPKGS/default.nix"; then
 148    AC_MSG_RESULT([$NIXPKGS])
 149    AC_SUBST([NIXPKGS])
 150 else
 151    AC_MSG_RESULT([not found])
 152 fi
 153
 154 LIBGCRYPT="libgcrypt"
 155 LIBGCRYPT_LIBDIR="no"
 156 LIBGCRYPT_PREFIX="no"
 157
 158 AC_ARG_WITH([libgcrypt-prefix],
 159   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 160   [case "$withval" in
 161     yes|no)
 162       ;;
 163     *)
 164       LIBGCRYPT="$withval/lib/libgcrypt"
 165       LIBGCRYPT_PREFIX="$withval"
 166       LIBGCRYPT_LIBDIR="$withval/lib"
 167       ;;
 168    esac])
 169
 170 AC_ARG_WITH([libgcrypt-libdir],
 171   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 172      [search for GNU libgcrypt's shared library in DIR])],
 173   [case "$withval" in
 174     yes|no)
 175       LIBGCRYPT="libgcrypt"
 176       LIBGCRYPT_LIBDIR="no"
 177       ;;
 178     *)
 179       LIBGCRYPT="$withval/libgcrypt"
 180       LIBGCRYPT_LIBDIR="$withval"
 181       ;;
 182    esac])
 183
 184 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 185 dnl absolute file name of libgcrypt.so.
 186 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 187   xnono)
 188     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 189     if test "x$LIBGCRYPT_LIBDIR" != x; then
 190       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 191     else
 192       dnl 'config-daemon.ac' expects "no" in this case.
 193       LIBGCRYPT_LIBDIR="no"
 194     fi
 195     ;;
 196 esac
 197
 198 dnl Library name suitable for `dynamic-link'.
 199 AC_MSG_CHECKING([for libgcrypt shared library name])
 200 AC_MSG_RESULT([$LIBGCRYPT])
 201 AC_SUBST([LIBGCRYPT])
 202 AC_SUBST([LIBGCRYPT_PREFIX])
 203 AC_SUBST([LIBGCRYPT_LIBDIR])
 204
 205 GUIX_ASSERT_LIBGCRYPT_USABLE
 206
 207 dnl Library name of zlib suitable for 'dynamic-link'.
 208 GUIX_LIBZ_LIBDIR([libz_libdir])
 209 if test "x$libz_libdir" = "x"; then
 210   LIBZ="libz"
 211 else
 212   LIBZ="$libz_libdir/libz"
 213 fi
 214 AC_MSG_CHECKING([for zlib's shared library name])
 215 AC_MSG_RESULT([$LIBZ])
 216 AC_SUBST([LIBZ])
 217
 218 AC_CACHE_SAVE
 219
 220 m4_include([config-daemon.ac])
 221
 222 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 223 dnl See `Building from Git' in the manual for more info.
 224 AM_MISSING_PROG([DOT], [dot])
 225
 226 dnl Manual pages.
 227 AM_MISSING_PROG([HELP2MAN], [help2man])
 228
 229 AC_CONFIG_FILES([Makefile
 230                  po/guix/Makefile.in
 231                  po/packages/Makefile.in
 232                  guix/config.scm])
 233
 234 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 235 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 236 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 237   [chmod +x pre-inst-env])
 238
 239 dnl Emacs interface.
 240 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 241 AM_PATH_LISPDIR
 242 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 243
 244 emacsuidir="${guilemoduledir}/guix/emacs"
 245 AC_SUBST([emacsuidir])
 246 AC_CONFIG_FILES([emacs/guix-config.el
 247                  emacs/guix-helper.scm])
 248
 249 AC_OUTPUT