gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017, 2020 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018, 2019 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (guix utils)
  28   #:use-module (gnu packages admin)
  29   #:use-module (gnu packages ci)
  30   #:use-module (gnu packages version-control)
  31   #:use-module (gnu services)
  32   #:use-module (gnu services base)
  33   #:use-module (gnu services databases)
  34   #:use-module (gnu services shepherd)
  35   #:use-module (gnu services admin)
  36   #:use-module (gnu system shadow)
  37   #:export (<cuirass-remote-server-configuration>
  38             cuirass-remote-server-configuration
  39             cuirass-remote-server-configuration?
  40
  41             <cuirass-configuration>
  42             cuirass-configuration
  43             cuirass-configuration?
  44             cuirass-service-type
  45
  46             <cuirass-remote-worker-configuration>
  47             cuirass-remote-worker-configuration
  48             cuirass-remote-worker-configuration?
  49             cuirass-remote-worker-service-type))
  50
  51 ;;;; Commentary:
  52 ;;;
  53 ;;; This module implements a service that to run instances of Cuirass, a
  54 ;;; continuous integration tool.
  55 ;;;
  56 ;;;; Code:
  57
  58 (define %cuirass-default-database
  59   "dbname=cuirass host=/var/run/postgresql")
  60
  61 (define-record-type* <cuirass-remote-server-configuration>
  62   cuirass-remote-server-configuration make-cuirass-remote-server-configuration
  63   cuirass-remote-server-configuration?
  64   (backend-port     cuirass-remote-server-configuration-backend-port ;int
  65                     (default #f))
  66   (publish-port     cuirass-remote-server-configuration-publish-port ;int
  67                     (default #f))
  68   (log-file         cuirass-remote-server-log-file ;string
  69                     (default "/var/log/cuirass-remote-server.log"))
  70   (cache            cuirass-remote-server-configuration-cache ;string
  71                     (default "/var/cache/cuirass/remote/"))
  72   (trigger-url      cuirass-remote-server-trigger-url ;string
  73                     (default #f))
  74   (public-key       cuirass-remote-server-configuration-public-key ;string
  75                     (default #f))
  76   (private-key      cuirass-remote-server-configuration-private-key ;string
  77                     (default #f)))
  78
  79 (define-record-type* <cuirass-configuration>
  80   cuirass-configuration make-cuirass-configuration
  81   cuirass-configuration?
  82   (cuirass          cuirass-configuration-cuirass ;package
  83                     (default cuirass))
  84   (log-file         cuirass-configuration-log-file ;string
  85                     (default "/var/log/cuirass.log"))
  86   (web-log-file     cuirass-configuration-web-log-file ;string
  87                     (default "/var/log/cuirass-web.log"))
  88   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  89                     (default "/var/cache/cuirass"))
  90   (user             cuirass-configuration-user ;string
  91                     (default "cuirass"))
  92   (group            cuirass-configuration-group ;string
  93                     (default "cuirass"))
  94   (interval         cuirass-configuration-interval ;integer (seconds)
  95                     (default 60))
  96   (remote-server    cuirass-configuration-remote-server
  97                     (default #f))
  98   (database         cuirass-configuration-database ;string
  99                     (default %cuirass-default-database))
 100   (port             cuirass-configuration-port ;integer (port)
 101                     (default 8081))
 102   (host             cuirass-configuration-host ;string
 103                     (default "localhost"))
 104   (specifications   cuirass-configuration-specifications)
 105                                   ;gexp that evaluates to specification-alist
 106   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
 107                     (default #f))
 108   (one-shot?        cuirass-configuration-one-shot? ;boolean
 109                     (default #f))
 110   (fallback?        cuirass-configuration-fallback? ;boolean
 111                     (default #f))
 112   (zabbix-uri       cuirass-configuration-zabbix-uri ;string
 113                     (default #f))
 114   (extra-options    cuirass-configuration-extra-options
 115                     (default '())))
 116
 117 (define (cuirass-shepherd-service config)
 118   "Return a <shepherd-service> for the Cuirass service with CONFIG."
 119   (let ((cuirass          (cuirass-configuration-cuirass config))
 120         (cache-directory  (cuirass-configuration-cache-directory config))
 121         (web-log-file     (cuirass-configuration-web-log-file config))
 122         (log-file         (cuirass-configuration-log-file config))
 123         (user             (cuirass-configuration-user config))
 124         (group            (cuirass-configuration-group config))
 125         (interval         (cuirass-configuration-interval config))
 126         (remote-server    (cuirass-configuration-remote-server config))
 127         (database         (cuirass-configuration-database config))
 128         (port             (cuirass-configuration-port config))
 129         (host             (cuirass-configuration-host config))
 130         (specs            (cuirass-configuration-specifications config))
 131         (use-substitutes? (cuirass-configuration-use-substitutes? config))
 132         (one-shot?        (cuirass-configuration-one-shot? config))
 133         (fallback?        (cuirass-configuration-fallback? config))
 134         (zabbix-uri       (cuirass-configuration-zabbix-uri config))
 135         (extra-options    (cuirass-configuration-extra-options config)))
 136     `(,(shepherd-service
 137         (documentation "Run Cuirass.")
 138         (provision '(cuirass))
 139         (requirement '(guix-daemon postgres networking))
 140         (start #~(make-forkexec-constructor
 141                   (list (string-append #$cuirass "/bin/cuirass")
 142                         "--cache-directory" #$cache-directory
 143                         "--specifications"
 144                         #$(scheme-file "cuirass-specs.scm" specs)
 145                         "--database" #$database
 146                         "--interval" #$(number->string interval)
 147                         #$@(if remote-server '("--build-remote") '())
 148                         #$@(if use-substitutes? '("--use-substitutes") '())
 149                         #$@(if one-shot? '("--one-shot") '())
 150                         #$@(if fallback? '("--fallback") '())
 151                         #$@(if zabbix-uri
 152                                (list (string-append
 153                                       "--zabbix-uri="
 154                                       zabbix-uri))
 155                                '())
 156                         #$@extra-options)
 157
 158                   #:environment-variables
 159                   (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 160                         (string-append "GIT_EXEC_PATH=" #$git
 161                                        "/libexec/git-core"))
 162
 163                   #:user #$user
 164                   #:group #$group
 165                   #:log-file #$log-file))
 166         (stop #~(make-kill-destructor)))
 167       ,(shepherd-service
 168         (documentation "Run Cuirass web interface.")
 169         (provision '(cuirass-web))
 170         (requirement '(guix-daemon postgres networking))
 171         (start #~(make-forkexec-constructor
 172                   (list (string-append #$cuirass "/bin/cuirass")
 173                         "--cache-directory" #$cache-directory
 174                         "--database" #$database
 175                         "--web"
 176                         "--port" #$(number->string port)
 177                         "--listen" #$host
 178                         "--interval" #$(number->string interval)
 179                         #$@(if use-substitutes? '("--use-substitutes") '())
 180                         #$@(if fallback? '("--fallback") '())
 181                         #$@extra-options)
 182
 183                   #:user #$user
 184                   #:group #$group
 185                   #:log-file #$web-log-file))
 186         (stop #~(make-kill-destructor)))
 187       ,@(if remote-server
 188             (match-record remote-server <cuirass-remote-server-configuration>
 189               (backend-port publish-port log-file cache trigger-url
 190                             public-key private-key)
 191               (list
 192                (shepherd-service
 193                 (documentation "Run Cuirass remote build server.")
 194                 (provision '(cuirass-remote-server))
 195                 (requirement '(avahi-daemon cuirass guix-daemon networking))
 196                 (start #~(make-forkexec-constructor
 197                           (list (string-append #$cuirass "/bin/remote-server")
 198                                 (string-append "--database=" #$database)
 199                                 (string-append "--cache=" #$cache)
 200                                 (string-append "--user=" #$user)
 201                                 #$@(if backend-port
 202                                        (list (string-append
 203                                               "--backend-port="
 204                                               (number->string backend-port)))
 205                                        '())
 206                                 #$@(if publish-port
 207                                        (list (string-append
 208                                               "--publish-port="
 209                                               (number->string publish-port)))
 210                                        '())
 211                                 #$@(if trigger-url
 212                                        (list
 213                                         (string-append
 214                                          "--trigger-substitute-url="
 215                                          trigger-url))
 216                                        '())
 217                                 #$@(if public-key
 218                                        (list
 219                                         (string-append "--public-key="
 220                                                        public-key))
 221                                        '())
 222                                 #$@(if private-key
 223                                        (list
 224                                         (string-append "--private-key="
 225                                                        private-key))
 226                                        '()))
 227                           #:log-file #$log-file))
 228                 (stop #~(make-kill-destructor)))))
 229             '()))))
 230
 231 (define (cuirass-account config)
 232   "Return the user accounts and user groups for CONFIG."
 233   (let ((cuirass-user  (cuirass-configuration-user config))
 234         (cuirass-group (cuirass-configuration-group config)))
 235     (list (user-group
 236            (name cuirass-group)
 237            (system? #t))
 238           (user-account
 239            (name cuirass-user)
 240            (group cuirass-group)
 241            (system? #t)
 242            (comment "Cuirass privilege separation user")
 243            (home-directory (string-append "/var/lib/" cuirass-user))
 244            (shell (file-append shadow "/sbin/nologin"))))))
 245
 246 (define (cuirass-postgresql-role config)
 247   (let ((user (cuirass-configuration-user config)))
 248     (list (postgresql-role
 249            (name user)
 250            (create-database? #t)))))
 251
 252 (define (cuirass-activation config)
 253   "Return the activation code for CONFIG."
 254   (let* ((cache          (cuirass-configuration-cache-directory config))
 255          (remote-server  (cuirass-configuration-remote-server config))
 256          (remote-cache   (and remote-server
 257                               (cuirass-remote-server-configuration-cache
 258                                remote-server)))
 259          (db             (dirname
 260                           (cuirass-configuration-database config)))
 261          (user           (cuirass-configuration-user config))
 262          (log            "/var/log/cuirass")
 263          (group          (cuirass-configuration-group config)))
 264     (with-imported-modules '((guix build utils))
 265       #~(begin
 266           (use-modules (guix build utils))
 267
 268           (mkdir-p #$cache)
 269           (mkdir-p #$db)
 270           (mkdir-p #$log)
 271
 272           (when #$remote-cache
 273             (mkdir-p #$remote-cache))
 274
 275           (let ((uid (passwd:uid (getpw #$user)))
 276                 (gid (group:gid (getgr #$group))))
 277             (chown #$cache uid gid)
 278             (chown #$db uid gid)
 279             (chown #$log uid gid)
 280
 281             (when #$remote-cache
 282               (chown #$remote-cache uid gid)))))))
 283
 284 (define (cuirass-log-rotations config)
 285   "Return the list of log rotations that corresponds to CONFIG."
 286   (list (log-rotation
 287          (files (list (cuirass-configuration-log-file config)))
 288          (frequency 'weekly)
 289          (options '("rotate 40")))))              ;worth keeping
 290
 291 (define cuirass-service-type
 292   (service-type
 293    (name 'cuirass)
 294    (extensions
 295     (list
 296      (service-extension profile-service-type      ;for 'info cuirass'
 297                         (compose list cuirass-configuration-cuirass))
 298      (service-extension rottlog-service-type cuirass-log-rotations)
 299      (service-extension activation-service-type cuirass-activation)
 300      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 301      (service-extension account-service-type cuirass-account)
 302      (service-extension postgresql-role-service-type
 303                         cuirass-postgresql-role)))
 304    (description
 305     "Run the Cuirass continuous integration service.")))
 306
 307 (define-record-type* <cuirass-remote-worker-configuration>
 308   cuirass-remote-worker-configuration make-cuirass-remote-worker-configuration
 309   cuirass-remote-worker-configuration?
 310   (cuirass          cuirass-remote-worker-configuration-cuirass ;package
 311                     (default cuirass))
 312   (workers          cuirass-remote-worker-workers ;int
 313                     (default 1))
 314   (systems          cuirass-remote-worker-systems ;list
 315                     (default (list (%current-system))))
 316   (log-file         cuirass-remote-worker-log-file ;string
 317                     (default "/var/log/cuirass-remote-worker.log"))
 318   (publish-port     cuirass-remote-worker-configuration-publish-port ;int
 319                     (default #f))
 320   (public-key       cuirass-remote-worker-configuration-public-key ;string
 321                     (default #f))
 322   (private-key      cuirass-remote-worker-configuration-private-key ;string
 323                     (default #f)))
 324
 325 (define (cuirass-remote-worker-shepherd-service config)
 326   "Return a <shepherd-service> for the Cuirass remote worker service with
 327 CONFIG."
 328   (match-record config <cuirass-remote-worker-configuration>
 329     (cuirass workers systems log-file publish-port public-key private-key)
 330     (list (shepherd-service
 331            (documentation "Run Cuirass remote build worker.")
 332            (provision '(cuirass-remote-worker))
 333            (requirement '(avahi-daemon guix-daemon networking))
 334            (start #~(make-forkexec-constructor
 335                      (list (string-append #$cuirass "/bin/remote-worker")
 336                            (string-append "--workers="
 337                                           #$(number->string workers))
 338                            #$@(if systems
 339                                   (list (string-append
 340                                          "--systems="
 341                                          (string-join systems ",")))
 342                                   '())
 343                            #$@(if publish-port
 344                                   (list (string-append
 345                                          "--publish-port="
 346                                          (number->string publish-port)))
 347                                   '())
 348                            #$@(if public-key
 349                                   (list
 350                                    (string-append "--public-key="
 351                                                   public-key))
 352                                   '())
 353                            #$@(if private-key
 354                                   (list
 355                                    (string-append "--private-key="
 356                                                   private-key))
 357                                   '()))
 358                     #:log-file #$log-file))
 359            (stop #~(make-kill-destructor))))))
 360
 361 (define cuirass-remote-worker-service-type
 362   (service-type
 363    (name 'cuirass-remote-worker)
 364    (extensions
 365     (list
 366      (service-extension shepherd-root-service-type
 367                         cuirass-remote-worker-shepherd-service)))
 368    (description
 369     "Run the Cuirass remote build worker service.")))