gnu/packages/scheme.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (gnu packages scheme)
  20   #:use-module (gnu packages)
  21   #:use-module (guix licenses)
  22   #:use-module (guix packages)
  23   #:use-module (guix download)
  24   #:use-module (guix build-system gnu)
  25   #:use-module (gnu packages m4)
  26   #:use-module (gnu packages multiprecision)
  27   #:use-module (gnu packages emacs)
  28   #:use-module (gnu packages texinfo)
  29   #:use-module (gnu packages patchelf)
  30   #:use-module (gnu packages which)
  31   #:use-module (gnu packages pkg-config)
  32   #:use-module (gnu packages avahi)
  33   #:use-module (gnu packages libphidget)
  34   #:use-module (gnu packages glib)
  35   #:use-module (gnu packages gtk)
  36   #:use-module (gnu packages libffi)
  37   #:use-module (gnu packages libjpeg)
  38   #:use-module (ice-9 match))
  39
  40 (define-public mit-scheme
  41   (package
  42     (name "mit-scheme")
  43     (version "9.1.1")
  44     (source #f)                                   ; see below
  45     (build-system gnu-build-system)
  46     (arguments
  47      `(#:tests? #f                                ; no "check" target
  48        #:phases
  49        (alist-replace
  50         'unpack
  51         (lambda* (#:key inputs #:allow-other-keys)
  52           (and (zero? (system* "tar" "xzvf"
  53                                (assoc-ref inputs "source")))
  54                (chdir ,(string-append name "-" version))
  55                (begin
  56                  ;; Delete these dangling symlinks since they break
  57                  ;; `patch-shebangs'.
  58                  (for-each delete-file
  59                            (append (find-files "src/lib/lib" "\\.so$")
  60                                    (find-files "src/lib" "^ffi-test")))
  61                  (chdir "src")
  62                  #t)))
  63         (alist-replace
  64          'build
  65          (lambda* (#:key system outputs #:allow-other-keys)
  66            (let ((out (assoc-ref outputs "out")))
  67              (if (or (string-prefix? "x86_64" system)
  68                      (string-prefix? "i686" system))
  69                  (zero? (system* "make" "compile-microcode"))
  70                  (zero? (system* "./etc/make-liarc.sh"
  71                                  (string-append "--prefix=" out))))))
  72          %standard-phases))))
  73     (inputs
  74      `(;; TODO: Build doc when TeX Live is available.
  75        ;; ("automake" ,automake)
  76        ;; ("texlive-core" ,texlive-core)
  77        ("texinfo" ,texinfo)
  78        ("m4" ,m4)
  79
  80        ("source"
  81
  82         ;; MIT/GNU Scheme is not bootstrappable, so it's recommended to
  83         ;; compile from the architecture-specific tarballs, which contain
  84         ;; pre-built binaries.  It leads to more efficient code than when
  85         ;; building the tarball that contains generated C code instead of
  86         ;; those binaries.
  87         ,(origin
  88           (method url-fetch)
  89           (uri (string-append "mirror://gnu/mit-scheme/stable.pkg/"
  90                               version "/mit-scheme-"
  91                               version "-"
  92                               (match (%current-system)
  93                                 ("x86_64-linux" "x86-64")
  94                                 ("i686-linux" "i386")
  95                                 (_ "c"))
  96                               ".tar.gz"))
  97           (sha256
  98            (match (%current-system)
  99              ("x86_64-linux"
 100               (base32
 101                "1wcxm9hyfc53myvlcn93fyqrnnn4scwkknl9hkbp1cphc6mp291x"))
 102              ("i686-linux"
 103               (base32
 104                "0vi760fy550d9db538m0vzbq1mpdncvw9g8bk4lswk0kcdira55z"))
 105              (_
 106               (base32
 107                "0pclakzwxbqgy6wqwvs6ml62wgby8ba8xzmwzdwhx1v8wv05yw1j"))))))))
 108     (home-page "http://www.gnu.org/software/mit-scheme/")
 109     (synopsis "Scheme implementation with integrated editor and debugger")
 110     (description
 111      "MIT/GNU Scheme is an implementation of the Scheme programming
 112 language, providing an interpreter, compiler, source-code debugger,
 113 integrated Emacs-like editor, and a large runtime library.  MIT/GNU
 114 Scheme is best suited to programming large applications with a rapid
 115 development cycle.")
 116     (license gpl2+)))
 117
 118 (define-public bigloo
 119   (package
 120     (name "bigloo")
 121     (version "4.0b")
 122     (source (origin
 123              (method url-fetch)
 124              (uri (string-append "ftp://ftp-sop.inria.fr/indes/fp/Bigloo/bigloo"
 125                                  version ".tar.gz"))
 126              (sha256
 127               (base32
 128                "1fck2h48f0bvh8fl437cagmp0syfxy9lqacy1zwsis20fc76jvzi"))))
 129     (build-system gnu-build-system)
 130     (arguments
 131      `(#:patches (list (assoc-ref %build-inputs "patch/shebangs"))
 132        #:test-target "test"
 133        #:phases (alist-replace
 134                  'configure
 135                  (lambda* (#:key outputs #:allow-other-keys)
 136
 137                    (substitute* "configure"
 138                      (("^shell=.*$")
 139                       (string-append "shell=" (which "bash") "\n")))
 140
 141                    ;; Since libgc's pthread redirects are used, we end up
 142                    ;; using libgc symbols, so we must link against it.
 143                    ;; Reported on 2013-06-25.
 144                    (substitute* "api/pthread/src/Makefile"
 145                      (("^EXTRALIBS[[:blank:]]*=(.*)$" _ value)
 146                       (string-append "EXTRALIBS = "
 147                                      (string-trim-right value)
 148                                      " -l$(GCLIB)_fth-$(RELEASE)"
 149                                      " -Wl,-rpath=" (assoc-ref outputs "out")
 150                                      "/lib/bigloo/" ,version)))
 151
 152                    ;; Those variables are used by libgc's `configure'.
 153                    (setenv "SHELL" (which "sh"))
 154                    (setenv "CONFIG_SHELL" (which "sh"))
 155
 156                    ;; ... but they turned out to be overridden later, so work
 157                    ;; around that.
 158                    (substitute* (find-files "gc" "^configure-gc")
 159                      (("sh=/bin/sh")
 160                       (string-append "sh=" (which "sh"))))
 161
 162                    ;; The `configure' script doesn't understand options
 163                    ;; of those of Autoconf.
 164                    (let ((out (assoc-ref outputs "out")))
 165                      (zero?
 166                       (system* "./configure"
 167                                (string-append "--prefix=" out)
 168                                (string-append"--mv=" (which "mv"))
 169                                (string-append "--rm=" (which "rm"))))))
 170                  (alist-cons-after
 171                   'install 'install-emacs-modes
 172                   (lambda* (#:key outputs #:allow-other-keys)
 173                     (let* ((out (assoc-ref outputs "out"))
 174                            (dir (string-append out "/share/emacs/site-lisp")))
 175                       (zero? (system* "make" "-C" "bmacs" "all" "install"
 176                                       (string-append "EMACSBRAND=emacs24")
 177                                       (string-append "EMACSDIR=" dir)))))
 178                   %standard-phases))))
 179     (inputs
 180      `(("emacs" ,emacs)
 181        ("patch/shebangs" ,(search-patch "bigloo-gc-shebangs.patch"))
 182
 183        ;; Optional APIs for which Bigloo has bindings.
 184        ("avahi" ,avahi)
 185        ("libphidget" ,libphidget)))
 186     (native-inputs
 187      `(("pkg-config" ,pkg-config)))
 188     (propagated-inputs
 189      `(("gmp" ,gmp)))                             ; bigloo.h refers to gmp.h
 190     (home-page "http://www-sop.inria.fr/indes/fp/Bigloo/")
 191     (synopsis "Bigloo, an efficient Scheme compiler")
 192     (description
 193      "Bigloo is a Scheme implementation devoted to one goal: enabling
 194 Scheme based programming style where C(++) is usually
 195 required.  Bigloo attempts to make Scheme practical by offering
 196 features usually presented by traditional programming languages
 197 but not offered by Scheme and functional programming.  Bigloo
 198 compiles Scheme modules.  It delivers small and fast stand alone
 199 binary executables.  Bigloo enables full connections between
 200 Scheme and C programs, between Scheme and Java programs, and
 201 between Scheme and C# programs.")
 202     (license gpl2+)))
 203
 204 (define-public hop
 205   (package
 206     (name "hop")
 207     (version "2.4.0")
 208     (source (origin
 209              (method url-fetch)
 210              (uri (string-append "ftp://ftp-sop.inria.fr/indes/fp/Hop/hop-"
 211                                  version ".tar.gz"))
 212              (sha256
 213               (base32
 214                "1v2r4ga58kk1sx0frn8qa8ccmjpic9csqzpk499wc95y9c4b1wy3"))))
 215     (build-system gnu-build-system)
 216     (arguments
 217      '(#:phases
 218        (alist-replace
 219         'configure
 220         (lambda* (#:key inputs outputs #:allow-other-keys)
 221           (let ((out (assoc-ref outputs "out")))
 222             (zero?
 223              (system* "./configure"
 224                       (string-append"--prefix=" out)))))
 225         (alist-cons-after
 226          'strip 'patch-rpath
 227          (lambda* (#:key outputs #:allow-other-keys)
 228            ;; Patch the RPATH of every installed library to point to $out/lib
 229            ;; instead of $TMPDIR.  Note that "patchelf --set-rpath" produces
 230            ;; invalid binaries when used before stripping.
 231            (let ((out    (assoc-ref outputs "out"))
 232                  (tmpdir (getcwd)))
 233              (every (lambda (lib)
 234                       (let* ((in    (open-pipe* OPEN_READ "patchelf"
 235                                                 "--print-rpath" lib))
 236                              (rpath (read-line in)))
 237                         (and (zero? (close-pipe in))
 238                              (let ((rpath* (regexp-substitute/global
 239                                             #f (regexp-quote tmpdir) rpath
 240                                             'pre out 'post)))
 241                                (or (equal? rpath rpath*)
 242                                    (begin
 243                                      (format #t "~a: changing RPATH from `~a' to `~a'~%"
 244                                              lib rpath rpath*)
 245                                      (zero?
 246                                       (system* "patchelf" "--set-rpath"
 247                                                rpath* lib))))))))
 248                     (append (find-files (string-append out "/bin")
 249                                         ".*")
 250                             (find-files (string-append out "/lib")
 251                                         "\\.so$")))))
 252          %standard-phases))
 253        #:tests? #f                                ; no test suite
 254        #:patches (list (assoc-ref %build-inputs "patch/bigloo-4.0b"))
 255        #:modules ((guix build gnu-build-system)
 256                   (guix build utils)
 257                   (ice-9 popen)
 258                   (ice-9 regex)
 259                   (ice-9 rdelim)
 260                   (srfi srfi-1))))
 261     (inputs `(("bigloo" ,bigloo)
 262               ("which" ,which)
 263               ("patchelf" ,patchelf)
 264
 265               ("patch/bigloo-4.0b"
 266                ,(search-patch "hop-bigloo-4.0b.patch"))))
 267     (home-page "http://hop.inria.fr/")
 268     (synopsis "A multi-tier programming language for the Web 2.0")
 269     (description
 270      "HOP is a multi-tier programming language for the Web 2.0 and the
 271 so-called diffuse Web.  It is designed for programming interactive web
 272 applications in many fields such as multimedia (web galleries, music players,
 273 ...), ubiquitous and house automation (SmartPhones, personal appliance),
 274 mashups, office (web agendas, mail clients, ...), etc.")
 275     (license gpl2+)))
 276
 277 (define-public chicken
 278   (package
 279     (name "chicken")
 280     (version "4.8.0.3")
 281     (source (origin
 282              (method url-fetch)
 283              (uri (string-append "http://code.call-cc.org/releases/4.8.0/chicken-"
 284                                  version ".tar.gz"))
 285              (sha256
 286               (base32
 287                "1hwrnc2dhgbnz3mlpcb4qvg76kwsfzqylw24gxyy91jmygk1853a"))))
 288     (build-system gnu-build-system)
 289     (arguments
 290      `(#:modules ((guix build gnu-build-system)
 291                   (guix build utils)
 292                   (srfi srfi-1))
 293
 294        ;; No `configure' script; run "make check" after "make install" as
 295        ;; prescribed by README.
 296        #:phases (alist-cons-after
 297                  'install 'check
 298                  (assoc-ref %standard-phases 'check)
 299                  (fold alist-delete %standard-phases
 300                        '(configure check)))
 301
 302        #:make-flags (let ((out (assoc-ref %outputs "out")))
 303                       (list "PLATFORM=linux"
 304                             (string-append "PREFIX=" out)
 305                             (string-append "VARDIR=" out "/var/lib")))
 306
 307        ;; Parallel builds are not supported, as noted in README.
 308        #:parallel-build? #f))
 309     (home-page "http://www.call-cc.org/")
 310     (synopsis "R5RS Scheme implementation that compiles native code via C")
 311     (description
 312      "CHICKEN is a compiler for the Scheme programming language.  CHICKEN
 313 produces portable and efficient C, supports almost all of the R5RS Scheme
 314 language standard, and includes many enhancements and extensions.")
 315     (license bsd-3)))
 316
 317 (define-public scheme48
 318   (package
 319     (name "scheme48")
 320     (version "1.9")
 321     (source (origin
 322              (method url-fetch)
 323              (uri (string-append "http://s48.org/" version
 324                                  "/scheme48-" version ".tgz"))
 325              (sha256
 326               (base32
 327                "0rw2lz5xgld0klvld292ds6hvfk5l12vskzgf1hhwjdpa38r3fnw"))))
 328     (build-system gnu-build-system)
 329     (arguments `(#:patches (list (assoc-ref %build-inputs "patch/tests"))))
 330     (inputs `(("patch/tests" ,(search-patch "scheme48-tests.patch"))))
 331     (home-page "http://s48.org/")
 332     (synopsis "Scheme implementation using a bytecode interpreter")
 333     (description
 334      "Scheme 48 is an implementation of Scheme based on a byte-code
 335 interpreter and is designed to be used as a testbed for experiments in
 336 implementation techniques and as an expository tool.")
 337
 338     ;; Most files are BSD-3; see COPYING for the few exceptions.
 339     (license bsd-3)))
 340
 341 (define-public racket
 342   (package
 343     (name "racket")
 344     (version "5.3.4")
 345     (source (origin
 346              (method url-fetch)
 347              (uri (list (string-append "http://download.racket-lang.org/installers/"
 348                                        version "/racket/racket-" version
 349                                        "-src-unix.tgz")
 350                         (string-append
 351                          "http://mirror.informatik.uni-tuebingen.de/mirror/racket/"
 352                          version "/racket/racket-" version "-src-unix.tgz")))
 353              (sha256
 354               ;; XXX: Used to be 1xhnx3yd74zrvn6sfcqmk57kxj51cwvm660dwiaxr1qxnm5lq0v7.
 355               (base32 "0yrdmpdvzf092869y6zjjjxl6j2kypgiv7qrfkv7lj8w01pbh7sd"))))
 356     (build-system gnu-build-system)
 357     (arguments
 358      '(#:phases
 359        (let* ((gui-libs
 360                (lambda (inputs)
 361                  (define (lib input)
 362                    (string-append (assoc-ref inputs input) "/lib"))
 363
 364                  (list (lib "glib")
 365                        (lib "cairo")
 366                        (lib "pango")
 367                        (lib "libjpeg")
 368                        (lib "gtk")
 369                        (lib "gdk-pixbuf")))))
 370          (alist-cons-before
 371           'configure 'pre-configure
 372           (lambda* (#:key inputs #:allow-other-keys)
 373             (chdir "src")
 374
 375             ;; The GUI libs are dynamically opened through the FFI, so they
 376             ;; must be in the loader's search path.
 377             (setenv "LD_LIBRARY_PATH" (string-join (gui-libs inputs) ":")))
 378           (alist-cons-after
 379            'unpack 'patch-/bin/sh
 380            (lambda _
 381              (substitute* "collects/racket/system.rkt"
 382                (("/bin/sh") (which "sh"))))
 383            (alist-cons-after
 384             'install 'wrap-programs
 385             (lambda* (#:key inputs outputs #:allow-other-keys)
 386               (let ((out (assoc-ref outputs "out")))
 387                 (define (wrap prog)
 388                   (wrap-program prog
 389                                 `("LD_LIBRARY_PATH" ":" prefix
 390                                   ,(gui-libs inputs))))
 391
 392                 (with-directory-excursion (string-append out "/bin")
 393                   (for-each wrap
 394                             (list "gracket" "drracket" "slideshow" "mred"))
 395                   #t)))
 396             %standard-phases))))
 397        #:tests? #f                                ; XXX: how to run them?
 398        ))
 399     (inputs `(("libffi" ,libffi)
 400               ("glib" ,glib)                      ; for DrRacket
 401               ("cairo" ,cairo)
 402               ("pango" ,pango)
 403               ("libjpeg" ,libjpeg-8)
 404               ("gdk-pixbuf" ,gdk-pixbuf)
 405               ("gtk" ,gtk+-2)))
 406     (home-page "http://racket-lang.org")
 407     (synopsis "Implementation of Scheme and related languages")
 408     (description
 409      "Racket is an implementation of the Scheme programming language (R5RS and
 410 R6RS) and related languages, such as Typed Racket.  It features a compiler and
 411 a virtual machine with just-in-time native compilation, as well as a large set
 412 of libraries.")
 413     (license lgpl2.0+)))