gnu/packages/autotools.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012 Nikita Karetnikov <nikita@karetnikov.org>
   3 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2020, 2021 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2015 Mathieu Lirzin <mthl@openmailbox.org>
   5 ;;; Copyright © 2014 Manolis Fragkiskos Ragkousis <manolis837@gmail.com>
   6 ;;; Copyright © 2015, 2017, 2018 Mark H Weaver <mhw@netris.org>
   7 ;;; Copyright © 2016 David Thompson <davet@gnu.org>
   8 ;;; Copyright © 2017 Nikita <nikita@n0.is>
   9 ;;; Copyright © 2017, 2019 Efraim Flashner <efraim@flashner.co.il>
  10 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  11 ;;; Copyright © 2018 Ricardo Wurmus <rekado@elephly.net>
  12 ;;; Copyright © 2019 Pierre-Moana Levesque <pierre.moana.levesque@gmail.com>
  13 ;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
  14 ;;; Copyright © 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  15 ;;;
  16 ;;; This file is part of GNU Guix.
  17 ;;;
  18 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  19 ;;; under the terms of the GNU General Public License as published by
  20 ;;; the Free Software Foundation; either version 3 of the License, or (at
  21 ;;; your option) any later version.
  22 ;;;
  23 ;;; GNU Guix is distributed in the hope that it will be useful, but
  24 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;;; GNU General Public License for more details.
  27 ;;;
  28 ;;; You should have received a copy of the GNU General Public License
  29 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 (define-module (gnu packages autotools)
  32   #:use-module (guix licenses)
  33   #:use-module (gnu packages)
  34   #:use-module (gnu packages perl)
  35   #:use-module (gnu packages python)
  36   #:use-module (gnu packages m4)
  37   #:use-module (gnu packages man)
  38   #:use-module (gnu packages bash)
  39   #:use-module (guix utils)
  40   #:use-module (guix packages)
  41   #:use-module (guix download)
  42   #:use-module (guix git-download)
  43   #:use-module (guix build-system gnu)
  44   #:use-module (guix build-system trivial)
  45   #:use-module (ice-9 match)
  46   #:export (autoconf-wrapper))
  47
  48 (define-public autoconf-2.69
  49   (package
  50     (name "autoconf")
  51     (version "2.69")
  52     (source
  53      (origin
  54       (method url-fetch)
  55       (uri (string-append "mirror://gnu/autoconf/autoconf-"
  56                           version ".tar.xz"))
  57       (sha256
  58        (base32
  59         "113nlmidxy9kjr45kg9x3ngar4951mvag1js2a3j8nxcz34wxsv4"))))
  60     (build-system gnu-build-system)
  61     (inputs
  62      ;; TODO: remove `if' in the next rebuild cycle.
  63      (if (%current-target-system)
  64          `(("bash" ,bash-minimal)
  65            ("perl" ,perl)
  66            ("m4" ,m4))
  67          '()))
  68     (native-inputs
  69      `(("perl" ,perl)
  70        ("m4" ,m4)))
  71     (arguments
  72      `(;; XXX: testsuite: 209 and 279 failed.  The latter is an impurity.  It
  73        ;; should use our own "cpp" instead of "/lib/cpp".
  74        #:tests? #f
  75        ,@(if (%current-target-system)
  76              `(#:phases
  77                (modify-phases %standard-phases
  78                  (add-after 'install 'patch-non-shebang-references
  79                    (lambda* (#:key build inputs outputs #:allow-other-keys)
  80                      ;; `patch-shebangs' patches shebangs only, and the Perl
  81                      ;; scripts use a re-exec feature that references the
  82                      ;; build hosts' perl.  Also, BASH and M4 store references
  83                      ;; hide in the scripts.
  84                      (let ((bash (assoc-ref inputs "bash"))
  85                            (m4 (assoc-ref inputs "m4"))
  86                            (perl (assoc-ref inputs "perl"))
  87                            (out  (assoc-ref outputs "out"))
  88                            (store-directory (%store-directory)))
  89                       (substitute* (find-files (string-append out "/bin"))
  90                         (((string-append store-directory "/[^/]*-bash-[^/]*"))
  91                          bash)
  92                         (((string-append store-directory "/[^/]*-m4-[^/]*"))
  93                          m4)
  94                         (((string-append store-directory "/[^/]*-perl-[^/]*"))
  95                          perl))
  96                       #t)))))
  97              '())))
  98     (home-page "https://www.gnu.org/software/autoconf/")
  99     (synopsis "Create source code configuration scripts")
 100     (description
 101      "Autoconf offers the developer a robust set of M4 macros which expand
 102 into shell code to test the features of Unix-like systems and to adapt
 103 automatically their software package to these systems.  The resulting shell
 104 scripts are self-contained and portable, freeing the user from needing to
 105 know anything about Autoconf or M4.")
 106     (license gpl3+))) ; some files are under GPLv2+
 107
 108 ;; This is the renaissance version, which is not widely supported yet.
 109 (define-public autoconf-2.71
 110   (package
 111     (inherit autoconf-2.69)
 112     (version "2.71")
 113     (source
 114      (origin
 115        (method url-fetch)
 116        (uri (string-append "mirror://gnu/autoconf/autoconf-"
 117                            version ".tar.xz"))
 118        (sha256
 119         (base32
 120          "197sl23irn6s9pd54rxj5vcp5y8dv65jb9yfqgr2g56cxg7q6k7i"))))
 121     (arguments
 122      (substitute-keyword-arguments (package-arguments autoconf-2.69)
 123        ((#:tests? _ #f)
 124         ;; FIXME: To run the test suite, fix all the instances where scripts
 125         ;; generates "#! /bin/sh" shebangs.
 126         #f)
 127        ((#:phases phases '%standard-phases)
 128         `(modify-phases ,phases
 129            (add-before 'check 'prepare-tests
 130              (lambda _
 131                (for-each patch-shebang
 132                          (append (find-files "tests"
 133                                              (lambda (file stat)
 134                                                (executable-file? file)))
 135                                  (find-files "bin"
 136                                              (lambda (file stat)
 137                                                (executable-file? file)))))
 138                #t))))))))
 139
 140 (define-public autoconf autoconf-2.69)
 141
 142 (define-public autoconf-2.68
 143   (package (inherit autoconf)
 144     (version "2.68")
 145     (source
 146      (origin
 147       (method url-fetch)
 148       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 149                           version ".tar.xz"))
 150       (sha256
 151        (base32
 152         "1fjm21k2na07f3vasf288a0zx66lbv0hd3l9bvv3q8p62s3pg569"))))))
 153
 154 (define-public autoconf-2.64
 155   ;; As of GDB 7.8, GDB is still developed using this version of Autoconf.
 156   (package (inherit autoconf)
 157     (version "2.64")
 158     (source
 159      (origin
 160       (method url-fetch)
 161       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 162                           version ".tar.xz"))
 163       (sha256
 164        (base32
 165         "0j3jdjpf5ly39dlp0bg70h72nzqr059k0x8iqxvaxf106chpgn9j"))))))
 166
 167 (define-public autoconf-2.13
 168   ;; GNU IceCat 52.x requires autoconf-2.13 to build!
 169   (package (inherit autoconf)
 170     (version "2.13")
 171     (source
 172      (origin
 173       (method url-fetch)
 174       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 175                           version ".tar.gz"))
 176       (sha256
 177        (base32
 178         "07krzl4czczdsgzrrw9fiqx35xcf32naf751khg821g5pqv12qgh"))))
 179     (arguments
 180      `(#:tests? #f
 181        #:phases
 182        ;; The 'configure' script in autoconf-2.13 can't cope with "SHELL=" and
 183        ;; "CONFIG_SHELL=" arguments, so we set them as environment variables
 184        ;; and pass a simplified set of arguments.
 185        (modify-phases %standard-phases
 186          (replace 'configure
 187            (lambda* (#:key build inputs outputs #:allow-other-keys)
 188              (let ((bash (which "bash"))
 189                    (out  (assoc-ref outputs "out")))
 190                (setenv "CONFIG_SHELL" bash)
 191                (setenv "SHELL" bash)
 192                (invoke bash "./configure"
 193                        (string-append "--prefix=" out)
 194                        (string-append "--build=" build))))))))))
 195
 196
 197 (define (make-autoconf-wrapper autoconf)
 198   "Return a wrapper around AUTOCONF that generates `configure' scripts that
 199 use our own Bash instead of /bin/sh in shebangs.  For that reason, it should
 200 only be used internally---users should not end up distributing `configure'
 201 files with a system-specific shebang."
 202   (package (inherit autoconf)
 203     (name (string-append (package-name autoconf) "-wrapper"))
 204     (build-system trivial-build-system)
 205     (inputs `(("guile"
 206                ;; XXX: Kludge to hide the circular dependency.
 207                ,(module-ref (resolve-interface '(gnu packages guile))
 208                             'guile-2.0))
 209               ("autoconf" ,autoconf)
 210               ("bash" ,bash)))
 211     (arguments
 212      '(#:modules ((guix build utils))
 213        #:builder
 214        (begin
 215          (use-modules (guix build utils))
 216          (let* ((out      (assoc-ref %outputs "out"))
 217                 (bin      (string-append out "/bin"))
 218                 (autoconf (string-append
 219                            (assoc-ref %build-inputs "autoconf")
 220                            "/bin/autoconf"))
 221                 (guile    (string-append
 222                            (assoc-ref %build-inputs "guile")
 223                            "/bin/guile"))
 224                 (sh       (string-append
 225                            (assoc-ref %build-inputs "bash")
 226                            "/bin/sh"))
 227                 (modules  ((compose dirname dirname dirname)
 228                            (search-path %load-path
 229                                         "guix/build/utils.scm"))))
 230            (mkdir-p bin)
 231
 232            ;; Symlink all the binaries but `autoconf'.
 233            (with-directory-excursion bin
 234              (for-each (lambda (file)
 235                          (unless (string=? (basename file) "autoconf")
 236                            (symlink file (basename file))))
 237                        (find-files (dirname autoconf) ".*")))
 238
 239            ;; Add an `autoconf' binary that wraps the real one.
 240            (call-with-output-file (string-append bin "/autoconf")
 241              (lambda (port)
 242                ;; Shamefully, Guile can be used in shebangs only if a
 243                ;; single argument is passed (-ds); otherwise it gets
 244                ;; them all as a single argument and fails to parse them.
 245                (format port "#!~a
 246 export GUILE_LOAD_PATH=\"~a\"
 247 export GUILE_LOAD_COMPILED_PATH=\"~a\"
 248 exec ~a --no-auto-compile \"$0\" \"$@\"
 249 !#~%"
 250                        sh modules modules guile)
 251                (write
 252                 `(begin
 253                    (use-modules (guix build utils))
 254                    (let ((result (apply system* ,autoconf
 255                                         (cdr (command-line)))))
 256                      (when (and (file-exists? "configure")
 257                                 (not (file-exists? "/bin/sh")))
 258                        ;; Patch regardless of RESULT, because `autoconf
 259                        ;; -Werror' can both create a `configure' file and
 260                        ;; return a non-zero exit code.
 261                        (patch-shebang "configure"))
 262                      (exit (status:exit-val result))))
 263                 port)))
 264            (chmod (string-append bin "/autoconf") #o555)
 265            #t))))
 266
 267     ;; Do not show it in the UI since it's meant for internal use.
 268     (properties '((hidden? . #t)))))
 269
 270 (define-public autoconf-wrapper
 271   (make-autoconf-wrapper autoconf))
 272
 273 (define-public autoconf-archive
 274   (package
 275     (name "autoconf-archive")
 276     (version "2019.01.06")
 277     (source
 278      (origin
 279       (method url-fetch)
 280       (uri (string-append "mirror://gnu/autoconf-archive/autoconf-archive-"
 281                           version ".tar.xz"))
 282       (sha256
 283        (base32
 284         "0gqya7nf4j5k98dkky0c3bnr0paciya91vkqazg7knlq621mq68p"))))
 285     (build-system gnu-build-system)
 286     (home-page "https://www.gnu.org/software/autoconf-archive/")
 287     (synopsis "Collection of freely reusable Autoconf macros")
 288     (description
 289      "Autoconf Archive is a collection of over 450 new macros for Autoconf,
 290 greatly expanding the domain of its functionality.  These macros have been
 291 contributed as free software by the community.")
 292     (license gpl3+)))
 293
 294 (define-public autobuild
 295   (package
 296     (name "autobuild")
 297     (version "5.3")
 298     (source (origin
 299               (method url-fetch)
 300               (uri (string-append "mirror://savannah/autobuild/autobuild-"
 301                                   version ".tar.gz"))
 302               (sha256
 303                (base32
 304                 "0gv7g61ja9q9zg1m30k4snqwwy1kq7b4df6sb7d2qra7kbdq8af1"))))
 305     (build-system gnu-build-system)
 306     (inputs `(("perl" ,perl)))
 307     (synopsis "Process generated build logs")
 308     (description "Autobuild is a package that processes build logs generated
 309 when building software.  Autobuild is primarily focused on packages using
 310 Autoconf and Automake, but can be used with other build systems too.
 311 Autobuild generates an HTML summary file, containing links to each build log.
 312 The summary includes project name, version, build hostname, host type (cross
 313 compile aware), date of build, and indication of success or failure.  The
 314 output is indexed in many ways to simplify browsing.")
 315     (home-page "https://josefsson.org/autobuild/")
 316     (license gpl3+)))
 317
 318 (define-public automake
 319   (package
 320     (name "automake")
 321     (version "1.16.2")
 322     (source (origin
 323              (method url-fetch)
 324              (uri (string-append "mirror://gnu/automake/automake-"
 325                                  version ".tar.xz"))
 326              (sha256
 327               (base32
 328                 "1l7dkqbsmbf94ax29jj1jf6a0r6ikc8jybg1p5m0c3ki7pg5ki6c"))
 329              (patches
 330               (search-patches "automake-skip-amhello-tests.patch"))))
 331     (build-system gnu-build-system)
 332     (inputs
 333      ;; TODO: remove `if' in the next rebuild cycle.
 334      (if (%current-target-system)
 335          `(("autoconf" ,autoconf-wrapper)
 336            ("bash" ,bash-minimal)
 337            ("perl" ,perl))
 338          '()))
 339     (native-inputs
 340      `(("autoconf" ,autoconf-wrapper)
 341        ("perl" ,perl)))
 342     (native-search-paths
 343      (list (search-path-specification
 344             (variable "ACLOCAL_PATH")
 345             (files '("share/aclocal")))))
 346     (arguments
 347      `(#:modules ((guix build gnu-build-system)
 348                   (guix build utils)
 349                   (srfi srfi-1)
 350                   (srfi srfi-26)
 351                   (rnrs io ports))
 352        #:phases
 353        (modify-phases %standard-phases
 354          (add-before 'patch-source-shebangs 'patch-tests-shebangs
 355            (lambda _
 356              (let ((sh (which "sh")))
 357                (substitute* (find-files "t" "\\.(sh|tap)$")
 358                  (("#![[:blank:]]?/bin/sh")
 359                   (string-append "#!" sh)))
 360
 361                ;; Set these variables for all the `configure' runs
 362                ;; that occur during the test suite.
 363                (setenv "SHELL" sh)
 364                (setenv "CONFIG_SHELL" sh)
 365                #t)))
 366
 367            (add-before 'check 'skip-test
 368              (lambda _
 369                ;; This test requires 'etags' and fails if it's missing.
 370                ;; Skip it.
 371                (substitute* "t/tags-lisp-space.sh"
 372                  (("^required.*" all)
 373                   (string-append "exit 77\n" all "\n")))
 374                #t))
 375
 376            ,@(if (%current-target-system)
 377                  `((add-after 'install 'patch-non-shebang-references
 378                      (lambda* (#:key build inputs outputs #:allow-other-keys)
 379                      ;; `patch-shebangs' patches shebangs only, and the Perl
 380                      ;; scripts use a re-exec feature that references the
 381                      ;; build hosts' perl.  Also, AUTOCONF and BASH store
 382                      ;; references hide in the scripts.
 383                        (let ((autoconf (assoc-ref inputs "autoconf"))
 384                              (bash (assoc-ref inputs "bash"))
 385                              (perl (assoc-ref inputs "perl"))
 386                              (out  (assoc-ref outputs "out"))
 387                              (store-directory (%store-directory)))
 388                          (substitute* (find-files (string-append out "/bin"))
 389                            (((string-append store-directory "/[^/]*-autoconf-[^/]*"))
 390                             autoconf)
 391                            (((string-append store-directory "/[^/]*-bash-[^/]*"))
 392                             bash)
 393                            (((string-append store-directory "/[^/]*-perl-[^/]*"))
 394                             perl))
 395                          #t))))
 396                  '())
 397
 398          ;; Files like `install-sh', `mdate.sh', etc. must use
 399          ;; #!/bin/sh, otherwise users could leak erroneous shebangs
 400          ;; in the wild.  See <http://bugs.gnu.org/14201> for an
 401          ;; example.
 402          (add-after 'install 'unpatch-shebangs
 403            (lambda* (#:key outputs #:allow-other-keys)
 404              (let* ((out (assoc-ref outputs "out"))
 405                     (dir (string-append out "/share")))
 406                (define (starts-with-shebang? file)
 407                  (equal? (call-with-input-file file
 408                            (lambda (p)
 409                              (list (get-u8 p) (get-u8 p))))
 410                          (map char->integer '(#\# #\!))))
 411
 412                (for-each (lambda (file)
 413                            (when (and (starts-with-shebang? file)
 414                                       (executable-file? file))
 415                              (format #t "restoring shebang on `~a'~%"
 416                                      file)
 417                              (substitute* file
 418                                (("^#!.*/bin/sh")
 419                                 "#!/bin/sh")
 420                                (("^#!.*/bin/env(.*)$" _ args)
 421                                 (string-append "#!/usr/bin/env"
 422                                                args)))))
 423                          (find-files dir ".*"))
 424                #t))))))
 425     (home-page "https://www.gnu.org/software/automake/")
 426     (synopsis "Making GNU standards-compliant Makefiles")
 427     (description
 428      "Automake the part of the GNU build system for producing
 429 standards-compliant Makefiles.  Build requirements are entered in an
 430 intuitive format and then Automake works with Autoconf to produce a robust
 431 Makefile, simplifying the entire process for the developer.")
 432     (license gpl2+)))                      ; some files are under GPLv3+
 433
 434 (define-public libtool
 435   (package
 436     (name "libtool")
 437     (version "2.4.6")
 438     (source (origin
 439               (method url-fetch)
 440               (uri (string-append "mirror://gnu/libtool/libtool-"
 441                                   version ".tar.xz"))
 442               (sha256
 443                (base32
 444                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))
 445               (patches (search-patches "libtool-skip-tests2.patch"))))
 446     (build-system gnu-build-system)
 447     (propagated-inputs `(("m4" ,m4)))
 448     (native-inputs `(("m4" ,m4)
 449                      ("perl" ,perl)
 450                      ;; XXX: this shouldn't be necessary, but without it test
 451                      ;; 102 fails because it cannot find ltdl/libltdl.la.
 452                      ("libltdl" ,libltdl)
 453                      ("help2man" ,help2man) ;because we modify ltmain.sh
 454                      ("automake" ,automake)      ;some tests rely on 'aclocal'
 455                      ("autoconf" ,autoconf-wrapper))) ;others on 'autom4te'
 456
 457     (arguments
 458      `(;; Libltdl is provided as a separate package, so don't install it here.
 459        #:configure-flags '("--disable-ltdl-install")
 460
 461        ;; XXX: There are test failures on mips64el-linux starting from 2.4.4:
 462        ;; <http://hydra.gnu.org/build/181662>.
 463        ;; Also, do not run tests when cross compiling
 464        #:tests? ,(not (or (%current-target-system)
 465                           (string-prefix? "mips64"
 466                                           (%current-system))))
 467
 468        #:phases
 469        (modify-phases %standard-phases
 470          (add-before 'check 'pre-check
 471            (lambda* (#:key inputs native-inputs #:allow-other-keys)
 472              ;; Run the test suite in parallel, if possible.
 473              (setenv "TESTSUITEFLAGS"
 474                      (string-append
 475                       "-j"
 476                       (number->string (parallel-job-count))))
 477            ;; Patch references to /bin/sh.
 478            (let ((bash (assoc-ref (or native-inputs inputs) "bash")))
 479              (substitute* "tests/testsuite"
 480                (("/bin/sh")
 481                 (string-append bash "/bin/sh")))
 482              #t)))
 483          (add-after 'patch-source-shebangs 'restore-ltmain-shebang
 484            (lambda* (#:key inputs #:allow-other-keys)
 485              (substitute* "build-aux/ltmain.in"
 486                (("^#!.*/bin/sh$") "#!/bin/sh"))
 487              #t)))))
 488
 489     (synopsis "Generic shared library support tools")
 490     (description
 491      "GNU Libtool helps in the creation and use of shared libraries, by
 492 presenting a single consistent, portable interface that hides the usual
 493 complexity of working with shared libraries across platforms.")
 494     (license gpl3+)
 495     (home-page "https://www.gnu.org/software/libtool/")))
 496
 497 (define-public config
 498   (let ((revision "1")
 499         (commit "c8ddc8472f8efcadafc1ef53ca1d863415fddd5f"))
 500     (package
 501       (name "config")
 502       (version (git-version "0.0.0" revision commit)) ;no release tag
 503       (source (origin
 504                 (method git-fetch)
 505                 (uri (git-reference
 506                       (url "https://git.savannah.gnu.org/git/config.git/")
 507                       (commit commit)))
 508                 (file-name (git-file-name name version))
 509                 (sha256
 510                  (base32
 511                   "0x6ycvkmmhhhag97wsf0pw8n5fvh12rjvrck90rz17my4ys16qwv"))))
 512       (build-system gnu-build-system)
 513       (arguments
 514        `(#:phases (modify-phases %standard-phases
 515                     (add-after 'unpack 'patch-/bin/sh
 516                       (lambda _
 517                         (substitute* "testsuite/config-guess.sh"
 518                           (("#!/bin/sh")
 519                            (string-append "#!" (which "sh"))))
 520                         #t))
 521                     (replace 'build
 522                       (lambda _
 523                         (invoke "make" "manpages")))
 524                     (delete 'configure)
 525                     (replace 'install
 526                       (lambda* (#:key outputs #:allow-other-keys)
 527                         (let* ((out (assoc-ref outputs "out"))
 528                                (bin (string-append out "/bin"))
 529                                (man1 (string-append out "/share/man/man1")))
 530                           (install-file "config.guess" bin)
 531                           (install-file "config.sub" bin)
 532                           (install-file "doc/config.guess.1" man1)
 533                           (install-file "doc/config.sub.1" man1)
 534                           #t))))))
 535       (native-inputs
 536        `(("help2man" ,help2man)))
 537       (home-page "https://savannah.gnu.org/projects/config")
 538       (synopsis "Ubiquitious config.guess and config.sub scripts")
 539       (description "The `config.guess' script tries to guess a canonical system triple,
 540 and `config.sub' validates and canonicalizes.  These are used as part of
 541 configuration in nearly all GNU packages (and many others).")
 542       (license gpl2+))))
 543
 544 (define-public libltdl
 545   ;; This is a libltdl package separate from the libtool package.  This is
 546   ;; useful because, unlike libtool, it has zero extra dependencies (making it
 547   ;; readily usable during bootstrap), and it builds very quickly since
 548   ;; Libtool's extensive test suite isn't run.
 549   (package
 550     (name "libltdl")
 551     (version "2.4.6")
 552     (source (origin
 553               (method url-fetch)
 554               (uri (string-append "mirror://gnu/libtool/libtool-"
 555                                   version ".tar.xz"))
 556               (sha256
 557                (base32
 558                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))))
 559     (build-system gnu-build-system)
 560     (arguments
 561      '(#:configure-flags '("--enable-ltdl-install") ;really install it
 562        #:phases (modify-phases %standard-phases
 563                   (add-before 'configure 'change-directory
 564                     (lambda _ (chdir "libltdl") #t)))))
 565
 566     (synopsis "System-independent dlopen wrapper of GNU libtool")
 567     (description (package-description libtool))
 568     (home-page (package-home-page libtool))
 569     (license lgpl2.1+)))
 570
 571 (define-public pyconfigure
 572   (package
 573     (name "pyconfigure")
 574     (version "0.2.3")
 575     (source (origin
 576               (method url-fetch)
 577               (uri (string-append "mirror://gnu/pyconfigure/pyconfigure-"
 578                                   version ".tar.gz"))
 579               (sha256
 580                (base32
 581                 "0kxi9bg7l6ric39vbz9ykz4a21xlihhh2zcc3297db8amvhqwhrp"))))
 582     (build-system gnu-build-system)
 583     (arguments
 584      `(#:phases
 585        (modify-phases %standard-phases
 586          (add-before 'configure 'patch-python
 587            (lambda _
 588              (substitute* "pyconf.in"
 589                (("/usr/bin/env python") (which "python3")))
 590              #t)))))
 591     (inputs
 592      `(("python" ,python-3)))
 593     (synopsis "@command{configure} interface for Python-based packages")
 594     (description
 595      "GNU pyconfigure provides template files for easily implementing
 596 standards-compliant configure scripts and Makefiles for Python-based packages.
 597 It is designed to work alongside existing Python setup scripts, making it easy
 598 to integrate into existing projects.  Powerful and flexible Autoconf macros
 599 are available, allowing you to easily make adjustments to the installation
 600 procedure based on the capabilities of the target computer.")
 601     (home-page "https://www.gnu.org/software/pyconfigure/manual/")
 602     (license
 603      (fsf-free
 604       "https://www.gnu.org/prep/maintain/html_node/License-Notices-for-Other-Files.html"))))