gnu/packages/ghostscript.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   3 ;;; Copyright © 2014, 2015, 2016, 2017 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2013, 2015, 2016, 2017, 2019 Ludovic Courtès <ludo@gnu.org>
   6 ;;; Copyright © 2017 Alex Vong <alexvong1995@gmail.com>
   7 ;;; Copyright © 2017, 2018, 2019 Efraim Flashner <efraim@flashner.co.il>
   8 ;;; Copyright © 2017 Leo Famulari <leo@famulari.name>
   9 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  10 ;;; Copyright © 2018 Marius Bakke <mbakke@fastmail.com>
  11 ;;; Copyright © 2019 Mathieu Othacehe <m.othacehe@gmail.com>
  12 ;;;
  13 ;;; This file is part of GNU Guix.
  14 ;;;
  15 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  16 ;;; under the terms of the GNU General Public License as published by
  17 ;;; the Free Software Foundation; either version 3 of the License, or (at
  18 ;;; your option) any later version.
  19 ;;;
  20 ;;; GNU Guix is distributed in the hope that it will be useful, but
  21 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;;; GNU General Public License for more details.
  24 ;;;
  25 ;;; You should have received a copy of the GNU General Public License
  26 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 (define-module (gnu packages ghostscript)
  29   #:use-module (gnu packages)
  30   #:use-module (gnu packages autotools)
  31   #:use-module (gnu packages compression)
  32   #:use-module (gnu packages cups)
  33   #:use-module (gnu packages fontutils)
  34   #:use-module (gnu packages image)
  35   #:use-module (gnu packages perl)
  36   #:use-module (gnu packages pkg-config)
  37   #:use-module (gnu packages python)
  38   #:use-module (gnu packages tcl)
  39   #:use-module (gnu packages xorg)
  40   #:use-module ((guix licenses) #:prefix license:)
  41   #:use-module (guix packages)
  42   #:use-module (guix download)
  43   #:use-module (guix utils)
  44   #:use-module (guix build-system gnu)
  45   #:use-module (guix build-system trivial)
  46   #:use-module (srfi srfi-1))
  47
  48 (define-public lcms
  49   (package
  50    (name "lcms")
  51    (version "2.9")
  52    (source (origin
  53             (method url-fetch)
  54             (uri (string-append "mirror://sourceforge/lcms/lcms/" version
  55                                 "/lcms2-" version ".tar.gz"))
  56
  57             (patches (search-patches "lcms-CVE-2018-16435.patch"))
  58             (sha256 (base32
  59                      "083xisy6z01zhm7p7rgk4bx9d6zlr8l20qkfv1g29ylnhgwzvij8"))))
  60    (build-system gnu-build-system)
  61    (arguments
  62     `(#:configure-flags '("--disable-static")))
  63    (inputs `(("libjpeg" ,libjpeg)
  64              ("libtiff" ,libtiff)
  65              ("zlib" ,zlib)))
  66    (synopsis "Little CMS, a small-footprint colour management engine")
  67    (description
  68     "Little CMS is a small-footprint colour management engine, with special
  69 focus on accuracy and performance.  It uses the International Color
  70 Consortium standard (ICC), approved as ISO 15076-1.")
  71    (license license:x11)
  72    (home-page "http://www.littlecms.com/")
  73    (properties '((cpe-name . "little_cms_color_engine")))))
  74
  75 (define-public libpaper
  76   (package
  77    (name "libpaper")
  78    (version "1.1.24")
  79    (source (origin
  80             (method url-fetch)
  81             (uri (string-append
  82                    ;; Debian moved their libpaper-1.1.24 to archive.debian.net
  83                    ;; but in the move the hash of their tarball changed.
  84                    "http://pkgs.fedoraproject.org/repo/pkgs/libpaper/libpaper_"
  85                    version ".tar.gz/5bc87d494ba470aba54f6d2d51471834/libpaper_"
  86                    version ".tar.gz"))
  87             (sha256 (base32
  88                      "0zhcx67afb6b5r936w5jmaydj3ks8zh83n9rm5sv3m3k8q8jib1q"))))
  89    (build-system gnu-build-system)
  90    (native-inputs
  91     `(("automake" ,automake))) ; For up to date 'config.guess' and 'config.sub'.
  92    (arguments
  93     `(#:configure-flags '("--disable-static")
  94       #:phases
  95       (modify-phases %standard-phases
  96         (add-after 'unpack 'fix-configure
  97           (lambda* (#:key inputs native-inputs #:allow-other-keys)
  98             ;; Replace outdated config.sub and config.guess:
  99             (for-each (lambda (file)
 100                         (install-file
 101                          (string-append (assoc-ref
 102                                          (or native-inputs inputs) "automake")
 103                                         "/share/automake-"
 104                                         ,(version-major+minor
 105                                           (package-version automake))
 106                                         "/" file) "."))
 107                       '("config.sub" "config.guess"))
 108             #t)))))
 109    (synopsis "Library for handling paper sizes")
 110    (description
 111     "The paper library and accompanying files are intended to provide a simple
 112 way for applications to take actions based on a system- or user-specified
 113 paper size.")
 114    (license license:gpl2)
 115    (home-page "https://packages.qa.debian.org/libp/libpaper.html")))
 116
 117 (define-public psutils
 118   (package
 119    (name "psutils")
 120    (version "17")
 121    (source (origin
 122             (method url-fetch)
 123             (uri "ftp://ftp.knackered.org/pub/psutils/psutils.tar.gz")
 124             (sha256 (base32
 125                      "1r4ab1fvgganm02kmm70b2r1azwzbav2am41gbigpa2bb1wynlrq"))))
 126    (build-system gnu-build-system)
 127    (inputs `(("perl" ,perl)))
 128    (arguments
 129     `(#:tests? #f ; none provided
 130       #:phases
 131       (modify-phases %standard-phases
 132         (replace 'configure
 133           (lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
 134            (let ((perl (assoc-ref inputs "perl"))
 135                  (out (assoc-ref outputs "out")))
 136             (copy-file "Makefile.unix" "Makefile")
 137             (substitute* "Makefile"
 138               (("/usr/local/bin/perl") (string-append perl "/bin/perl")))
 139             (substitute* "Makefile"
 140               (("/usr/local") out))
 141             ;; for the install phase
 142             (substitute* "Makefile"
 143               (("-mkdir") "mkdir -p"))
 144             ;; drop installation of non-free files
 145             (substitute* "Makefile"
 146               ((" install.include") "")))
 147            #t)))))
 148    (synopsis "Collection of utilities for manipulating PostScript documents")
 149    (description
 150     "PSUtils is a collection of utilities for manipulating PostScript
 151 documents.  Programs included are psnup, for placing out several logical pages
 152 on a single sheet of paper, psselect, for selecting pages from a document,
 153 pstops, for general imposition, psbook, for signature generation for booklet
 154 printing, and psresize, for adjusting page sizes.")
 155    (license (license:non-copyleft "file://LICENSE"
 156                                 "See LICENSE in the distribution."))
 157    (home-page "http://knackered.org/angus/psutils/")))
 158
 159 (define-public ghostscript
 160   (package
 161     (name "ghostscript")
 162     (version "9.50")
 163     (source
 164       (origin
 165         (method url-fetch)
 166         (uri (string-append "https://github.com/ArtifexSoftware/"
 167                             "ghostpdl-downloads/releases/download/gs"
 168                             (string-delete #\. version)
 169                             "/ghostscript-" version ".tar.xz"))
 170         (sha256
 171          (base32
 172           "1m770dwc82afdgzgq2kar3120r1lbybm3mssdm79f8kggf0v16yv"))
 173         (patches (search-patches "ghostscript-no-header-creationdate.patch"
 174                                  "ghostscript-no-header-id.patch"
 175                                  "ghostscript-no-header-uuid.patch"))
 176         (modules '((guix build utils)))
 177         (snippet
 178           ;; Remove bundled libraries. The bundled OpenJPEG is a patched fork so
 179           ;; we leave it, at least for now.
 180           ;; TODO Try unbundling ijs, which is developed alongside Ghostscript.
 181           ;; Likewise for the thread-safe lcms2 fork called "lcms2art".
 182          '(begin
 183             (for-each delete-file-recursively '("freetype" "jbig2dec" "jpeg"
 184                                                 "libpng" "tiff" "zlib"))
 185             #t))))
 186     (build-system gnu-build-system)
 187     (outputs '("out" "doc"))                  ;19 MiB of HTML/PS doc + examples
 188     (arguments
 189      `(#:disallowed-references ("doc")
 190        ;; XXX: Starting with version 9.27, building the tests in parallel
 191        ;; occasionally fails like this:
 192        ;;  In file included from ./base/memory_.h:23:0,
 193        ;;                   from ./obj/gsmd5.h:1,
 194        ;;                   from ./obj/gsmd5.c:56:
 195        ;;  ./base/std.h:25:10: fatal error: arch.h: No such file or directory
 196        #:parallel-tests? #f
 197        #:configure-flags
 198        (list (string-append "LDFLAGS=-Wl,-rpath="
 199                             (assoc-ref %outputs "out") "/lib")
 200              "--with-system-libtiff"
 201              "LIBS=-lz"
 202              (string-append "ZLIBDIR="
 203                             (assoc-ref %build-inputs "zlib") "/include")
 204              "--enable-dynamic"
 205              "--disable-compile-inits"
 206              (string-append "--with-fontpath="
 207                             (assoc-ref %build-inputs "gs-fonts")
 208                             "/share/fonts/type1/ghostscript")
 209
 210              ,@(if (%current-target-system)
 211                    '(;; Specify the native compiler, which is used to build 'echogs'
 212                      ;; and other intermediary tools when cross-compiling; see
 213                      ;; <https://ghostscript.com/FAQ.html>.
 214                      "CCAUX=gcc"
 215
 216                      ;; Save 'config.log' etc. of the native build under
 217                      ;; auxtmp/, useful for debugging.
 218                      "--enable-save_confaux")
 219                    '()))
 220        #:phases
 221        (modify-phases %standard-phases
 222         (add-before 'configure 'create-output-directory
 223           (lambda* (#:key outputs #:allow-other-keys)
 224             ;; The configure script refuses to function if the directory
 225             ;; specified as -rpath does not already exist.
 226             (mkdir-p (string-append (assoc-ref outputs "out") "/lib"))
 227             #t))
 228         (add-after 'configure 'remove-doc-reference
 229           (lambda _
 230             ;; Don't retain a reference to the 'doc' output in 'gs'.
 231             ;; The only use of this definition is in the output of
 232             ;; 'gs --help', so this change is fine.
 233             (substitute* "base/gscdef.c"
 234               (("GS_DOCDIR")
 235                "\"~/.guix-profile/share/doc/ghostscript\""))
 236             ;; The docdir default changed in 9.23 and a compatibility
 237             ;; symlink was added from datadir->docdir.  Remove it.
 238             (substitute* "base/unixinst.mak"
 239               (("ln -s \\$\\(DESTDIR\\)\\$\\(docdir\\).*") ""))
 240             #t))
 241          (add-after 'configure 'patch-config-files
 242            (lambda _
 243              (substitute* "base/unixhead.mak"
 244                (("/bin/sh") (which "sh")))
 245              #t))
 246          ,@(if (%current-target-system)
 247                `((add-after 'configure 'add-native-lz
 248                    (lambda _
 249                      ;; Add missing '-lz' for native tools such as 'mkromfs'.
 250                      (substitute* "Makefile"
 251                        (("^AUXEXTRALIBS=(.*)$" _ value)
 252                         (string-append "AUXEXTRALIBS = -lz " value "\n")))
 253                      #t)))
 254                '())
 255          (replace 'build
 256            (lambda _
 257              ;; Build 'libgs.so', but don't build the statically-linked 'gs'
 258              ;; binary (saves 22 MiB).
 259              (invoke "make" "so" "-j"
 260                      (number->string (parallel-job-count)))))
 261          (replace 'install
 262            (lambda _
 263              (invoke "make" "soinstall")))
 264          (add-after 'install 'create-gs-symlink
 265            (lambda* (#:key outputs #:allow-other-keys)
 266              (let ((out (assoc-ref outputs "out")))
 267                ;; Some programs depend on having a 'gs' binary available.
 268                (symlink "gsc" (string-append out "/bin/gs"))
 269                #t))))))
 270     (native-inputs
 271      `(("perl" ,perl)
 272        ("pkg-config" ,pkg-config)       ;needed for freetype
 273        ("python" ,python-wrapper)
 274        ("tcl" ,tcl)
 275
 276        ;; When cross-compiling, some of the natively-built tools require all
 277        ;; these libraries.
 278        ,@(if (%current-target-system)
 279              `(("zlib/native" ,zlib)
 280                ("libjpeg/native" ,libjpeg))
 281              '())))
 282     (inputs
 283      `(("fontconfig" ,fontconfig)
 284        ("freetype" ,freetype)
 285        ("gs-fonts" ,gs-fonts)
 286        ("jbig2dec" ,jbig2dec)
 287        ("libjpeg" ,libjpeg)
 288        ("libpaper" ,libpaper)
 289        ("libpng" ,libpng)
 290        ("libtiff" ,libtiff)
 291        ("zlib" ,zlib)))
 292     (synopsis "PostScript and PDF interpreter")
 293     (description
 294      "Ghostscript is an interpreter for the PostScript language and the PDF
 295 file format.  It also includes a C library that implements the graphics
 296 capabilities of the PostScript language.  It supports a wide variety of
 297 output file formats and printers.")
 298     (home-page "https://www.ghostscript.com/")
 299     (license license:agpl3+)))
 300
 301 (define-public ghostscript/x
 302   (package/inherit ghostscript
 303     (name (string-append (package-name ghostscript) "-with-x"))
 304     (inputs `(("libxext" ,libxext)
 305               ("libxt" ,libxt)
 306               ,@(package-inputs ghostscript)))))
 307
 308 (define-public ghostscript/cups
 309   (package/inherit ghostscript
 310     (name "ghostscript-with-cups")
 311     (inputs `(("cups" ,cups-minimal)
 312               ,@(package-inputs ghostscript)))))
 313
 314 (define-public ijs
 315   (package
 316    (name "ijs")
 317    (version (package-version ghostscript))
 318    (source (package-source ghostscript))
 319    (build-system gnu-build-system)
 320    (native-inputs
 321     `(("libtool"    ,libtool)
 322       ("automake"   ,automake)
 323       ("autoconf"   ,autoconf)))
 324    (arguments
 325     `(#:phases
 326       (modify-phases %standard-phases
 327         (add-after 'unpack 'autogen
 328           (lambda _
 329             ;; need to regenerate macros
 330             (system* "autoreconf" "-if")
 331             ;; do not run configure
 332             (substitute* "autogen.sh"
 333               (("^.*\\$srcdir/configure.*") ""))
 334             (system* "bash" "autogen.sh")
 335             ;; create configure script in ./ijs/
 336             (chdir "ijs")
 337             ;; do not run configure
 338             (substitute* "autogen.sh"
 339               (("^.*\\$srcdir/configure.*") "")
 340               (("^ + && echo Now type.*$")  ""))
 341             (invoke "bash" "autogen.sh"))))))
 342    (synopsis "IJS driver framework for inkjet and other raster devices")
 343    (description
 344     "IJS is a protocol for transmission of raster page images.  This package
 345 provides the reference implementation of the raster printer driver
 346 architecture.")
 347    (license license:expat)
 348    (home-page (package-home-page ghostscript))))
 349
 350 (define-public gs-fonts
 351   (package
 352    (name "gs-fonts")
 353    (version "8.11")
 354    (source (origin
 355             (method url-fetch)
 356             (uri (string-append "mirror://sourceforge/gs-fonts/gs-fonts/"
 357                                 version
 358                                 "%20%28base%2035%2C%20GPL%29/ghostscript-fonts-std-"
 359                                 version
 360                                 ".tar.gz"))
 361             (sha256 (base32
 362                      "00f4l10xd826kak51wsmaz69szzm2wp8a41jasr4jblz25bg7dhf"))))
 363    (build-system gnu-build-system)
 364    (arguments
 365     `(#:tests? #f ; nothing to check, just files to copy
 366
 367       #:modules ((guix build gnu-build-system)
 368                  (guix build utils)
 369                  (srfi srfi-1))
 370       #:phases
 371       (modify-phases %standard-phases
 372         (delete 'configure)
 373         (delete 'build)
 374         (replace 'install
 375           (lambda* (#:key outputs #:allow-other-keys)
 376             (let* ((out (assoc-ref outputs "out"))
 377                    (dir (string-append out "/share/fonts/type1/ghostscript")))
 378               (mkdir-p dir)
 379               (for-each
 380                 (lambda (file)
 381                   (copy-file file (string-append dir "/" file)))
 382                 (find-files "." "pfb|afm"))
 383               #t))))))
 384    (synopsis "Free replacements for the PostScript fonts")
 385    (description
 386     "Ghostscript fonts provides fonts and font metrics customarily distributed with
 387 Ghostscript.  It currently includes the 35 standard PostScript fonts.")
 388    (license license:gpl2)
 389    (home-page "https://sourceforge.net/projects/gs-fonts/")))
 390
 391 (define-public libspectre
 392   (package
 393    (name "libspectre")
 394    (version "0.2.8")
 395    (source (origin
 396             (method url-fetch)
 397             (uri (string-append "https://libspectre.freedesktop.org/releases/libspectre-"
 398                                 version ".tar.gz"))
 399             (sha256 (base32
 400                      "1a67iglsc3r05mzngyg9kb1gy8whq4fgsnyjwi7bqfw2i7rnl9b5"))))
 401    (build-system gnu-build-system)
 402    (inputs `(("ghostscript" ,ghostscript)))
 403    (native-inputs `(("pkg-config" ,pkg-config)))
 404    (synopsis "Postscript rendering library")
 405    (description
 406     "libspectre is a small library for rendering Postscript documents.
 407 It provides a convenient easy to use API for handling and rendering
 408 Postscript documents.")
 409    (license license:gpl2+)
 410    (home-page "https://www.freedesktop.org/wiki/Software/libspectre")))