gnu/system/linux-initrd.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu system linux-initrd)
  23   #:use-module (guix monads)
  24   #:use-module (guix store)
  25   #:use-module (guix gexp)
  26   #:use-module (guix utils)
  27   #:use-module ((guix store)
  28                 #:select (%store-prefix))
  29   #:use-module ((guix derivations)
  30                 #:select (derivation->output-path))
  31   #:use-module (guix modules)
  32   #:use-module (gnu packages compression)
  33   #:use-module (gnu packages disk)
  34   #:use-module (gnu packages linux)
  35   #:use-module (gnu packages guile)
  36   #:use-module ((gnu packages make-bootstrap)
  37                 #:select (%guile-static-stripped))
  38   #:use-module (gnu system file-systems)
  39   #:use-module (gnu system mapped-devices)
  40   #:use-module (ice-9 match)
  41   #:use-module (ice-9 regex)
  42   #:use-module (srfi srfi-1)
  43   #:use-module (srfi srfi-26)
  44   #:export (expression->initrd
  45             raw-initrd
  46             file-system-packages
  47             base-initrd))
  48
  49 \f
  50 ;;; Commentary:
  51 ;;;
  52 ;;; Tools to build initial RAM disks (initrd's) for Linux-Libre, and in
  53 ;;; particular initrd's that run Guile.
  54 ;;;
  55 ;;; Code:
  56
  57
  58 (define* (expression->initrd exp
  59                              #:key
  60                              (guile %guile-static-stripped)
  61                              (gzip gzip)
  62                              (name "guile-initrd")
  63                              (system (%current-system)))
  64   "Return a derivation that builds a Linux initrd (a gzipped cpio archive)
  65 containing GUILE and that evaluates EXP, a G-expression, upon booting.  All
  66 the derivations referenced by EXP are automatically copied to the initrd."
  67
  68   ;; General Linux overview in `Documentation/early-userspace/README' and
  69   ;; `Documentation/filesystems/ramfs-rootfs-initramfs.txt'.
  70
  71   (define init
  72     (program-file "init" exp #:guile guile))
  73
  74   (define builder
  75     (with-imported-modules (source-module-closure
  76                             '((gnu build linux-initrd)))
  77       #~(begin
  78           (use-modules (gnu build linux-initrd))
  79
  80           (mkdir #$output)
  81
  82           ;; The guile used in the initrd must be present in the store, so
  83           ;; that module loading works once the root is switched.
  84           ;;
  85           ;; To ensure that is the case, add an explicit reference to the
  86           ;; guile package used in the initrd to the output.
  87           ;;
  88           ;; This fixes guix-patches bug #28399, "Fix mysql activation, and
  89           ;; add a basic test".
  90           (call-with-output-file (string-append #$ output "/references")
  91             (lambda (port)
  92               (simple-format port "~A\n" #$guile)))
  93
  94           (build-initrd (string-append #$output "/initrd")
  95                         #:guile #$guile
  96                         #:init #$init
  97                         ;; Copy everything INIT refers to into the initrd.
  98                         #:references-graphs '("closure")
  99                         #:gzip (string-append #$gzip "/bin/gzip")))))
 100
 101   (gexp->derivation name builder
 102                     #:references-graphs `(("closure" ,init))))
 103
 104 (define (flat-linux-module-directory linux modules)
 105   "Return a flat directory containing the Linux kernel modules listed in
 106 MODULES and taken from LINUX."
 107   (define build-exp
 108     (with-imported-modules (source-module-closure
 109                             '((guix build utils)
 110                               (gnu build linux-modules)))
 111       #~(begin
 112           (use-modules (ice-9 match) (ice-9 regex)
 113                        (srfi srfi-1)
 114                        (guix build utils)
 115                        (gnu build linux-modules))
 116
 117           (define (string->regexp str)
 118             ;; Return a regexp that matches STR exactly.
 119             (string-append "^" (regexp-quote str) "$"))
 120
 121           (define module-dir
 122             (string-append #$linux "/lib/modules"))
 123
 124           (define (lookup module)
 125             (let ((name (ensure-dot-ko module)))
 126               (match (find-files module-dir (string->regexp name))
 127                 ((file)
 128                  file)
 129                 (()
 130                  (error "module not found" name module-dir))
 131                 ((_ ...)
 132                  (error "several modules by that name"
 133                         name module-dir)))))
 134
 135           (define modules
 136             (let ((modules (map lookup '#$modules)))
 137               (append modules
 138                       (recursive-module-dependencies modules
 139                                                      #:lookup-module lookup))))
 140
 141           (mkdir #$output)
 142           (for-each (lambda (module)
 143                       (format #t "copying '~a'...~%" module)
 144                       (copy-file module
 145                                  (string-append #$output "/"
 146                                                 (basename module))))
 147                     (delete-duplicates modules)))))
 148
 149   (computed-file "linux-modules" build-exp))
 150
 151 (define* (raw-initrd file-systems
 152                       #:key
 153                       (linux linux-libre)
 154                       (linux-modules '())
 155                       (mapped-devices '())
 156                       (helper-packages '())
 157                       qemu-networking?
 158                       volatile-root?
 159                       (on-error 'debug))
 160   "Return a monadic derivation that builds a raw initrd, with kernel
 161 modules taken from LINUX.  FILE-SYSTEMS is a list of file-systems to be
 162 mounted by the initrd, possibly in addition to the root file system specified
 163 on the kernel command line via '--root'. LINUX-MODULES is a list of kernel
 164 modules to be loaded at boot time. MAPPED-DEVICES is a list of device
 165 mappings to realize before FILE-SYSTEMS are mounted.
 166 HELPER-PACKAGES is a list of packages to be copied in the initrd. It may include
 167 e2fsck/static or other packages needed by the initrd to check root partition.
 168
 169 When QEMU-NETWORKING? is true, set up networking with the standard QEMU
 170 parameters.
 171
 172 When VOLATILE-ROOT? is true, the root file system is writable but any changes
 173 to it are lost.
 174
 175 ON-ERROR is passed to 'call-with-error-handling'; it determines what happens
 176 upon error."
 177   (define device-mapping-commands
 178     ;; List of gexps to open the mapped devices.
 179     (map (lambda (md)
 180            (let* ((source (mapped-device-source md))
 181                   (target (mapped-device-target md))
 182                   (type   (mapped-device-type md))
 183                   (open   (mapped-device-kind-open type)))
 184              (open source target)))
 185          mapped-devices))
 186
 187   (define kodir
 188     (flat-linux-module-directory linux linux-modules))
 189
 190   (expression->initrd
 191    (with-imported-modules (source-module-closure
 192                            '((gnu build linux-boot)
 193                              (guix build utils)
 194                              (guix build bournish)
 195                              (gnu system file-systems)
 196                              (gnu build file-systems)))
 197      #~(begin
 198          (use-modules (gnu build linux-boot)
 199                       (gnu system file-systems)
 200                       (guix build utils)
 201                       (guix build bournish)   ;add the 'bournish' meta-command
 202                       (srfi srfi-26)
 203
 204                       ;; FIXME: The following modules are for
 205                       ;; LUKS-DEVICE-MAPPING.  We should instead propagate
 206                       ;; this info via gexps.
 207                       ((gnu build file-systems)
 208                        #:select (find-partition-by-luks-uuid))
 209                       (rnrs bytevectors))
 210
 211          (with-output-to-port (%make-void-port "w")
 212            (lambda ()
 213              (set-path-environment-variable "PATH" '("bin" "sbin")
 214                                             '#$helper-packages)))
 215
 216          (boot-system #:mounts
 217                       (map spec->file-system
 218                            '#$(map file-system->spec file-systems))
 219                       #:pre-mount (lambda ()
 220                                     (and #$@device-mapping-commands))
 221                       #:linux-modules '#$linux-modules
 222                       #:linux-module-directory '#$kodir
 223                       #:qemu-guest-networking? #$qemu-networking?
 224                       #:volatile-root? '#$volatile-root?
 225                       #:on-error '#$on-error)))
 226    #:name "raw-initrd"))
 227
 228 (define* (file-system-packages file-systems #:key (volatile-root? #f))
 229   "Return the list of statically-linked, stripped packages to check
 230 FILE-SYSTEMS."
 231   `(,@(if (find (lambda (fs)
 232                   (string-prefix? "ext" (file-system-type fs)))
 233                 file-systems)
 234           (list e2fsck/static)
 235           '())
 236     ,@(if (find (lambda (fs)
 237                   (string-suffix? "fat" (file-system-type fs)))
 238                 file-systems)
 239           (list fatfsck/static)
 240           '())
 241     ,@(if (find (file-system-type-predicate "btrfs") file-systems)
 242           (list btrfs-progs/static)
 243           '())))
 244
 245 (define* (base-initrd file-systems
 246                       #:key
 247                       (linux linux-libre)
 248                       (mapped-devices '())
 249                       qemu-networking?
 250                       volatile-root?
 251                       (virtio? #t)
 252                       (extra-modules '())
 253                       (on-error 'debug))
 254   "Return a monadic derivation that builds a generic initrd, with kernel
 255 modules taken from LINUX.  FILE-SYSTEMS is a list of file-systems to be
 256 mounted by the initrd, possibly in addition to the root file system specified
 257 on the kernel command line via '--root'.  MAPPED-DEVICES is a list of device
 258 mappings to realize before FILE-SYSTEMS are mounted.
 259
 260 QEMU-NETWORKING? and VOLATILE-ROOT? behaves as in raw-initrd.
 261
 262 When VIRTIO? is true, load additional modules so the initrd can
 263 be used as a QEMU guest with the root file system on a para-virtualized block
 264 device.
 265
 266 The initrd is automatically populated with all the kernel modules necessary
 267 for FILE-SYSTEMS and for the given options.  However, additional kernel
 268 modules can be listed in EXTRA-MODULES.  They will be added to the initrd, and
 269 loaded at boot time in the order in which they appear."
 270   (define virtio-modules
 271     ;; Modules for Linux para-virtualized devices, for use in QEMU guests.
 272     '("virtio_pci" "virtio_balloon" "virtio_blk" "virtio_net"
 273       "virtio_console"))
 274
 275   (define cifs-modules
 276     ;; Modules needed to mount CIFS file systems.
 277     '("md4" "ecb" "cifs"))
 278
 279   (define virtio-9p-modules
 280     ;; Modules for the 9p paravirtualized file system.
 281     '("9p" "9pnet_virtio"))
 282
 283   (define (file-system-type-predicate type)
 284     (lambda (fs)
 285       (string=? (file-system-type fs) type)))
 286
 287   (define linux-modules
 288     ;; Modules added to the initrd and loaded from the initrd.
 289     `("ahci"                                  ;for SATA controllers
 290       "usb-storage" "uas"                     ;for the installation image etc.
 291       "usbhid" "hid-generic" "hid-apple"      ;keyboards during early boot
 292       "dm-crypt" "xts" "serpent_generic" "wp512" ;for encrypted root partitions
 293       "nls_iso8859-1"                            ;for `mkfs.fat`, et.al
 294       ,@(if (string-match "^(x86_64|i[3-6]86)-" (%current-system))
 295             '("pata_acpi" "pata_atiixp"    ;for ATA controllers
 296               "isci")                      ;for SAS controllers like Intel C602
 297             '())
 298       ,@(if (or virtio? qemu-networking?)
 299             virtio-modules
 300             '())
 301       ,@(if (find (file-system-type-predicate "cifs") file-systems)
 302             cifs-modules
 303             '())
 304       ,@(if (find (file-system-type-predicate "9p") file-systems)
 305             virtio-9p-modules
 306             '())
 307       ,@(if (find (file-system-type-predicate "btrfs") file-systems)
 308             '("btrfs")
 309             '())
 310       ,@(if (find (file-system-type-predicate "iso9660") file-systems)
 311             '("isofs")
 312             '())
 313       ,@(if volatile-root?
 314             '("overlay")
 315             '())
 316       ,@extra-modules))
 317
 318   (define helper-packages
 319     (file-system-packages file-systems #:volatile-root? volatile-root?))
 320
 321   (raw-initrd file-systems
 322               #:linux linux
 323               #:linux-modules linux-modules
 324               #:mapped-devices mapped-devices
 325               #:helper-packages helper-packages
 326               #:qemu-networking? qemu-networking?
 327               #:volatile-root? volatile-root?
 328               #:on-error on-error))
 329
 330 ;;; linux-initrd.scm ends here