configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P$])
  91
  92 dnl Search for 'guile' and 'guild'.  This macro defines
  93 dnl 'GUILE_EFFECTIVE_VERSION'.
  94 GUILE_PKG([2.2 2.0])
  95 GUILE_PROGS
  96 if test "x$GUILD" = "x"; then
  97    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  98 fi
  99
 100 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
 101   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
 102 fi
 103
 104 dnl Installation directories for .scm and .go files.
 105 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 106 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 107 AC_SUBST([guilemoduledir])
 108 AC_SUBST([guileobjectdir])
 109
 110 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 111 dnl pull', among other things.
 112 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 113 if test "x$have_gnutls" != "xyes"; then
 114   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 115 fi
 116
 117 dnl Check for Guile-Git.
 118 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 119 if test "x$have_guile_git" != "xyes"; then
 120   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 121 fi
 122
 123 dnl Guile-JSON is used in various places.
 124 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 125 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 126
 127 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 128 GUIX_CHECK_GUILE_SQLITE3
 129 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 130   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 131 fi
 132
 133 dnl Make sure we have a full-fledged Guile.
 134 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 135
 136 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 137 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 138 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 139
 140 AC_PROG_SED
 141
 142 dnl Decompressors, for use by the substituter and other modules.
 143 AC_PATH_PROG([GZIP], [gzip])
 144 AC_PATH_PROG([BZIP2], [bzip2])
 145 AC_PATH_PROG([XZ], [xz])
 146 AC_SUBST([GZIP])
 147 AC_SUBST([BZIP2])
 148 AC_SUBST([XZ])
 149
 150 AC_ARG_WITH([nix-prefix],
 151   [AS_HELP_STRING([--with-nix-prefix=DIR],
 152     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 153   [case "$withval" in
 154     yes|no) ;;
 155     *)
 156       NIX_PREFIX="$withval"
 157       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 158       AC_SUBST([NIX_PREFIX])
 159       ;;
 160    esac],
 161   [])
 162
 163 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 164 AC_PATH_PROG([NIX_HASH], [nix-hash])
 165 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 166    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 167 fi
 168
 169 if test "x$NIX_INSTANTIATE" = "x"; then
 170    # This program is an optional dependency, so we just want it to be
 171    # taken from $PATH if it's not available right now.
 172    NIX_INSTANTIATE="nix-instantiate"
 173 fi
 174
 175 AC_ARG_WITH([nixpkgs],
 176   [AS_HELP_STRING([--with-nixpkgs=DIR],
 177     [search for Nixpkgs in DIR (for testing purposes only)])],
 178   [case "$withval" in
 179     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 180     *)      NIXPKGS="$withval";;
 181    esac],
 182   [])
 183
 184 AC_MSG_CHECKING([for Nixpkgs source tree])
 185 if test -f "$NIXPKGS/default.nix"; then
 186    AC_MSG_RESULT([$NIXPKGS])
 187    AC_SUBST([NIXPKGS])
 188 else
 189    AC_MSG_RESULT([not found])
 190 fi
 191
 192 LIBGCRYPT="libgcrypt"
 193 LIBGCRYPT_LIBDIR="no"
 194 LIBGCRYPT_PREFIX="no"
 195
 196 AC_ARG_WITH([libgcrypt-prefix],
 197   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 198   [case "$withval" in
 199     yes|no)
 200       ;;
 201     *)
 202       LIBGCRYPT="$withval/lib/libgcrypt"
 203       LIBGCRYPT_PREFIX="$withval"
 204       LIBGCRYPT_LIBDIR="$withval/lib"
 205       ;;
 206    esac])
 207
 208 AC_ARG_WITH([libgcrypt-libdir],
 209   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 210      [search for GNU libgcrypt's shared library in DIR])],
 211   [case "$withval" in
 212     yes|no)
 213       LIBGCRYPT="libgcrypt"
 214       LIBGCRYPT_LIBDIR="no"
 215       ;;
 216     *)
 217       LIBGCRYPT="$withval/libgcrypt"
 218       LIBGCRYPT_LIBDIR="$withval"
 219       ;;
 220    esac])
 221
 222 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 223 dnl absolute file name of libgcrypt.so.
 224 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 225   xnono)
 226     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 227     if test "x$LIBGCRYPT_LIBDIR" != x; then
 228       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 229     else
 230       dnl 'config-daemon.ac' expects "no" in this case.
 231       LIBGCRYPT_LIBDIR="no"
 232     fi
 233     ;;
 234 esac
 235
 236 dnl Library name suitable for `dynamic-link'.
 237 AC_MSG_CHECKING([for libgcrypt shared library name])
 238 AC_MSG_RESULT([$LIBGCRYPT])
 239 AC_SUBST([LIBGCRYPT])
 240 AC_SUBST([LIBGCRYPT_PREFIX])
 241 AC_SUBST([LIBGCRYPT_LIBDIR])
 242
 243 GUIX_ASSERT_LIBGCRYPT_USABLE
 244
 245 dnl Library name of zlib suitable for 'dynamic-link'.
 246 GUIX_LIBZ_LIBDIR([libz_libdir])
 247 if test "x$libz_libdir" = "x"; then
 248   LIBZ="libz"
 249 else
 250   LIBZ="$libz_libdir/libz"
 251 fi
 252 AC_MSG_CHECKING([for zlib's shared library name])
 253 AC_MSG_RESULT([$LIBZ])
 254 AC_SUBST([LIBZ])
 255
 256 dnl Check for Guile-SSH, for the (guix ssh) module.
 257 GUIX_CHECK_GUILE_SSH
 258 AM_CONDITIONAL([HAVE_GUILE_SSH],
 259   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 260
 261 AC_CACHE_SAVE
 262
 263 m4_include([config-daemon.ac])
 264
 265 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 266 dnl See `Building from Git' in the manual for more info.
 267 AM_MISSING_PROG([DOT], [dot])
 268
 269 dnl Manual pages.
 270 AM_MISSING_PROG([HELP2MAN], [help2man])
 271
 272 dnl Documentation translation.
 273 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 274 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 275
 276 dnl Emacs (optional), for 'etc/indent-package.el'.
 277 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 278 AC_SUBST([EMACS])
 279
 280 case "$storedir" in
 281   /gnu/store)
 282     ;;
 283   *)
 284     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 285     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 286     ;;
 287 esac
 288
 289 AC_CONFIG_FILES([Makefile
 290                  po/guix/Makefile.in
 291                  po/packages/Makefile.in
 292                  etc/guix-daemon.cil
 293                  guix/config.scm])
 294
 295 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 296 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 297   [chmod +x pre-inst-env])
 298 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 299
 300 AC_OUTPUT