gnu/system/vm.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   4 ;;; Copyright © 2016, 2017 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   6 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
   7 ;;; Copyright © 2018 Chris Marusich <cmmarusich@gmail.com>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  12 ;;; under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 3 of the License, or (at
  14 ;;; your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful, but
  17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu system vm)
  25   #:use-module (guix config)
  26   #:use-module (guix store)
  27   #:use-module (guix gexp)
  28   #:use-module (guix derivations)
  29   #:use-module (guix packages)
  30   #:use-module (guix monads)
  31   #:use-module (guix records)
  32   #:use-module (guix modules)
  33   #:use-module (guix utils)
  34   #:use-module (gcrypt hash)
  35   #:use-module (guix base32)
  36   #:use-module ((guix self) #:select (make-config.scm))
  37
  38   #:use-module ((gnu build vm)
  39                 #:select (qemu-command))
  40   #:use-module (gnu packages base)
  41   #:use-module (gnu packages bootloaders)
  42   #:use-module (gnu packages cdrom)
  43   #:use-module (gnu packages compression)
  44   #:use-module (gnu packages guile)
  45   #:autoload   (gnu packages gnupg) (guile-gcrypt)
  46   #:use-module (gnu packages gawk)
  47   #:use-module (gnu packages bash)
  48   #:use-module (gnu packages less)
  49   #:use-module (gnu packages virtualization)
  50   #:use-module (gnu packages disk)
  51   #:use-module (gnu packages zile)
  52   #:use-module (gnu packages linux)
  53   #:use-module ((gnu packages make-bootstrap)
  54                 #:select (%guile-static-stripped))
  55   #:use-module (gnu packages admin)
  56
  57   #:use-module (gnu bootloader)
  58   #:use-module (gnu bootloader grub)
  59   #:use-module (gnu system shadow)
  60   #:use-module (gnu system pam)
  61   #:use-module (gnu system linux-container)
  62   #:use-module (gnu system linux-initrd)
  63   #:use-module (gnu bootloader)
  64   #:use-module (gnu system file-systems)
  65   #:use-module (gnu system)
  66   #:use-module (gnu services)
  67   #:use-module (gnu services base)
  68   #:use-module (gnu system uuid)
  69
  70   #:use-module (srfi srfi-1)
  71   #:use-module (srfi srfi-26)
  72   #:use-module (rnrs bytevectors)
  73   #:use-module (ice-9 match)
  74
  75   #:export (expression->derivation-in-linux-vm
  76             qemu-image
  77             virtualized-operating-system
  78             system-qemu-image
  79
  80             system-qemu-image/shared-store
  81             system-qemu-image/shared-store-script
  82             system-disk-image
  83             system-docker-image
  84
  85             virtual-machine
  86             virtual-machine?))
  87
  88 \f
  89 ;;; Commentary:
  90 ;;;
  91 ;;; Tools to evaluate build expressions within virtual machines.
  92 ;;;
  93 ;;; Code:
  94
  95 (define %linux-vm-file-systems
  96   ;; File systems mounted for 'derivation-in-linux-vm'.  These are shared with
  97   ;; the host over 9p.
  98   ;;
  99   ;; The 9p documentation says that cache=loose is "intended for exclusive,
 100   ;; read-only mounts", without additional details.  It's much faster than the
 101   ;; default cache=none, especially when copying and registering store items.
 102   ;; Thus, use cache=loose, except for /xchg where we want to ensure
 103   ;; consistency.
 104   (list (file-system
 105           (mount-point (%store-prefix))
 106           (device "store")
 107           (type "9p")
 108           (needed-for-boot? #t)
 109           (flags '(read-only))
 110           (options "trans=virtio,cache=loose")
 111           (check? #f))
 112         (file-system
 113           (mount-point "/xchg")
 114           (device "xchg")
 115           (type "9p")
 116           (needed-for-boot? #t)
 117           (options "trans=virtio")
 118           (check? #f))
 119         (file-system
 120           (mount-point "/tmp")
 121           (device "tmp")
 122           (type "9p")
 123           (needed-for-boot? #t)
 124           (options "trans=virtio,cache=loose")
 125           (check? #f))))
 126
 127 (define not-config?
 128   ;; Select (guix …) and (gnu …) modules, except (guix config).
 129   (match-lambda
 130     (('guix 'config) #f)
 131     (('guix rest ...) #t)
 132     (('gnu rest ...) #t)
 133     (rest #f)))
 134
 135 (define gcrypt-sqlite3&co
 136   ;; Guile-Gcrypt, Guile-SQLite3, and their propagated inputs.
 137   (append-map (lambda (package)
 138                 (cons package
 139                       (match (package-transitive-propagated-inputs package)
 140                         (((labels packages) ...)
 141                          packages))))
 142               (list guile-gcrypt guile-sqlite3)))
 143
 144 (define* (expression->derivation-in-linux-vm name exp
 145                                              #:key
 146                                              (system (%current-system))
 147                                              (linux linux-libre)
 148                                              initrd
 149                                              (qemu qemu-minimal)
 150                                              (env-vars '())
 151                                              (guile-for-build
 152                                               (%guile-for-build))
 153                                              (file-systems
 154                                               %linux-vm-file-systems)
 155
 156                                              (single-file-output? #f)
 157                                              (make-disk-image? #f)
 158                                              (references-graphs #f)
 159                                              (memory-size 256)
 160                                              (disk-image-format "qcow2")
 161                                              (disk-image-size 'guess))
 162   "Evaluate EXP in a QEMU virtual machine running LINUX with INITRD (a
 163 derivation).  The virtual machine runs with MEMORY-SIZE MiB of memory.  In the
 164 virtual machine, EXP has access to FILE-SYSTEMS, which, by default, includes a
 165 9p share of the store, the '/xchg' where EXP should put its output file(s),
 166 and a 9p share of /tmp.
 167
 168 If SINGLE-FILE-OUTPUT? is true, copy a single file from '/xchg' to OUTPUT.
 169 Otherwise, copy the contents of /xchg to a new directory OUTPUT.
 170
 171 When MAKE-DISK-IMAGE? is true, then create a QEMU disk image of type
 172 DISK-IMAGE-FORMAT (e.g., 'qcow2' or 'raw'), of DISK-IMAGE-SIZE bytes and
 173 return it.  When DISK-IMAGE-SIZE is 'guess, estimate the image size based
 174 based on the size of the closure of REFERENCES-GRAPHS.
 175
 176 When REFERENCES-GRAPHS is true, it must be a list of file name/store path
 177 pairs, as for `derivation'.  The files containing the reference graphs are
 178 made available under the /xchg CIFS share."
 179   (define user-builder
 180     (program-file "builder-in-linux-vm" exp))
 181
 182   (define loader
 183     ;; Invoke USER-BUILDER instead using 'primitive-load'.  The reason for
 184     ;; this is to allow USER-BUILDER to dlopen stuff by using a full-featured
 185     ;; Guile, which it couldn't do using the statically-linked guile used in
 186     ;; the initrd.  See example at
 187     ;; <https://lists.gnu.org/archive/html/guix-devel/2017-10/msg00233.html>.
 188     (program-file "linux-vm-loader"
 189                   ;; When USER-BUILDER succeeds, reboot (indicating a
 190                   ;; success), otherwise die, which causes a kernel panic
 191                   ;; ("Attempted to kill init!").
 192                   #~(if (zero? (system* #$user-builder))
 193                         (reboot)
 194                         (exit 1))))
 195
 196   (let ((initrd (or initrd
 197                     (base-initrd file-systems
 198                                  #:on-error 'backtrace
 199                                  #:linux linux
 200                                  #:linux-modules %base-initrd-modules
 201                                  #:qemu-networking? #t))))
 202
 203     (define builder
 204       ;; Code that launches the VM that evaluates EXP.
 205       (with-extensions gcrypt-sqlite3&co
 206         (with-imported-modules `(,@(source-module-closure
 207                                     '((guix build utils)
 208                                       (gnu build vm))
 209                                     #:select? not-config?)
 210
 211                                  ;; For consumption by (gnu store database).
 212                                  ((guix config) => ,(make-config.scm)))
 213           #~(begin
 214               (use-modules (guix build utils)
 215                            (gnu build vm))
 216
 217               (let* ((inputs  '#$(list qemu (canonical-package coreutils)))
 218                      (linux   (string-append #$linux "/"
 219                                              #$(system-linux-image-file-name)))
 220                      (initrd  #$initrd)
 221                      (loader  #$loader)
 222                      (graphs  '#$(match references-graphs
 223                                    (((graph-files . _) ...) graph-files)
 224                                    (_ #f)))
 225                      (size    #$(if (eq? 'guess disk-image-size)
 226                                     #~(+ (* 70 (expt 2 20)) ;ESP
 227                                          (estimated-partition-size graphs))
 228                                     disk-image-size)))
 229
 230                 (set-path-environment-variable "PATH" '("bin") inputs)
 231
 232                 (load-in-linux-vm loader
 233                                   #:output #$output
 234                                   #:linux linux #:initrd initrd
 235                                   #:memory-size #$memory-size
 236                                   #:make-disk-image? #$make-disk-image?
 237                                   #:single-file-output? #$single-file-output?
 238                                   ;; FIXME: ‘target-arm32?’ may not operate on
 239                                   ;; the right system/target values.  Rewrite
 240                                   ;; using ‘let-system’ when available.
 241                                   #:target-arm32? #$(target-arm32?)
 242                                   #:disk-image-format #$disk-image-format
 243                                   #:disk-image-size size
 244                                   #:references-graphs graphs))))))
 245
 246     (gexp->derivation name builder
 247                       ;; TODO: Require the "kvm" feature.
 248                       #:system system
 249                       #:env-vars env-vars
 250                       #:guile-for-build guile-for-build
 251                       #:references-graphs references-graphs)))
 252
 253 (define (has-guix-service-type? os)
 254   "Return true if OS contains a service of the type GUIX-SERVICE-TYPE."
 255   (not (not (find (lambda (service)
 256                      (eq? (service-kind service) guix-service-type))
 257                    (operating-system-services os)))))
 258
 259 (define* (iso9660-image #:key
 260                         (name "iso9660-image")
 261                         file-system-label
 262                         file-system-uuid
 263                         (system (%current-system))
 264                         (qemu qemu-minimal)
 265                         os
 266                         bootcfg-drv
 267                         bootloader
 268                         (register-closures? (has-guix-service-type? os))
 269                         (inputs '())
 270                         (grub-mkrescue-environment '()))
 271   "Return a bootable, stand-alone iso9660 image.
 272
 273 INPUTS is a list of inputs (as for packages)."
 274   (define schema
 275     (and register-closures?
 276          (local-file (search-path %load-path
 277                                   "guix/store/schema.sql"))))
 278
 279   (expression->derivation-in-linux-vm
 280    name
 281    (with-extensions gcrypt-sqlite3&co
 282      (with-imported-modules `(,@(source-module-closure '((gnu build vm)
 283                                                          (guix store database)
 284                                                          (guix build utils))
 285                                                        #:select? not-config?)
 286                               ((guix config) => ,(make-config.scm)))
 287        #~(begin
 288            (use-modules (gnu build vm)
 289                         (guix store database)
 290                         (guix build utils))
 291
 292            (sql-schema #$schema)
 293
 294            ;; Allow non-ASCII file names--e.g., 'nss-certs'--to be decoded.
 295            (setenv "GUIX_LOCPATH"
 296                    #+(file-append glibc-utf8-locales "/lib/locale"))
 297            (setlocale LC_ALL "en_US.utf8")
 298
 299            (let ((inputs
 300                   '#$(append (list qemu parted e2fsprogs dosfstools xorriso)
 301                              (map canonical-package
 302                                   (list sed grep coreutils findutils gawk))))
 303
 304
 305                  (graphs     '#$(match inputs
 306                                   (((names . _) ...)
 307                                    names)))
 308                  ;; This variable is unused but allows us to add INPUTS-TO-COPY
 309                  ;; as inputs.
 310                  (to-register
 311                   '#$(map (match-lambda
 312                             ((name thing) thing)
 313                             ((name thing output) `(,thing ,output)))
 314                           inputs)))
 315
 316              (set-path-environment-variable "PATH" '("bin" "sbin") inputs)
 317              (make-iso9660-image #$xorriso
 318                                  '#$grub-mkrescue-environment
 319                                  #$(bootloader-package bootloader)
 320                                  #$bootcfg-drv
 321                                  #$os
 322                                  "/xchg/guixsd.iso"
 323                                  #:register-closures? #$register-closures?
 324                                  #:closures graphs
 325                                  #:volume-id #$file-system-label
 326                                  #:volume-uuid #$(and=> file-system-uuid
 327                                                         uuid-bytevector))))))
 328    #:system system
 329
 330    ;; Keep a local file system for /tmp so that we can populate it directly as
 331    ;; root and have files owned by root.  See <https://bugs.gnu.org/31752>.
 332    #:file-systems (remove (lambda (file-system)
 333                             (string=? (file-system-mount-point file-system)
 334                                       "/tmp"))
 335                           %linux-vm-file-systems)
 336
 337    #:make-disk-image? #f
 338    #:single-file-output? #t
 339    #:references-graphs inputs
 340
 341    ;; Xorriso seems to be quite memory-hungry, so increase the VM's RAM size.
 342    #:memory-size 512))
 343
 344 (define* (qemu-image #:key
 345                      (name "qemu-image")
 346                      (system (%current-system))
 347                      (qemu qemu-minimal)
 348                      (disk-image-size 'guess)
 349                      (disk-image-format "qcow2")
 350                      (file-system-type "ext4")
 351                      file-system-label
 352                      file-system-uuid
 353                      os
 354                      bootcfg-drv
 355                      bootloader
 356                      (register-closures? (has-guix-service-type? os))
 357                      (inputs '())
 358                      copy-inputs?)
 359   "Return a bootable, stand-alone QEMU image of type DISK-IMAGE-FORMAT (e.g.,
 360 'qcow2' or 'raw'), with a root partition of type FILE-SYSTEM-TYPE.
 361 Optionally, FILE-SYSTEM-LABEL can be specified as the volume name for the root
 362 partition; likewise FILE-SYSTEM-UUID, if true, specifies the UUID of the root
 363 partition (a UUID object).
 364
 365 The returned image is a full disk image that runs OS-DERIVATION,
 366 with a GRUB installation that uses GRUB-CONFIGURATION as its configuration
 367 file (GRUB-CONFIGURATION must be the name of a file in the VM.)
 368
 369 INPUTS is a list of inputs (as for packages).  When COPY-INPUTS? is true, copy
 370 all of INPUTS into the image being built.  When REGISTER-CLOSURES? is true,
 371 register INPUTS in the store database of the image so that Guix can be used in
 372 the image.  By default, REGISTER-CLOSURES? is set to true only if a service of
 373 type GUIX-SERVICE-TYPE is present in the services definition of the operating
 374 system."
 375   (define schema
 376     (and register-closures?
 377          (local-file (search-path %load-path
 378                                   "guix/store/schema.sql"))))
 379
 380   (expression->derivation-in-linux-vm
 381    name
 382    (with-extensions gcrypt-sqlite3&co
 383      (with-imported-modules `(,@(source-module-closure '((gnu build vm)
 384                                                          (gnu build bootloader)
 385                                                          (guix store database)
 386                                                          (guix build utils))
 387                                                        #:select? not-config?)
 388                               ((guix config) => ,(make-config.scm)))
 389        #~(begin
 390            (use-modules (gnu build bootloader)
 391                         (gnu build vm)
 392                         (guix store database)
 393                         (guix build utils)
 394                         (srfi srfi-26)
 395                         (ice-9 binary-ports))
 396
 397            (sql-schema #$schema)
 398
 399            ;; Allow non-ASCII file names--e.g., 'nss-certs'--to be decoded.
 400            (setenv "GUIX_LOCPATH"
 401                    #+(file-append glibc-utf8-locales "/lib/locale"))
 402            (setlocale LC_ALL "en_US.utf8")
 403
 404            (let ((inputs
 405                   '#$(append (list qemu parted e2fsprogs dosfstools)
 406                              (map canonical-package
 407                                   (list sed grep coreutils findutils gawk))))
 408
 409                  ;; This variable is unused but allows us to add INPUTS-TO-COPY
 410                  ;; as inputs.
 411                  (to-register
 412                   '#$(map (match-lambda
 413                             ((name thing) thing)
 414                             ((name thing output) `(,thing ,output)))
 415                           inputs)))
 416
 417              (set-path-environment-variable "PATH" '("bin" "sbin") inputs)
 418
 419              (let* ((graphs     '#$(match inputs
 420                                      (((names . _) ...)
 421                                       names)))
 422                     (initialize (root-partition-initializer
 423                                  #:closures graphs
 424                                  #:copy-closures? #$copy-inputs?
 425                                  #:register-closures? #$register-closures?
 426                                  #:system-directory #$os
 427
 428                                  ;; Disable deduplication to speed things up,
 429                                  ;; and because it doesn't help much for a
 430                                  ;; single system generation.
 431                                  #:deduplicate? #f))
 432                     (root-size  #$(if (eq? 'guess disk-image-size)
 433                                       #~(max
 434                                          ;; Minimum 20 MiB root size
 435                                          (* 20 (expt 2 20))
 436                                          (estimated-partition-size
 437                                           (map (cut string-append "/xchg/" <>)
 438                                                graphs)))
 439                                       (- disk-image-size
 440                                          (* 50 (expt 2 20)))))
 441                     (partitions
 442                      (append
 443                       (list (partition
 444                              (size root-size)
 445                              (label #$file-system-label)
 446                              (uuid #$(and=> file-system-uuid
 447                                             uuid-bytevector))
 448                              (file-system #$file-system-type)
 449                              (flags '(boot))
 450                              (initializer initialize)))
 451                       ;; Append a small EFI System Partition for use with UEFI
 452                       ;; bootloaders if we are not targeting ARM because UEFI
 453                       ;; support in U-Boot is experimental.
 454                       ;;
 455                       ;; FIXME: ‘target-arm32?’ may be not operate on the right
 456                       ;; system/target values.  Rewrite using ‘let-system’ when
 457                       ;; available.
 458                       (if #$(target-arm32?)
 459                           '()
 460                           (list (partition
 461                                  ;; The standalone grub image is about 10MiB, but
 462                                  ;; leave some room for custom or multiple images.
 463                                  (size (* 40 (expt 2 20)))
 464                                  (label "GNU-ESP") ;cosmetic only
 465                                  ;; Use "vfat" here since this property is used
 466                                  ;; when mounting. The actual FAT-ness is based
 467                                  ;; on file system size (16 in this case).
 468                                  (file-system "vfat")
 469                                  (flags '(esp))))))))
 470                (initialize-hard-disk "/dev/vda"
 471                                      #:partitions partitions
 472                                      #:grub-efi #$grub-efi
 473                                      #:bootloader-package
 474                                      #$(bootloader-package bootloader)
 475                                      #:bootcfg #$bootcfg-drv
 476                                      #:bootcfg-location
 477                                      #$(bootloader-configuration-file bootloader)
 478                                      #:bootloader-installer
 479                                      #$(bootloader-installer bootloader)))))))
 480    #:system system
 481    #:make-disk-image? #t
 482    #:disk-image-size disk-image-size
 483    #:disk-image-format disk-image-format
 484    #:references-graphs inputs))
 485
 486 (define* (system-docker-image os
 487                               #:key
 488                               (name "guix-docker-image")
 489                               (register-closures? (has-guix-service-type? os)))
 490   "Build a docker image.  OS is the desired <operating-system>.  NAME is the
 491 base name to use for the output file.  When REGISTER-CLOSURES? is true,
 492 register the closure of OS with Guix in the resulting Docker image.  By
 493 default, REGISTER-CLOSURES? is set to true only if a service of type
 494 GUIX-SERVICE-TYPE is present in the services definition of the operating
 495 system."
 496   (define schema
 497     (and register-closures?
 498          (local-file (search-path %load-path
 499                                   "guix/store/schema.sql"))))
 500
 501   (define boot-program
 502     ;; Program that runs the boot script of OS, which in turn starts shepherd.
 503     (program-file "boot-program"
 504                   #~(let ((system (cadr (command-line))))
 505                       (setenv "GUIX_NEW_SYSTEM" system)
 506                       (execl #$(file-append guile-2.2 "/bin/guile")
 507                              "guile" "--no-auto-compile"
 508                              (string-append system "/boot")))))
 509
 510
 511   (let ((os    (operating-system-with-gc-roots
 512                 (containerized-operating-system os '())
 513                 (list boot-program)))
 514         (name  (string-append name ".tar.gz"))
 515         (graph "system-graph"))
 516     (define build
 517       (with-extensions (cons guile-json-3         ;for (guix docker)
 518                              gcrypt-sqlite3&co)   ;for (guix store database)
 519         (with-imported-modules `(,@(source-module-closure
 520                                     '((guix docker)
 521                                       (guix store database)
 522                                       (guix build utils)
 523                                       (guix build store-copy)
 524                                       (gnu build vm))
 525                                     #:select? not-config?)
 526                                  ((guix config) => ,(make-config.scm)))
 527           #~(begin
 528               (use-modules (guix docker)
 529                            (guix build utils)
 530                            (gnu build vm)
 531                            (srfi srfi-19)
 532                            (guix build store-copy)
 533                            (guix store database))
 534
 535               ;; Set the SQL schema location.
 536               (sql-schema #$schema)
 537
 538               ;; Allow non-ASCII file names--e.g., 'nss-certs'--to be decoded.
 539               (setenv "GUIX_LOCPATH"
 540                       #+(file-append glibc-utf8-locales "/lib/locale"))
 541               (setlocale LC_ALL "en_US.utf8")
 542
 543               (let* (;; This initializer requires elevated privileges that are
 544                      ;; not normally available in the build environment (e.g.,
 545                      ;; it needs to create device nodes).  In order to obtain
 546                      ;; such privileges, we run it as root in a VM.
 547                      (initialize (root-partition-initializer
 548                                   #:closures '(#$graph)
 549                                   #:register-closures? #$register-closures?
 550                                   #:system-directory #$os
 551                                   ;; De-duplication would fail due to
 552                                   ;; cross-device link errors, so don't do it.
 553                                   #:deduplicate? #f))
 554                      ;; Even as root in a VM, the initializer would fail due to
 555                      ;; lack of privileges if we use a root-directory that is on
 556                      ;; a file system that is shared with the host (e.g., /tmp).
 557                      (root-directory "/guixsd-system-root"))
 558                 (set-path-environment-variable "PATH" '("bin" "sbin") '(#+tar))
 559                 (mkdir root-directory)
 560                 (initialize root-directory)
 561                 (build-docker-image
 562                  (string-append "/xchg/" #$name) ;; The output file.
 563                  (cons* root-directory
 564                         (map store-info-item
 565                              (call-with-input-file
 566                                  (string-append "/xchg/" #$graph)
 567                                read-reference-graph)))
 568                  #$os
 569                  #:entry-point '(#$boot-program #$os)
 570                  #:compressor '(#+(file-append gzip "/bin/gzip") "-9n")
 571                  #:creation-time (make-time time-utc 0 1)
 572                  #:transformations `((,root-directory -> ""))))))))
 573
 574     (expression->derivation-in-linux-vm
 575      name build
 576      #:make-disk-image? #f
 577      #:single-file-output? #t
 578      #:references-graphs `((,graph ,os)))))
 579
 580 \f
 581 ;;;
 582 ;;; VM and disk images.
 583 ;;;
 584
 585 (define* (operating-system-uuid os #:optional (type 'dce))
 586   "Compute UUID object with a deterministic \"UUID\" for OS, of the given
 587 TYPE (one of 'iso9660 or 'dce).  Return a UUID object."
 588   ;; Note: For this to be deterministic, we must not hash things that contains
 589   ;; (directly or indirectly) procedures, for example.  That rules out
 590   ;; anything that contains gexps, thunk or delayed record fields, etc.
 591
 592   (define service-name
 593     (compose service-type-name service-kind))
 594
 595   (define (file-system-digest fs)
 596     ;; Return a hashable digest that does not contain 'dependencies' since
 597     ;; this field can contain procedures.
 598     (let ((device (file-system-device fs)))
 599       (list (file-system-mount-point fs)
 600             (file-system-type fs)
 601             (cond ((file-system-label? device)
 602                    (file-system-label->string device))
 603                   ((uuid? device)
 604                    (uuid->string device))
 605                   ((string? device)
 606                    device)
 607                   (else #f))
 608             (file-system-options fs))))
 609
 610   (if (eq? type 'iso9660)
 611       (let ((pad (compose (cut string-pad <> 2 #\0)
 612                           number->string))
 613             (h   (hash (map service-name (operating-system-services os))
 614                        3600)))
 615         (bytevector->uuid
 616          (string->iso9660-uuid
 617           (string-append "1970-01-01-"
 618                          (pad (hash (operating-system-host-name os) 24)) "-"
 619                          (pad (quotient h 60)) "-"
 620                          (pad (modulo h 60)) "-"
 621                          (pad (hash (map file-system-digest
 622                                          (operating-system-file-systems os))
 623                                     100))))
 624          'iso9660))
 625       (bytevector->uuid
 626        (uint-list->bytevector
 627         (list (hash file-system-type
 628                     (- (expt 2 32) 1))
 629               (hash (operating-system-host-name os)
 630                     (- (expt 2 32) 1))
 631               (hash (map service-name (operating-system-services os))
 632                     (- (expt 2 32) 1))
 633               (hash (map file-system-digest (operating-system-file-systems os))
 634                     (- (expt 2 32) 1)))
 635         (endianness little)
 636         4)
 637        type)))
 638
 639 (define* (system-disk-image os
 640                             #:key
 641                             (name "disk-image")
 642                             (file-system-type "ext4")
 643                             (disk-image-size (* 900 (expt 2 20)))
 644                             (volatile? #t))
 645   "Return the derivation of a disk image of DISK-IMAGE-SIZE bytes of the
 646 system described by OS.  Said image can be copied on a USB stick as is.  When
 647 VOLATILE? is true, the root file system is made volatile; this is useful
 648 to USB sticks meant to be read-only."
 649   (define normalize-label
 650     ;; ISO labels are all-caps (case-insensitive), but since
 651     ;; 'find-partition-by-label' is case-sensitive, make it all-caps here.
 652     (if (string=? "iso9660" file-system-type)
 653         string-upcase
 654         identity))
 655
 656   (define root-label
 657     ;; Volume name of the root file system.
 658     (normalize-label "Guix_image"))
 659
 660   (define (root-uuid os)
 661     ;; UUID of the root file system, computed in a deterministic fashion.
 662     ;; This is what we use to locate the root file system so it has to be
 663     ;; different from the user's own file system UUIDs.
 664     (operating-system-uuid os
 665                            (if (string=? file-system-type "iso9660")
 666                                'iso9660
 667                                'dce)))
 668
 669   (define file-systems-to-keep
 670     (remove (lambda (fs)
 671               (string=? (file-system-mount-point fs) "/"))
 672             (operating-system-file-systems os)))
 673
 674   (let* ((os (operating-system (inherit os)
 675                ;; Since this is meant to be used on real hardware, don't
 676                ;; install QEMU networking or anything like that.  Assume USB
 677                ;; mass storage devices (usb-storage.ko) are available.
 678                (initrd (lambda (file-systems . rest)
 679                          (apply (operating-system-initrd os)
 680                                 file-systems
 681                                 #:volatile-root? #t
 682                                 rest)))
 683
 684                (bootloader (if (string=? "iso9660" file-system-type)
 685                                (bootloader-configuration
 686                                  (inherit (operating-system-bootloader os))
 687                                  (bootloader grub-mkrescue-bootloader))
 688                                (operating-system-bootloader os)))
 689
 690                ;; Force our own root file system.  (We need a "/" file system
 691                ;; to call 'root-uuid'.)
 692                (file-systems (cons (file-system
 693                                      (mount-point "/")
 694                                      (device "/dev/placeholder")
 695                                      (type file-system-type))
 696                                    file-systems-to-keep))))
 697          (uuid (root-uuid os))
 698          (os (operating-system
 699                (inherit os)
 700                (file-systems (cons (file-system
 701                                      (mount-point "/")
 702                                      (device uuid)
 703                                      (type file-system-type))
 704                                    file-systems-to-keep))))
 705         (bootcfg (operating-system-bootcfg os)))
 706     (if (string=? "iso9660" file-system-type)
 707         (iso9660-image #:name name
 708                        #:file-system-label root-label
 709                        #:file-system-uuid uuid
 710                        #:os os
 711                        #:bootcfg-drv bootcfg
 712                        #:bootloader (bootloader-configuration-bootloader
 713                                      (operating-system-bootloader os))
 714                        #:inputs `(("system" ,os)
 715                                   ("bootcfg" ,bootcfg))
 716                        #:grub-mkrescue-environment
 717                        '(("MKRESCUE_SED_MODE" . "mbr_hfs")))
 718         (qemu-image #:name name
 719                     #:os os
 720                     #:bootcfg-drv bootcfg
 721                     #:bootloader (bootloader-configuration-bootloader
 722                                   (operating-system-bootloader os))
 723                     #:disk-image-size disk-image-size
 724                     #:disk-image-format "raw"
 725                     #:file-system-type file-system-type
 726                     #:file-system-label root-label
 727                     #:file-system-uuid uuid
 728                     #:copy-inputs? #t
 729                     #:inputs `(("system" ,os)
 730                                ("bootcfg" ,bootcfg))))))
 731
 732 (define* (system-qemu-image os
 733                             #:key
 734                             (file-system-type "ext4")
 735                             (disk-image-size (* 900 (expt 2 20))))
 736   "Return the derivation of a freestanding QEMU image of DISK-IMAGE-SIZE bytes
 737 of the GNU system as described by OS."
 738   (define file-systems-to-keep
 739     ;; Keep only file systems other than root and not normally bound to real
 740     ;; devices.
 741     (remove (lambda (fs)
 742               (let ((target (file-system-mount-point fs))
 743                     (source (file-system-device fs)))
 744                 (or (string=? target "/")
 745                     (string-prefix? "/dev/" source))))
 746             (operating-system-file-systems os)))
 747
 748   (define root-uuid
 749     ;; UUID of the root file system.
 750     (operating-system-uuid os
 751                            (if (string=? file-system-type "iso9660")
 752                                'iso9660
 753                                'dce)))
 754
 755
 756   (let* ((os (operating-system (inherit os)
 757                ;; Assume we have an initrd with the whole QEMU shebang.
 758
 759                ;; Force our own root file system.  Refer to it by UUID so that
 760                ;; it works regardless of how the image is used ("qemu -hda",
 761                ;; Xen, etc.).
 762                (file-systems (cons (file-system
 763                                      (mount-point "/")
 764                                      (device root-uuid)
 765                                      (type file-system-type))
 766                                    file-systems-to-keep))))
 767          (bootcfg (operating-system-bootcfg os)))
 768     (qemu-image  #:os os
 769                  #:bootcfg-drv bootcfg
 770                  #:bootloader (bootloader-configuration-bootloader
 771                                (operating-system-bootloader os))
 772                  #:disk-image-size disk-image-size
 773                  #:file-system-type file-system-type
 774                  #:file-system-uuid root-uuid
 775                  #:inputs `(("system" ,os)
 776                             ("bootcfg" ,bootcfg))
 777                  #:copy-inputs? #t)))
 778
 779 \f
 780 ;;;
 781 ;;; VMs that share file systems with the host.
 782 ;;;
 783
 784 (define (file-system->mount-tag fs)
 785   "Return a 9p mount tag for host file system FS."
 786   ;; QEMU mount tags must be ASCII, at most 31-byte long, cannot contain
 787   ;; slashes, and cannot start with '_'.  Compute an identifier that
 788   ;; corresponds to the rules.
 789   (string-append "TAG"
 790                  (string-drop (bytevector->base32-string
 791                                (sha1 (string->utf8 fs)))
 792                               4)))
 793
 794 (define (mapping->file-system mapping)
 795   "Return a 9p file system that realizes MAPPING."
 796   (match mapping
 797     (($ <file-system-mapping> source target writable?)
 798      (file-system
 799        (mount-point target)
 800        (device (file-system->mount-tag source))
 801        (type "9p")
 802        (flags (if writable? '() '(read-only)))
 803        (options "trans=virtio,cache=loose")
 804        (check? #f)
 805        (create-mount-point? #t)))))
 806
 807 (define* (virtualized-operating-system os mappings #:optional (full-boot? #f))
 808   "Return an operating system based on OS suitable for use in a virtualized
 809 environment with the store shared with the host.  MAPPINGS is a list of
 810 <file-system-mapping> to realize in the virtualized OS."
 811   (define user-file-systems
 812     ;; Remove file systems that conflict with those added below, or that are
 813     ;; normally bound to real devices.
 814     (remove (lambda (fs)
 815               (let ((target (file-system-mount-point fs))
 816                     (source (file-system-device fs)))
 817                 (or (string=? target (%store-prefix))
 818                     (string=? target "/")
 819                     (and (string? source)
 820                          (string-prefix? "/dev/" source))
 821
 822                     ;; Labels and UUIDs are necessarily invalid in the VM.
 823                     (and (file-system-mount? fs)
 824                          (or (file-system-label? source)
 825                              (uuid? source))))))
 826             (operating-system-file-systems os)))
 827
 828   (define virtual-file-systems
 829     (cons (file-system
 830             (mount-point "/")
 831             (device "/dev/vda1")
 832             (type "ext4"))
 833
 834           (append (map mapping->file-system mappings)
 835                   user-file-systems)))
 836
 837   (operating-system (inherit os)
 838
 839     ;; XXX: Until we run QEMU with UEFI support (with the OVMF firmware),
 840     ;; force the traditional i386/BIOS method.
 841     ;; See <https://bugs.gnu.org/28768>.
 842     (bootloader (bootloader-configuration
 843                   (inherit (operating-system-bootloader os))
 844                   (bootloader grub-bootloader)
 845                   (target "/dev/vda")))
 846
 847     (initrd (lambda (file-systems . rest)
 848               (apply (operating-system-initrd os)
 849                      file-systems
 850                      #:volatile-root? #t
 851                      rest)))
 852
 853     ;; Disable swap.
 854     (swap-devices '())
 855
 856     ;; XXX: When FULL-BOOT? is true, do not add a 9p mount for /gnu/store
 857     ;; since that would lead the bootloader config to look for the kernel and
 858     ;; initrd in it.
 859     (file-systems (if full-boot?
 860                       virtual-file-systems
 861                       (cons
 862                        (file-system
 863                          (inherit (mapping->file-system %store-mapping))
 864                          (needed-for-boot? #t))
 865                        virtual-file-systems)))))
 866
 867 (define* (system-qemu-image/shared-store
 868           os
 869           #:key
 870           full-boot?
 871           (disk-image-size (* (if full-boot? 500 30) (expt 2 20))))
 872   "Return a derivation that builds a QEMU image of OS that shares its store
 873 with the host.
 874
 875 When FULL-BOOT? is true, return an image that does a complete boot sequence,
 876 bootloaded included; thus, make a disk image that contains everything the
 877 bootloader refers to: OS kernel, initrd, bootloader data, etc."
 878   (define root-uuid
 879     ;; Use a fixed UUID to improve determinism.
 880     (operating-system-uuid os 'dce))
 881
 882   (define bootcfg
 883     (operating-system-bootcfg os))
 884
 885   ;; XXX: When FULL-BOOT? is true, we end up creating an image that contains
 886   ;; BOOTCFG and all its dependencies, including the output of OS.
 887   ;; This is more than needed (we only need the kernel, initrd, GRUB for its
 888   ;; font, and the background image), but it's hard to filter that.
 889   (qemu-image #:os os
 890               #:bootcfg-drv bootcfg
 891               #:bootloader (bootloader-configuration-bootloader
 892                             (operating-system-bootloader os))
 893               #:disk-image-size disk-image-size
 894               #:file-system-uuid root-uuid
 895               #:inputs (if full-boot?
 896                            `(("bootcfg" ,bootcfg))
 897                            '())
 898
 899               ;; XXX: Passing #t here is too slow, so let it off by default.
 900               #:register-closures? #f
 901               #:copy-inputs? full-boot?))
 902
 903 (define* (common-qemu-options image shared-fs)
 904   "Return the a string-value gexp with the common QEMU options to boot IMAGE,
 905 with '-virtfs' options for the host file systems listed in SHARED-FS."
 906
 907   (define (virtfs-option fs)
 908     #~(format #f "-virtfs local,path=~s,security_model=none,mount_tag=~s"
 909               #$fs #$(file-system->mount-tag fs)))
 910
 911   #~(;; Only enable kvm if we see /dev/kvm exists.
 912      ;; This allows users without hardware virtualization to still use these
 913      ;; commands.
 914      #$@(if (file-exists? "/dev/kvm")
 915             '("-enable-kvm")
 916             '())
 917
 918      "-no-reboot"
 919      "-net nic,model=virtio"
 920      "-object" "rng-random,filename=/dev/urandom,id=guixsd-vm-rng"
 921      "-device" "virtio-rng-pci,rng=guixsd-vm-rng"
 922
 923      #$@(map virtfs-option shared-fs)
 924      "-vga std"
 925      (format #f "-drive file=~a,if=virtio,cache=writeback,werror=report,readonly"
 926              #$image)))
 927
 928 (define* (system-qemu-image/shared-store-script os
 929                                                 #:key
 930                                                 (qemu qemu)
 931                                                 (graphic? #t)
 932                                                 (memory-size 256)
 933                                                 (mappings '())
 934                                                 full-boot?
 935                                                 (disk-image-size
 936                                                  (* (if full-boot? 500 70)
 937                                                     (expt 2 20)))
 938                                                 (options '()))
 939   "Return a derivation that builds a script to run a virtual machine image of
 940 OS that shares its store with the host.  The virtual machine runs with
 941 MEMORY-SIZE MiB of memory.
 942
 943 MAPPINGS is a list of <file-system-mapping> specifying mapping of host file
 944 systems into the guest.
 945
 946 When FULL-BOOT? is true, the returned script runs everything starting from the
 947 bootloader; otherwise it directly starts the operating system kernel.  The
 948 DISK-IMAGE-SIZE parameter specifies the size in bytes of the root disk image;
 949 it is mostly useful when FULL-BOOT?  is true."
 950   (mlet* %store-monad ((os ->  (virtualized-operating-system os mappings full-boot?))
 951                        (image  (system-qemu-image/shared-store
 952                                 os
 953                                 #:full-boot? full-boot?
 954                                 #:disk-image-size disk-image-size)))
 955     (define kernel-arguments
 956       #~(list #$@(if graphic? #~() #~("console=ttyS0"))
 957               #+@(operating-system-kernel-arguments os "/dev/vda1")))
 958
 959     (define qemu-exec
 960       #~(list (string-append #$qemu "/bin/" #$(qemu-command (%current-system)))
 961               #$@(if full-boot?
 962                      #~()
 963                      #~("-kernel" #$(operating-system-kernel-file os)
 964                         "-initrd" #$(file-append os "/initrd")
 965                         (format #f "-append ~s"
 966                                 (string-join #$kernel-arguments " "))))
 967               #$@(common-qemu-options image
 968                                       (map file-system-mapping-source
 969                                            (cons %store-mapping mappings)))
 970               "-m " (number->string #$memory-size)
 971               #$@options))
 972
 973     (define builder
 974       #~(call-with-output-file #$output
 975           (lambda (port)
 976             (format port "#!~a~% exec ~a \"$@\"~%"
 977                     #$(file-append bash "/bin/sh")
 978                     (string-join #$qemu-exec " "))
 979             (chmod port #o555))))
 980
 981     (gexp->derivation "run-vm.sh" builder)))
 982
 983 \f
 984 ;;;
 985 ;;; High-level abstraction.
 986 ;;;
 987
 988 (define-record-type* <virtual-machine> %virtual-machine
 989   make-virtual-machine
 990   virtual-machine?
 991   (operating-system virtual-machine-operating-system) ;<operating-system>
 992   (qemu             virtual-machine-qemu              ;<package>
 993                     (default qemu))
 994   (graphic?         virtual-machine-graphic?      ;Boolean
 995                     (default #f))
 996   (memory-size      virtual-machine-memory-size   ;integer (MiB)
 997                     (default 256))
 998   (disk-image-size  virtual-machine-disk-image-size   ;integer (bytes)
 999                     (default 'guess))
1000   (port-forwardings virtual-machine-port-forwardings ;list of integer pairs
1001                     (default '())))
1002
1003 (define-syntax virtual-machine
1004   (syntax-rules ()
1005     "Declare a virtual machine running the specified OS, with the given
1006 options."
1007     ((_ os)                                       ;shortcut
1008      (%virtual-machine (operating-system os)))
1009     ((_ fields ...)
1010      (%virtual-machine fields ...))))
1011
1012 (define (port-forwardings->qemu-options forwardings)
1013   "Return the QEMU option for the given port FORWARDINGS as a string, where
1014 FORWARDINGS is a list of host-port/guest-port pairs."
1015   (string-join
1016    (map (match-lambda
1017           ((host-port . guest-port)
1018            (string-append "hostfwd=tcp::"
1019                           (number->string host-port)
1020                           "-:" (number->string guest-port))))
1021         forwardings)
1022    ","))
1023
1024 (define-gexp-compiler (virtual-machine-compiler (vm <virtual-machine>)
1025                                                 system target)
1026   ;; XXX: SYSTEM and TARGET are ignored.
1027   (match vm
1028     (($ <virtual-machine> os qemu graphic? memory-size disk-image-size ())
1029      (system-qemu-image/shared-store-script os
1030                                             #:qemu qemu
1031                                             #:graphic? graphic?
1032                                             #:memory-size memory-size
1033                                             #:disk-image-size
1034                                             disk-image-size))
1035     (($ <virtual-machine> os qemu graphic? memory-size disk-image-size
1036                           forwardings)
1037      (let ((options
1038             `("-net" ,(string-append
1039                        "user,"
1040                        (port-forwardings->qemu-options forwardings)))))
1041        (system-qemu-image/shared-store-script os
1042                                               #:qemu qemu
1043                                               #:graphic? graphic?
1044                                               #:memory-size memory-size
1045                                               #:disk-image-size
1046                                               disk-image-size
1047                                               #:options options)))))
1048
1049 ;;; vm.scm ends here