gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018, 2019 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (gnu packages admin)
  28   #:use-module (gnu packages ci)
  29   #:use-module (gnu packages version-control)
  30   #:use-module (gnu services)
  31   #:use-module (gnu services base)
  32   #:use-module (gnu services shepherd)
  33   #:use-module (gnu services admin)
  34   #:use-module (gnu system shadow)
  35   #:export (<cuirass-configuration>
  36             cuirass-configuration
  37             cuirass-configuration?
  38
  39             cuirass-service-type))
  40
  41 ;;;; Commentary:
  42 ;;;
  43 ;;; This module implements a service that to run instances of Cuirass, a
  44 ;;; continuous integration tool.
  45 ;;;
  46 ;;;; Code:
  47
  48 (define-record-type* <cuirass-configuration>
  49   cuirass-configuration make-cuirass-configuration
  50   cuirass-configuration?
  51   (cuirass          cuirass-configuration-cuirass ;package
  52                     (default cuirass))
  53   (log-file         cuirass-configuration-log-file ;string
  54                     (default "/var/log/cuirass.log"))
  55   (web-log-file     cuirass-configuration-web-log-file ;string
  56                     (default "/var/log/cuirass-web.log"))
  57   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  58                     (default "/var/cache/cuirass"))
  59   (ttl              cuirass-configuration-ttl     ;integer
  60                     (default (* 30 24 3600)))
  61   (user             cuirass-configuration-user ;string
  62                     (default "cuirass"))
  63   (group            cuirass-configuration-group ;string
  64                     (default "cuirass"))
  65   (interval         cuirass-configuration-interval ;integer (seconds)
  66                     (default 60))
  67   (database         cuirass-configuration-database ;string (file-name)
  68                     (default "/var/lib/cuirass/cuirass.db"))
  69   (port             cuirass-configuration-port ;integer (port)
  70                     (default 8081))
  71   (host             cuirass-configuration-host ;string
  72                     (default "localhost"))
  73   (specifications   cuirass-configuration-specifications)
  74                                   ;gexp that evaluates to specification-alist
  75   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
  76                     (default #f))
  77   (one-shot?        cuirass-configuration-one-shot? ;boolean
  78                     (default #f))
  79   (fallback?        cuirass-configuration-fallback? ;boolean
  80                     (default #f))
  81   (extra-options    cuirass-configuration-extra-options
  82                     (default '())))
  83
  84 (define (cuirass-shepherd-service config)
  85   "Return a <shepherd-service> for the Cuirass service with CONFIG."
  86   (let ((cuirass          (cuirass-configuration-cuirass config))
  87         (cache-directory  (cuirass-configuration-cache-directory config))
  88         (web-log-file     (cuirass-configuration-web-log-file config))
  89         (log-file         (cuirass-configuration-log-file config))
  90         (user             (cuirass-configuration-user config))
  91         (group            (cuirass-configuration-group config))
  92         (interval         (cuirass-configuration-interval config))
  93         (database         (cuirass-configuration-database config))
  94         (ttl              (cuirass-configuration-ttl config))
  95         (port             (cuirass-configuration-port config))
  96         (host             (cuirass-configuration-host config))
  97         (specs            (cuirass-configuration-specifications config))
  98         (use-substitutes? (cuirass-configuration-use-substitutes? config))
  99         (one-shot?        (cuirass-configuration-one-shot? config))
 100         (fallback?        (cuirass-configuration-fallback? config))
 101         (extra-options    (cuirass-configuration-extra-options config)))
 102     (list (shepherd-service
 103            (documentation "Run Cuirass.")
 104            (provision '(cuirass))
 105            (requirement '(guix-daemon networking))
 106            (start #~(make-forkexec-constructor
 107                      (list (string-append #$cuirass "/bin/cuirass")
 108                            "--cache-directory" #$cache-directory
 109                            "--specifications"
 110                            #$(scheme-file "cuirass-specs.scm" specs)
 111                            "--database" #$database
 112                            "--ttl" #$(string-append (number->string ttl) "s")
 113                            "--interval" #$(number->string interval)
 114                            #$@(if use-substitutes? '("--use-substitutes") '())
 115                            #$@(if one-shot? '("--one-shot") '())
 116                            #$@(if fallback? '("--fallback") '())
 117                            #$@extra-options)
 118
 119                      #:environment-variables
 120                      (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 121                            (string-append "GIT_EXEC_PATH=" #$git
 122                                           "/libexec/git-core"))
 123
 124                      #:user #$user
 125                      #:group #$group
 126                      #:log-file #$log-file))
 127            (stop #~(make-kill-destructor)))
 128           (shepherd-service
 129            (documentation "Run Cuirass web interface.")
 130            (provision '(cuirass-web))
 131            (requirement '(guix-daemon networking))
 132            (start #~(make-forkexec-constructor
 133                      (list (string-append #$cuirass "/bin/cuirass")
 134                            "--cache-directory" #$cache-directory
 135                            "--specifications"
 136                            #$(scheme-file "cuirass-specs.scm" specs)
 137                            "--database" #$database
 138                            "--ttl" #$(string-append (number->string ttl) "s")
 139                            "--web"
 140                            "--port" #$(number->string port)
 141                            "--listen" #$host
 142                            "--interval" #$(number->string interval)
 143                            #$@(if use-substitutes? '("--use-substitutes") '())
 144                            #$@(if fallback? '("--fallback") '())
 145                            #$@extra-options)
 146
 147                      #:user #$user
 148                      #:group #$group
 149                      #:log-file #$web-log-file))
 150            (stop #~(make-kill-destructor))))))
 151
 152 (define (cuirass-account config)
 153   "Return the user accounts and user groups for CONFIG."
 154   (let ((cuirass-user  (cuirass-configuration-user config))
 155         (cuirass-group (cuirass-configuration-group config)))
 156     (list (user-group
 157            (name cuirass-group)
 158            (system? #t))
 159           (user-account
 160            (name cuirass-user)
 161            (group cuirass-group)
 162            (system? #t)
 163            (comment "Cuirass privilege separation user")
 164            (home-directory (string-append "/var/lib/" cuirass-user))
 165            (shell (file-append shadow "/sbin/nologin"))))))
 166
 167 (define (cuirass-activation config)
 168   "Return the activation code for CONFIG."
 169   (let ((cache (cuirass-configuration-cache-directory config))
 170         (db    (dirname (cuirass-configuration-database config)))
 171         (user  (cuirass-configuration-user config))
 172         (log   "/var/log/cuirass")
 173         (group (cuirass-configuration-group config)))
 174     (with-imported-modules '((guix build utils))
 175       #~(begin
 176           (use-modules (guix build utils))
 177
 178           (mkdir-p #$cache)
 179           (mkdir-p #$db)
 180           (mkdir-p #$log)
 181
 182           (let ((uid (passwd:uid (getpw #$user)))
 183                 (gid (group:gid (getgr #$group))))
 184             (chown #$cache uid gid)
 185             (chown #$db uid gid)
 186             (chown #$log uid gid))))))
 187
 188 (define (cuirass-log-rotations config)
 189   "Return the list of log rotations that corresponds to CONFIG."
 190   (list (log-rotation
 191          (files (list (cuirass-configuration-log-file config)))
 192          (frequency 'weekly)
 193          (options '("rotate 40")))))              ;worth keeping
 194
 195 (define cuirass-service-type
 196   (service-type
 197    (name 'cuirass)
 198    (extensions
 199     (list
 200      (service-extension profile-service-type      ;for 'info cuirass'
 201                         (compose list cuirass-configuration-cuirass))
 202      (service-extension rottlog-service-type cuirass-log-rotations)
 203      (service-extension activation-service-type cuirass-activation)
 204      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 205      (service-extension account-service-type cuirass-account)))
 206    (description
 207     "Run the Cuirass continuous integration service.")))
 208