gnu/packages/nettle.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2017 Efraim Flashner <efraim@flashner.co.il>
   5 ;;;
   6 ;;; This file is part of GNU Guix.
   7 ;;;
   8 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   9 ;;; under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 3 of the License, or (at
  11 ;;; your option) any later version.
  12 ;;;
  13 ;;; GNU Guix is distributed in the hope that it will be useful, but
  14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU General Public License
  19 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 (define-module (gnu packages nettle)
  22   #:use-module (guix utils)
  23   #:use-module (guix licenses)
  24   #:use-module (guix packages)
  25   #:use-module (guix download)
  26   #:use-module (guix build-system gnu)
  27   #:use-module (gnu packages multiprecision)
  28   #:use-module (gnu packages m4))
  29
  30 (define-public nettle-2
  31   (package
  32     (name "nettle")
  33     (version "2.7.1")
  34     (source (origin
  35              (method url-fetch)
  36              (uri (string-append "mirror://gnu/nettle/nettle-"
  37                                  version ".tar.gz"))
  38              (sha256
  39               (base32
  40                "0h2vap31yvi1a438d36lg1r1nllfx3y19r4rfxv7slrm6kafnwdw"))))
  41     (build-system gnu-build-system)
  42     (arguments
  43      ;; 'sexp-conv' and other programs need to have their RUNPATH point to
  44      ;; $libdir, which is not the case by default.  Work around it.
  45      '(#:configure-flags (list (string-append "LDFLAGS=-Wl,-rpath="
  46                                               (assoc-ref %outputs "out")
  47                                               "/lib"))
  48        #:phases (modify-phases %standard-phases
  49                   (add-after 'install 'move-static-libraries
  50                     (lambda* (#:key outputs #:allow-other-keys)
  51                       (let ((out (assoc-ref outputs "out"))
  52                             (slib (string-append (assoc-ref outputs "static")
  53                                                  "/lib")))
  54                         (mkdir-p slib)
  55                         (with-directory-excursion (string-append out "/lib")
  56                           (for-each (lambda (ar)
  57                                       (rename-file ar (string-append
  58                                                        slib "/"
  59                                                        (basename ar))))
  60                                     (find-files "." "\\.a$")))
  61                         #t))))))
  62     (outputs '("out" "debug" "static"))
  63     (native-inputs `(("m4" ,m4)))
  64     (propagated-inputs `(("gmp" ,gmp)))
  65     (home-page "https://www.lysator.liu.se/~nisse/nettle/")
  66     (synopsis "C library for low-level cryptographic functionality")
  67     (description
  68      "GNU Nettle is a low-level cryptographic library.  It is designed to
  69 fit in easily in almost any context.  It can be easily included in
  70 cryptographic toolkits for object-oriented languages or in applications
  71 themselves.")
  72     (license gpl2+)))
  73
  74 (define-public nettle
  75   ;; This version is not API-compatible with version 2.  In particular, lsh
  76   ;; cannot use it yet.  So keep it separate.
  77   (package (inherit nettle-2)
  78     (version "3.5.1")
  79     (source (origin
  80               (method url-fetch)
  81               (uri (string-append "mirror://gnu/nettle/nettle-"
  82                                   version ".tar.gz"))
  83               (sha256
  84                (base32
  85                 "06clvkdfxhlbagn4afssylmn5vrak59dlmnvy8b2xc31hycs3k3m"))))
  86     (arguments
  87      (substitute-keyword-arguments (package-arguments nettle-2)
  88        ((#:configure-flags flags)
  89         ;; Build "fat" binaries where the right implementation is chosen
  90         ;; at run time based on CPU features (starting from 3.1.)
  91         `(cons "--enable-fat" ,flags))))))