configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.10.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 dnl Better be verbose.
  45 AC_MSG_CHECKING([for the store directory])
  46 AC_MSG_RESULT([$storedir])
  47
  48 AC_ARG_ENABLE([daemon],
  49   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  50   [guix_build_daemon="$enableval"],
  51   [guix_build_daemon="yes"])
  52
  53 # Prepare a version of $localstatedir & co. that does not contain references
  54 # to shell variables.
  55 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  56 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  57 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  58 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  59 AC_SUBST([guix_localstatedir])
  60 AC_SUBST([guix_sysconfdir])
  61 AC_SUBST([guix_sbindir])
  62
  63 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  64 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  65
  66 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  67 dnl Make sure they are available.
  68 m4_pattern_forbid([PKG_CHECK_MODULES])
  69 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  70
  71 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  72 AC_PATH_PROG([GUILE], [guile])
  73 AC_PATH_PROG([GUILD], [guild])
  74 if test "x$GUILD" = "x"; then
  75    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  76 fi
  77
  78 dnl guile-json is used for the PyPI package importer
  79 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  80 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  81
  82 dnl Make sure we have a full-fledged Guile.
  83 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  84
  85 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  86 GUIX_CHECK_SRFI_37
  87 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  88
  89 dnl Check whether (guix build syscalls) can be built.
  90 GUIX_CHECK_LIBC_MOUNT
  91 AM_CONDITIONAL([BUILD_SYSCALLS_MODULE],
  92   [test "x$guix_cv_libc_has_mount" = "xyes"])
  93
  94 dnl Decompressors, for use by the substituter and other modules.
  95 AC_PATH_PROG([GZIP], [gzip])
  96 AC_PATH_PROG([BZIP2], [bzip2])
  97 AC_PATH_PROG([XZ], [xz])
  98 AC_SUBST([GZIP])
  99 AC_SUBST([BZIP2])
 100 AC_SUBST([XZ])
 101
 102 AC_ARG_WITH([nix-prefix],
 103   [AS_HELP_STRING([--with-nix-prefix=DIR],
 104     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 105   [case "$withval" in
 106     yes|no) ;;
 107     *)
 108       NIX_PREFIX="$withval"
 109       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 110       AC_SUBST([NIX_PREFIX])
 111       ;;
 112    esac],
 113   [])
 114
 115 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 116 AC_PATH_PROG([NIX_HASH], [nix-hash])
 117 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 118    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 119 fi
 120
 121 if test "x$NIX_INSTANTIATE" = "x"; then
 122    # This program is an optional dependency, so we just want it to be
 123    # taken from $PATH if it's not available right now.
 124    NIX_INSTANTIATE="nix-instantiate"
 125 fi
 126
 127 AC_ARG_WITH([nixpkgs],
 128   [AS_HELP_STRING([--with-nixpkgs=DIR],
 129     [search for Nixpkgs in DIR (for testing purposes only)])],
 130   [case "$withval" in
 131     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 132     *)      NIXPKGS="$withval";;
 133    esac],
 134   [])
 135
 136 AC_MSG_CHECKING([for Nixpkgs source tree])
 137 if test -f "$NIXPKGS/default.nix"; then
 138    AC_MSG_RESULT([$NIXPKGS])
 139    AC_SUBST([NIXPKGS])
 140 else
 141    AC_MSG_RESULT([not found])
 142 fi
 143
 144 LIBGCRYPT="libgcrypt"
 145 LIBGCRYPT_LIBDIR="no"
 146 LIBGCRYPT_PREFIX="no"
 147
 148 AC_ARG_WITH([libgcrypt-prefix],
 149   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 150   [case "$withval" in
 151     yes|no)
 152       ;;
 153     *)
 154       LIBGCRYPT="$withval/lib/libgcrypt"
 155       LIBGCRYPT_PREFIX="$withval"
 156       LIBGCRYPT_LIBDIR="$withval/lib"
 157       ;;
 158    esac])
 159
 160 AC_ARG_WITH([libgcrypt-libdir],
 161   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 162      [search for GNU libgcrypt's shared library in DIR])],
 163   [case "$withval" in
 164     yes|no)
 165       LIBGCRYPT="libgcrypt"
 166       LIBGCRYPT_LIBDIR="no"
 167       ;;
 168     *)
 169       LIBGCRYPT="$withval/libgcrypt"
 170       LIBGCRYPT_LIBDIR="$withval"
 171       ;;
 172    esac])
 173
 174 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 175 dnl absolute file name of libgcrypt.so.
 176 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 177   xnono)
 178     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 179     if test "x$LIBGCRYPT_LIBDIR" != x; then
 180       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 181     else
 182       dnl 'config-daemon.ac' expects "no" in this case.
 183       LIBGCRYPT_LIBDIR="no"
 184     fi
 185     ;;
 186 esac
 187
 188 dnl Library name suitable for `dynamic-link'.
 189 AC_MSG_CHECKING([for libgcrypt shared library name])
 190 AC_MSG_RESULT([$LIBGCRYPT])
 191 AC_SUBST([LIBGCRYPT])
 192 AC_SUBST([LIBGCRYPT_PREFIX])
 193 AC_SUBST([LIBGCRYPT_LIBDIR])
 194
 195 GUIX_ASSERT_LIBGCRYPT_USABLE
 196
 197 dnl Library name of zlib suitable for 'dynamic-link'.
 198 GUIX_LIBZ_LIBDIR([libz_libdir])
 199 if test "x$libz_libdir" = "x"; then
 200   LIBZ="libz"
 201 else
 202   LIBZ="$libz_libdir/libz"
 203 fi
 204 AC_MSG_CHECKING([for zlib's shared library name])
 205 AC_MSG_RESULT([$LIBZ])
 206 AC_SUBST([LIBZ])
 207
 208 AC_CACHE_SAVE
 209
 210 m4_include([config-daemon.ac])
 211
 212 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 213 dnl See `Building from Git' in the manual for more info.
 214 AM_MISSING_PROG([DOT], [dot])
 215
 216 dnl Manual pages.
 217 AM_MISSING_PROG([HELP2MAN], [help2man])
 218
 219 AC_CONFIG_FILES([Makefile
 220                  po/guix/Makefile.in
 221                  po/packages/Makefile.in
 222                  guix/config.scm])
 223
 224 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 225 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 226 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 227   [chmod +x pre-inst-env])
 228
 229 dnl Emacs interface.
 230 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 231 AM_PATH_LISPDIR
 232 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 233
 234 emacsuidir="${guilemoduledir}/guix/emacs"
 235 AC_SUBST([emacsuidir])
 236 AC_CONFIG_FILES([emacs/guix-config.el
 237                  emacs/guix-helper.scm])
 238
 239 AC_OUTPUT