gnu/services/ssh.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 David Craven <david@craven.ch>
   4 ;;; Copyright © 2016 Julien Lepiller <julien@lepiller.eu>
   5 ;;; Copyright © 2017 Clément Lassieur <clement@lassieur.org>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu services ssh)
  23   #:use-module (gnu packages ssh)
  24   #:use-module (gnu packages admin)
  25   #:use-module (gnu services)
  26   #:use-module (gnu services shepherd)
  27   #:use-module (gnu system pam)
  28   #:use-module (gnu system shadow)
  29   #:use-module (guix gexp)
  30   #:use-module (guix records)
  31   #:use-module (guix modules)
  32   #:use-module (srfi srfi-1)
  33   #:use-module (srfi srfi-26)
  34   #:use-module (ice-9 match)
  35   #:export (lsh-configuration
  36             lsh-configuration?
  37             lsh-service
  38             lsh-service-type
  39
  40             openssh-configuration
  41             openssh-configuration?
  42             openssh-service-type
  43
  44             dropbear-configuration
  45             dropbear-configuration?
  46             dropbear-service-type
  47             dropbear-service))
  48
  49 ;;; Commentary:
  50 ;;;
  51 ;;; This module implements secure shell (SSH) services.
  52 ;;;
  53 ;;; Code:
  54
  55 (define-record-type* <lsh-configuration>
  56   lsh-configuration make-lsh-configuration
  57   lsh-configuration?
  58   (lsh lsh-configuration-lsh
  59        (default lsh))
  60   (daemonic? lsh-configuration-daemonic?)
  61   (host-key lsh-configuration-host-key)
  62   (interfaces lsh-configuration-interfaces)
  63   (port-number lsh-configuration-port-number)
  64   (allow-empty-passwords? lsh-configuration-allow-empty-passwords?)
  65   (root-login? lsh-configuration-root-login?)
  66   (syslog-output? lsh-configuration-syslog-output?)
  67   (pid-file? lsh-configuration-pid-file?)
  68   (pid-file lsh-configuration-pid-file)
  69   (x11-forwarding? lsh-configuration-x11-forwarding?)
  70   (tcp/ip-forwarding? lsh-configuration-tcp/ip-forwarding?)
  71   (password-authentication? lsh-configuration-password-authentication?)
  72   (public-key-authentication? lsh-configuration-public-key-authentication?)
  73   (initialize? lsh-configuration-initialize?))
  74
  75 (define %yarrow-seed
  76   "/var/spool/lsh/yarrow-seed-file")
  77
  78 (define (lsh-initialization lsh host-key)
  79   "Return the gexp to initialize the LSH service for HOST-KEY."
  80   #~(begin
  81       (unless (file-exists? #$%yarrow-seed)
  82         (system* (string-append #$lsh "/bin/lsh-make-seed")
  83                  "--sloppy" "-o" #$%yarrow-seed))
  84
  85       (unless (file-exists? #$host-key)
  86         (mkdir-p (dirname #$host-key))
  87         (format #t "creating SSH host key '~a'...~%" #$host-key)
  88
  89         ;; FIXME: We're just doing a simple pipeline, but 'system' cannot be
  90         ;; used yet because /bin/sh might be dangling; factorize this somehow.
  91         (let* ((in+out (pipe))
  92                (keygen (primitive-fork)))
  93           (case keygen
  94             ((0)
  95              (close-port (car in+out))
  96              (close-fdes 1)
  97              (dup2 (fileno (cdr in+out)) 1)
  98              (execl (string-append #$lsh "/bin/lsh-keygen")
  99                     "lsh-keygen" "--server"))
 100             (else
 101              (let ((write-key (primitive-fork)))
 102                (case write-key
 103                  ((0)
 104                   (close-port (cdr in+out))
 105                   (close-fdes 0)
 106                   (dup2 (fileno (car in+out)) 0)
 107                   (execl (string-append #$lsh "/bin/lsh-writekey")
 108                          "lsh-writekey" "--server" "-o" #$host-key))
 109                  (else
 110                   (close-port (car in+out))
 111                   (close-port (cdr in+out))
 112                   (waitpid keygen)
 113                   (waitpid write-key))))))))))
 114
 115 (define (lsh-activation config)
 116   "Return the activation gexp for CONFIG."
 117   #~(begin
 118       (use-modules (guix build utils))
 119       (mkdir-p "/var/spool/lsh")
 120       #$(if (lsh-configuration-initialize? config)
 121             (lsh-initialization (lsh-configuration-lsh config)
 122                                 (lsh-configuration-host-key config))
 123             #t)))
 124
 125 (define (lsh-shepherd-service config)
 126   "Return a <shepherd-service> for lsh with CONFIG."
 127   (define lsh (lsh-configuration-lsh config))
 128   (define pid-file (lsh-configuration-pid-file config))
 129   (define pid-file? (lsh-configuration-pid-file? config))
 130   (define daemonic? (lsh-configuration-daemonic? config))
 131   (define interfaces (lsh-configuration-interfaces config))
 132
 133   (define lsh-command
 134     (append
 135      (cons (file-append lsh "/sbin/lshd")
 136            (if daemonic?
 137                (let ((syslog (if (lsh-configuration-syslog-output? config)
 138                                  '()
 139                                  (list "--no-syslog"))))
 140                  (cons "--daemonic"
 141                        (if pid-file?
 142                            (cons #~(string-append "--pid-file=" #$pid-file)
 143                                  syslog)
 144                            (cons "--no-pid-file" syslog))))
 145                (if pid-file?
 146                    (list #~(string-append "--pid-file=" #$pid-file))
 147                    '())))
 148      (cons* #~(string-append "--host-key="
 149                              #$(lsh-configuration-host-key config))
 150             #~(string-append "--password-helper=" #$lsh "/sbin/lsh-pam-checkpw")
 151             #~(string-append "--subsystems=sftp=" #$lsh "/sbin/sftp-server")
 152             "-p" (number->string (lsh-configuration-port-number config))
 153             (if (lsh-configuration-password-authentication? config)
 154                 "--password" "--no-password")
 155             (if (lsh-configuration-public-key-authentication? config)
 156                 "--publickey" "--no-publickey")
 157             (if (lsh-configuration-root-login? config)
 158                 "--root-login" "--no-root-login")
 159             (if (lsh-configuration-x11-forwarding? config)
 160                 "--x11-forward" "--no-x11-forward")
 161             (if (lsh-configuration-tcp/ip-forwarding? config)
 162                 "--tcpip-forward" "--no-tcpip-forward")
 163             (if (null? interfaces)
 164                 '()
 165                 (map (cut string-append "--interface=" <>)
 166                      interfaces)))))
 167
 168   (define requires
 169     (if (and daemonic? (lsh-configuration-syslog-output? config))
 170         '(networking syslogd)
 171         '(networking)))
 172
 173   (list (shepherd-service
 174          (documentation "GNU lsh SSH server")
 175          (provision '(ssh-daemon))
 176          (requirement requires)
 177          (start #~(make-forkexec-constructor (list #$@lsh-command)))
 178          (stop  #~(make-kill-destructor)))))
 179
 180 (define (lsh-pam-services config)
 181   "Return a list of <pam-services> for lshd with CONFIG."
 182   (list (unix-pam-service
 183          "lshd"
 184          #:allow-empty-passwords?
 185          (lsh-configuration-allow-empty-passwords? config))))
 186
 187 (define lsh-service-type
 188   (service-type (name 'lsh)
 189                 (description
 190                  "Run the GNU@tie{}lsh secure shell (SSH) daemon,
 191 @command{lshd}.")
 192                 (extensions
 193                  (list (service-extension shepherd-root-service-type
 194                                           lsh-shepherd-service)
 195                        (service-extension pam-root-service-type
 196                                           lsh-pam-services)
 197                        (service-extension activation-service-type
 198                                           lsh-activation)))))
 199
 200 (define* (lsh-service #:key
 201                       (lsh lsh)
 202                       (daemonic? #t)
 203                       (host-key "/etc/lsh/host-key")
 204                       (interfaces '())
 205                       (port-number 22)
 206                       (allow-empty-passwords? #f)
 207                       (root-login? #f)
 208                       (syslog-output? #t)
 209                       (pid-file? #f)
 210                       (pid-file "/var/run/lshd.pid")
 211                       (x11-forwarding? #t)
 212                       (tcp/ip-forwarding? #t)
 213                       (password-authentication? #t)
 214                       (public-key-authentication? #t)
 215                       (initialize? #t))
 216   "Run the @command{lshd} program from @var{lsh} to listen on port @var{port-number}.
 217 @var{host-key} must designate a file containing the host key, and readable
 218 only by root.
 219
 220 When @var{daemonic?} is true, @command{lshd} will detach from the
 221 controlling terminal and log its output to syslogd, unless one sets
 222 @var{syslog-output?} to false.  Obviously, it also makes lsh-service
 223 depend on existence of syslogd service.  When @var{pid-file?} is true,
 224 @command{lshd} writes its PID to the file called @var{pid-file}.
 225
 226 When @var{initialize?} is true, automatically create the seed and host key
 227 upon service activation if they do not exist yet.  This may take long and
 228 require interaction.
 229
 230 When @var{initialize?} is false, it is up to the user to initialize the
 231 randomness generator (@pxref{lsh-make-seed,,, lsh, LSH Manual}), and to create
 232 a key pair with the private key stored in file @var{host-key} (@pxref{lshd
 233 basics,,, lsh, LSH Manual}).
 234
 235 When @var{interfaces} is empty, lshd listens for connections on all the
 236 network interfaces; otherwise, @var{interfaces} must be a list of host names
 237 or addresses.
 238
 239 @var{allow-empty-passwords?} specifies whether to accept log-ins with empty
 240 passwords, and @var{root-login?} specifies whether to accept log-ins as
 241 root.
 242
 243 The other options should be self-descriptive."
 244   (service lsh-service-type
 245            (lsh-configuration (lsh lsh) (daemonic? daemonic?)
 246                               (host-key host-key) (interfaces interfaces)
 247                               (port-number port-number)
 248                               (allow-empty-passwords? allow-empty-passwords?)
 249                               (root-login? root-login?)
 250                               (syslog-output? syslog-output?)
 251                               (pid-file? pid-file?) (pid-file pid-file)
 252                               (x11-forwarding? x11-forwarding?)
 253                               (tcp/ip-forwarding? tcp/ip-forwarding?)
 254                               (password-authentication?
 255                                password-authentication?)
 256                               (public-key-authentication?
 257                                public-key-authentication?)
 258                               (initialize? initialize?))))
 259
 260 \f
 261 ;;;
 262 ;;; OpenSSH.
 263 ;;;
 264
 265 (define-record-type* <openssh-configuration>
 266   openssh-configuration make-openssh-configuration
 267   openssh-configuration?
 268   ;; <package>
 269   (openssh               openssh-configuration-openssh
 270                          (default openssh))
 271   ;; string
 272   (pid-file              openssh-configuration-pid-file
 273                          (default "/var/run/sshd.pid"))
 274   ;; integer
 275   (port-number           openssh-configuration-port-number
 276                          (default 22))
 277   ;; Boolean | 'without-password
 278   (permit-root-login     openssh-configuration-permit-root-login
 279                          (default #f))
 280   ;; Boolean
 281   (allow-empty-passwords? openssh-configuration-allow-empty-passwords?
 282                           (default #f))
 283   ;; Boolean
 284   (password-authentication? openssh-configuration-password-authentication?
 285                             (default #t))
 286   ;; Boolean
 287   (public-key-authentication? openssh-configuration-public-key-authentication?
 288                               (default #t))
 289   ;; Boolean
 290   (x11-forwarding?       openssh-configuration-x11-forwarding?
 291                          (default #f))
 292
 293   ;; Boolean
 294   (allow-agent-forwarding? openssh-configuration-allow-agent-forwarding?
 295                            (default #t))
 296
 297   ;; Boolean
 298   (allow-tcp-forwarding? openssh-configuration-allow-tcp-forwarding?
 299                          (default #t))
 300
 301   ;; Boolean
 302   (gateway-ports? openssh-configuration-gateway-ports?
 303                          (default #f))
 304
 305   ;; Boolean
 306   (challenge-response-authentication? openssh-challenge-response-authentication?
 307                                       (default #f))
 308   ;; Boolean
 309   (use-pam?              openssh-configuration-use-pam?
 310                          (default #t))
 311   ;; Boolean
 312   (print-last-log?       openssh-configuration-print-last-log?
 313                          (default #t))
 314   ;; list of two-element lists
 315   (subsystems            openssh-configuration-subsystems
 316                          (default '(("sftp" "internal-sftp"))))
 317
 318   ;; list of strings
 319   (accepted-environment  openssh-configuration-accepted-environment
 320                          (default '()))
 321
 322   ;; symbol
 323   (log-level             openssh-configuration-log-level
 324                          (default 'info))
 325
 326   ;; list of user-name/file-like tuples
 327   (authorized-keys       openssh-authorized-keys
 328                          (default '()))
 329
 330   ;; Boolean
 331   ;; XXX: This should really be handled in an orthogonal way, for instance as
 332   ;; proposed in <https://bugs.gnu.org/27155>.  Keep it internal/undocumented
 333   ;; for now.
 334   (%auto-start?          openssh-auto-start?
 335                          (default #t)))
 336
 337 (define %openssh-accounts
 338   (list (user-group (name "sshd") (system? #t))
 339         (user-account
 340           (name "sshd")
 341           (group "sshd")
 342           (system? #t)
 343           (comment "sshd privilege separation user")
 344           (home-directory "/var/run/sshd")
 345           (shell #~(string-append #$shadow "/sbin/nologin")))))
 346
 347 (define (openssh-activation config)
 348   "Return the activation GEXP for CONFIG."
 349   (with-imported-modules '((guix build utils))
 350     #~(begin
 351         (use-modules (guix build utils))
 352
 353         (define (touch file-name)
 354           (call-with-output-file file-name (const #t)))
 355
 356         ;; Make sure /etc/ssh can be read by the 'sshd' user.
 357         (mkdir-p "/etc/ssh")
 358         (chmod "/etc/ssh" #o755)
 359         (mkdir-p (dirname #$(openssh-configuration-pid-file config)))
 360
 361         ;; 'sshd' complains if the authorized-key directory and its parents
 362         ;; are group-writable, which rules out /gnu/store.  Thus we copy the
 363         ;; authorized-key directory to /etc.
 364         (catch 'system-error
 365           (lambda ()
 366             (delete-file-recursively "/etc/authorized_keys.d"))
 367           (lambda args
 368             (unless (= ENOENT (system-error-errno args))
 369               (apply throw args))))
 370         (copy-recursively #$(authorized-key-directory
 371                              (openssh-authorized-keys config))
 372                           "/etc/ssh/authorized_keys.d")
 373
 374         (chmod "/etc/ssh/authorized_keys.d" #o555)
 375
 376         (let ((lastlog "/var/log/lastlog"))
 377           (when #$(openssh-configuration-print-last-log? config)
 378             (unless (file-exists? lastlog)
 379               (touch lastlog))))
 380
 381         ;; Generate missing host keys.
 382         (system* (string-append #$(openssh-configuration-openssh config)
 383                                 "/bin/ssh-keygen") "-A"))))
 384
 385 (define (authorized-key-directory keys)
 386   "Return a directory containing the authorized keys specified in KEYS, a list
 387 of user-name/file-like tuples."
 388   (define build
 389     (with-imported-modules (source-module-closure '((guix build utils)))
 390       #~(begin
 391           (use-modules (ice-9 match) (srfi srfi-26)
 392                        (guix build utils))
 393
 394           (mkdir #$output)
 395           (for-each (match-lambda
 396                       ((user keys ...)
 397                        (let ((file (string-append #$output "/" user)))
 398                          (call-with-output-file file
 399                            (lambda (port)
 400                              (for-each (lambda (key)
 401                                          (call-with-input-file key
 402                                            (cut dump-port <> port)))
 403                                        keys))))))
 404                     '#$keys))))
 405
 406   (computed-file "openssh-authorized-keys" build))
 407
 408 (define (openssh-config-file config)
 409   "Return the sshd configuration file corresponding to CONFIG."
 410   (computed-file
 411    "sshd_config"
 412    #~(begin
 413        (use-modules (ice-9 match))
 414        (call-with-output-file #$output
 415          (lambda (port)
 416            (display "# Generated by 'openssh-service'.\n" port)
 417            (format port "Port ~a\n"
 418                    #$(number->string
 419                       (openssh-configuration-port-number config)))
 420            (format port "PermitRootLogin ~a\n"
 421                    #$(match (openssh-configuration-permit-root-login config)
 422                        (#t "yes")
 423                        (#f "no")
 424                        ('without-password "without-password")))
 425            (format port "PermitEmptyPasswords ~a\n"
 426                    #$(if (openssh-configuration-allow-empty-passwords? config)
 427                          "yes" "no"))
 428            (format port "PasswordAuthentication ~a\n"
 429                    #$(if (openssh-configuration-password-authentication? config)
 430                          "yes" "no"))
 431            (format port "PubkeyAuthentication ~a\n"
 432                    #$(if (openssh-configuration-public-key-authentication?
 433                           config)
 434                          "yes" "no"))
 435            (format port "X11Forwarding ~a\n"
 436                    #$(if (openssh-configuration-x11-forwarding? config)
 437                          "yes" "no"))
 438            (format port "AllowAgentForwarding ~a\n"
 439                    #$(if (openssh-configuration-allow-agent-forwarding? config)
 440                          "yes" "no"))
 441            (format port "AllowTcpForwarding ~a\n"
 442                    #$(if (openssh-configuration-allow-tcp-forwarding? config)
 443                          "yes" "no"))
 444            (format port "GatewayPorts ~a\n"
 445                    #$(if (openssh-configuration-gateway-ports? config)
 446                          "yes" "no"))
 447            (format port "PidFile ~a\n"
 448                    #$(openssh-configuration-pid-file config))
 449            (format port "ChallengeResponseAuthentication ~a\n"
 450                    #$(if (openssh-challenge-response-authentication? config)
 451                          "yes" "no"))
 452            (format port "UsePAM ~a\n"
 453                    #$(if (openssh-configuration-use-pam? config)
 454                          "yes" "no"))
 455            (format port "PrintLastLog ~a\n"
 456                    #$(if (openssh-configuration-print-last-log? config)
 457                          "yes" "no"))
 458            (format port "LogLevel ~a\n"
 459                    #$(string-upcase
 460                       (symbol->string
 461                        (openssh-configuration-log-level config))))
 462
 463            ;; Add '/etc/authorized_keys.d/%u', which we populate.
 464            (format port "AuthorizedKeysFile \
 465  .ssh/authorized_keys .ssh/authorized_keys2 /etc/ssh/authorized_keys.d/%u\n")
 466
 467            (for-each (lambda (s) (format port "AcceptEnv ~a\n" s))
 468                      '#$(openssh-configuration-accepted-environment config))
 469
 470            (for-each
 471             (match-lambda
 472               ((name command) (format port "Subsystem\t~a\t~a\n" name command)))
 473             '#$(openssh-configuration-subsystems config))
 474            #t)))))
 475
 476 (define (openssh-shepherd-service config)
 477   "Return a <shepherd-service> for openssh with CONFIG."
 478
 479   (define pid-file
 480     (openssh-configuration-pid-file config))
 481
 482   (define openssh-command
 483     #~(list (string-append #$(openssh-configuration-openssh config) "/sbin/sshd")
 484             "-D" "-f" #$(openssh-config-file config)))
 485
 486   (list (shepherd-service
 487          (documentation "OpenSSH server.")
 488          (requirement '(syslogd loopback))
 489          (provision '(ssh-daemon))
 490          (start #~(make-forkexec-constructor #$openssh-command
 491                                              #:pid-file #$pid-file))
 492          (stop #~(make-kill-destructor))
 493          (auto-start? (openssh-auto-start? config)))))
 494
 495 (define (openssh-pam-services config)
 496   "Return a list of <pam-services> for sshd with CONFIG."
 497   (list (unix-pam-service
 498          "sshd"
 499          #:allow-empty-passwords?
 500          (openssh-configuration-allow-empty-passwords? config))))
 501
 502 (define (extend-openssh-authorized-keys config keys)
 503   "Extend CONFIG with the extra authorized keys listed in KEYS."
 504   (openssh-configuration
 505    (inherit config)
 506    (authorized-keys
 507     (append (openssh-authorized-keys config) keys))))
 508
 509 (define openssh-service-type
 510   (service-type (name 'openssh)
 511                 (description
 512                  "Run the OpenSSH secure shell (SSH) server, @command{sshd}.")
 513                 (extensions
 514                  (list (service-extension shepherd-root-service-type
 515                                           openssh-shepherd-service)
 516                        (service-extension pam-root-service-type
 517                                           openssh-pam-services)
 518                        (service-extension activation-service-type
 519                                           openssh-activation)
 520                        (service-extension account-service-type
 521                                           (const %openssh-accounts))))
 522                 (compose concatenate)
 523                 (extend extend-openssh-authorized-keys)
 524                 (default-value (openssh-configuration))))
 525
 526 \f
 527 ;;;
 528 ;;; Dropbear.
 529 ;;;
 530
 531 (define-record-type* <dropbear-configuration>
 532   dropbear-configuration make-dropbear-configuration
 533   dropbear-configuration?
 534   (dropbear               dropbear-configuration-dropbear
 535                           (default dropbear))
 536   (port-number            dropbear-configuration-port-number
 537                           (default 22))
 538   (syslog-output?         dropbear-configuration-syslog-output?
 539                           (default #t))
 540   (pid-file               dropbear-configuration-pid-file
 541                           (default "/var/run/dropbear.pid"))
 542   (root-login?            dropbear-configuration-root-login?
 543                           (default #f))
 544   (allow-empty-passwords? dropbear-configuration-allow-empty-passwords?
 545                           (default #f))
 546   (password-authentication? dropbear-configuration-password-authentication?
 547                             (default #t)))
 548
 549 (define (dropbear-activation config)
 550   "Return the activation gexp for CONFIG."
 551   #~(begin
 552       (use-modules (guix build utils))
 553       (mkdir-p "/etc/dropbear")))
 554
 555 (define (dropbear-shepherd-service config)
 556   "Return a <shepherd-service> for dropbear with CONFIG."
 557   (define dropbear
 558     (dropbear-configuration-dropbear config))
 559
 560   (define pid-file
 561     (dropbear-configuration-pid-file config))
 562
 563   (define dropbear-command
 564     #~(list (string-append #$dropbear "/sbin/dropbear")
 565
 566             ;; '-R' allows host keys to be automatically generated upon first
 567             ;; connection, at a time when /dev/urandom is more likely securely
 568             ;; seeded.
 569             "-F" "-R"
 570
 571             "-p" #$(number->string (dropbear-configuration-port-number config))
 572             "-P" #$pid-file
 573             #$@(if (dropbear-configuration-syslog-output? config) '() '("-E"))
 574             #$@(if (dropbear-configuration-root-login? config) '() '("-w"))
 575             #$@(if (dropbear-configuration-password-authentication? config)
 576                    '()
 577                    '("-s" "-g"))
 578             #$@(if (dropbear-configuration-allow-empty-passwords? config)
 579                    '("-B")
 580                    '())))
 581
 582   (define requires
 583     (if (dropbear-configuration-syslog-output? config)
 584         '(networking syslogd) '(networking)))
 585
 586   (list (shepherd-service
 587          (documentation "Dropbear SSH server.")
 588          (requirement requires)
 589          (provision '(ssh-daemon))
 590          (start #~(make-forkexec-constructor #$dropbear-command
 591                                              #:pid-file #$pid-file))
 592          (stop #~(make-kill-destructor)))))
 593
 594 (define dropbear-service-type
 595   (service-type (name 'dropbear)
 596                 (description
 597                  "Run the Dropbear secure shell (SSH) server.")
 598                 (extensions
 599                  (list (service-extension shepherd-root-service-type
 600                                           dropbear-shepherd-service)
 601                        (service-extension activation-service-type
 602                                           dropbear-activation)))))
 603
 604 (define* (dropbear-service #:optional (config (dropbear-configuration)))
 605   "Run the @uref{https://matt.ucc.asn.au/dropbear/dropbear.html,Dropbear SSH
 606 daemon} with the given @var{config}, a @code{<dropbear-configuration>}
 607 object."
 608   (service dropbear-service-type config))
 609
 610 ;;; ssh.scm ends here