doc/build.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;; This file contains machinery to build HTML and PDF copies of the manual
  21 ;; that can be readily published on the web site.  To do that, run:
  22 ;;
  23 ;;  guix build -f build.scm
  24 ;;
  25 ;; The result is a directory hierarchy that can be used as the manual/
  26 ;; sub-directory of the web site.
  27
  28 (use-modules (guix)
  29              (guix gexp)
  30              (guix git)
  31              (guix git-download)
  32              (guix utils)
  33              (git)
  34              (gnu packages base)
  35              (gnu packages gawk)
  36              (gnu packages gettext)
  37              (gnu packages guile)
  38              (gnu packages guile-xyz)
  39              (gnu packages iso-codes)
  40              (gnu packages texinfo)
  41              (gnu packages tex)
  42              (srfi srfi-19)
  43              (srfi srfi-71))
  44
  45 (define file-append*
  46   (@@ (guix self) file-append*))
  47
  48 (define translated-texi-manuals
  49   (@@ (guix self) translate-texi-manuals))
  50
  51 (define info-manual
  52   (@@ (guix self) info-manual))
  53
  54 (define %manual
  55   ;; The manual to build--i.e., the base name of a .texi file, such as "guix"
  56   ;; or "guix-cookbook".
  57   (or (getenv "GUIX_MANUAL")
  58       "guix"))
  59
  60 (define %languages
  61   '("de" "en" "es" "fr" "ru" "zh_CN"))
  62
  63 (define (texinfo-manual-images source)
  64   "Return a directory containing all the images used by the user manual, taken
  65 from SOURCE, the root of the source tree."
  66   (define graphviz
  67     (module-ref (resolve-interface '(gnu packages graphviz))
  68                 'graphviz))
  69
  70   (define images
  71     (file-append* source "doc/images"))
  72
  73   (define build
  74     (with-imported-modules '((guix build utils))
  75       #~(begin
  76           (use-modules (guix build utils)
  77                        (srfi srfi-26))
  78
  79           (define (dot->image dot-file format)
  80             (invoke #+(file-append graphviz "/bin/dot")
  81                     "-T" format "-Gratio=.9" "-Gnodesep=.005"
  82                     "-Granksep=.00005" "-Nfontsize=9"
  83                     "-Nheight=.1" "-Nwidth=.1"
  84                     "-o" (string-append #$output "/"
  85                                         (basename dot-file ".dot")
  86                                         "." format)
  87                     dot-file))
  88
  89           ;; Build graphs.
  90           (mkdir-p #$output)
  91           (for-each (lambda (dot-file)
  92                       (for-each (cut dot->image dot-file <>)
  93                                 '("png" "pdf")))
  94                     (find-files #$images "\\.dot$"))
  95
  96           ;; Copy other PNGs.
  97           (for-each (lambda (png-file)
  98                       (install-file png-file #$output))
  99                     (find-files #$images "\\.png$")))))
 100
 101   (computed-file "texinfo-manual-images" build))
 102
 103 (define* (texinfo-manual-source source #:key
 104                                 (version "0.0")
 105                                 (languages %languages)
 106                                 (date 1))
 107   "Gather all the source files of the Texinfo manuals from SOURCE--.texi file
 108 as well as images, OS examples, and translations."
 109   (define documentation
 110     (file-append* source "doc"))
 111
 112   (define examples
 113     (file-append* source "gnu/system/examples"))
 114
 115   (define build
 116     (with-imported-modules '((guix build utils))
 117       #~(begin
 118           (use-modules (guix build utils)
 119                        (srfi srfi-19))
 120
 121           (define (make-version-texi language)
 122             ;; Create the 'version.texi' file for LANGUAGE.
 123             (let ((file (if (string=? language "en")
 124                             "version.texi"
 125                             (string-append "version-" language ".texi"))))
 126               (call-with-output-file (string-append #$output "/" file)
 127                 (lambda (port)
 128                   (let* ((version #$version)
 129                          (time    (make-time time-utc 0 #$date))
 130                          (date    (time-utc->date time)))
 131                     (format port "
 132 @set UPDATED ~a
 133 @set UPDATED-MONTH ~a
 134 @set EDITION ~a
 135 @set VERSION ~a\n"
 136                             (date->string date "~e ~B ~Y")
 137                             (date->string date "~B ~Y")
 138                             version version))))))
 139
 140           (install-file #$(file-append* documentation "/htmlxref.cnf")
 141                         #$output)
 142
 143           (for-each (lambda (texi)
 144                       (install-file texi #$output))
 145                     (append (find-files #$documentation "\\.(texi|scm)$")
 146                             (find-files #$(translated-texi-manuals source)
 147                                         "\\.texi$")))
 148
 149           ;; Create 'version.texi'.
 150           (for-each make-version-texi '#$languages)
 151
 152           ;; Copy configuration templates that the manual includes.
 153           (for-each (lambda (template)
 154                       (copy-file template
 155                                  (string-append
 156                                   #$output "/os-config-"
 157                                   (basename template ".tmpl")
 158                                   ".texi")))
 159                     (find-files #$examples "\\.tmpl$"))
 160
 161           (symlink #$(texinfo-manual-images source)
 162                    (string-append #$output "/images")))))
 163
 164   (computed-file "texinfo-manual-source" build))
 165
 166 (define %web-site-url
 167   ;; URL of the web site home page.
 168   (or (getenv "GUIX_WEB_SITE_URL")
 169       "/software/guix/"))
 170
 171 (define %makeinfo-html-options
 172   ;; Options passed to 'makeinfo --html'.
 173   '("--css-ref=https://www.gnu.org/software/gnulib/manual.css"
 174     "-c" "EXTRA_HEAD=<meta name=\"viewport\" \
 175 content=\"width=device-width, initial-scale=1\" />"))
 176
 177 (define guile-lib/htmlprag-fixed
 178   ;; Guile-Lib with a hotfix for (htmlprag).
 179   (package
 180     (inherit guile-lib)
 181     (source (origin
 182               (inherit (package-source guile-lib))
 183               (modules '(( guix build utils)))
 184               (snippet
 185                '(begin
 186                   ;; When parsing
 187                   ;; "<body><blockquote><p>foo</p>\n</blockquote></body>",
 188                   ;; 'html->shtml' would mistakenly close 'blockquote' right
 189                   ;; before <p>.  This patch removes 'p' from the
 190                   ;; 'parent-constraints' alist to fix that.
 191                   (substitute* "src/htmlprag.scm"
 192                     (("^[[:blank:]]*\\(p[[:blank:]]+\\. \\(body td th\\)\\).*")
 193                      ""))
 194                   #t))))
 195     (arguments
 196      (substitute-keyword-arguments (package-arguments guile-lib)
 197        ((#:phases phases '%standard-phases)
 198         `(modify-phases ,phases
 199           (add-before 'check 'skip-known-failure
 200             (lambda _
 201               ;; XXX: The above change causes one test failure among
 202               ;; the htmlprag tests.
 203               (setenv "XFAIL_TESTS" "htmlprag.scm")
 204               #t))))))))
 205
 206 (define* (syntax-highlighted-html input
 207                                   #:key
 208                                   (name "highlighted-syntax")
 209                                   (syntax-css-url
 210                                    "/static/base/css/code.css"))
 211   "Return a derivation called NAME that processes all the HTML files in INPUT
 212 to (1) add them a link to SYNTAX-CSS-URL, and (2) highlight the syntax of all
 213 its <pre class=\"lisp\"> blocks (as produced by 'makeinfo --html')."
 214   (define build
 215     (with-extensions (list guile-lib/htmlprag-fixed guile-syntax-highlight)
 216       (with-imported-modules '((guix build utils))
 217         #~(begin
 218             (use-modules (htmlprag)
 219                          (syntax-highlight)
 220                          (syntax-highlight scheme)
 221                          (syntax-highlight lexers)
 222                          (guix build utils)
 223                          (ice-9 match)
 224                          (ice-9 threads))
 225
 226             (define (pair-open/close lst)
 227               ;; Pair 'open' and 'close' tags produced by 'highlights' and
 228               ;; produce nested 'paren' tags instead.
 229               (let loop ((lst lst)
 230                          (level 0)
 231                          (result '()))
 232                 (match lst
 233                   ((('open open) rest ...)
 234                    (call-with-values
 235                        (lambda ()
 236                          (loop rest (+ 1 level) '()))
 237                      (lambda (inner close rest)
 238                        (loop rest level
 239                              (cons `(paren ,level ,open ,inner ,close)
 240                                    result)))))
 241                   ((('close str) rest ...)
 242                    (if (> level 0)
 243                        (values (reverse result) str rest)
 244                        (begin
 245                          (format (current-error-port)
 246                                  "warning: extra closing paren; context:~% ~y~%"
 247                                  (reverse result))
 248                          (loop rest 0 (cons `(close ,str) result)))))
 249                   ((item rest ...)
 250                    (loop rest level (cons item result)))
 251                   (()
 252                    (when (> level 0)
 253                      (format (current-error-port)
 254                              "warning: missing ~a closing parens; context:~% ~y%"
 255                              level (reverse result)))
 256                    (values (reverse result) "" '())))))
 257
 258             (define (highlights->sxml* highlights)
 259               ;; Like 'highlights->sxml', but handle nested 'paren tags.  This
 260               ;; allows for paren matching highlights via appropriate CSS
 261               ;; "hover" properties.
 262               (define (tag->class tag)
 263                 (string-append "syntax-" (symbol->string tag)))
 264
 265               (map (match-lambda
 266                      ((? string? str) str)
 267                      (('paren level open (body ...) close)
 268                       `(span (@ (class ,(string-append "syntax-paren"
 269                                                        (number->string level))))
 270                              ,open
 271                              (span (@ (class "syntax-symbol"))
 272                                    ,@(highlights->sxml* body))
 273                              ,close))
 274                      ((tag text)
 275                       `(span (@ (class ,(tag->class tag))) ,text)))
 276                    highlights))
 277
 278             (define entity->string
 279               (match-lambda
 280                 ("rArr"   "⇒")
 281                 ("rarr"   "→")
 282                 ("hellip" "…")
 283                 ("rsquo"  "’")
 284                 (e (pk 'unknown-entity e) (primitive-exit 2))))
 285
 286             (define (concatenate-snippets pieces)
 287               ;; Concatenate PIECES, which contains strings and entities,
 288               ;; replacing entities with their corresponding string.
 289               (let loop ((pieces pieces)
 290                          (strings '()))
 291                 (match pieces
 292                   (()
 293                    (string-concatenate-reverse strings))
 294                   (((? string? str) . rest)
 295                    (loop rest (cons str strings)))
 296                   ((('*ENTITY* "additional" entity) . rest)
 297                    (loop rest (cons (entity->string entity) strings)))
 298                   ((('span _ lst ...) . rest)     ;for <span class="roman">
 299                    (loop (append lst rest) strings))
 300                   (something
 301                    (pk 'unsupported-code-snippet something)
 302                    (primitive-exit 1)))))
 303
 304             (define (syntax-highlight sxml)
 305               ;; Recurse over SXML and syntax-highlight code snippets.
 306               (match sxml
 307                 (('*TOP* decl body ...)
 308                  `(*TOP* ,decl ,@(map syntax-highlight body)))
 309                 (('head things ...)
 310                  `(head ,@things
 311                         (link (@ (rel "stylesheet")
 312                                  (type "text/css")
 313                                  (href #$syntax-css-url)))))
 314                 (('pre ('@ ('class "lisp")) code-snippet ...)
 315                  `(pre (@ (class "lisp"))
 316                        ,@(highlights->sxml*
 317                           (pair-open/close
 318                            (highlight lex-scheme
 319                                       (concatenate-snippets code-snippet))))))
 320                 ((tag ('@ attributes ...) body ...)
 321                  `(,tag (@ ,@attributes) ,@(map syntax-highlight body)))
 322                 ((tag body ...)
 323                  `(,tag ,@(map syntax-highlight body)))
 324                 ((? string? str)
 325                  str)))
 326
 327             (define (process-html file)
 328               ;; Parse FILE and perform syntax highlighting for its Scheme
 329               ;; snippets.  Install the result to #$output.
 330               (format (current-error-port) "processing ~a...~%" file)
 331               (let* ((shtml        (call-with-input-file file html->shtml))
 332                      (highlighted  (syntax-highlight shtml))
 333                      (base         (string-drop file (string-length #$input)))
 334                      (target       (string-append #$output base)))
 335                 (mkdir-p (dirname target))
 336                 (call-with-output-file target
 337                   (lambda (port)
 338                     (write-shtml-as-html highlighted port)))))
 339
 340             (define (copy-as-is file)
 341               ;; Copy FILE as is to #$output.
 342               (let* ((base   (string-drop file (string-length #$input)))
 343                      (target (string-append #$output base)))
 344                 (mkdir-p (dirname target))
 345                 (catch 'system-error
 346                   (lambda ()
 347                     (if (eq? 'symlink (stat:type (lstat file)))
 348                         (symlink (readlink file) target)
 349                         (link file target)))
 350                   (lambda args
 351                     (let ((errno (system-error-errno args)))
 352                       (pk 'error-link file target (strerror errno))
 353                       (primitive-exit 3))))))
 354
 355             ;; Install a UTF-8 locale so we can process UTF-8 files.
 356             (setenv "GUIX_LOCPATH"
 357                     #+(file-append glibc-utf8-locales "/lib/locale"))
 358             (setlocale LC_ALL "en_US.utf8")
 359
 360             (n-par-for-each (parallel-job-count)
 361                             (lambda (file)
 362                               (if (string-suffix? ".html" file)
 363                                   (process-html file)
 364                                   (copy-as-is file)))
 365                             (find-files #$input))))))
 366
 367   (computed-file name build))
 368
 369 (define* (html-manual source #:key (languages %languages)
 370                       (version "0.0")
 371                       (manual %manual)
 372                       (date 1)
 373                       (options %makeinfo-html-options))
 374   "Return the HTML manuals built from SOURCE for all LANGUAGES, with the given
 375 makeinfo OPTIONS."
 376   (define manual-source
 377     (texinfo-manual-source source
 378                            #:version version
 379                            #:languages languages
 380                            #:date date))
 381
 382   (define images
 383     (texinfo-manual-images source))
 384
 385   (define build
 386     (with-imported-modules '((guix build utils))
 387       #~(begin
 388           (use-modules (guix build utils)
 389                        (ice-9 match))
 390
 391           (define (normalize language)
 392             ;; Normalize LANGUAGE.  For instance, "zh_CN" becomes "zh-cn".
 393             (string-map (match-lambda
 394                           (#\_ #\-)
 395                           (chr chr))
 396                         (string-downcase language)))
 397
 398           (define (language->texi-file-name language)
 399             (if (string=? language "en")
 400                 (string-append #$manual-source "/"
 401                                #$manual ".texi")
 402                 (string-append #$manual-source "/"
 403                                #$manual "." language ".texi")))
 404
 405           ;; Install a UTF-8 locale so that 'makeinfo' is at ease.
 406           (setenv "GUIX_LOCPATH"
 407                   #+(file-append glibc-utf8-locales "/lib/locale"))
 408           (setenv "LC_ALL" "en_US.utf8")
 409
 410           (setvbuf (current-output-port) 'line)
 411           (setvbuf (current-error-port) 'line)
 412
 413           (for-each (lambda (language)
 414                       (let* ((texi (language->texi-file-name language))
 415                              (opts `("--html"
 416                                      "-c" ,(string-append "TOP_NODE_UP_URL=/manual/"
 417                                                          language)
 418                                      #$@options
 419                                      ,texi)))
 420                         (format #t "building HTML manual for language '~a'...~%"
 421                                 language)
 422                         (mkdir-p (string-append #$output "/"
 423                                                 (normalize language)))
 424                         (setenv "LANGUAGE" language)
 425                         (apply invoke #$(file-append texinfo "/bin/makeinfo")
 426                                "-o" (string-append #$output "/"
 427                                                    (normalize language)
 428                                                    "/html_node")
 429                                opts)
 430                         (apply invoke #$(file-append texinfo "/bin/makeinfo")
 431                                "--no-split"
 432                                "-o"
 433                                (string-append #$output "/"
 434                                               (normalize language)
 435                                               "/" #$manual
 436                                               (if (string=? language "en")
 437                                                   ""
 438                                                   (string-append "." language))
 439                                               ".html")
 440                                opts)
 441
 442                         ;; Make sure images are available.
 443                         (symlink #$images
 444                                  (string-append #$output "/" (normalize language)
 445                                                 "/images"))
 446                         (symlink #$images
 447                                  (string-append #$output "/" (normalize language)
 448                                                 "/html_node/images"))))
 449                     (filter (compose file-exists? language->texi-file-name)
 450                             '#$languages)))))
 451
 452   (let* ((name   (string-append manual "-html-manual"))
 453          (manual (computed-file name build)))
 454     (syntax-highlighted-html manual
 455                              #:name (string-append name "-highlighted"))))
 456
 457 (define* (pdf-manual source #:key (languages %languages)
 458                      (version "0.0")
 459                      (manual %manual)
 460                      (date 1)
 461                      (options '()))
 462   "Return the HTML manuals built from SOURCE for all LANGUAGES, with the given
 463 makeinfo OPTIONS."
 464   (define manual-source
 465     (texinfo-manual-source source
 466                            #:version version
 467                            #:languages languages
 468                            #:date date))
 469
 470   ;; FIXME: This union works, except for the table of contents of non-English
 471   ;; manuals, which contains escape sequences like "^^ca^^fe" instead of
 472   ;; accented letters.
 473   ;;
 474   ;; (define texlive
 475   ;;   (texlive-union (list texlive-tex-texinfo
 476   ;;                        texlive-generic-epsf
 477   ;;                        texlive-fonts-ec)))
 478
 479   (define build
 480     (with-imported-modules '((guix build utils))
 481       #~(begin
 482           (use-modules (guix build utils)
 483                        (srfi srfi-34)
 484                        (ice-9 match))
 485
 486           (define (normalize language)            ;XXX: deduplicate
 487             ;; Normalize LANGUAGE.  For instance, "zh_CN" becomes "zh-cn".
 488             (string-map (match-lambda
 489                           (#\_ #\-)
 490                           (chr chr))
 491                         (string-downcase language)))
 492
 493           ;; Install a UTF-8 locale so that 'makeinfo' is at ease.
 494           (setenv "GUIX_LOCPATH"
 495                   #+(file-append glibc-utf8-locales "/lib/locale"))
 496           (setenv "LC_ALL" "en_US.utf8")
 497           (setenv "PATH"
 498                   (string-append #+(file-append texlive "/bin") ":"
 499                                  #+(file-append texinfo "/bin") ":"
 500
 501                                  ;; Below are command-line tools needed by
 502                                  ;; 'texi2dvi' and friends.
 503                                  #+(file-append sed "/bin") ":"
 504                                  #+(file-append grep "/bin") ":"
 505                                  #+(file-append coreutils "/bin") ":"
 506                                  #+(file-append gawk "/bin") ":"
 507                                  #+(file-append tar "/bin") ":"
 508                                  #+(file-append diffutils "/bin")))
 509
 510           (setvbuf (current-output-port) 'line)
 511           (setvbuf (current-error-port) 'line)
 512
 513           (setenv "HOME" (getcwd))                ;for kpathsea/mktextfm
 514
 515           ;; 'SOURCE_DATE_EPOCH' is honored by pdftex.
 516           (setenv "SOURCE_DATE_EPOCH" "1")
 517
 518           (for-each (lambda (language)
 519                       (let ((opts `("--pdf"
 520                                     "-I" "."
 521                                     #$@options
 522                                     ,(if (string=? language "en")
 523                                          (string-append #$manual-source "/"
 524                                                         #$manual ".texi")
 525                                          (string-append #$manual-source "/"
 526                                                         #$manual "." language ".texi")))))
 527                         (format #t "building PDF manual for language '~a'...~%"
 528                                 language)
 529                         (mkdir-p (string-append #$output "/"
 530                                                 (normalize language)))
 531                         (setenv "LANGUAGE" language)
 532
 533
 534                         ;; FIXME: Unfortunately building PDFs for non-Latin
 535                         ;; alphabets doesn't work:
 536                         ;; <https://lists.gnu.org/archive/html/help-texinfo/2012-01/msg00014.html>.
 537                         (guard (c ((invoke-error? c)
 538                                    (format (current-error-port)
 539                                            "~%~%Failed to produce \
 540 PDF for language '~a'!~%~%"
 541                                            language)))
 542                          (apply invoke #$(file-append texinfo "/bin/makeinfo")
 543                                 "--pdf" "-o"
 544                                 (string-append #$output "/"
 545                                                (normalize language)
 546                                                "/" #$manual
 547                                                (if (string=? language "en")
 548                                                    ""
 549                                                    (string-append "."
 550                                                                   language))
 551                                                ".pdf")
 552                                 opts))))
 553                     '#$languages))))
 554
 555   (computed-file (string-append manual "-pdf-manual") build))
 556
 557 (define (guix-manual-text-domain source languages)
 558   "Return the PO files for LANGUAGES of the 'guix-manual' text domain taken
 559 from SOURCE."
 560   (define po-directory
 561     (file-append* source "/po/doc"))
 562
 563   (define build
 564     (with-imported-modules '((guix build utils))
 565       #~(begin
 566           (use-modules (guix build utils))
 567
 568           (mkdir-p #$output)
 569           (for-each (lambda (language)
 570                       (define directory
 571                         (string-append #$output "/" language
 572                                        "/LC_MESSAGES"))
 573
 574                       (mkdir-p directory)
 575                       (invoke #+(file-append gnu-gettext "/bin/msgfmt")
 576                               "-c" "-o"
 577                               (string-append directory "/guix-manual.mo")
 578                               (string-append #$po-directory "/guix-manual."
 579                                              language ".po")))
 580                     '#$(delete "en" languages)))))
 581
 582   (computed-file "guix-manual-po" build))
 583
 584 (define* (html-manual-indexes source
 585                               #:key (languages %languages)
 586                               (version "0.0")
 587                               (manual %manual)
 588                               (title (if (string=? "guix" manual)
 589                                          "GNU Guix Reference Manual"
 590                                          "GNU Guix Cookbook"))
 591                               (date 1))
 592   (define build
 593     (with-extensions (list guile-json-3)
 594       (with-imported-modules '((guix build utils))
 595         #~(begin
 596             (use-modules (guix build utils)
 597                          (json)
 598                          (ice-9 match)
 599                          (ice-9 popen)
 600                          (sxml simple)
 601                          (srfi srfi-1)
 602                          (srfi srfi-19))
 603
 604             (define (normalize language)          ;XXX: deduplicate
 605               ;; Normalize LANGUAGE.  For instance, "zh_CN" becomes "zh-cn".
 606               (string-map (match-lambda
 607                             (#\_ #\-)
 608                             (chr chr))
 609                           (string-downcase language)))
 610
 611             (define-syntax-rule (with-language language exp ...)
 612               (let ((lang (getenv "LANGUAGE")))
 613                 (dynamic-wind
 614                   (lambda ()
 615                     (setenv "LANGUAGE" language)
 616                     (setlocale LC_MESSAGES))
 617                   (lambda () exp ...)
 618                   (lambda ()
 619                     (if lang
 620                         (setenv "LANGUAGE" lang)
 621                         (unsetenv "LANGUAGE"))
 622                     (setlocale LC_MESSAGES)))))
 623
 624             ;; (put 'with-language 'scheme-indent-function 1)
 625             (define* (translate str language
 626                                 #:key (domain "guix-manual"))
 627               (define exp
 628                 `(begin
 629                    (bindtextdomain "guix-manual"
 630                                    #+(guix-manual-text-domain
 631                                       source
 632                                       languages))
 633                    (bindtextdomain "iso_639-3"    ;language names
 634                                    #+(file-append iso-codes
 635                                                   "/share/locale"))
 636                    (write (gettext ,str ,domain))))
 637
 638               (with-language language
 639                 ;; Since the 'gettext' function caches msgid translations,
 640                 ;; regardless of $LANGUAGE, we have to spawn a new process each
 641                 ;; time we want to translate to a different language.  Bah!
 642                 (let* ((pipe (open-pipe* OPEN_READ
 643                                          #+(file-append guile-2.2
 644                                                         "/bin/guile")
 645                                          "-c" (object->string exp)))
 646                        (str  (read pipe)))
 647                   (close-pipe pipe)
 648                   str)))
 649
 650             (define (seconds->string seconds language)
 651               (let* ((time (make-time time-utc 0 seconds))
 652                      (date (time-utc->date time)))
 653                 (with-language language (date->string date "~e ~B ~Y"))))
 654
 655             (define (guix-url path)
 656               (string-append #$%web-site-url path))
 657
 658             (define (sxml-index language title body)
 659               ;; FIXME: Avoid duplicating styling info from guix-artwork.git.
 660               `(html (@ (lang ,language))
 661                      (head
 662                       (title ,(string-append title " — GNU Guix"))
 663                       (meta (@ (charset "UTF-8")))
 664                       (meta (@ (name "viewport") (content "width=device-width, initial-scale=1.0")))
 665                       ;; Menu prefetch.
 666                       (link (@ (rel "prefetch") (href ,(guix-url "menu/index.html"))))
 667                       ;; Base CSS.
 668                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/elements.css"))))
 669                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/common.css"))))
 670                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/messages.css"))))
 671                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/navbar.css"))))
 672                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/breadcrumbs.css"))))
 673                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/buttons.css"))))
 674                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/footer.css"))))
 675
 676                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/page.css"))))
 677                       (link (@ (rel "stylesheet") (href ,(guix-url "static/base/css/post.css")))))
 678                      (body
 679                       (header (@ (class "navbar"))
 680                               (h1 (a (@ (class "branding")
 681                                         (href #$%web-site-url)))
 682                                   (span (@ (class "a11y-offset"))
 683                                         "Guix"))
 684                               (nav (@ (class "menu"))))
 685                       (nav (@ (class "breadcrumbs"))
 686                            (a (@ (class "crumb")
 687                                  (href #$%web-site-url))
 688                               "Home"))
 689                       ,body
 690                       (footer))))
 691
 692             (define (language-index language)
 693               (define title
 694                 (translate #$title language))
 695
 696               (sxml-index
 697                language title
 698                `(main
 699                  (article
 700                   (@ (class "page centered-block limit-width"))
 701                   (h2 ,title)
 702                   (p (@ (class "post-metadata centered-text"))
 703                      #$version " — "
 704                      ,(seconds->string #$date language))
 705
 706                   (div
 707                    (ul
 708                     (li (a (@ (href "html_node"))
 709                            "HTML, with one page per node"))
 710                     (li (a (@ (href
 711                                ,(string-append
 712                                  #$manual
 713                                  (if (string=? language
 714                                                "en")
 715                                      ""
 716                                      (string-append "."
 717                                                     language))
 718                                  ".html")))
 719                            "HTML, entirely on one page"))
 720                     ,@(if (member language '("ru" "zh_CN"))
 721                           '()
 722                           `((li (a (@ (href ,(string-append
 723                                               #$manual
 724                                               (if (string=? language "en")
 725                                                   ""
 726                                                   (string-append "."
 727                                                                  language))
 728                                               ".pdf"))))
 729                                 "PDF")))))))))
 730
 731             (define %iso639-languages
 732               (vector->list
 733                (assoc-ref (call-with-input-file
 734                               #+(file-append iso-codes
 735                                              "/share/iso-codes/json/iso_639-3.json")
 736                             json->scm)
 737                           "639-3")))
 738
 739             (define (language-code->name code)
 740               "Return the full name of a language from its ISO-639-3 code."
 741               (let ((code (match (string-index code #\_)
 742                             (#f    code)
 743                             (index (string-take code index)))))
 744                (any (lambda (language)
 745                       (and (string=? (or (assoc-ref language "alpha_2")
 746                                          (assoc-ref language "alpha_3"))
 747                                      code)
 748                            (assoc-ref language "name")))
 749                     %iso639-languages)))
 750
 751             (define (top-level-index languages)
 752               (define title #$title)
 753               (sxml-index
 754                "en" title
 755                `(main
 756                  (article
 757                   (@ (class "page centered-block limit-width"))
 758                   (h2 ,title)
 759                   (div
 760                    "This document is available in the following
 761 languages:\n"
 762                    (ul
 763                     ,@(map (lambda (language)
 764                              `(li (a (@ (href ,(normalize language)))
 765                                      ,(translate
 766                                        (language-code->name language)
 767                                        language
 768                                        #:domain "iso_639-3"))))
 769                            languages)))))))
 770
 771             (define (write-html file sxml)
 772               (call-with-output-file file
 773                 (lambda (port)
 774                   (display "<!DOCTYPE html>\n" port)
 775                   (sxml->xml sxml port))))
 776
 777             (setenv "GUIX_LOCPATH"
 778                     #+(file-append glibc-utf8-locales "/lib/locale"))
 779             (setenv "LC_ALL" "en_US.utf8")
 780             (setlocale LC_ALL "en_US.utf8")
 781
 782             (for-each (lambda (language)
 783                         (define directory
 784                           (string-append #$output "/"
 785                                          (normalize language)))
 786
 787                         (mkdir-p directory)
 788                         (write-html (string-append directory "/index.html")
 789                                     (language-index language)))
 790                       '#$languages)
 791
 792             (write-html (string-append #$output "/index.html")
 793                         (top-level-index '#$languages))))))
 794
 795   (computed-file "html-indexes" build))
 796
 797 (define* (pdf+html-manual source
 798                           #:key (languages %languages)
 799                           (version "0.0")
 800                           (date (time-second (current-time time-utc)))
 801                           (manual %manual))
 802   "Return the union of the HTML and PDF manuals, as well as the indexes."
 803   (directory-union (string-append manual "-manual")
 804                    (map (lambda (proc)
 805                           (proc source
 806                                 #:date date
 807                                 #:languages languages
 808                                 #:version version
 809                                 #:manual manual))
 810                         (list html-manual-indexes
 811                               html-manual pdf-manual))
 812                    #:copy? #t))
 813
 814 (define (latest-commit+date directory)
 815   "Return two values: the last commit ID (a hex string) for DIRECTORY, and its
 816 commit date (an integer)."
 817   (let* ((repository (repository-open directory))
 818          (head       (repository-head repository))
 819          (oid        (reference-target head))
 820          (commit     (commit-lookup repository oid)))
 821     ;; TODO: Use (git describe) when it's widely available.
 822     (values (oid->string oid) (commit-time commit))))
 823
 824 \f
 825 (let* ((root (canonicalize-path
 826               (string-append (current-source-directory) "/..")))
 827        (commit date (latest-commit+date root)))
 828   (format (current-error-port)
 829           "building manual from work tree around commit ~a, ~a~%"
 830           commit
 831           (let* ((time (make-time time-utc 0 date))
 832                  (date (time-utc->date time)))
 833             (date->string date "~e ~B ~Y")))
 834   (pdf+html-manual (local-file root "guix" #:recursive? #t
 835                                #:select? (git-predicate root))
 836                    #:version (or (getenv "GUIX_MANUAL_VERSION")
 837                                  (string-take commit 7))
 838                    #:date date))