gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017, 2020 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018, 2019 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (guix utils)
  28   #:use-module (gnu packages admin)
  29   #:use-module (gnu packages ci)
  30   #:use-module (gnu packages version-control)
  31   #:use-module (gnu services)
  32   #:use-module (gnu services base)
  33   #:use-module (gnu services databases)
  34   #:use-module (gnu services shepherd)
  35   #:use-module (gnu services admin)
  36   #:use-module (gnu system shadow)
  37   #:export (<cuirass-remote-server-configuration>
  38             cuirass-remote-server-configuration
  39             cuirass-remote-server-configuration?
  40
  41             <cuirass-configuration>
  42             cuirass-configuration
  43             cuirass-configuration?
  44             cuirass-service-type
  45
  46             <cuirass-remote-worker-configuration>
  47             cuirass-remote-worker-configuration
  48             cuirass-remote-worker-configuration?
  49             cuirass-remote-worker-service-type))
  50
  51 ;;;; Commentary:
  52 ;;;
  53 ;;; This module implements a service that to run instances of Cuirass, a
  54 ;;; continuous integration tool.
  55 ;;;
  56 ;;;; Code:
  57
  58 (define %cuirass-default-database
  59   "dbname=cuirass host=/var/run/postgresql")
  60
  61 (define-record-type* <cuirass-remote-server-configuration>
  62   cuirass-remote-server-configuration make-cuirass-remote-server-configuration
  63   cuirass-remote-server-configuration?
  64   (backend-port     cuirass-remote-server-configuration-backend-port ;int
  65                     (default #f))
  66   (publish-port     cuirass-remote-server-configuration-publish-port ;int
  67                     (default #f))
  68   (log-file         cuirass-remote-server-log-file ;string
  69                     (default "/var/log/cuirass-remote-server.log"))
  70   (cache            cuirass-remote-server-configuration-cache ;string
  71                     (default "/var/cache/cuirass/remote/"))
  72   (trigger-url      cuirass-remote-server-trigger-url ;string
  73                     (default #f))
  74   (public-key       cuirass-remote-server-configuration-public-key ;string
  75                     (default #f))
  76   (private-key      cuirass-remote-server-configuration-private-key ;string
  77                     (default #f)))
  78
  79 (define-record-type* <cuirass-configuration>
  80   cuirass-configuration make-cuirass-configuration
  81   cuirass-configuration?
  82   (cuirass          cuirass-configuration-cuirass ;package
  83                     (default cuirass))
  84   (log-file         cuirass-configuration-log-file ;string
  85                     (default "/var/log/cuirass.log"))
  86   (web-log-file     cuirass-configuration-web-log-file ;string
  87                     (default "/var/log/cuirass-web.log"))
  88   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  89                     (default "/var/cache/cuirass"))
  90   (user             cuirass-configuration-user ;string
  91                     (default "cuirass"))
  92   (group            cuirass-configuration-group ;string
  93                     (default "cuirass"))
  94   (interval         cuirass-configuration-interval ;integer (seconds)
  95                     (default 60))
  96   (remote-server    cuirass-configuration-remote-server
  97                     (default #f))
  98   (database         cuirass-configuration-database ;string
  99                     (default %cuirass-default-database))
 100   (port             cuirass-configuration-port ;integer (port)
 101                     (default 8081))
 102   (host             cuirass-configuration-host ;string
 103                     (default "localhost"))
 104   (specifications   cuirass-configuration-specifications)
 105                                   ;gexp that evaluates to specification-alist
 106   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
 107                     (default #f))
 108   (one-shot?        cuirass-configuration-one-shot? ;boolean
 109                     (default #f))
 110   (fallback?        cuirass-configuration-fallback? ;boolean
 111                     (default #f))
 112   (extra-options    cuirass-configuration-extra-options
 113                     (default '())))
 114
 115 (define (cuirass-shepherd-service config)
 116   "Return a <shepherd-service> for the Cuirass service with CONFIG."
 117   (let ((cuirass          (cuirass-configuration-cuirass config))
 118         (cache-directory  (cuirass-configuration-cache-directory config))
 119         (web-log-file     (cuirass-configuration-web-log-file config))
 120         (log-file         (cuirass-configuration-log-file config))
 121         (user             (cuirass-configuration-user config))
 122         (group            (cuirass-configuration-group config))
 123         (interval         (cuirass-configuration-interval config))
 124         (remote-server    (cuirass-configuration-remote-server config))
 125         (database         (cuirass-configuration-database config))
 126         (port             (cuirass-configuration-port config))
 127         (host             (cuirass-configuration-host config))
 128         (specs            (cuirass-configuration-specifications config))
 129         (use-substitutes? (cuirass-configuration-use-substitutes? config))
 130         (one-shot?        (cuirass-configuration-one-shot? config))
 131         (fallback?        (cuirass-configuration-fallback? config))
 132         (extra-options    (cuirass-configuration-extra-options config)))
 133     `(,(shepherd-service
 134         (documentation "Run Cuirass.")
 135         (provision '(cuirass))
 136         (requirement '(guix-daemon postgres networking))
 137         (start #~(make-forkexec-constructor
 138                   (list (string-append #$cuirass "/bin/cuirass")
 139                         "--cache-directory" #$cache-directory
 140                         "--specifications"
 141                         #$(scheme-file "cuirass-specs.scm" specs)
 142                         "--database" #$database
 143                         "--interval" #$(number->string interval)
 144                         #$@(if remote-server '("--build-remote") '())
 145                         #$@(if use-substitutes? '("--use-substitutes") '())
 146                         #$@(if one-shot? '("--one-shot") '())
 147                         #$@(if fallback? '("--fallback") '())
 148                         #$@extra-options)
 149
 150                   #:environment-variables
 151                   (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 152                         (string-append "GIT_EXEC_PATH=" #$git
 153                                        "/libexec/git-core"))
 154
 155                   #:user #$user
 156                   #:group #$group
 157                   #:log-file #$log-file))
 158         (stop #~(make-kill-destructor)))
 159       ,(shepherd-service
 160         (documentation "Run Cuirass web interface.")
 161         (provision '(cuirass-web))
 162         (requirement '(guix-daemon postgres networking))
 163         (start #~(make-forkexec-constructor
 164                   (list (string-append #$cuirass "/bin/cuirass")
 165                         "--cache-directory" #$cache-directory
 166                         "--database" #$database
 167                         "--web"
 168                         "--port" #$(number->string port)
 169                         "--listen" #$host
 170                         "--interval" #$(number->string interval)
 171                         #$@(if use-substitutes? '("--use-substitutes") '())
 172                         #$@(if fallback? '("--fallback") '())
 173                         #$@extra-options)
 174
 175                   #:user #$user
 176                   #:group #$group
 177                   #:log-file #$web-log-file))
 178         (stop #~(make-kill-destructor)))
 179       ,@(if remote-server
 180             (match-record remote-server <cuirass-remote-server-configuration>
 181               (backend-port publish-port log-file cache trigger-url
 182                             public-key private-key)
 183               (list
 184                (shepherd-service
 185                 (documentation "Run Cuirass remote build server.")
 186                 (provision '(cuirass-remote-server))
 187                 (requirement '(avahi-daemon cuirass guix-daemon networking))
 188                 (start #~(make-forkexec-constructor
 189                           (list (string-append #$cuirass "/bin/remote-server")
 190                                 (string-append "--database=" #$database)
 191                                 (string-append "--cache=" #$cache)
 192                                 (string-append "--user=" #$user)
 193                                 #$@(if backend-port
 194                                        (list (string-append
 195                                               "--backend-port="
 196                                               (number->string backend-port)))
 197                                        '())
 198                                 #$@(if publish-port
 199                                        (list (string-append
 200                                               "--publish-port="
 201                                               (number->string publish-port)))
 202                                        '())
 203                                 #$@(if trigger-url
 204                                        (list
 205                                         (string-append
 206                                          "--trigger-substitute-url="
 207                                          trigger-url))
 208                                        '())
 209                                 #$@(if public-key
 210                                        (list
 211                                         (string-append "--public-key="
 212                                                        public-key))
 213                                        '())
 214                                 #$@(if private-key
 215                                        (list
 216                                         (string-append "--private-key="
 217                                                        private-key))
 218                                        '()))
 219                           #:log-file #$log-file))
 220                 (stop #~(make-kill-destructor)))))
 221             '()))))
 222
 223 (define (cuirass-account config)
 224   "Return the user accounts and user groups for CONFIG."
 225   (let ((cuirass-user  (cuirass-configuration-user config))
 226         (cuirass-group (cuirass-configuration-group config)))
 227     (list (user-group
 228            (name cuirass-group)
 229            (system? #t))
 230           (user-account
 231            (name cuirass-user)
 232            (group cuirass-group)
 233            (system? #t)
 234            (comment "Cuirass privilege separation user")
 235            (home-directory (string-append "/var/lib/" cuirass-user))
 236            (shell (file-append shadow "/sbin/nologin"))))))
 237
 238 (define (cuirass-postgresql-role config)
 239   (let ((user (cuirass-configuration-user config)))
 240     (list (postgresql-role
 241            (name user)
 242            (create-database? #t)))))
 243
 244 (define (cuirass-activation config)
 245   "Return the activation code for CONFIG."
 246   (let ((cache (cuirass-configuration-cache-directory config))
 247         (db    (dirname (cuirass-configuration-database config)))
 248         (user  (cuirass-configuration-user config))
 249         (log   "/var/log/cuirass")
 250         (group (cuirass-configuration-group config)))
 251     (with-imported-modules '((guix build utils))
 252       #~(begin
 253           (use-modules (guix build utils))
 254
 255           (mkdir-p #$cache)
 256           (mkdir-p #$db)
 257           (mkdir-p #$log)
 258
 259           (let ((uid (passwd:uid (getpw #$user)))
 260                 (gid (group:gid (getgr #$group))))
 261             (chown #$cache uid gid)
 262             (chown #$db uid gid)
 263             (chown #$log uid gid))))))
 264
 265 (define (cuirass-log-rotations config)
 266   "Return the list of log rotations that corresponds to CONFIG."
 267   (list (log-rotation
 268          (files (list (cuirass-configuration-log-file config)))
 269          (frequency 'weekly)
 270          (options '("rotate 40")))))              ;worth keeping
 271
 272 (define cuirass-service-type
 273   (service-type
 274    (name 'cuirass)
 275    (extensions
 276     (list
 277      (service-extension profile-service-type      ;for 'info cuirass'
 278                         (compose list cuirass-configuration-cuirass))
 279      (service-extension rottlog-service-type cuirass-log-rotations)
 280      (service-extension activation-service-type cuirass-activation)
 281      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 282      (service-extension account-service-type cuirass-account)
 283      (service-extension postgresql-role-service-type
 284                         cuirass-postgresql-role)))
 285    (description
 286     "Run the Cuirass continuous integration service.")))
 287
 288 (define-record-type* <cuirass-remote-worker-configuration>
 289   cuirass-remote-worker-configuration make-cuirass-remote-worker-configuration
 290   cuirass-remote-worker-configuration?
 291   (cuirass          cuirass-remote-worker-configuration-cuirass ;package
 292                     (default cuirass))
 293   (workers          cuirass-remote-worker-workers ;int
 294                     (default 1))
 295   (systems          cuirass-remote-worker-systems ;list
 296                     (default (list (%current-system))))
 297   (log-file         cuirass-remote-worker-log-file ;string
 298                     (default "/var/log/cuirass-remote-worker.log"))
 299   (publish-port     cuirass-remote-worker-configuration-publish-port ;int
 300                     (default #f))
 301   (public-key       cuirass-remote-worker-configuration-public-key ;string
 302                     (default #f))
 303   (private-key      cuirass-remote-worker-configuration-private-key ;string
 304                     (default #f)))
 305
 306 (define (cuirass-remote-worker-shepherd-service config)
 307   "Return a <shepherd-service> for the Cuirass remote worker service with
 308 CONFIG."
 309   (match-record config <cuirass-remote-worker-configuration>
 310     (cuirass workers systems log-file publish-port public-key private-key)
 311     (list (shepherd-service
 312            (documentation "Run Cuirass remote build worker.")
 313            (provision '(cuirass-remote-worker))
 314            (requirement '(avahi-daemon guix-daemon networking))
 315            (start #~(make-forkexec-constructor
 316                      (list (string-append #$cuirass "/bin/remote-worker")
 317                            (string-append "--workers="
 318                                           #$(number->string workers))
 319                            #$@(if systems
 320                                   (list (string-append
 321                                          "--systems="
 322                                          (string-join systems ",")))
 323                                   '())
 324                            #$@(if publish-port
 325                                   (list (string-append
 326                                          "--publish-port="
 327                                          (number->string publish-port)))
 328                                   '())
 329                            #$@(if public-key
 330                                   (list
 331                                    (string-append "--public-key="
 332                                                   public-key))
 333                                   '())
 334                            #$@(if private-key
 335                                   (list
 336                                    (string-append "--private-key="
 337                                                   private-key))
 338                                   '()))
 339                     #:log-file #$log-file))
 340            (stop #~(make-kill-destructor))))))
 341
 342 (define cuirass-remote-worker-service-type
 343   (service-type
 344    (name 'cuirass-remote-worker)
 345    (extensions
 346     (list
 347      (service-extension shepherd-root-service-type
 348                         cuirass-remote-worker-shepherd-service)))
 349    (description
 350     "Run the Cuirass remote build worker service.")))