etc/release-manifest.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; This file returns a manifest containing release-critical bit, for all the
  21 ;;; supported architectures and cross-compilation targets.
  22
  23 (use-modules (gnu packages)
  24              (guix packages)
  25              (guix profiles)
  26              ((gnu ci) #:select (%cross-targets))
  27              ((gnu services xorg) #:select (%default-xorg-modules))
  28              (guix utils)
  29              (srfi srfi-1)
  30              (srfi srfi-26))
  31
  32 (define* (package->manifest-entry* package system
  33                                    #:key target)
  34   "Return a manifest entry for PACKAGE on SYSTEM, optionally cross-compiled to
  35 TARGET."
  36   (manifest-entry
  37     (inherit (package->manifest-entry package))
  38     (name (string-append (package-name package) "." system
  39                          (if target
  40                              (string-append "." target)
  41                              "'")))
  42     (item (with-parameters ((%current-system system)
  43                             (%current-target-system target))
  44             package))))
  45
  46 (define %base-packages
  47   ;; Packages that must be substitutable on all the platforms Guix supports.
  48   (map specification->package
  49        '("bootstrap-tarballs" "gcc-toolchain" "nss-certs"
  50          "openssh" "emacs" "vim" "python" "guile" "guix")))
  51
  52 (define %base-packages/hurd
  53   ;; XXX: For now we are less demanding of "i586-gnu".
  54   (map specification->package
  55        '("coreutils" "grep" "findutils" "gawk" "make"
  56          "gcc-toolchain" "tar" "xz")))
  57
  58 (define %system-packages
  59   ;; Key packages proposed by the Guix System installer.
  60   (append (map specification->package
  61                '("xorg-server" "xfce" "gnome" "mate" "enlightenment"
  62                  "openbox" "awesome" "i3-wm" "ratpoison"
  63                  "emacs" "emacs-exwm" "emacs-desktop-environment"
  64                  "xlockmore" "slock" "libreoffice"
  65                  "connman" "network-manager" "network-manager-applet"
  66                  "openssh" "ntp" "tor"
  67                  "linux-libre" "grub-hybrid"
  68                  ;; FIXME: Add IceCat when Rust is available on i686.
  69                  ;;"icecat"
  70                  ))
  71           %default-xorg-modules))
  72
  73 (define %packages-to-cross-build
  74   ;; Packages that must be cross-buildable from x86_64-linux.
  75   ;; FIXME: Add (@ (gnu packages gcc) gcc) when <https://bugs.gnu.org/40463>
  76   ;; is fixed.
  77   (append (list (@ (gnu packages guile) guile-3.0/fixed))
  78           (map specification->package
  79                '("coreutils" "grep" "sed" "findutils" "diffutils" "patch"
  80                  "gawk" "gettext" "gzip" "xz"
  81                  "hello" "zlib"))))
  82
  83 (define %packages-to-cross-build-for-mingw
  84   ;; Many things don't build for MinGW.  Restrict to what's known to work.
  85   (map specification->package '("hello")))
  86
  87 (define %cross-bootstrap-targets
  88   ;; Cross-compilation triplets for which 'bootstrap-tarballs' must be
  89   ;; buildable.
  90   '("i586-pc-gnu"
  91     "arm-linux-gnueabihf"
  92     "aarch64-linux-gnu"))
  93
  94 \f
  95 ;;;
  96 ;;; Manifests.
  97 ;;;
  98
  99 (define %base-manifest
 100   (manifest
 101    (append-map (lambda (system)
 102                  (map (cut package->manifest-entry* <> system)
 103                       (if (string=? system "i586-gnu")
 104                           %base-packages/hurd
 105                           %base-packages)))
 106                %cuirass-supported-systems)))
 107
 108 (define %system-manifest
 109   (manifest
 110    (append-map (lambda (system)
 111                  (map (cut package->manifest-entry* <> system)
 112                       %system-packages))
 113                '("x86_64-linux" "i686-linux"))))  ;Guix System
 114
 115 (define %cross-manifest
 116   (manifest
 117    (append-map (lambda (target)
 118                  (map (cut package->manifest-entry* <> "x86_64-linux"
 119                            #:target target)
 120                       (if (target-mingw? target)
 121                           %packages-to-cross-build-for-mingw
 122                           %packages-to-cross-build)))
 123                ;; XXX: Important bits like libsigsegv and libffi don't support
 124                ;; RISCV at the moment, so don't require RISCV support.
 125                (delete "riscv64-linux-gnu" %cross-targets))))
 126
 127 (define %cross-bootstrap-manifest
 128   (manifest
 129    (map (lambda (target)
 130           (package->manifest-entry*
 131            (specification->package "bootstrap-tarballs")
 132            "x86_64-linux" #:target target))
 133         %cross-bootstrap-targets)))
 134
 135 ;; Return the union of all three manifests.
 136 (concatenate-manifests (list %base-manifest
 137                              %system-manifest
 138                              %cross-manifest
 139                              %cross-bootstrap-manifest))