gnu/packages/gcc.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014, 2015, 2018 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2014, 2015, 2016, 2017, 2019 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2015 Andreas Enge <andreas@enge.fr>
   6 ;;; Copyright © 2015, 2016, 2017, 2018 Efraim Flashner <efraim@flashner.co.il>
   7 ;;; Copyright © 2016 Carlos Sánchez de La Lama <csanchezdll@gmail.com>
   8 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
   9 ;;; Copyright © 2018 Marius Bakke <mbakke@fastmail.com>
  10 ;;;
  11 ;;; This file is part of GNU Guix.
  12 ;;;
  13 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  14 ;;; under the terms of the GNU General Public License as published by
  15 ;;; the Free Software Foundation; either version 3 of the License, or (at
  16 ;;; your option) any later version.
  17 ;;;
  18 ;;; GNU Guix is distributed in the hope that it will be useful, but
  19 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;;; GNU General Public License for more details.
  22 ;;;
  23 ;;; You should have received a copy of the GNU General Public License
  24 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 (define-module (gnu packages gcc)
  27   #:use-module ((guix licenses)
  28                 #:select (gpl3+ gpl2+ lgpl2.1+ lgpl2.0+ fdl1.3+))
  29   #:use-module (gnu packages)
  30   #:use-module (gnu packages bootstrap)
  31   #:use-module (gnu packages compression)
  32   #:use-module (gnu packages multiprecision)
  33   #:use-module (gnu packages texinfo)
  34   #:use-module (gnu packages dejagnu)
  35   #:use-module (gnu packages documentation)
  36   #:use-module (gnu packages xml)
  37   #:use-module (gnu packages docbook)
  38   #:use-module (gnu packages graphviz)
  39   #:use-module (gnu packages elf)
  40   #:use-module (gnu packages perl)
  41   #:use-module (guix packages)
  42   #:use-module (guix download)
  43   #:use-module (guix build-system gnu)
  44   #:use-module (guix build-system trivial)
  45   #:use-module (guix utils)
  46   #:use-module (srfi srfi-1)
  47   #:use-module (ice-9 regex))
  48
  49 (define %gcc-infrastructure
  50   ;; Base URL for GCC's infrastructure.
  51   "mirror://gcc/infrastructure/")
  52
  53 (define (gcc-configure-flags-for-triplet target)
  54   "Return a list of additional GCC `configure' flags for TARGET, a GNU triplet.
  55
  56 The purpose of this procedure is to translate extended GNU triplets---e.g.,
  57 where the OS part is overloaded to denote a specific ABI---into GCC
  58 `configure' options.  We take extended GNU triplets that glibc recognizes."
  59   (cond ((string-match "^mips64el.*gnuabin?64$" target)
  60          ;; Triplets recognized by glibc as denoting the N64 ABI; see
  61          ;; ports/sysdeps/mips/preconfigure.
  62          '("--with-abi=64"))
  63
  64         ((string-match "^arm.*-gnueabihf$" target)
  65          '("--with-arch=armv7-a"
  66            "--with-float=hard"
  67            "--with-mode=thumb"
  68            "--with-fpu=neon"))
  69
  70         ((and (string-suffix? "-gnu" target)
  71               (not (string-contains target "-linux")))
  72          ;; Cross-compilation of libcilkrts in GCC 5.5.0 to GNU/Hurd fails
  73          ;; with:
  74          ;;   libcilkrts/runtime/os-unix.c:388:2: error: #error "Unknown architecture"
  75          ;; Cilk has been removed from GCC 8 anyway.
  76          '("--disable-libcilkrts"))
  77
  78         (else
  79          ;; TODO: Add `arm.*-gnueabi', etc.
  80          '())))
  81
  82 (define-public gcc-4.7
  83   (let* ((stripped? #t)      ;whether to strip the compiler, not the libraries
  84          (maybe-target-tools
  85           (lambda ()
  86             ;; Return the `_FOR_TARGET' variables that are needed when
  87             ;; cross-compiling GCC.
  88             (let ((target (%current-target-system)))
  89               (if target
  90                   (map (lambda (var tool)
  91                          (string-append (string-append var "_FOR_TARGET")
  92                                         "=" target "-" tool))
  93                        '("CC"  "CXX" "LD" "AR" "NM" "OBJDUMP" "RANLIB" "STRIP")
  94                        '("gcc" "g++" "ld" "ar" "nm" "objdump" "ranlib" "strip"))
  95                   '()))))
  96          (libdir
  97           (let ((base '(or (assoc-ref outputs "lib")
  98                            (assoc-ref outputs "out"))))
  99             (lambda ()
 100               ;; Return the directory that contains lib/libgcc_s.so et al.
 101               (if (%current-target-system)
 102                   `(string-append ,base "/" ,(%current-target-system))
 103                   base))))
 104          (configure-flags
 105           (lambda ()
 106             ;; This is terrible.  Since we have two levels of quasiquotation,
 107             ;; we have to do this convoluted thing just so we can insert the
 108             ;; contents of (maybe-target-tools).
 109             (list 'quasiquote
 110                   (append
 111                    '("--enable-plugin"
 112                      "--enable-languages=c,c++"
 113                      "--disable-multilib"
 114                      "--with-system-zlib"
 115
 116                      ;; No pre-compiled libstdc++ headers, to save space.
 117                      "--disable-libstdcxx-pch"
 118
 119                      "--with-local-prefix=/no-gcc-local-prefix"
 120
 121                      ;; With a separate "lib" output, the build system
 122                      ;; incorrectly guesses GPLUSPLUS_INCLUDE_DIR, so force
 123                      ;; it.  (Don't use a versioned sub-directory, that's
 124                      ;; unnecessary.)
 125                      ,(string-append "--with-gxx-include-dir="
 126                                      (assoc-ref %outputs "out")
 127                                      "/include/c++")
 128
 129                      ,(let ((libc (assoc-ref %build-inputs "libc")))
 130                         (if libc
 131                             (string-append "--with-native-system-header-dir=" libc
 132                                            "/include")
 133                             "--without-headers")))
 134
 135                    ;; Pass the right options for the target triplet.
 136                    (let ((triplet
 137                           (or (%current-target-system)
 138                               (nix-system->gnu-triplet (%current-system)))))
 139                      (gcc-configure-flags-for-triplet triplet))
 140
 141                    (maybe-target-tools))))))
 142     (hidden-package
 143      (package
 144        (name "gcc")
 145        (version "4.7.4")
 146        (source (origin
 147                  (method url-fetch)
 148                  (uri (string-append "mirror://gnu/gcc/gcc-"
 149                                      version "/gcc-" version ".tar.bz2"))
 150                  (sha256
 151                   (base32
 152                    "10k2k71kxgay283ylbbhhs51cl55zn2q38vj5pk4k950qdnirrlj"))
 153                  (patches (search-patches "gcc-4-compile-with-gcc-5.patch"
 154                                           "gcc-fix-texi2pod.patch"))))
 155        (build-system gnu-build-system)
 156
 157        ;; Separate out the run-time support libraries because all the
 158        ;; dynamic-linked objects depend on it.
 159        (outputs '("out"                    ;commands, etc. (60+ MiB)
 160                   "lib"                    ;libgcc_s, libgomp, etc. (15+ MiB)
 161                   "debug"))                ;debug symbols of run-time libraries
 162
 163        (inputs `(("gmp" ,gmp)
 164                  ("mpfr" ,mpfr)
 165                  ("mpc" ,mpc)
 166                  ("libelf" ,libelf)
 167                  ("zlib" ,zlib)))
 168
 169        ;; GCC < 5 is one of the few packages that doesn't ship .info files.
 170        ;; Newer texinfos fail to build the manual, so we use an older one.
 171        (native-inputs `(("perl" ,perl)   ;for manpages
 172                         ("texinfo" ,texinfo-5)))
 173
 174        (arguments
 175         `(#:out-of-source? #t
 176           #:configure-flags ,(configure-flags)
 177           #:make-flags
 178           ;; None of the flags below are needed when doing a Canadian cross.
 179           ;; TODO: Simplify this.
 180           ,(if (%current-target-system)
 181                (if stripped?
 182                    ''("CFLAGS=-g0 -O2")
 183                    ''())
 184                `(let* ((libc        (assoc-ref %build-inputs "libc"))
 185                        (libc-native (or (assoc-ref %build-inputs "libc-native")
 186                                         libc)))
 187                   `(,@(if libc
 188                           (list (string-append "LDFLAGS_FOR_TARGET="
 189                                                "-B" libc "/lib "
 190                                                "-Wl,-dynamic-linker "
 191                                                "-Wl," libc
 192                                                ,(glibc-dynamic-linker)))
 193                           '())
 194
 195                     ;; Native programs like 'genhooks' also need that right.
 196                     ,(string-append "LDFLAGS="
 197                                     "-Wl,-rpath=" libc-native "/lib "
 198                                     "-Wl,-dynamic-linker "
 199                                     "-Wl," libc-native ,(glibc-dynamic-linker))
 200                     ,(string-append "BOOT_CFLAGS=-O2 "
 201                                     ,(if stripped? "-g0" "-g")))))
 202
 203           #:tests? #f
 204
 205           #:phases
 206           (modify-phases %standard-phases
 207             (add-before 'configure 'pre-configure
 208               (lambda* (#:key inputs outputs #:allow-other-keys)
 209                 (let ((libdir ,(libdir))
 210                       (libc   (assoc-ref inputs "libc")))
 211                   (when libc
 212                     ;; The following is not performed for `--without-headers'
 213                     ;; cross-compiler builds.
 214
 215                     ;; Join multi-line definitions of GLIBC_DYNAMIC_LINKER* into a
 216                     ;; single line, to allow the next step to work properly.
 217                     (for-each
 218                      (lambda (x)
 219                        (substitute* (find-files "gcc/config"
 220                                                 "^(linux|gnu|sysv4)(64|-elf|-eabi)?\\.h$")
 221                          (("(#define (GLIBC|GNU_USER)_DYNAMIC_LINKER.*)\\\\\n$" _ line)
 222                           line)))
 223                      '(1 2 3))
 224
 225                     ;; Fix the dynamic linker's file name.
 226                     (substitute* (find-files "gcc/config"
 227                                              "^(linux|gnu|sysv4)(64|-elf|-eabi)?\\.h$")
 228                       (("#define (GLIBC|GNU_USER)_DYNAMIC_LINKER([^ \t]*).*$"
 229                         _ gnu-user suffix)
 230                        (format #f "#define ~a_DYNAMIC_LINKER~a \"~a\"~%"
 231                                gnu-user suffix
 232                                (string-append libc ,(glibc-dynamic-linker)))))
 233
 234                     ;; Tell where to find libstdc++, libc, and `?crt*.o', except
 235                     ;; `crt{begin,end}.o', which come with GCC.
 236                     (substitute* (find-files "gcc/config"
 237                                              "^gnu-user.*\\.h$")
 238                       (("#define GNU_USER_TARGET_LIB_SPEC (.*)$" _ suffix)
 239                        ;; Help libgcc_s.so be found (see also below.)  Always use
 240                        ;; '-lgcc_s' so that libgcc_s.so is always found by those
 241                        ;; programs that use 'pthread_cancel' (glibc dlopens
 242                        ;; libgcc_s.so when pthread_cancel support is needed, but
 243                        ;; having it in the application's RUNPATH isn't enough; see
 244                        ;; <http://sourceware.org/ml/libc-help/2013-11/msg00023.html>.)
 245                        ;;
 246                        ;; NOTE: The '-lgcc_s' added below needs to be removed in a
 247                        ;; later phase of %gcc-static.  If you change the string
 248                        ;; below, make sure to update the relevant code in
 249                        ;; %gcc-static package as needed.
 250                        (format #f "#define GNU_USER_TARGET_LIB_SPEC \
 251 \"-L~a/lib %{!static:-rpath=~a/lib %{!static-libgcc:-rpath=~a/lib -lgcc_s}} \" ~a"
 252                                libc libc libdir suffix))
 253                       (("#define GNU_USER_TARGET_STARTFILE_SPEC.*$" line)
 254                        (format #f "#define STANDARD_STARTFILE_PREFIX_1 \"~a/lib\"
 255 #define STANDARD_STARTFILE_PREFIX_2 \"\"
 256 ~a"
 257                                libc line)))
 258
 259                     ;; The rs6000 (a.k.a. powerpc) config in GCC does not use
 260                     ;; GNU_USER_* defines.  Do the above for this case.
 261                     (substitute*
 262                         "gcc/config/rs6000/sysv4.h"
 263                       (("#define LIB_LINUX_SPEC (.*)$" _ suffix)
 264                        (format #f "#define LIB_LINUX_SPEC \
 265 \"-L~a/lib %{!static:-rpath=~a/lib %{!static-libgcc:-rpath=~a/lib -lgcc_s}} \" ~a"
 266                                libc libc libdir suffix))
 267                       (("#define        STARTFILE_LINUX_SPEC.*$" line)
 268                        (format #f "#define STANDARD_STARTFILE_PREFIX_1 \"~a/lib\"
 269 #define STANDARD_STARTFILE_PREFIX_2 \"\"
 270 ~a"
 271                                libc line))))
 272
 273                   ;; Don't retain a dependency on the build-time sed.
 274                   (substitute* "fixincludes/fixincl.x"
 275                     (("static char const sed_cmd_z\\[\\] =.*;")
 276                      "static char const sed_cmd_z[] = \"sed\";"))
 277
 278                   ;; Aarch64 support didn't land in GCC until the 4.8 series.
 279                   (when (file-exists? "gcc/config/aarch64")
 280                     ;; Force Aarch64 libdir to be /lib and not /lib64
 281                     (substitute* "gcc/config/aarch64/t-aarch64-linux"
 282                       (("lib64") "lib")))
 283
 284                   (when (file-exists? "libbacktrace")
 285                     ;; GCC 4.8+ comes with libbacktrace.  By default it builds
 286                     ;; with -Werror, which fails with a -Wcast-qual error in glibc
 287                     ;; 2.21's stdlib-bsearch.h.  Remove -Werror.
 288                     (substitute* "libbacktrace/configure"
 289                       (("WARN_FLAGS=(.*)-Werror" _ flags)
 290                        (string-append "WARN_FLAGS=" flags)))
 291
 292                     (when (file-exists? "libsanitizer/libbacktrace")
 293                       ;; Same in libsanitizer's bundled copy (!) found in 4.9+.
 294                       (substitute* "libsanitizer/libbacktrace/Makefile.in"
 295                         (("-Werror")
 296                          ""))))
 297
 298                   ;; Add a RUNPATH to libstdc++.so so that it finds libgcc_s.
 299                   ;; See <https://gcc.gnu.org/bugzilla/show_bug.cgi?id=32354>
 300                   ;; and <http://bugs.gnu.org/20358>.
 301                   (substitute* "libstdc++-v3/src/Makefile.in"
 302                     (("^OPT_LDFLAGS = ")
 303                      "OPT_LDFLAGS = -Wl,-rpath=$(libdir) "))
 304
 305                   ;; Move libstdc++*-gdb.py to the "lib" output to avoid a
 306                   ;; circularity between "out" and "lib".  (Note:
 307                   ;; --with-python-dir is useless because it imposes $(prefix) as
 308                   ;; the parent directory.)
 309                   (substitute* "libstdc++-v3/python/Makefile.in"
 310                     (("pythondir = .*$")
 311                      (string-append "pythondir = " libdir "/share"
 312                                     "/gcc-$(gcc_version)/python\n")))
 313
 314                   ;; Avoid another circularity between the outputs: this #define
 315                   ;; ends up in auto-host.h in the "lib" output, referring to
 316                   ;; "out".  (This variable is used to augment cpp's search path,
 317                   ;; but there's nothing useful to look for here.)
 318                   (substitute* "gcc/config.in"
 319                     (("PREFIX_INCLUDE_DIR")
 320                      "PREFIX_INCLUDE_DIR_isnt_necessary_here"))
 321                   #t)))
 322
 323             (add-after 'configure 'post-configure
 324               (lambda _
 325                 ;; Don't store configure flags, to avoid retaining references to
 326                 ;; build-time dependencies---e.g., `--with-ppl=/gnu/store/xxx'.
 327                 (substitute* "Makefile"
 328                   (("^TOPLEVEL_CONFIGURE_ARGUMENTS=(.*)$" _ rest)
 329                    "TOPLEVEL_CONFIGURE_ARGUMENTS=\n"))
 330                 #t)))))
 331
 332        (native-search-paths
 333         ;; Use the language-specific variables rather than 'CPATH' because they
 334         ;; are equivalent to '-isystem' whereas 'CPATH' is equivalent to '-I'.
 335         ;; The intent is to allow headers that are in the search path to be
 336         ;; treated as "system headers" (headers exempt from warnings) just like
 337         ;; the typical /usr/include headers on an FHS system.
 338         (list (search-path-specification
 339                (variable "C_INCLUDE_PATH")
 340                (files '("include")))
 341               (search-path-specification
 342                (variable "CPLUS_INCLUDE_PATH")
 343                (files '("include")))
 344               (search-path-specification
 345                (variable "LIBRARY_PATH")
 346                (files '("lib" "lib64")))))
 347
 348        (properties `((gcc-libc . ,(assoc-ref inputs "libc"))))
 349        (synopsis "GNU Compiler Collection")
 350        (description
 351         "GCC is the GNU Compiler Collection.  It provides compiler front-ends
 352 for several languages, including C, C++, Objective-C, Fortran, Java, Ada, and
 353 Go.  It also includes runtime support libraries for these languages.")
 354        (license gpl3+)
 355        (supported-systems (delete "aarch64-linux" %supported-systems))
 356        (home-page "https://gcc.gnu.org/")))))
 357
 358 (define-public gcc-4.8
 359   (package (inherit gcc-4.7)
 360     (version "4.8.5")
 361     (source (origin
 362               (method url-fetch)
 363               (uri (string-append "mirror://gnu/gcc/gcc-"
 364                                   version "/gcc-" version ".tar.bz2"))
 365               (sha256
 366                (base32
 367                 "08yggr18v373a1ihj0rg2vd6psnic42b518xcgp3r9k81xz1xyr2"))
 368               (patches (search-patches "gcc-arm-link-spec-fix.patch"
 369                                        "gcc-4.8-libsanitizer-fix.patch"
 370                                        "gcc-asan-missing-include.patch"
 371                                        "gcc-fix-texi2pod.patch"))
 372               (modules '((guix build utils)))
 373               ;; This is required for building with glibc-2.26.
 374               ;; https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81712
 375               (snippet
 376                '(begin
 377                   (for-each
 378                    (lambda (dir)
 379                      (substitute* (string-append "libgcc/config/"
 380                                                  dir "/linux-unwind.h")
 381                        (("struct ucontext") "ucontext_t")))
 382                    '("aarch64" "alpha" "bfin" "i386" "m68k"
 383                      "pa" "sh" "tilepro" "xtensa"))
 384                   #t))))
 385     (supported-systems %supported-systems)
 386     (inputs
 387      `(("isl" ,isl-0.11)
 388        ("cloog" ,cloog)
 389        ,@(package-inputs gcc-4.7)))))
 390
 391 (define-public gcc-4.9
 392   (package (inherit gcc-4.8)
 393     (version "4.9.4")
 394     (source (origin
 395               (method url-fetch)
 396               (uri (string-append "mirror://gnu/gcc/gcc-"
 397                                   version "/gcc-" version ".tar.bz2"))
 398               (sha256
 399                (base32
 400                 "14l06m7nvcvb0igkbip58x59w3nq6315k6jcz3wr9ch1rn9d44bc"))
 401               (patches (search-patches "gcc-4.9-libsanitizer-fix.patch"
 402                                        "gcc-4.9-libsanitizer-ustat.patch"
 403                                        "gcc-arm-bug-71399.patch"
 404                                        "gcc-asan-missing-include.patch"
 405                                        "gcc-libvtv-runpath.patch"
 406                                        "gcc-fix-texi2pod.patch"))
 407               (modules '((guix build utils)))
 408               ;; This is required for building with glibc-2.26.
 409               ;; https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81712
 410               (snippet
 411                '(begin
 412                   (for-each
 413                    (lambda (dir)
 414                      (substitute* (string-append "libgcc/config/"
 415                                                  dir "/linux-unwind.h")
 416                        (("struct ucontext") "ucontext_t")))
 417                    '("aarch64" "alpha" "bfin" "i386" "m68k" "nios2"
 418                      "pa" "sh" "tilepro" "xtensa"))
 419                   #t))))
 420     ;; Override inherited texinfo-5 with latest version.
 421     (native-inputs `(("perl" ,perl)   ;for manpages
 422                      ("texinfo" ,texinfo)))))
 423
 424 (define-public gcc-5
 425   ;; Note: GCC >= 5 ships with .info files but 'make install' fails to install
 426   ;; them in a VPATH build.
 427   (package (inherit gcc-4.9)
 428     (version "5.5.0")
 429     (source (origin
 430               (method url-fetch)
 431               (uri (string-append "mirror://gnu/gcc/gcc-"
 432                                   version "/gcc-" version ".tar.xz"))
 433               (sha256
 434                (base32
 435                 "11zd1hgzkli3b2v70qsm2hyqppngd4616qc96lmm9zl2kl9yl32k"))
 436               (patches (search-patches "gcc-arm-bug-71399.patch"
 437                                        "gcc-libsanitizer-ustat.patch"
 438                                        "gcc-strmov-store-file-names.patch"
 439                                        "gcc-5.0-libvtv-runpath.patch"
 440                                        "gcc-5-source-date-epoch-1.patch"
 441                                        "gcc-5-source-date-epoch-2.patch"
 442                                        "gcc-fix-texi2pod.patch"))
 443               (modules '((guix build utils)))
 444               (snippet
 445                ;; Fix 'libcc1/configure' error when cross-compiling GCC.
 446                ;; Without that, 'libcc1/configure' wrongfully determines that
 447                ;; '-rdynamic' support is missing because $gcc_cv_objdump is
 448                ;; empty:
 449                ;;
 450                ;;   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=67590
 451                ;;   http://cgit.openembedded.org/openembedded-core/commit/?id=f6e47aa9b12f9ab61530c40e0343f451699d9077
 452                '(begin
 453                   (substitute* "libcc1/configure"
 454                     (("\\$gcc_cv_objdump -T")
 455                      "$OBJDUMP_FOR_TARGET -T"))
 456                   #t))))
 457     (inputs
 458      `(;; GCC5 needs <isl/band.h> which is removed in later versions.
 459        ("isl" ,isl-0.18)
 460        ,@(package-inputs gcc-4.7)))))
 461
 462 (define-public gcc-6
 463   (package
 464     (inherit gcc-5)
 465     (version "6.5.0")
 466     (source (origin
 467               (method url-fetch)
 468               (uri (string-append "mirror://gnu/gcc/gcc-"
 469                                   version "/gcc-" version ".tar.xz"))
 470               (sha256
 471                (base32
 472                 "0i89fksfp6wr1xg9l8296aslcymv2idn60ip31wr9s4pwin7kwby"))
 473               (patches (search-patches "gcc-strmov-store-file-names.patch"
 474                                        "gcc-6-source-date-epoch-1.patch"
 475                                        "gcc-6-source-date-epoch-2.patch"
 476                                        "gcc-5.0-libvtv-runpath.patch"))))
 477     (inputs
 478      `(("isl" ,isl)
 479        ,@(package-inputs gcc-4.7)))
 480
 481     (native-search-paths
 482      ;; We have to use 'CPATH' for GCC > 5, not 'C_INCLUDE_PATH' & co., due to
 483      ;; <https://gcc.gnu.org/bugzilla/show_bug.cgi?id=70129>.
 484      (list (search-path-specification
 485             (variable "CPATH")
 486             (files '("include")))
 487            (search-path-specification
 488             (variable "LIBRARY_PATH")
 489             (files '("lib" "lib64")))))))
 490
 491 (define-public gcc-7
 492   (package
 493     (inherit gcc-6)
 494     (version "7.4.0")
 495     (source (origin
 496               (method url-fetch)
 497               (uri (string-append "mirror://gnu/gcc/gcc-"
 498                                   version "/gcc-" version ".tar.xz"))
 499               (sha256
 500                (base32
 501                 "0lgy170b0pp60j9cczqkmaqyjjb584vfamj4c30swd7k0j6y5pgd"))
 502               (patches (search-patches "gcc-strmov-store-file-names.patch"
 503                                        "gcc-5.0-libvtv-runpath.patch"))))
 504     (description
 505      "GCC is the GNU Compiler Collection.  It provides compiler front-ends
 506 for several languages, including C, C++, Objective-C, Fortran, Ada, and Go.
 507 It also includes runtime support libraries for these languages.")))
 508
 509 (define-public gcc-8
 510   (package
 511     (inherit gcc-7)
 512     (version "8.3.0")
 513     (source (origin
 514               (method url-fetch)
 515               (uri (string-append "mirror://gnu/gcc/gcc-"
 516                                   version "/gcc-" version ".tar.xz"))
 517               (sha256
 518                (base32
 519                 "0b3xv411xhlnjmin2979nxcbnidgvzqdf4nbhix99x60dkzavfk4"))
 520               (patches (search-patches "gcc-8-strmov-store-file-names.patch"
 521                                        "gcc-5.0-libvtv-runpath.patch"))))))
 522
 523 (define-public gcc-9
 524   (package
 525    (inherit gcc-8)
 526    (version "9.2.0")
 527    (source (origin
 528             (method url-fetch)
 529             (uri (string-append "mirror://gnu/gcc/gcc-"
 530                                 version "/gcc-" version ".tar.xz"))
 531             (sha256
 532              (base32
 533               "01mj3yk7z49i49168hg2cg7qs4bsccrrnv7pjmbdlf8j2a7z0vpa"))
 534             (patches (search-patches "gcc-9-strmov-store-file-names.patch"
 535                                      "gcc-9-asan-fix-limits-include.patch"
 536                                      "gcc-5.0-libvtv-runpath.patch"))))))
 537
 538 ;; Note: When changing the default gcc version, update
 539 ;;       the gcc-toolchain-* definitions and the gfortran definition
 540 ;;       accordingly.
 541 (define-public gcc gcc-7)
 542
 543 (define-public (make-libstdc++ gcc)
 544   "Return a libstdc++ package based on GCC.  The primary use case is when
 545 using compilers other than GCC."
 546   (package
 547     (inherit gcc)
 548     (name "libstdc++")
 549     (arguments
 550      `(#:out-of-source? #t
 551        #:phases (alist-cons-before
 552                  'configure 'chdir
 553                  (lambda _
 554                    (chdir "libstdc++-v3")
 555                    #t)
 556                  %standard-phases)
 557        #:configure-flags `("--disable-libstdcxx-pch"
 558                            ,(string-append "--with-gxx-include-dir="
 559                                            (assoc-ref %outputs "out")
 560                                            "/include"))))
 561     (outputs '("out" "debug"))
 562     (inputs '())
 563     (native-inputs '())
 564     (propagated-inputs '())
 565     (synopsis "GNU C++ standard library")))
 566
 567 (define-public libstdc++-4.9
 568   (make-libstdc++ gcc-4.9))
 569
 570 (define (make-libiberty gcc)
 571   "Return a libiberty package based on GCC."
 572   (package
 573     (inherit gcc)
 574     (name "libiberty")
 575     (arguments
 576      `(#:out-of-source? #t
 577        #:phases
 578        (modify-phases %standard-phases
 579          (add-before 'configure 'chdir
 580                      (lambda _
 581                        (chdir "libiberty")
 582                        #t))
 583          (replace
 584           'install
 585           (lambda* (#:key outputs #:allow-other-keys)
 586             (let* ((out     (assoc-ref outputs "out"))
 587                    (lib     (string-append out "/lib/"))
 588                    (include (string-append out "/include/")))
 589               (mkdir-p lib)
 590               (mkdir-p include)
 591               (copy-file "libiberty.a"
 592                          (string-append lib "libiberty.a"))
 593               (copy-file "../include/libiberty.h"
 594                          (string-append include "libiberty.h"))
 595               #t))))))
 596     (inputs '())
 597     (outputs '("out"))
 598     (native-inputs '())
 599     (propagated-inputs '())
 600     (synopsis "Collection of subroutines used by various GNU programs")))
 601
 602 (define-public libiberty
 603   (make-libiberty gcc))
 604
 605 (define* (custom-gcc gcc name languages
 606                      #:optional
 607                      (search-paths (package-native-search-paths gcc))
 608                      #:key (separate-lib-output? #t))
 609   "Return a custom version of GCC that supports LANGUAGES.  Use SEARCH-PATHS
 610 as the 'native-search-paths' field."
 611   (package (inherit gcc)
 612     (name name)
 613     (outputs (if separate-lib-output?
 614                  (package-outputs gcc)
 615                  (delete "lib" (package-outputs gcc))))
 616     (native-search-paths search-paths)
 617     (properties (alist-delete 'hidden? (package-properties gcc)))
 618     (arguments
 619      (substitute-keyword-arguments `(#:modules ((guix build gnu-build-system)
 620                                                 (guix build utils)
 621                                                 (ice-9 regex)
 622                                                 (srfi srfi-1)
 623                                                 (srfi srfi-26))
 624                                                ,@(package-arguments gcc))
 625        ((#:configure-flags flags)
 626         `(cons (string-append "--enable-languages="
 627                               ,(string-join languages ","))
 628                (remove (cut string-match "--enable-languages.*" <>)
 629                        ,flags)))
 630        ((#:phases phases)
 631         `(modify-phases ,phases
 632            (add-after 'install 'remove-broken-or-conflicting-files
 633              (lambda* (#:key outputs #:allow-other-keys)
 634                (for-each delete-file
 635                          (find-files (string-append (assoc-ref outputs "out") "/bin")
 636                                      ".*(c\\+\\+|cpp|g\\+\\+|gcov|gcc|gcc-.*)"))
 637                #t))))))))
 638
 639 (define %generic-search-paths
 640   ;; This is the language-neutral search path for GCC.  Entries in $CPATH are
 641   ;; not considered "system headers", which means GCC can raise warnings for
 642   ;; issues in those headers.  'CPATH' is the only one that works for
 643   ;; front-ends not in the C family.
 644   (list (search-path-specification
 645          (variable "CPATH")
 646          (files '("include")))
 647         (search-path-specification
 648          (variable "LIBRARY_PATH")
 649          (files '("lib" "lib64")))))
 650
 651 (define-public gfortran-4.8
 652   (custom-gcc gcc-4.8 "gfortran" '("fortran")
 653               %generic-search-paths))
 654
 655 (define-public gfortran-4.9
 656   (custom-gcc gcc-4.9 "gfortran" '("fortran")
 657               %generic-search-paths))
 658
 659 (define-public gfortran-5
 660   (custom-gcc gcc-5 "gfortran" '("fortran")
 661               %generic-search-paths))
 662
 663 (define-public gfortran-6
 664   (custom-gcc gcc-6 "gfortran" '("fortran")
 665               %generic-search-paths))
 666
 667 (define-public gfortran-7
 668   (custom-gcc gcc-7 "gfortran" '("fortran")
 669               %generic-search-paths))
 670
 671 (define-public gfortran-8
 672   (custom-gcc gcc-8 "gfortran" '("fortran")
 673               %generic-search-paths))
 674
 675 (define-public gfortran-9
 676   (custom-gcc gcc-9 "gfortran" '("fortran")
 677               %generic-search-paths))
 678
 679 (define-public gfortran
 680   ;; Note: Update this when GCC changes!  We cannot use
 681   ;; (custom-gcc gcc "fortran" …) because that would lead to a package object
 682   ;; that is not 'eq?' with GFORTRAN-5, and thus 'fold-packages' would
 683   ;; report two gfortran@5 that are in fact identical.
 684   gfortran-7)
 685
 686 (define-public gccgo-4.9
 687   (custom-gcc gcc-4.9 "gccgo" '("go")
 688               %generic-search-paths
 689               ;; Suppress the separate "lib" output, because otherwise the
 690               ;; "lib" and "out" outputs would refer to each other, creating
 691               ;; a cyclic dependency.  <http://debbugs.gnu.org/18101>
 692               #:separate-lib-output? #f))
 693
 694 (define-public gcc-objc-4.8
 695   (custom-gcc gcc-4.8 "gcc-objc" '("objc")
 696               (list (search-path-specification
 697                      (variable "OBJC_INCLUDE_PATH")
 698                      (files '("include")))
 699                     (search-path-specification
 700                      (variable "LIBRARY_PATH")
 701                      (files '("lib" "lib64"))))))
 702
 703 (define-public gcc-objc-4.9
 704   (custom-gcc gcc-4.9 "gcc-objc" '("objc")
 705               (list (search-path-specification
 706                      (variable "OBJC_INCLUDE_PATH")
 707                      (files '("include")))
 708                     (search-path-specification
 709                      (variable "LIBRARY_PATH")
 710                      (files '("lib" "lib64"))))))
 711
 712 (define-public gcc-objc-5
 713   (custom-gcc gcc-5 "gcc-objc" '("objc")
 714               (list (search-path-specification
 715                      (variable "OBJC_INCLUDE_PATH")
 716                      (files '("include")))
 717                     (search-path-specification
 718                      (variable "LIBRARY_PATH")
 719                      (files '("lib" "lib64"))))))
 720
 721 (define-public gcc-objc-6
 722   (custom-gcc gcc-6 "gcc-objc" '("objc")
 723               (list (search-path-specification
 724                      (variable "OBJC_INCLUDE_PATH")
 725                      (files '("include")))
 726                     (search-path-specification
 727                      (variable "LIBRARY_PATH")
 728                      (files '("lib" "lib64"))))))
 729
 730 (define-public gcc-objc-7
 731   (custom-gcc gcc-7 "gcc-objc" '("objc")
 732               (list (search-path-specification
 733                      (variable "OBJC_INCLUDE_PATH")
 734                      (files '("include")))
 735                     (search-path-specification
 736                      (variable "LIBRARY_PATH")
 737                      (files '("lib" "lib64"))))))
 738
 739 (define-public gcc-objc-8
 740   (custom-gcc gcc-8 "gcc-objc" '("objc")
 741               (list (search-path-specification
 742                      (variable "OBJC_INCLUDE_PATH")
 743                      (files '("include")))
 744                     (search-path-specification
 745                      (variable "LIBRARY_PATH")
 746                      (files '("lib" "lib64"))))))
 747
 748 (define-public gcc-objc gcc-objc-7)
 749
 750 (define-public gcc-objc++-4.8
 751   (custom-gcc gcc-4.8 "gcc-objc++" '("obj-c++")
 752               (list (search-path-specification
 753                      (variable "OBJCPLUS_INCLUDE_PATH")
 754                      (files '("include")))
 755                     (search-path-specification
 756                      (variable "LIBRARY_PATH")
 757                      (files '("lib" "lib64"))))))
 758
 759 (define-public gcc-objc++-4.9
 760   (custom-gcc gcc-4.9 "gcc-objc++" '("obj-c++")
 761               (list (search-path-specification
 762                      (variable "OBJCPLUS_INCLUDE_PATH")
 763                      (files '("include")))
 764                     (search-path-specification
 765                      (variable "LIBRARY_PATH")
 766                      (files '("lib" "lib64"))))))
 767
 768 (define-public gcc-objc++-5
 769   (custom-gcc gcc-5 "gcc-objc++" '("obj-c++")
 770               (list (search-path-specification
 771                      (variable "OBJCPLUS_INCLUDE_PATH")
 772                      (files '("include")))
 773                     (search-path-specification
 774                      (variable "LIBRARY_PATH")
 775                      (files '("lib" "lib64"))))))
 776
 777 (define-public gcc-objc++-6
 778   (custom-gcc gcc-6 "gcc-objc++" '("obj-c++")
 779               (list (search-path-specification
 780                      (variable "OBJCPLUS_INCLUDE_PATH")
 781                      (files '("include")))
 782                     (search-path-specification
 783                      (variable "LIBRARY_PATH")
 784                      (files '("lib" "lib64"))))))
 785
 786 (define-public gcc-objc++-7
 787   (custom-gcc gcc-7 "gcc-objc++" '("obj-c++")
 788               (list (search-path-specification
 789                      (variable "OBJCPLUS_INCLUDE_PATH")
 790                      (files '("include")))
 791                     (search-path-specification
 792                      (variable "LIBRARY_PATH")
 793                      (files '("lib" "lib64"))))))
 794
 795 (define-public gcc-objc++-8
 796   (custom-gcc gcc-8 "gcc-objc++" '("obj-c++")
 797               (list (search-path-specification
 798                      (variable "OBJCPLUS_INCLUDE_PATH")
 799                      (files '("include")))
 800                     (search-path-specification
 801                      (variable "LIBRARY_PATH")
 802                      (files '("lib" "lib64"))))))
 803
 804 (define-public gcc-objc++ gcc-objc++-7)
 805
 806 (define (make-libstdc++-doc gcc)
 807   "Return a package with the libstdc++ documentation for GCC."
 808   (package
 809     (inherit gcc)
 810     (name "libstdc++-doc")
 811     (version (package-version gcc))
 812     (synopsis "GNU libstdc++ documentation")
 813     (outputs '("out"))
 814     (native-inputs `(("doxygen" ,doxygen)
 815                      ("texinfo" ,texinfo)
 816                      ("libxml2" ,libxml2)
 817                      ("libxslt" ,libxslt)
 818                      ("docbook-xml" ,docbook-xml)
 819                      ("docbook-xsl" ,docbook-xsl)
 820                      ("graphviz" ,graphviz))) ;for 'dot', invoked by 'doxygen'
 821     (inputs '())
 822     (propagated-inputs '())
 823     (arguments
 824      '(#:out-of-source? #t
 825        #:tests? #f                                ;it's just documentation
 826        #:phases (modify-phases %standard-phases
 827                   (add-before 'configure 'chdir
 828                               (lambda _
 829                                 (chdir "libstdc++-v3")
 830                                 #t))
 831                   (add-before 'configure 'set-xsl-directory
 832                               (lambda* (#:key inputs #:allow-other-keys)
 833                                 (let ((docbook (assoc-ref inputs "docbook-xsl")))
 834                                   (substitute* (find-files "doc"
 835                                                            "^Makefile\\.in$")
 836                                     (("@XSL_STYLE_DIR@")
 837                                      (string-append
 838                                       docbook "/xml/xsl/"
 839                                       (strip-store-file-name docbook))))
 840                                   #t)))
 841                   (replace 'build
 842                            (lambda _
 843                              ;; XXX: There's also a 'doc-info' target, but it
 844                              ;; relies on docbook2X, which itself relies on
 845                              ;; DocBook 4.1.2, which is not really usable
 846                              ;; (lacks a catalog.xml.)
 847                              (invoke "make"
 848                                      "doc-html"
 849                                      "doc-man")))
 850                   (replace 'install
 851                            (lambda* (#:key outputs #:allow-other-keys)
 852                              (let ((out (assoc-ref outputs "out")))
 853                                (invoke "make"
 854                                        "doc-install-html"
 855                                        "doc-install-man")))))))
 856     (properties (alist-delete 'hidden? (package-properties gcc)))))
 857
 858 (define-public libstdc++-doc-5
 859   (make-libstdc++-doc gcc-5))
 860
 861 (define-public libstdc++-doc-9
 862   (make-libstdc++-doc gcc-9))
 863
 864 (define-public isl
 865   (package
 866     (name "isl")
 867     (version "0.21")
 868     (source (origin
 869              (method url-fetch)
 870              (uri (list (string-append
 871                          "http://isl.gforge.inria.fr/isl-"
 872                          version
 873                          ".tar.bz2")
 874                         (string-append %gcc-infrastructure
 875                                        name "-" version ".tar.bz2")))
 876              (sha256
 877               (base32
 878                "0ng8l3q1px9lkzb44nxnzhh6fhdbclrwng9xs2v9m8yii8gs336i"))))
 879     (build-system gnu-build-system)
 880     (inputs `(("gmp" ,gmp)))
 881     (home-page "http://isl.gforge.inria.fr/")
 882     (synopsis
 883      "Manipulating sets and relations of integer points \
 884 bounded by linear constraints")
 885     (description
 886      "isl is a library for manipulating sets and relations of integer points
 887 bounded by linear constraints.  Supported operations on sets include
 888 intersection, union, set difference, emptiness check, convex hull, (integer)
 889 affine hull, integer projection, computing the lexicographic minimum using
 890 parametric integer programming, coalescing and parametric vertex
 891 enumeration.  It also includes an ILP solver based on generalized basis
 892 reduction, transitive closures on maps (which may encode infinite graphs),
 893 dependence analysis and bounds on piecewise step-polynomials.")
 894     (license lgpl2.1+)))
 895
 896 (define-public isl-0.18
 897   (package
 898     (inherit isl)
 899     (version "0.18")
 900     (source (origin
 901               (method url-fetch)
 902               (uri (list (string-append "http://isl.gforge.inria.fr/isl-"
 903                                         version ".tar.bz2")
 904                          (string-append %gcc-infrastructure
 905                                         "isl-" version ".tar.bz2")))
 906               (sha256
 907                (base32
 908                 "06ybml6llhi4i56q90jnimbcgk1lpcdwhy9nxdxra2hxz3bhz2vb"))))))
 909
 910 (define-public isl-0.11
 911   (package
 912     (inherit isl)
 913     (name "isl")
 914     (version "0.11.1")
 915     (source (origin
 916              (method url-fetch)
 917              (uri (list (string-append
 918                          "http://isl.gforge.inria.fr/isl-"
 919                          version
 920                          ".tar.bz2")
 921                         (string-append %gcc-infrastructure
 922                                        name "-" version ".tar.bz2")))
 923              (sha256
 924               (base32
 925                "13d9cqa5rzhbjq0xf0b2dyxag7pqa72xj9dhsa03m8ccr1a4npq9"))
 926              (patches (search-patches "isl-0.11.1-aarch64-support.patch"))))))
 927
 928 (define-public cloog
 929   (package
 930     (name "cloog")
 931     (version "0.18.0")
 932     (source
 933      (origin
 934       (method url-fetch)
 935       (uri (list (string-append
 936                   "http://www.bastoul.net/cloog/pages/download/count.php3?url=cloog-"
 937                   version
 938                   ".tar.gz")
 939                  (string-append %gcc-infrastructure
 940                                 name "-" version ".tar.gz")))
 941       (sha256
 942        (base32
 943         "0a12rwfwp22zd0nlld0xyql11cj390rrq1prw35yjsw8wzfshjhw"))
 944       (file-name (string-append name "-" version ".tar.gz"))))
 945     (build-system gnu-build-system)
 946     (inputs `(("gmp" ,gmp)
 947               ("isl" ,isl-0.11)))
 948     (arguments '(#:configure-flags '("--with-isl=system")))
 949     (home-page "http://www.cloog.org/")
 950     (synopsis "Library to generate code for scanning Z-polyhedra")
 951     (description
 952      "CLooG is a free software library to generate code for scanning
 953 Z-polyhedra.  That is, it finds a code (e.g., in C, FORTRAN...) that
 954 reaches each integral point of one or more parameterized polyhedra.
 955 CLooG has been originally written to solve the code generation problem
 956 for optimizing compilers based on the polytope model.  Nevertheless it
 957 is used now in various area e.g., to build control automata for
 958 high-level synthesis or to find the best polynomial approximation of a
 959 function.  CLooG may help in any situation where scanning polyhedra
 960 matters.  While the user has full control on generated code quality,
 961 CLooG is designed to avoid control overhead and to produce a very
 962 effective code.")
 963     (license gpl2+)))
 964
 965 (define-public gnu-c-manual
 966   (package
 967     (name "gnu-c-manual")
 968     (version "0.2.5")
 969     (source (origin
 970               (method url-fetch)
 971               (uri (string-append "mirror://gnu/gnu-c-manual/gnu-c-manual-"
 972                                   version ".tar.gz"))
 973               (sha256
 974                (base32
 975                 "1sfsj9256w18qzylgag2h5h377aq8in8929svblfnj9svfriqcys"))))
 976     (build-system gnu-build-system)
 977     (native-inputs `(("texinfo" ,texinfo)))
 978     (arguments
 979      '(#:phases (modify-phases %standard-phases
 980                   (delete 'configure)
 981                   (delete 'check)
 982                   (replace 'build
 983                            (lambda _
 984                              (invoke "make"
 985                                      "gnu-c-manual.info"
 986                                      "gnu-c-manual.html")))
 987                   (replace 'install
 988                            (lambda* (#:key outputs #:allow-other-keys)
 989                              (let* ((out (assoc-ref outputs "out"))
 990                                     (info (string-append out "/share/info"))
 991                                     (html (string-append
 992                                            out "/share/doc/gnu-c-manual")))
 993                                (mkdir-p info)
 994                                (mkdir-p html)
 995
 996                                (for-each (lambda (file)
 997                                            (copy-file file
 998                                                       (string-append info "/"
 999                                                                      file)))
1000                                          (find-files "." "\\.info(-[0-9])?$"))
1001                                (for-each (lambda (file)
1002                                            (copy-file file
1003                                                       (string-append html "/"
1004                                                                      file)))
1005                                          (find-files "." "\\.html$"))
1006                                #t))))))
1007     (synopsis "Reference manual for the C programming language")
1008     (description
1009      "This is a reference manual for the C programming language, as
1010 implemented by the GNU C Compiler (gcc).  As a reference, it is not intended
1011 to be a tutorial of the language.  Rather, it outlines all of the constructs
1012 of the language.  Library functions are not included.")
1013     (home-page "https://www.gnu.org/software/gnu-c-manual/")
1014     (license fdl1.3+)))