gnu/packages/ncurses.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014, 2016 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015, 2017 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2016 Nils Gillmann <ng0@n0.is>
   6 ;;; Copyright © 2016 Efraim Flashner <efraim@flashner.co.il>
   7 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
   8 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
   9 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  10 ;;;
  11 ;;; This file is part of GNU Guix.
  12 ;;;
  13 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  14 ;;; under the terms of the GNU General Public License as published by
  15 ;;; the Free Software Foundation; either version 3 of the License, or (at
  16 ;;; your option) any later version.
  17 ;;;
  18 ;;; GNU Guix is distributed in the hope that it will be useful, but
  19 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;;; GNU General Public License for more details.
  22 ;;;
  23 ;;; You should have received a copy of the GNU General Public License
  24 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 (define-module (gnu packages ncurses)
  27   #:use-module (gnu packages)
  28   #:use-module (guix licenses)
  29   #:use-module (guix packages)
  30   #:use-module (guix download)
  31   #:use-module (guix build-system gnu)
  32   #:use-module (guix build-system perl)
  33   #:use-module (gnu packages)
  34   #:use-module (gnu packages perl)
  35   #:use-module (gnu packages pkg-config)
  36   #:use-module (gnu packages swig)
  37   #:use-module (gnu packages linux)
  38   #:use-module (guix utils))
  39
  40 (define-public ncurses
  41   (package
  42     (name "ncurses")
  43     (version "6.1")
  44     (source (origin
  45               (method url-fetch)
  46               (uri (string-append "mirror://gnu/ncurses/ncurses-"
  47                                   (car (string-split version #\-))
  48                                   ".tar.gz"))
  49               (sha256
  50                (base32
  51                 "05qdmbmrrn88ii9f66rkcmcyzp1kb1ymkx7g040lfkd1nkp7w1da"))))
  52     (build-system gnu-build-system)
  53     (outputs '("out"
  54                "doc"))                ;1 MiB of man pages
  55     (arguments
  56      (let ((patch-makefile-phase
  57             '(lambda _
  58                (for-each patch-makefile-SHELL
  59                          (find-files "." "Makefile.in"))
  60                #t))
  61            (configure-phase
  62             ;; The 'configure' script does not understand '--docdir', so we must
  63             ;; override that and use '--mandir' instead.
  64             '(lambda* (#:key build target outputs configure-flags
  65                        #:allow-other-keys)
  66                (let ((out (assoc-ref outputs "out"))
  67                      (doc (assoc-ref outputs "doc")))
  68                  (apply invoke "./configure"
  69                         (string-append "SHELL=" (which "sh"))
  70                         (string-append "--build=" build)
  71                         (string-append "--prefix=" out)
  72                         (string-append "--mandir=" doc "/share/man")
  73                         (if target
  74                             (cons (string-append "--host=" target)
  75                                   configure-flags)
  76                             configure-flags))
  77                  #t)))
  78            (apply-rollup-patch-phase
  79             ;; Ncurses distributes "stable" patchsets to be applied on top
  80             ;; of the release tarball.  These are only available as shell
  81             ;; scripts(!) so we decompress and apply them in a phase.
  82             ;; See <https://invisible-mirror.net/archives/ncurses/6.1/README>.
  83             '(lambda* (#:key inputs native-inputs #:allow-other-keys)
  84                (copy-file (assoc-ref (or native-inputs inputs) "rollup-patch")
  85                           (string-append (getcwd) "/rollup-patch.sh.bz2"))
  86                (invoke "bzip2" "-d" "rollup-patch.sh.bz2")
  87                (invoke "sh" "rollup-patch.sh")
  88                #t))
  89            (remove-shebang-phase
  90             '(lambda _
  91                ;; To avoid retaining a reference to the bootstrap Bash via the
  92                ;; shebang of the 'ncursesw6-config' script, simply remove that
  93                ;; shebang: it'll work just as well without it.  Likewise, do not
  94                ;; retain a reference to the "doc" output.
  95                (substitute* "misc/ncurses-config.in"
  96                  (("#!@SHELL@")
  97                   "# No shebang here, use /bin/sh!\n")
  98                  (("@SHELL@ \\$0")
  99                   "$0")
 100                  (("mandir=.*$")
 101                   "mandir=share/man"))
 102                #t))
 103            (post-install-phase
 104             `(lambda* (#:key outputs #:allow-other-keys)
 105                (let ((out (assoc-ref outputs "out")))
 106                  ;; When building a wide-character (Unicode) build, create backward
 107                  ;; compatibility links from the the "normal" libraries to the
 108                  ;; wide-character ones (e.g. libncurses.so to libncursesw.so).
 109                  ,@(if (target-mingw?)
 110                        '( ;; TODO: create .la files to link to the .dll?
 111                          (with-directory-excursion (string-append out "/bin")
 112                            (for-each
 113                             (lambda (lib)
 114                               (define lib.dll
 115                                 (string-append "lib" lib ".dll"))
 116                               (define libw6.dll
 117                                 (string-append "lib" lib "w6.dll"))
 118
 119                               (when (file-exists? libw6.dll)
 120                                 (format #t "creating symlinks for `lib~a'~%" lib)
 121                                 (symlink libw6.dll lib.dll)))
 122                             '("curses" "ncurses" "form" "panel" "menu"))))
 123                        '())
 124                  (with-directory-excursion (string-append out "/lib")
 125                    (for-each (lambda (lib)
 126                                (define libw.a
 127                                  (string-append "lib" lib "w.a"))
 128                                (define lib.a
 129                                  (string-append "lib" lib ".a"))
 130
 131                                ,@(if (not (target-mingw?))
 132                                      '((define libw.so.x
 133                                          (string-append "lib" lib "w.so.6"))
 134                                        (define lib.so.x
 135                                          (string-append "lib" lib ".so.6"))
 136                                        (define lib.so
 137                                          (string-append "lib" lib ".so"))
 138                                        (define packagew.pc
 139                                          (string-append lib "w.pc"))
 140                                        (define package.pc
 141                                          (string-append lib ".pc")))
 142                                      '())
 143
 144                                (when (file-exists? libw.a)
 145                                  (format #t "creating symlinks for `lib~a'~%" lib)
 146                                  (symlink libw.a lib.a)
 147                                  ,@(if (not (target-mingw?))
 148                                        '((symlink libw.so.x lib.so.x)
 149                                          (false-if-exception (delete-file lib.so))
 150                                          (call-with-output-file lib.so
 151                                            (lambda (p)
 152                                              (format p "INPUT (-l~aw)~%" lib)))
 153                                          (with-directory-excursion "pkgconfig"
 154                                            (format #t "creating symlink for `~a'~%"
 155                                                    package.pc)
 156                                            (when (file-exists? packagew.pc)
 157                                              (symlink packagew.pc package.pc))))
 158                                        '())))
 159                              '("curses" "ncurses" "form" "panel" "menu")))
 160                  #t))))
 161        `(#:configure-flags
 162          ,(cons*
 163            'quasiquote
 164            `(("--with-shared" "--without-debug" "--enable-widec"
 165
 166               "--enable-pc-files"
 167               ,(list 'unquote '(string-append "--with-pkg-config-libdir="
 168                                               (assoc-ref %outputs "out")
 169                                               "/lib/pkgconfig"))
 170
 171               ;; By default headers land in an `ncursesw' subdir, which is not
 172               ;; what users expect.
 173               ,(list 'unquote '(string-append "--includedir=" (assoc-ref %outputs "out")
 174                                               "/include"))
 175               "--enable-overwrite"      ;really honor --includedir
 176
 177               ;; Make sure programs like 'tic', 'reset', and 'clear' have a
 178               ;; correct RUNPATH.
 179               ,(list 'unquote '(string-append "LDFLAGS=-Wl,-rpath=" (assoc-ref %outputs "out")
 180                                               "/lib"))
 181
 182               ;; Starting from ncurses 6.1, "make install" runs "install -s"
 183               ;; by default, which doesn't work for cross-compiled binaries
 184               ;; because it invokes 'strip' instead of 'TRIPLET-strip'.  Work
 185               ;; around this.
 186               ,@(if (%current-target-system) '("--disable-stripping") '())
 187
 188               ;; MinGW: Use term-driver created for the MinGW port.
 189               ,@(if (target-mingw?) '("--enable-term-driver") '()))))
 190          #:tests? #f                  ; no "check" target
 191          #:phases (modify-phases %standard-phases
 192                     (replace 'configure ,configure-phase)
 193                     (add-after 'install 'post-install
 194                       ,post-install-phase)
 195                     (add-before 'configure 'patch-makefile-SHELL
 196                       ,patch-makefile-phase)
 197                     (add-after 'unpack 'remove-unneeded-shebang
 198                       ,remove-shebang-phase)))))
 199     (self-native-input? #t)           ; for `tic'
 200     (native-inputs
 201      `(("pkg-config" ,pkg-config)))
 202     (native-search-paths
 203      (list (search-path-specification
 204             (variable "TERMINFO_DIRS")
 205             (files '("share/terminfo")))))
 206     (synopsis "Terminal emulation (termcap, terminfo) library")
 207     (description
 208      "GNU Ncurses is a library which provides capabilities to write text to
 209 a terminal in a terminal-independent manner.  It supports pads and color as
 210 well as multiple highlights and forms characters.  It is typically used to
 211 implement user interfaces for command-line applications.  The accompanying
 212 ncursesw library provides wide character support.")
 213     (license x11)
 214     (home-page "https://www.gnu.org/software/ncurses/")))
 215
 216 (define-public ncurses/gpm
 217   (package/inherit ncurses
 218     (name "ncurses-with-gpm")
 219     (arguments
 220      (substitute-keyword-arguments (package-arguments ncurses)
 221        ((#:configure-flags cf)
 222         `(cons (string-append "--with-gpm="
 223                               (assoc-ref %build-inputs "gpm")
 224                               "/lib/libgpm.so.2")
 225                ,cf))))
 226     (inputs
 227      `(("gpm" ,gpm)))))
 228
 229 (define-public dialog
 230   (package
 231     (name "dialog")
 232     (version "1.3-20180621")
 233     (source (origin
 234               (method url-fetch)
 235               (uri (string-append
 236                     "http://invisible-mirror.net/archives/dialog/dialog-"
 237                     version ".tgz"))
 238               (sha256
 239                (base32
 240                 "0yjqczlf64yppgvk4i6s0jm06mdr0mb5m6sj39nf891dnbi5jj2a"))))
 241     (build-system gnu-build-system)
 242     (arguments
 243      `(#:tests? #f))                    ; no test suite
 244     (inputs
 245      `(("ncurses" ,ncurses)))
 246     (synopsis "Curses widgets")
 247     (description "Dialog is a script-interpreter which provides a set of
 248 curses widgets, such as dialog boxes.")
 249     (home-page "https://invisible-island.net/dialog/dialog.html")
 250     ;; Includes the gpl3 file "config.sub" from Automake.
 251     (license (list lgpl2.1 gpl3))))
 252
 253 (define-public perl-curses
 254   (package
 255     (name "perl-curses")
 256     (version "1.36")
 257     (source
 258      (origin
 259        (method url-fetch)
 260        (uri (string-append "mirror://cpan/authors/id/G/GI/GIRAFFED/"
 261                            "Curses-" version ".tar.gz"))
 262        (sha256
 263         (base32
 264          "0r6xd9wr0c25rr28zixhqipak575zqsfb7r7f2693i9il1dpj554"))))
 265     (build-system perl-build-system)
 266     (inputs
 267      `(("ncurses" ,ncurses)))
 268     (arguments
 269      `(#:make-maker-flags (list "PANELS" "MENUS")
 270        #:phases
 271        (modify-phases %standard-phases
 272          (add-before
 273            'configure 'set-curses-ldflags
 274            (lambda* (#:key inputs #:allow-other-keys)
 275              (let* ((ncurses (assoc-ref inputs "ncurses"))
 276                     (include (string-append ncurses "/include"))
 277                     (lib (string-append ncurses "/lib")))
 278                (setenv "CURSES_LIBTYPE" "ncurses")
 279                (setenv "CURSES_CFLAGS" (string-append "-I" include))
 280                (setenv "CURSES_PANEL_CFLAGS" (string-append "-I" include))
 281                (setenv "CURSES_MENU_CFLAGS" (string-append "-I" include))
 282                (setenv "CURSES_FORM_CFLAGS" (string-append "-I" include))
 283                (setenv "CURSES_LDFLAGS" (string-append "-L" lib " -lncurses"))
 284                (setenv "CURSES_PANEL_LDFLAGS" (string-append "-L" lib " -lpanel"))
 285                (setenv "CURSES_MENU_LDFLAGS" (string-append "-L" lib " -lmenu"))
 286                (setenv "CURSES_FORM_LDFLAGS" (string-append "-L" lib " -lform"))
 287                #t))))))
 288     (home-page "https://metacpan.org/release/Curses")
 289     (synopsis "Terminal screen handling and optimization")
 290     (description
 291      "@code{Curses} is the interface between Perl and the curses library
 292 of your system.")
 293     (license perl-license)))
 294
 295 (define-public stfl
 296   (package
 297     (name "stfl")
 298     (version "0.24")
 299     (source
 300       (origin
 301         (method url-fetch)
 302         (uri (string-append "http://www.clifford.at/stfl/stfl-"
 303                             version ".tar.gz"))
 304         (sha256
 305          (base32
 306           "1460d5lc780p3q38l3wc9jfr2a7zlyrcra0li65aynj738cam9yl"))))
 307     (build-system gnu-build-system)
 308     (arguments
 309      '(#:tests? #f ; no test target
 310        #:make-flags (list (string-append "prefix=" (assoc-ref %outputs "out")))
 311        #:phases
 312        (modify-phases %standard-phases
 313          (delete 'configure) ; there is no configure script
 314          ;; in our ncurses, the headers are in /include
 315          (add-before 'build 'patch-ncursesw
 316            (lambda _
 317              (substitute* "stfl_internals.h"
 318                (("ncursesw/") ""))
 319              #t))
 320          (add-after 'install 'install-missing-symlink
 321            (lambda* (#:key outputs #:allow-other-keys)
 322              (let* ((out (assoc-ref outputs "out"))
 323                     (lib (string-append out "/lib")))
 324                ;; Some programs look for libstfl.so.0.
 325                (symlink "libstfl.so" (string-append lib "/libstfl.so.0"))))))))
 326     (inputs `(("ncurses" ,ncurses)))
 327     (native-inputs `(("swig" ,swig)))
 328     (home-page "http://www.clifford.at/stfl/")
 329     (synopsis "Structured terminal forms library")
 330     (description "Stfl is a library which implements a curses-based widget
 331 set for text terminals.")
 332     (license lgpl3+)))