configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 dnl Better be verbose.
  51 AC_MSG_CHECKING([for the store directory])
  52 AC_MSG_RESULT([$storedir])
  53
  54 AC_ARG_ENABLE([daemon],
  55   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  56   [guix_build_daemon="$enableval"],
  57   [guix_build_daemon="yes"])
  58
  59 # Prepare a version of $localstatedir & co. that does not contain references
  60 # to shell variables.
  61 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  62 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  63 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  64 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  65 AC_SUBST([guix_localstatedir])
  66 AC_SUBST([guix_sysconfdir])
  67 AC_SUBST([guix_sbindir])
  68
  69 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  70 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  71
  72 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  73 dnl Make sure they are available.
  74 m4_pattern_forbid([PKG_CHECK_MODULES])
  75 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  76 m4_pattern_forbid([^GUILE_P$])
  77
  78 dnl Search for 'guile' and 'guild'.  This macro defines
  79 dnl 'GUILE_EFFECTIVE_VERSION'.
  80 GUILE_PKG([2.2 2.0])
  81 GUILE_PROGS
  82 if test "x$GUILD" = "x"; then
  83    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  84 fi
  85
  86 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  87   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.9])
  88 fi
  89
  90 dnl Installation directories for .scm and .go files.
  91 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  92 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  93 AC_SUBST([guilemoduledir])
  94 AC_SUBST([guileobjectdir])
  95
  96 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  97 dnl pull', among other things.
  98 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  99 if test "x$have_gnutls" != "xyes"; then
 100   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 101 fi
 102
 103 dnl Check for Guile-Git.
 104 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 105 if test "x$have_guile_git" != "xyes"; then
 106   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 107 fi
 108
 109 dnl Guile-JSON is used in various places.
 110 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 111 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 112
 113 dnl Make sure we have a full-fledged Guile.
 114 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 115
 116 dnl Decompressors, for use by the substituter and other modules.
 117 AC_PATH_PROG([GZIP], [gzip])
 118 AC_PATH_PROG([BZIP2], [bzip2])
 119 AC_PATH_PROG([XZ], [xz])
 120 AC_SUBST([GZIP])
 121 AC_SUBST([BZIP2])
 122 AC_SUBST([XZ])
 123
 124 AC_ARG_WITH([nix-prefix],
 125   [AS_HELP_STRING([--with-nix-prefix=DIR],
 126     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 127   [case "$withval" in
 128     yes|no) ;;
 129     *)
 130       NIX_PREFIX="$withval"
 131       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 132       AC_SUBST([NIX_PREFIX])
 133       ;;
 134    esac],
 135   [])
 136
 137 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 138 AC_PATH_PROG([NIX_HASH], [nix-hash])
 139 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 140    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 141 fi
 142
 143 if test "x$NIX_INSTANTIATE" = "x"; then
 144    # This program is an optional dependency, so we just want it to be
 145    # taken from $PATH if it's not available right now.
 146    NIX_INSTANTIATE="nix-instantiate"
 147 fi
 148
 149 AC_ARG_WITH([nixpkgs],
 150   [AS_HELP_STRING([--with-nixpkgs=DIR],
 151     [search for Nixpkgs in DIR (for testing purposes only)])],
 152   [case "$withval" in
 153     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 154     *)      NIXPKGS="$withval";;
 155    esac],
 156   [])
 157
 158 AC_MSG_CHECKING([for Nixpkgs source tree])
 159 if test -f "$NIXPKGS/default.nix"; then
 160    AC_MSG_RESULT([$NIXPKGS])
 161    AC_SUBST([NIXPKGS])
 162 else
 163    AC_MSG_RESULT([not found])
 164 fi
 165
 166 LIBGCRYPT="libgcrypt"
 167 LIBGCRYPT_LIBDIR="no"
 168 LIBGCRYPT_PREFIX="no"
 169
 170 AC_ARG_WITH([libgcrypt-prefix],
 171   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 172   [case "$withval" in
 173     yes|no)
 174       ;;
 175     *)
 176       LIBGCRYPT="$withval/lib/libgcrypt"
 177       LIBGCRYPT_PREFIX="$withval"
 178       LIBGCRYPT_LIBDIR="$withval/lib"
 179       ;;
 180    esac])
 181
 182 AC_ARG_WITH([libgcrypt-libdir],
 183   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 184      [search for GNU libgcrypt's shared library in DIR])],
 185   [case "$withval" in
 186     yes|no)
 187       LIBGCRYPT="libgcrypt"
 188       LIBGCRYPT_LIBDIR="no"
 189       ;;
 190     *)
 191       LIBGCRYPT="$withval/libgcrypt"
 192       LIBGCRYPT_LIBDIR="$withval"
 193       ;;
 194    esac])
 195
 196 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 197 dnl absolute file name of libgcrypt.so.
 198 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 199   xnono)
 200     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 201     if test "x$LIBGCRYPT_LIBDIR" != x; then
 202       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 203     else
 204       dnl 'config-daemon.ac' expects "no" in this case.
 205       LIBGCRYPT_LIBDIR="no"
 206     fi
 207     ;;
 208 esac
 209
 210 dnl Library name suitable for `dynamic-link'.
 211 AC_MSG_CHECKING([for libgcrypt shared library name])
 212 AC_MSG_RESULT([$LIBGCRYPT])
 213 AC_SUBST([LIBGCRYPT])
 214 AC_SUBST([LIBGCRYPT_PREFIX])
 215 AC_SUBST([LIBGCRYPT_LIBDIR])
 216
 217 GUIX_ASSERT_LIBGCRYPT_USABLE
 218
 219 dnl Library name of zlib suitable for 'dynamic-link'.
 220 GUIX_LIBZ_LIBDIR([libz_libdir])
 221 if test "x$libz_libdir" = "x"; then
 222   LIBZ="libz"
 223 else
 224   LIBZ="$libz_libdir/libz"
 225 fi
 226 AC_MSG_CHECKING([for zlib's shared library name])
 227 AC_MSG_RESULT([$LIBZ])
 228 AC_SUBST([LIBZ])
 229
 230 dnl Check for Guile-SSH, for the (guix ssh) module.
 231 GUIX_CHECK_GUILE_SSH
 232 AM_CONDITIONAL([HAVE_GUILE_SSH],
 233   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 234
 235 AC_CACHE_SAVE
 236
 237 m4_include([config-daemon.ac])
 238
 239 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 240 dnl See `Building from Git' in the manual for more info.
 241 AM_MISSING_PROG([DOT], [dot])
 242
 243 dnl Manual pages.
 244 AM_MISSING_PROG([HELP2MAN], [help2man])
 245
 246 dnl Emacs (optional), for 'etc/indent-package.el'.
 247 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 248 AC_SUBST([EMACS])
 249
 250 case "$storedir" in
 251   /gnu/store)
 252     ;;
 253   *)
 254     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 255     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 256     ;;
 257 esac
 258
 259 AC_CONFIG_FILES([Makefile
 260                  po/guix/Makefile.in
 261                  po/packages/Makefile.in
 262                  guix/config.scm])
 263
 264 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 265 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 266 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 267   [chmod +x pre-inst-env])
 268 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 269
 270 AC_OUTPUT