gnu/packages/libffi.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014 Federico Beffa <beffa@fbengineering.ch>
   4 ;;; Copyright © 2015, 2019 Ricardo Wurmus <ricardo.wurmus@mdc-berlin.de>
   5 ;;; Copyright © 2016, 2017 Efraim Flashner <efraim@flashner.co.il>
   6 ;;; Copyright © 2016, 2017 Ben Woodcroft <donttrustben@gmail.com>
   7 ;;; Copyright © 2017, 2019 Marius Bakke <mbakke@fastmail.com>
   8 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
   9 ;;; Copyright © 2019 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  10 ;;;
  11 ;;; This file is part of GNU Guix.
  12 ;;;
  13 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  14 ;;; under the terms of the GNU General Public License as published by
  15 ;;; the Free Software Foundation; either version 3 of the License, or (at
  16 ;;; your option) any later version.
  17 ;;;
  18 ;;; GNU Guix is distributed in the hope that it will be useful, but
  19 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;;; GNU General Public License for more details.
  22 ;;;
  23 ;;; You should have received a copy of the GNU General Public License
  24 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 (define-module (gnu packages libffi)
  27   #:use-module (gnu packages)
  28   #:use-module (guix licenses)
  29   #:use-module (guix packages)
  30   #:use-module (guix download)
  31   #:use-module (gnu packages check)
  32   #:use-module (gnu packages pkg-config)
  33   #:use-module (gnu packages python)
  34   #:use-module (gnu packages python-xyz)
  35   #:use-module (gnu packages ruby)
  36   #:use-module (gnu packages sphinx)
  37   #:use-module (guix build-system gnu)
  38   #:use-module (guix build-system python)
  39   #:use-module (guix build-system ruby))
  40
  41 (define-public libffi
  42   (package
  43     (name "libffi")
  44     (version "3.3")
  45     (source (origin
  46               (method url-fetch)
  47               (uri
  48                (string-append "ftp://sourceware.org/pub/libffi/"
  49                               name "-" version ".tar.gz"))
  50               (sha256
  51                (base32
  52                 "0mi0cpf8aa40ljjmzxb7im6dbj45bb0kllcd09xgmp834y9agyvj"))))
  53     (build-system gnu-build-system)
  54     (arguments
  55      `(;; Prevent the build system from passing -march and -mtune to the
  56        ;; compiler.  See "ax_cc_maxopt.m4" and "ax_gcc_archflag.m4".
  57        #:configure-flags '("--enable-portable-binary" "--without-gcc-arch")))
  58     (outputs '("out" "debug"))
  59     (synopsis "Foreign function call interface library")
  60     (description
  61      "The libffi library provides a portable, high level programming interface
  62 to various calling conventions.  This allows a programmer to call any
  63 function specified by a call interface description at run-time.
  64
  65 FFI stands for Foreign Function Interface.  A foreign function interface is
  66 the popular name for the interface that allows code written in one language
  67 to call code written in another language.  The libffi library really only
  68 provides the lowest, machine dependent layer of a fully featured foreign
  69 function interface.  A layer must exist above libffi that handles type
  70 conversions for values passed between the two languages.")
  71     (home-page "http://sources.redhat.com/libffi/")
  72
  73     ;; See <https://github.com/atgreen/libffi/blob/master/LICENSE>.
  74     (license expat)))
  75
  76 (define-public python-cffi
  77   (package
  78     (name "python-cffi")
  79     (version "1.11.5")
  80     (source
  81      (origin
  82       (method url-fetch)
  83       (uri (pypi-uri "cffi" version))
  84       (sha256
  85        (base32 "1x3lrj928dcxx1k8k9gf3s4s3jwvzv8mc3kkyg1g7c3a1sc1f3z9"))
  86       (patches (search-patches "python-cffi-x87-stack-clean.patch"))))
  87     (build-system python-build-system)
  88     (inputs
  89      `(("libffi" ,libffi)))
  90     (propagated-inputs ; required at run-time
  91      `(("python-pycparser" ,python-pycparser)))
  92     (native-inputs
  93      `(("pkg-config" ,pkg-config)
  94        ("python-pytest" ,python-pytest)))
  95     (arguments
  96      `(#:modules ((ice-9 ftw)
  97                   (srfi srfi-26)
  98                   (guix build utils)
  99                   (guix build python-build-system))
 100        #:phases
 101        (modify-phases %standard-phases
 102          (replace 'check
 103            (lambda _
 104              (setenv "PYTHONPATH"
 105                      (string-append
 106                       (getenv "PYTHONPATH")
 107                       ":" (getcwd) "/build/"
 108                       (car (scandir "build" (cut string-prefix? "lib." <>)))))
 109
 110              ;; XXX The "normal" approach of setting CC and friends does
 111              ;; not work here.  Is this the correct way of doing things?
 112              (substitute* "testing/embedding/test_basic.py"
 113                (("c = distutils\\.ccompiler\\.new_compiler\\(\\)")
 114                 (string-append "c = distutils.ccompiler.new_compiler();"
 115                                "c.set_executables(compiler='gcc',"
 116                                "compiler_so='gcc',linker_exe='gcc',"
 117                                "linker_so='gcc -shared')")))
 118              (substitute* "testing/cffi0/test_ownlib.py"
 119                (("'cc testownlib") "'gcc testownlib"))
 120              (invoke "py.test" "-v" "c/" "testing/")
 121              #t))
 122          (add-before 'check 'patch-paths-of-dynamically-loaded-libraries
 123            (lambda* (#:key inputs #:allow-other-keys)
 124              ;; Shared libraries should be referred by their absolute path as
 125              ;; using find_library or the like with their name fail when the
 126              ;; resolved .so object is a linker script rather than an ELF
 127              ;; binary (this is a limitation of the ctype library of Python).
 128              (let* ((glibc (assoc-ref inputs "libc"))
 129                     (libm (string-append glibc "/lib/libm.so.6"))
 130                     (libc (string-append glibc "/lib/libc.so.6")))
 131                (substitute* '("testing/cffi0/test_function.py"
 132                               "testing/cffi0/test_parsing.py"
 133                               "testing/cffi0/test_unicode_literals.py"
 134                               "testing/cffi0/test_zdistutils.py"
 135                               "testing/cffi1/test_recompiler.py")
 136                  (("lib_m = ['\"]{1}m['\"]{1}")
 137                   (format #f "lib_m = '~a'" libm)))
 138                (substitute* '("testing/cffi0/test_verify.py"
 139                               "testing/cffi1/test_verify1.py")
 140                  (("lib_m = \\[['\"]{1}m['\"]{1}\\]")
 141                   (format #f "lib_m = ['~a']" libm)))
 142                (substitute* "c/test_c.py"
 143                  (("find_and_load_library\\(['\"]{1}c['\"]{1}")
 144                   (format #f "find_and_load_library('~a'" libc)))
 145                #t)))
 146          (add-before 'check 'disable-failing-test
 147            ;; This is assumed to be a libffi issue:
 148            ;; https://bitbucket.org/cffi/cffi/issues/312/tests-failed-with-armv8
 149            (lambda _
 150              (substitute* "testing/cffi0/test_ownlib.py"
 151                (("ret.left") "ownlib.left"))
 152              #t)))))
 153     (home-page "https://cffi.readthedocs.io/")
 154     (synopsis "Foreign function interface for Python")
 155     (description "Foreign Function Interface for Python calling C code.")
 156     (license expat)))
 157
 158 (define-public python2-cffi
 159   (package-with-python2 python-cffi))
 160
 161 (define-public python-cffi-documentation
 162   (package
 163     (name "python-cffi-documentation")
 164     (version (package-version python-cffi))
 165     (source (package-source python-cffi))
 166     (build-system gnu-build-system)
 167     (arguments
 168      `(#:tests? #f
 169        #:phases (modify-phases %standard-phases
 170                   (add-after 'unpack 'chdir
 171                     (lambda _ (chdir "doc") #t))
 172                   (delete 'configure)
 173                   (replace 'build
 174                     (lambda* (#:key (make-flags '()) #:allow-other-keys)
 175                       (apply invoke "make" "html" make-flags)))
 176                   (replace 'install
 177                     (lambda* (#:key outputs #:allow-other-keys)
 178                       (let ((out (assoc-ref outputs "out")))
 179                         (copy-recursively "build/html" (string-append out "/html"))
 180                         #t))))))
 181     (native-inputs
 182      `(("sphinx-build" ,python-sphinx)))
 183     (home-page (package-home-page python-cffi))
 184     (synopsis "Documentation for the Python CFFI interface")
 185     (description
 186      "This package contains HTML documentation for the @code{python-cffi}
 187 project.")
 188     (license (package-license python-cffi))))
 189
 190 (define-public ruby-ffi
 191   (package
 192     (name "ruby-ffi")
 193     (version "1.10.0")
 194     (source (origin
 195               (method url-fetch)
 196               (uri (rubygems-uri "ffi" version))
 197               (sha256
 198                (base32
 199                 "0j8pzj8raxbir5w5k6s7a042sb5k02pg0f8s4na1r5lan901j00p"))))
 200     (build-system ruby-build-system)
 201     ;; FIXME: Before running tests the build system attempts to build libffi
 202     ;; from sources.
 203     (arguments `(#:tests? #f))
 204     (native-inputs
 205      `(("ruby-rake-compiler" ,ruby-rake-compiler)
 206        ("ruby-rspec" ,ruby-rspec)
 207        ("ruby-rubygems-tasks" ,ruby-rubygems-tasks)))
 208     (inputs
 209      `(("libffi" ,libffi)))
 210     (synopsis "Ruby foreign function interface library")
 211     (description "Ruby-FFI is a Ruby extension for programmatically loading
 212 dynamic libraries, binding functions within them, and calling those functions
 213 from Ruby code.  Moreover, a Ruby-FFI extension works without changes on Ruby
 214 and JRuby.")
 215     (home-page "http://wiki.github.com/ffi/ffi")
 216     (license bsd-3)))