configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.11.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 AC_ARG_WITH([zsh-completion-dir],
  45   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  46     [name of the Zsh completion directory]),
  47   [zshcompletiondir="$withval"],
  48   [zshcompletiondir='${datadir}/zsh/site-functions'])
  49 AC_SUBST([zshcompletiondir])
  50
  51 dnl Better be verbose.
  52 AC_MSG_CHECKING([for the store directory])
  53 AC_MSG_RESULT([$storedir])
  54
  55 AC_ARG_ENABLE([daemon],
  56   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  57   [guix_build_daemon="$enableval"],
  58   [guix_build_daemon="yes"])
  59
  60 # Prepare a version of $localstatedir & co. that does not contain references
  61 # to shell variables.
  62 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  63 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  64 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  65 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  66 AC_SUBST([guix_localstatedir])
  67 AC_SUBST([guix_sysconfdir])
  68 AC_SUBST([guix_sbindir])
  69
  70 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  71 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  72
  73 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  74 dnl Make sure they are available.
  75 m4_pattern_forbid([PKG_CHECK_MODULES])
  76 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  77
  78 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  79 AC_PATH_PROG([GUILE], [guile])
  80 AC_PATH_PROG([GUILD], [guild])
  81 if test "x$GUILD" = "x"; then
  82    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  83 fi
  84
  85 dnl guile-json is used for the PyPI package importer
  86 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  87 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  88
  89 dnl Make sure we have a full-fledged Guile.
  90 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  91
  92 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  93 GUIX_CHECK_SRFI_37
  94 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  95
  96 dnl Decompressors, for use by the substituter and other modules.
  97 AC_PATH_PROG([GZIP], [gzip])
  98 AC_PATH_PROG([BZIP2], [bzip2])
  99 AC_PATH_PROG([XZ], [xz])
 100 AC_SUBST([GZIP])
 101 AC_SUBST([BZIP2])
 102 AC_SUBST([XZ])
 103
 104 AC_ARG_WITH([nix-prefix],
 105   [AS_HELP_STRING([--with-nix-prefix=DIR],
 106     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 107   [case "$withval" in
 108     yes|no) ;;
 109     *)
 110       NIX_PREFIX="$withval"
 111       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 112       AC_SUBST([NIX_PREFIX])
 113       ;;
 114    esac],
 115   [])
 116
 117 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 118 AC_PATH_PROG([NIX_HASH], [nix-hash])
 119 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 120    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 121 fi
 122
 123 if test "x$NIX_INSTANTIATE" = "x"; then
 124    # This program is an optional dependency, so we just want it to be
 125    # taken from $PATH if it's not available right now.
 126    NIX_INSTANTIATE="nix-instantiate"
 127 fi
 128
 129 AC_ARG_WITH([nixpkgs],
 130   [AS_HELP_STRING([--with-nixpkgs=DIR],
 131     [search for Nixpkgs in DIR (for testing purposes only)])],
 132   [case "$withval" in
 133     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 134     *)      NIXPKGS="$withval";;
 135    esac],
 136   [])
 137
 138 AC_MSG_CHECKING([for Nixpkgs source tree])
 139 if test -f "$NIXPKGS/default.nix"; then
 140    AC_MSG_RESULT([$NIXPKGS])
 141    AC_SUBST([NIXPKGS])
 142 else
 143    AC_MSG_RESULT([not found])
 144 fi
 145
 146 LIBGCRYPT="libgcrypt"
 147 LIBGCRYPT_LIBDIR="no"
 148 LIBGCRYPT_PREFIX="no"
 149
 150 AC_ARG_WITH([libgcrypt-prefix],
 151   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 152   [case "$withval" in
 153     yes|no)
 154       ;;
 155     *)
 156       LIBGCRYPT="$withval/lib/libgcrypt"
 157       LIBGCRYPT_PREFIX="$withval"
 158       LIBGCRYPT_LIBDIR="$withval/lib"
 159       ;;
 160    esac])
 161
 162 AC_ARG_WITH([libgcrypt-libdir],
 163   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 164      [search for GNU libgcrypt's shared library in DIR])],
 165   [case "$withval" in
 166     yes|no)
 167       LIBGCRYPT="libgcrypt"
 168       LIBGCRYPT_LIBDIR="no"
 169       ;;
 170     *)
 171       LIBGCRYPT="$withval/libgcrypt"
 172       LIBGCRYPT_LIBDIR="$withval"
 173       ;;
 174    esac])
 175
 176 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 177 dnl absolute file name of libgcrypt.so.
 178 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 179   xnono)
 180     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 181     if test "x$LIBGCRYPT_LIBDIR" != x; then
 182       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 183     else
 184       dnl 'config-daemon.ac' expects "no" in this case.
 185       LIBGCRYPT_LIBDIR="no"
 186     fi
 187     ;;
 188 esac
 189
 190 dnl Library name suitable for `dynamic-link'.
 191 AC_MSG_CHECKING([for libgcrypt shared library name])
 192 AC_MSG_RESULT([$LIBGCRYPT])
 193 AC_SUBST([LIBGCRYPT])
 194 AC_SUBST([LIBGCRYPT_PREFIX])
 195 AC_SUBST([LIBGCRYPT_LIBDIR])
 196
 197 GUIX_ASSERT_LIBGCRYPT_USABLE
 198
 199 dnl Library name of zlib suitable for 'dynamic-link'.
 200 GUIX_LIBZ_LIBDIR([libz_libdir])
 201 if test "x$libz_libdir" = "x"; then
 202   LIBZ="libz"
 203 else
 204   LIBZ="$libz_libdir/libz"
 205 fi
 206 AC_MSG_CHECKING([for zlib's shared library name])
 207 AC_MSG_RESULT([$LIBZ])
 208 AC_SUBST([LIBZ])
 209
 210 AC_CACHE_SAVE
 211
 212 m4_include([config-daemon.ac])
 213
 214 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 215 dnl See `Building from Git' in the manual for more info.
 216 AM_MISSING_PROG([DOT], [dot])
 217
 218 dnl Manual pages.
 219 AM_MISSING_PROG([HELP2MAN], [help2man])
 220
 221 AC_CONFIG_FILES([Makefile
 222                  po/guix/Makefile.in
 223                  po/packages/Makefile.in
 224                  guix/config.scm])
 225
 226 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 227 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 228 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 229   [chmod +x pre-inst-env])
 230
 231 dnl Emacs interface.
 232 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 233 AM_PATH_LISPDIR
 234 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 235
 236 emacsuidir="${guilemoduledir}/guix/emacs"
 237 AC_SUBST([emacsuidir])
 238 AC_CONFIG_FILES([emacs/guix-config.el
 239                  emacs/guix-helper.scm])
 240
 241 AC_OUTPUT