gnu/packages/bootloaders.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2016, 2017, 2018 Marius Bakke <mbakke@fastmail.com>
   7 ;;; Copyright © 2016, 2017 Danny Milosavljevic <dannym@scratchpost.org>
   8 ;;; Copyright © 2016, 2017 David Craven <david@craven.ch>
   9 ;;; Copyright © 2017, 2018 Efraim Flashner <efraim@flashner.co.il>
  10 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  11 ;;;
  12 ;;; This file is part of GNU Guix.
  13 ;;;
  14 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  15 ;;; under the terms of the GNU General Public License as published by
  16 ;;; the Free Software Foundation; either version 3 of the License, or (at
  17 ;;; your option) any later version.
  18 ;;;
  19 ;;; GNU Guix is distributed in the hope that it will be useful, but
  20 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;;; GNU General Public License for more details.
  23 ;;;
  24 ;;; You should have received a copy of the GNU General Public License
  25 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 (define-module (gnu packages bootloaders)
  28   #:use-module (gnu packages)
  29   #:use-module (gnu packages admin)
  30   #:use-module ((gnu packages algebra) #:select (bc))
  31   #:use-module (gnu packages assembly)
  32   #:use-module (gnu packages base)
  33   #:use-module (gnu packages disk)
  34   #:use-module (gnu packages bison)
  35   #:use-module (gnu packages cdrom)
  36   #:use-module (gnu packages cross-base)
  37   #:use-module (gnu packages disk)
  38   #:use-module (gnu packages flex)
  39   #:use-module (gnu packages fontutils)
  40   #:use-module (gnu packages gcc)
  41   #:use-module (gnu packages gettext)
  42   #:use-module (gnu packages linux)
  43   #:use-module (gnu packages man)
  44   #:use-module (gnu packages mtools)
  45   #:use-module (gnu packages ncurses)
  46   #:use-module (gnu packages perl)
  47   #:use-module (gnu packages pkg-config)
  48   #:use-module (gnu packages python)
  49   #:use-module (gnu packages texinfo)
  50   #:use-module (gnu packages tls)
  51   #:use-module (gnu packages swig)
  52   #:use-module (gnu packages virtualization)
  53   #:use-module (gnu packages web)
  54   #:use-module (guix build-system gnu)
  55   #:use-module (guix download)
  56   #:use-module (guix git-download)
  57   #:use-module ((guix licenses) #:prefix license:)
  58   #:use-module (guix packages)
  59   #:use-module (guix utils)
  60   #:use-module (srfi srfi-1)
  61   #:use-module (srfi srfi-26))
  62
  63 (define unifont
  64   ;; GNU Unifont, <http://gnu.org/s/unifont>.
  65   ;; GRUB needs it for its graphical terminal, gfxterm.
  66   (origin
  67     (method url-fetch)
  68     (uri
  69      "http://unifoundry.com/pub/unifont-7.0.06/font-builds/unifont-7.0.06.bdf.gz")
  70     (sha256
  71      (base32
  72       "0p2vhnc18cnbmb39vq4m7hzv4mhnm2l0a2s7gx3ar277fwng3hys"))))
  73
  74 (define-public grub
  75   (package
  76     (name "grub")
  77     (version "2.02")
  78     (source (origin
  79              (method url-fetch)
  80              (uri (string-append "mirror://gnu/grub/grub-" version ".tar.xz"))
  81              (sha256
  82               (base32
  83                "03vvdfhdmf16121v7xs8is2krwnv15wpkhkf16a4yf8nsfc3f2w1"))))
  84     (build-system gnu-build-system)
  85     (arguments
  86      `(#:phases (modify-phases %standard-phases
  87                   (add-after 'unpack 'patch-stuff
  88                    (lambda* (#:key inputs #:allow-other-keys)
  89                      (substitute* "grub-core/Makefile.in"
  90                        (("/bin/sh") (which "sh")))
  91
  92                      ;; Give the absolute file name of 'mdadm', used to
  93                      ;; determine the root file system when it's a RAID
  94                      ;; device.  Failing to do that, 'grub-probe' silently
  95                      ;; fails if 'mdadm' is not in $PATH.
  96                      (substitute* "grub-core/osdep/linux/getroot.c"
  97                        (("argv\\[0\\] = \"mdadm\"")
  98                         (string-append "argv[0] = \""
  99                                        (assoc-ref inputs "mdadm")
 100                                        "/sbin/mdadm\"")))
 101
 102                      ;; Make the font visible.
 103                      (copy-file (assoc-ref inputs "unifont") "unifont.bdf.gz")
 104                      (system* "gunzip" "unifont.bdf.gz")
 105                      #t))
 106                   (add-before 'check 'disable-flaky-test
 107                     (lambda _
 108                       ;; This test is unreliable. For more information, see:
 109                       ;; <https://bugs.gnu.org/26936>.
 110                       (substitute* "Makefile.in"
 111                         (("grub_cmd_date grub_cmd_set_date grub_cmd_sleep")
 112                           "grub_cmd_date grub_cmd_sleep"))
 113                       #t)))
 114        ;; Disable tests on ARM and AARCH64 platforms.
 115        #:tests? ,(not (any (cute string-prefix? <> (or (%current-target-system)
 116                                                        (%current-system)))
 117                            '("arm" "aarch64")))))
 118     (inputs
 119      `(("gettext" ,gettext-minimal)
 120
 121        ;; Depend on LVM2 for libdevmapper, used by 'grub-probe' and
 122        ;; 'grub-install' to recognize mapped devices (LUKS, etc.)
 123        ("lvm2" ,lvm2)
 124
 125        ;; Depend on mdadm, which is invoked by 'grub-probe' and 'grub-install'
 126        ;; to determine whether the root file system is RAID.
 127        ("mdadm" ,mdadm)
 128
 129        ("freetype" ,freetype)
 130        ;; ("libusb" ,libusb)
 131        ;; ("fuse" ,fuse)
 132        ("ncurses" ,ncurses)))
 133     (native-inputs
 134      `(("unifont" ,unifont)
 135        ("bison" ,bison)
 136        ;; Due to a bug in flex >= 2.6.2, GRUB must be built with an older flex:
 137        ;; <http://lists.gnu.org/archive/html/grub-devel/2017-02/msg00133.html>
 138        ;; TODO Try building with flex > 2.6.4.
 139        ("flex" ,flex-2.6.1)
 140        ("texinfo" ,texinfo)
 141        ("help2man" ,help2man)
 142
 143        ;; Dependencies for the test suite.  The "real" QEMU is needed here,
 144        ;; because several targets are used.
 145        ("parted" ,parted)
 146        ("qemu" ,qemu-minimal)
 147        ("xorriso" ,xorriso)))
 148     (home-page "https://www.gnu.org/software/grub/")
 149     (synopsis "GRand Unified Boot loader")
 150     (description
 151      "GRUB is a multiboot bootloader.  It is used for initially loading the
 152 kernel of an operating system and then transferring control to it.  The kernel
 153 then goes on to load the rest of the operating system.  As a multiboot
 154 bootloader, GRUB handles the presence of multiple operating systems installed
 155 on the same computer; upon booting the computer, the user is presented with a
 156 menu to select one of the installed operating systems.")
 157     (license license:gpl3+)
 158     (properties '((cpe-name . "grub2")))))
 159
 160 (define-public grub-efi
 161   (package
 162     (inherit grub)
 163     (name "grub-efi")
 164     (synopsis "GRand Unified Boot loader (UEFI version)")
 165     (inputs
 166      `(("efibootmgr" ,efibootmgr)
 167        ("mtools", mtools)
 168        ,@(package-inputs grub)))
 169     (arguments
 170      `(;; TODO: Tests need a UEFI firmware for qemu. There is one at
 171        ;; https://github.com/tianocore/edk2/tree/master/OvmfPkg .
 172        ;; Search for 'OVMF' in "tests/util/grub-shell.in".
 173        ,@(substitute-keyword-arguments (package-arguments grub)
 174            ((#:tests? _ #f) #f)
 175            ((#:configure-flags flags ''())
 176             `(cons "--with-platform=efi" ,flags))
 177            ((#:phases phases)
 178             `(modify-phases ,phases
 179                (add-after 'patch-stuff 'use-absolute-efibootmgr-path
 180                  (lambda* (#:key inputs #:allow-other-keys)
 181                    (substitute* "grub-core/osdep/unix/platform.c"
 182                      (("efibootmgr")
 183                       (string-append (assoc-ref inputs "efibootmgr")
 184                                      "/sbin/efibootmgr")))
 185                    #t))
 186                (add-after 'patch-stuff 'use-absolute-mtools-path
 187                  (lambda* (#:key inputs #:allow-other-keys)
 188                    (let ((mtools (assoc-ref inputs "mtools")))
 189                      (substitute* "util/grub-mkrescue.c"
 190                        (("\"mformat\"")
 191                         (string-append "\"" mtools
 192                                        "/bin/mformat\"")))
 193                      (substitute* "util/grub-mkrescue.c"
 194                        (("\"mcopy\"")
 195                         (string-append "\"" mtools
 196                                        "/bin/mcopy\"")))
 197                      #t))))))))))
 198
 199 ;; Because grub searches hardcoded paths it's easiest to just build grub
 200 ;; again to make it find both grub-pc and grub-efi.  There is a command
 201 ;; line argument which allows you to specify ONE platform - but
 202 ;; grub-mkrescue will use multiple platforms if they are available
 203 ;; in the installation directory (without command line argument).
 204 (define-public grub-hybrid
 205   (package
 206     (inherit grub-efi)
 207     (name "grub-hybrid")
 208     (synopsis "GRand Unified Boot loader (hybrid version)")
 209     (inputs
 210      `(("grub" ,grub)
 211        ,@(package-inputs grub-efi)))
 212     (arguments
 213      (substitute-keyword-arguments (package-arguments grub-efi)
 214        ((#:modules modules `((guix build utils) (guix build gnu-build-system)))
 215         `((ice-9 ftw) ,@modules))
 216        ((#:phases phases)
 217         `(modify-phases ,phases
 218            (add-after 'install 'install-non-efi
 219              (lambda* (#:key inputs outputs #:allow-other-keys)
 220                (let ((input-dir (string-append (assoc-ref inputs "grub")
 221                                                "/lib/grub"))
 222                      (output-dir (string-append (assoc-ref outputs "out")
 223                                                 "/lib/grub")))
 224                  (for-each
 225                   (lambda (basename)
 226                     (if (not (or (string-prefix? "." basename)
 227                                  (file-exists? (string-append output-dir "/" basename))))
 228                         (symlink (string-append input-dir "/" basename)
 229                                  (string-append output-dir "/" basename))))
 230                   (scandir input-dir))
 231                  #t)))))))))
 232
 233 (define-public syslinux
 234   (let ((commit "bb41e935cc83c6242de24d2271e067d76af3585c"))
 235     (package
 236       (name "syslinux")
 237       (version (git-version "6.04-pre" "1" commit))
 238       (source (origin
 239                 (method git-fetch)
 240                 (uri (git-reference
 241                       (url "https://github.com/geneC/syslinux")
 242                       (commit commit)))
 243                 (file-name (git-file-name name version))
 244                 (sha256
 245                  (base32
 246                   "0k8dvafd6410kqxf3kyr4y8jzmpmrih6wbjqg6gklak7945yflrc"))))
 247       (build-system gnu-build-system)
 248       (native-inputs
 249        `(("nasm" ,nasm)
 250          ("perl" ,perl)
 251          ("python-2" ,python-2)))
 252       (inputs
 253        `(("libuuid" ,util-linux)
 254          ("mtools" ,mtools)))
 255       (arguments
 256        `(#:parallel-build? #f
 257          #:make-flags
 258          (list (string-append "BINDIR=" %output "/bin")
 259                (string-append "SBINDIR=" %output "/sbin")
 260                (string-append "LIBDIR=" %output "/lib")
 261                (string-append "INCDIR=" %output "/include")
 262                (string-append "DATADIR=" %output "/share")
 263                (string-append "MANDIR=" %output "/share/man")
 264                "PERL=perl"
 265                "bios")
 266          #:phases
 267          (modify-phases %standard-phases
 268            (add-after 'unpack 'patch-files
 269              (lambda* (#:key inputs #:allow-other-keys)
 270                (substitute* (find-files "." "Makefile.*|ppmtolss16")
 271                  (("/bin/pwd") (which "pwd"))
 272                  (("/bin/echo") (which "echo"))
 273                  (("/usr/bin/perl") (which "perl")))
 274                (let ((mtools (assoc-ref inputs "mtools")))
 275                  (substitute* (find-files "." "\\.c$")
 276                    (("mcopy")
 277                     (string-append mtools "/bin/mcopy"))
 278                    (("mattrib")
 279                     (string-append mtools "/bin/mattrib"))))
 280                #t))
 281            (delete 'configure)
 282            (add-before 'build 'set-permissions
 283              (lambda _
 284                (zero? (system* "chmod" "a+w" "utils/isohybrid.in"))))
 285            (replace 'check
 286              (lambda _
 287                (setenv "CC" "gcc")
 288                (substitute* "tests/unittest/include/unittest/unittest.h"
 289                  ;; Don't look up headers under /usr.
 290                  (("/usr/include/") ""))
 291                (zero? (system* "make" "unittest")))))))
 292       (home-page "http://www.syslinux.org")
 293       (synopsis "Lightweight Linux bootloader")
 294       (description "Syslinux is a lightweight Linux bootloader.")
 295       (license (list license:gpl2+
 296                      license:bsd-3 ; gnu-efi/*
 297                      license:bsd-4 ; gnu-efi/inc/* gnu-efi/lib/*
 298                      ;; Also contains:
 299                      license:expat license:isc license:zlib)))))
 300
 301 (define-public dtc
 302   (package
 303     (name "dtc")
 304     (version "1.4.6")
 305     (source (origin
 306               (method url-fetch)
 307               (uri (string-append
 308                     "mirror://kernel.org/software/utils/dtc/"
 309                     "dtc-" version ".tar.xz"))
 310               (sha256
 311                (base32
 312                 "0zkvih0fpwvk31aqyyfy9kn13nbi76c21ihax15p6h1wrjzh48rq"))))
 313     (build-system gnu-build-system)
 314     (native-inputs
 315      `(("bison" ,bison)
 316        ("flex" ,flex)
 317        ("swig" ,swig)))
 318     (inputs
 319      `(("python-2" ,python-2)))
 320     (arguments
 321      `(#:make-flags
 322        (list "CC=gcc"
 323              (string-append "PREFIX=" (assoc-ref %outputs "out"))
 324              (string-append "SETUP_PREFIX=" (assoc-ref %outputs "out"))
 325              "INSTALL=install")
 326        #:phases
 327        (modify-phases %standard-phases
 328          (delete 'configure))))         ; no configure script
 329     (home-page "https://www.devicetree.org")
 330     (synopsis "Compiles device tree source files")
 331     (description "@command{dtc} compiles
 332 @uref{http://elinux.org/Device_Tree_Usage, device tree source files} to device
 333 tree binary files.  These are board description files used by Linux and BSD.")
 334     (license license:gpl2+)))
 335
 336 (define u-boot
 337   (package
 338     (name "u-boot")
 339     (version "2018.01")
 340     (source (origin
 341               (method url-fetch)
 342               (uri (string-append
 343                     "ftp://ftp.denx.de/pub/u-boot/"
 344                     "u-boot-" version ".tar.bz2"))
 345               (sha256
 346                (base32
 347                 "1nidnnjprgxdhiiz7gmaj8cgcf52l5gbv64cmzjq4gmkjirmk3wk"))))
 348     (native-inputs
 349      `(("bc" ,bc)
 350        ;("dtc" ,dtc) ; they have their own incompatible copy.
 351        ("python-2" ,python-2)
 352        ("swig" ,swig)))
 353     (build-system  gnu-build-system)
 354     (home-page "http://www.denx.de/wiki/U-Boot/")
 355     (synopsis "ARM bootloader")
 356     (description "U-Boot is a bootloader used mostly for ARM boards. It
 357 also initializes the boards (RAM etc).")
 358     (license license:gpl2+)))
 359
 360 (define (make-u-boot-package board triplet)
 361   "Returns a u-boot package for BOARD cross-compiled for TRIPLET."
 362   (let ((same-arch? (if (string-prefix? (%current-system)
 363                                         (gnu-triplet->nix-system triplet))
 364                       `#t
 365                       `#f)))
 366     (package
 367       (inherit u-boot)
 368       (name (string-append "u-boot-"
 369                            (string-replace-substring (string-downcase board)
 370                                                      "_" "-")))
 371       (native-inputs
 372        `(,@(if (not same-arch?)
 373              `(("cross-gcc" ,(cross-gcc triplet #:xgcc gcc-7))
 374                ("cross-binutils" ,(cross-binutils triplet)))
 375              `(("gcc-7" ,gcc-7)))
 376          ,@(package-native-inputs u-boot)))
 377       (arguments
 378        `(#:modules ((ice-9 ftw) (guix build utils) (guix build gnu-build-system))
 379          #:test-target "test"
 380          #:make-flags
 381          (list "HOSTCC=gcc"
 382                ,@(if (not same-arch?)
 383                    `((string-append "CROSS_COMPILE=" ,triplet "-"))
 384                    '()))
 385          #:phases
 386          (modify-phases %standard-phases
 387            (replace 'configure
 388              (lambda* (#:key outputs make-flags #:allow-other-keys)
 389                (let ((config-name (string-append ,board "_defconfig")))
 390                  (if (file-exists? (string-append "configs/" config-name))
 391                      (zero? (apply system* "make" `(,@make-flags ,config-name)))
 392                      (begin
 393                        (display "Invalid board name. Valid board names are:")
 394                        (let ((suffix-len (string-length "_defconfig")))
 395                          (scandir "configs"
 396                                   (lambda (file-name)
 397                                     (when (string-suffix? "_defconfig" file-name)
 398                                       (format #t
 399                                               "- ~A\n"
 400                                               (string-drop-right file-name
 401                                                                  suffix-len))))))
 402                        #f)))))
 403            (replace 'install
 404              (lambda* (#:key outputs #:allow-other-keys)
 405                (let* ((out (assoc-ref outputs "out"))
 406                       (libexec (string-append out "/libexec"))
 407                       (uboot-files (append
 408                                     (find-files "." ".*\\.(bin|efi|img|spl)$")
 409                                     (find-files "." "^MLO$"))))
 410                  (mkdir-p libexec)
 411                  (install-file ".config" libexec)
 412                  (for-each
 413                   (lambda (file)
 414                     (let ((target-file (string-append libexec "/" file)))
 415                       (mkdir-p (dirname target-file))
 416                       (copy-file file target-file)))
 417                   uboot-files))))))))))
 418
 419 (define-public u-boot-vexpress
 420   (make-u-boot-package "vexpress_ca9x4" "arm-linux-gnueabihf"))
 421
 422 (define-public u-boot-malta
 423   (make-u-boot-package "malta" "mips64el-linux-gnuabi64"))
 424
 425 (define-public u-boot-beagle-bone-black
 426   (make-u-boot-package "am335x_boneblack" "arm-linux-gnueabihf"))
 427
 428 (define-public u-boot-odroid-c2
 429   (make-u-boot-package "odroid-c2" "aarch64-linux-gnu"))
 430
 431 (define-public u-boot-banana-pi-m2-ultra
 432   (make-u-boot-package "Bananapi_M2_Ultra" "arm-linux-gnueabihf"))
 433
 434 (define-public u-boot-a20-olinuxino-lime
 435   (make-u-boot-package "A20-OLinuXino-Lime" "arm-linux-gnueabihf"))
 436
 437 (define-public u-boot-a20-olinuxino-lime2
 438   (make-u-boot-package "A20-OLinuXino-Lime2" "arm-linux-gnueabihf"))
 439
 440 (define-public u-boot-a20-olinuxino-micro
 441   (make-u-boot-package "A20-OLinuXino_MICRO" "arm-linux-gnueabihf"))
 442
 443 (define-public u-boot-nintendo-nes-classic-edition
 444   (make-u-boot-package "Nintendo_NES_Classic_Edition" "arm-linux-gnueabihf"))
 445
 446 (define-public vboot-utils
 447   (package
 448     (name "vboot-utils")
 449     (version "R63-10032.B")
 450     (source (origin
 451               ;; XXX: Snapshots are available but changes timestamps every download.
 452               (method git-fetch)
 453               (uri (git-reference
 454                     (url (string-append "https://chromium.googlesource.com"
 455                                         "/chromiumos/platform/vboot_reference"))
 456                     (commit (string-append "release-" version))))
 457               (file-name (string-append name "-" version "-checkout"))
 458               (sha256
 459                (base32
 460                 "0h0m3l69vp9dr6xrs1p6y7ilkq3jq8jraw2z20kqfv7lvc9l1lxj"))))
 461     (build-system gnu-build-system)
 462     (arguments
 463      `(#:make-flags (list "CC=gcc"
 464                           (string-append "DESTDIR=" (assoc-ref %outputs "out")))
 465        #:phases (modify-phases %standard-phases
 466                   (add-after 'unpack 'patch-hard-coded-paths
 467                     (lambda* (#:key inputs outputs #:allow-other-keys)
 468                       (let ((coreutils (assoc-ref inputs "coreutils"))
 469                             (diffutils (assoc-ref inputs "diffutils")))
 470                         (substitute* "futility/misc.c"
 471                           (("/bin/cp") (string-append coreutils "/bin/cp")))
 472                         (substitute* "tests/bitmaps/TestBmpBlock.py"
 473                           (("/usr/bin/cmp") (string-append diffutils "/bin/cmp")))
 474                         (substitute* "vboot_host.pc.in"
 475                           (("prefix=/usr")
 476                            (string-append "prefix=" (assoc-ref outputs "out"))))
 477                         #t)))
 478                   (delete 'configure)
 479                   (add-before 'check 'patch-tests
 480                     (lambda _
 481                       ;; These tests compare diffs against known-good values.
 482                       ;; Patch the paths to match those in the build container.
 483                       (substitute* (find-files "tests/futility/expect_output")
 484                         (("/mnt/host/source/src/platform/vboot_reference")
 485                          (string-append "/tmp/guix-build-" ,name "-" ,version
 486                                         ".drv-0/source")))
 487                       ;; Tests require write permissions to many of these files.
 488                       (for-each make-file-writable (find-files "tests/futility"))
 489                       #t)))
 490        #:test-target "runtests"))
 491     (native-inputs
 492      `(("pkg-config" ,pkg-config)
 493
 494        ;; For tests.
 495        ("diffutils" ,diffutils)
 496        ("python@2" ,python-2)))
 497     (inputs
 498      `(("coreutils" ,coreutils)
 499        ("libyaml" ,libyaml)
 500        ("openssl" ,openssl)
 501        ("openssl:static" ,openssl "static")
 502        ("util-linux" ,util-linux)))
 503     (home-page
 504      "https://dev.chromium.org/chromium-os/chromiumos-design-docs/verified-boot")
 505     (synopsis "ChromiumOS verified boot utilities")
 506     (description
 507      "vboot-utils is a collection of tools to facilitate booting of
 508 Chrome-branded devices.  This includes the @command{cgpt} partitioning
 509 program, the @command{futility} and @command{crossystem} firmware management
 510 tools, and more.")
 511     (license license:bsd-3)))
 512
 513 (define-public os-prober
 514   (package
 515     (name "os-prober")
 516     (version "1.76")
 517     (source
 518      (origin
 519        (method url-fetch)
 520        (uri (string-append "mirror://debian/pool/main/o/os-prober/os-prober_"
 521                            version ".tar.xz"))
 522        (sha256
 523         (base32
 524          "1vb45i76bqivlghrq7m3n07qfmmq4wxrkplqx8gywj011rhq19fk"))))
 525     (build-system gnu-build-system)
 526     (arguments
 527      `(#:modules ((guix build gnu-build-system)
 528                   (guix build utils)
 529                   (ice-9 regex)   ; for string-match
 530                   (srfi srfi-26)) ; for cut
 531        #:make-flags (list "CC=gcc")
 532        #:tests? #f ; no tests
 533        #:phases
 534        (modify-phases %standard-phases
 535          (replace 'configure
 536            (lambda* (#:key outputs #:allow-other-keys)
 537              (substitute* (find-files ".")
 538                (("/usr") (assoc-ref outputs "out")))
 539              (substitute* (find-files "." "50mounted-tests$")
 540                (("mkdir") "mkdir -p"))
 541              #t))
 542          (replace 'install
 543            (lambda* (#:key outputs #:allow-other-keys)
 544              (define (find-files-non-recursive directory)
 545                (find-files directory
 546                            (lambda (file stat)
 547                              (string-match (string-append "^" directory "/[^/]*$")
 548                                            file))
 549                            #:directories? #t))
 550
 551              (let* ((out (assoc-ref outputs "out"))
 552                     (bin (string-append out "/bin"))
 553                     (lib (string-append out "/lib"))
 554                     (share (string-append out "/share")))
 555                (for-each (cut install-file <> bin)
 556                          (list "linux-boot-prober" "os-prober"))
 557                (install-file "newns" (string-append lib "/os-prober"))
 558                (install-file "common.sh" (string-append share "/os-prober"))
 559                (install-file "os-probes/mounted/powerpc/20macosx"
 560                              (string-append lib "/os-probes/mounted"))
 561                (for-each
 562                 (lambda (directory)
 563                   (for-each
 564                    (lambda (file)
 565                      (let ((destination (string-append lib "/" directory
 566                                                        "/" (basename file))))
 567                        (mkdir-p (dirname destination))
 568                        (copy-recursively file destination)))
 569                    (append (find-files-non-recursive (string-append directory "/common"))
 570                            (find-files-non-recursive (string-append directory "/x86")))))
 571                 (list "os-probes" "os-probes/mounted" "os-probes/init"
 572                       "linux-boot-probes" "linux-boot-probes/mounted"))
 573                #t))))))
 574     (home-page "https://joeyh.name/code/os-prober")
 575     (synopsis "Detect other operating systems")
 576     (description "os-prober probes disks on the system for other operating
 577 systems so that they can be added to the bootloader.  It also works out how to
 578 boot existing GNU/Linux systems and detects what distribution is installed in
 579 order to add a suitable bootloader menu entry.")
 580     (license license:gpl2+)))