config-daemon.ac

   1 dnl -*- Autoconf -*- fragment for the C++ daemon.
   2
   3 AC_MSG_CHECKING([whether to build daemon])
   4 AC_MSG_RESULT([$guix_build_daemon])
   5
   6 dnl C++ environment.  This macro must be used unconditionnaly.
   7 AC_PROG_CXX
   8 AM_PROG_AR
   9 AC_LANG([C++])
  10
  11 if test "x$guix_build_daemon" = "xyes"; then
  12
  13   GUIX_ASSERT_CXX11
  14
  15   AC_PROG_RANLIB
  16   AC_CONFIG_HEADER([nix/config.h])
  17
  18   dnl Use 64-bit file system calls so that we can support files > 2 GiB.
  19   AC_SYS_LARGEFILE
  20
  21   dnl Look for zlib, a required dependency.
  22   AC_CHECK_LIB([z], [gzdopen], [true],
  23     [AC_MSG_ERROR([Guix requires zlib.  See http://www.zlib.net/.])])
  24   AC_CHECK_HEADERS([zlib.h], [true],
  25     [AC_MSG_ERROR([Guix requires zlib.  See http://www.zlib.net/.])])
  26
  27   dnl Look for libbz2, an optional dependency.
  28   AC_CHECK_LIB([bz2], [BZ2_bzWriteOpen], [HAVE_LIBBZ2=yes], [HAVE_LIBBZ2=no])
  29   if test "x$HAVE_LIBBZ2" = xyes; then
  30     AC_CHECK_HEADERS([bzlib.h])
  31     HAVE_LIBBZ2="$ac_cv_header_bzlib_h"
  32   fi
  33
  34   dnl Look for SQLite, a required dependency.
  35   PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= 3.6.19])
  36
  37   AC_DEFINE([NIX_VERSION], ["0.0.0"], [Fake Nix version number.])
  38   AC_DEFINE_UNQUOTED([SYSTEM], ["$guix_system"],
  39     [Guix host system type--i.e., platform and OS kernel tuple.])
  40
  41   case "$LIBGCRYPT_PREFIX" in
  42     no)
  43       LIBGCRYPT_CFLAGS=""
  44       ;;
  45     *)
  46       LIBGCRYPT_CFLAGS="-I$LIBGCRYPT_PREFIX/include"
  47       ;;
  48   esac
  49
  50   case "$LIBGCRYPT_LIBDIR" in
  51     no | "")
  52       LIBGCRYPT_LIBS="-lgcrypt"
  53       ;;
  54     *)
  55       LIBGCRYPT_LIBS="-L$LIBGCRYPT_LIBDIR -lgcrypt"
  56       ;;
  57   esac
  58
  59   AC_SUBST([LIBGCRYPT_CFLAGS])
  60   AC_SUBST([LIBGCRYPT_LIBS])
  61
  62   save_CFLAGS="$CFLAGS"
  63   save_LDFLAGS="$LDFLAGS"
  64   CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
  65   LDFLAGS="$LDFLAGS $LIBGCRYPT_LDFLAGS"
  66
  67   have_gcrypt=yes
  68   AC_CHECK_LIB([gcrypt], [gcry_md_open], [:], [have_gcrypt=no])
  69   AC_CHECK_HEADER([gcrypt.h], [:], [have_gcrypt=no])
  70   if test "x$have_gcrypt" != "xyes"; then
  71     AC_MSG_ERROR([GNU libgcrypt not found; please install it.])
  72   fi
  73
  74   CFLAGS="$save_CFLAGS"
  75   LDFLAGS="$save_LDFLAGS"
  76
  77   dnl Chroot support.
  78   AC_CHECK_FUNCS([chroot unshare])
  79   AC_CHECK_HEADERS([sched.h sys/param.h sys/mount.h sys/syscall.h])
  80
  81   if test "x$ac_cv_func_chroot" != "xyes"; then
  82     AC_MSG_ERROR(['chroot' function missing, bailing out])
  83   fi
  84
  85   dnl lutimes and lchown: used when canonicalizing store items.
  86   dnl posix_fallocate: used when extracting archives.
  87   dnl vfork: to speed up spawning of helper programs.
  88   dnl   `--> now disabled because of unpredictable behavior:
  89   dnl        see <http://lists.gnu.org/archive/html/guix-devel/2014-05/msg00036.html>
  90   dnl        and Nix commit f794465c (Nov. 2012).
  91   dnl sched_setaffinity: to improve RPC locality.
  92   dnl statvfs: to detect disk-full conditions.
  93   dnl strsignal: for error reporting.
  94   dnl statx: fine-grain 'stat' call, new in glibc 2.28.
  95   AC_CHECK_FUNCS([lutimes lchown posix_fallocate sched_setaffinity \
  96      statvfs nanosleep strsignal statx])
  97
  98   dnl Check whether the store optimiser can optimise symlinks.
  99   AC_MSG_CHECKING([whether it is possible to create a link to a symlink])
 100   ln -s bla tmp_link
 101   if ln tmp_link tmp_link2 2> /dev/null; then
 102       AC_MSG_RESULT(yes)
 103       AC_DEFINE(CAN_LINK_SYMLINK, 1, [Whether link() works on symlinks.])
 104   else
 105       AC_MSG_RESULT(no)
 106   fi
 107   rm -f tmp_link tmp_link2
 108
 109   dnl Check for <locale>.
 110   AC_LANG_PUSH(C++)
 111   AC_CHECK_HEADERS([locale])
 112   AC_LANG_POP(C++)
 113
 114
 115   dnl Check whether we have the `personality' syscall, which allows us
 116   dnl to do i686-linux builds on x86_64-linux machines.
 117   AC_CHECK_HEADERS([sys/personality.h])
 118
 119   dnl Determine the appropriate default list of substitute URLs (GnuTLS
 120   dnl is required so we can default to 'https'.)
 121   guix_substitute_urls="https://ci.guix.gnu.org"
 122
 123   AC_MSG_CHECKING([for default substitute URLs])
 124   AC_MSG_RESULT([$guix_substitute_urls])
 125
 126   AC_DEFINE_UNQUOTED([GUIX_SUBSTITUTE_URLS], ["$guix_substitute_urls"],
 127     [Default list of substitute URLs used by 'guix-daemon'.])
 128
 129   dnl Check for Guile-SSH, which is required by 'guix offload'.
 130   GUIX_CHECK_GUILE_SSH
 131
 132   case "x$guix_cv_have_recent_guile_ssh" in
 133     xyes)
 134       guix_build_daemon_offload="yes"
 135       AC_DEFINE([HAVE_DAEMON_OFFLOAD_HOOK], [1],
 136         [Define if the daemon's 'offload' build hook is being built (requires Guile-SSH).])
 137       ;;
 138     *)
 139       guix_build_daemon_offload="no"
 140       ;;
 141   esac
 142
 143   dnl Temporary directory used to store the daemon's data.
 144   GUIX_TEST_ROOT_DIRECTORY
 145   GUIX_TEST_ROOT="$ac_cv_guix_test_root"
 146   AC_SUBST([GUIX_TEST_ROOT])
 147
 148   GUIX_CHECK_LOCALSTATEDIR
 149 fi
 150
 151 AM_CONDITIONAL([HAVE_LIBBZ2], [test "x$HAVE_LIBBZ2" = "xyes"])
 152 AM_CONDITIONAL([BUILD_DAEMON], [test "x$guix_build_daemon" = "xyes"])
 153 AM_CONDITIONAL([BUILD_DAEMON_OFFLOAD],                  \
 154   [test "x$guix_build_daemon" = "xyes"                  \
 155    && test "x$guix_build_daemon_offload" = "xyes"])