configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P])
  91 m4_pattern_allow([^GUILE_PKG_ERRORS])
  92 m4_pattern_forbid([^GUIX_])
  93
  94 dnl Search for 'guile' and 'guild'.  This macro defines
  95 dnl 'GUILE_EFFECTIVE_VERSION'.
  96 GUILE_PKG([2.2 2.0])
  97 GUILE_PROGS
  98 if test "x$GUILD" = "x"; then
  99    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
 100 fi
 101
 102 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
 103   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
 104 fi
 105
 106 dnl Installation directories for .scm and .go files.
 107 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 108 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 109 AC_SUBST([guilemoduledir])
 110 AC_SUBST([guileobjectdir])
 111
 112 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 113 dnl pull', among other things.
 114 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 115 if test "x$have_gnutls" != "xyes"; then
 116   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 117 fi
 118
 119 dnl Check for Guile-Git.
 120 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 121 if test "x$have_guile_git" != "xyes"; then
 122   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 123 fi
 124
 125 dnl Check for Guile-JSON.
 126 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 127 if test "x$have_guile_json" != "xyes"; then
 128   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 129 fi
 130
 131 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 132 GUIX_CHECK_GUILE_SQLITE3
 133 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 134   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 135 fi
 136
 137 GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
 138 if test "x$have_guile_gcrypt" != "xyes"; then
 139   AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
 140 fi
 141
 142 dnl Make sure we have a full-fledged Guile.
 143 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 144
 145 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 146 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 147 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 148
 149 AC_PROG_SED
 150
 151 dnl Decompressors, for use by the substituter and other modules.
 152 AC_PATH_PROG([GZIP], [gzip])
 153 AC_PATH_PROG([BZIP2], [bzip2])
 154 AC_PATH_PROG([XZ], [xz])
 155 AC_SUBST([GZIP])
 156 AC_SUBST([BZIP2])
 157 AC_SUBST([XZ])
 158
 159 AC_ARG_WITH([nix-prefix],
 160   [AS_HELP_STRING([--with-nix-prefix=DIR],
 161     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 162   [case "$withval" in
 163     yes|no) ;;
 164     *)
 165       NIX_PREFIX="$withval"
 166       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 167       AC_SUBST([NIX_PREFIX])
 168       ;;
 169    esac],
 170   [])
 171
 172 AC_PATH_PROG([NIX_HASH], [nix-hash])
 173 if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
 174    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 175 fi
 176
 177 AC_ARG_WITH([nixpkgs],
 178   [AS_HELP_STRING([--with-nixpkgs=DIR],
 179     [search for Nixpkgs in DIR (for testing purposes only)])],
 180   [case "$withval" in
 181     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 182     *)      NIXPKGS="$withval";;
 183    esac],
 184   [])
 185
 186 AC_MSG_CHECKING([for Nixpkgs source tree])
 187 if test -f "$NIXPKGS/default.nix"; then
 188    AC_MSG_RESULT([$NIXPKGS])
 189    AC_SUBST([NIXPKGS])
 190 else
 191    AC_MSG_RESULT([not found])
 192 fi
 193
 194 LIBGCRYPT="libgcrypt"
 195 LIBGCRYPT_LIBDIR="no"
 196 LIBGCRYPT_PREFIX="no"
 197
 198 AC_ARG_WITH([libgcrypt-prefix],
 199   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 200   [case "$withval" in
 201     yes|no)
 202       ;;
 203     *)
 204       LIBGCRYPT="$withval/lib/libgcrypt"
 205       LIBGCRYPT_PREFIX="$withval"
 206       LIBGCRYPT_LIBDIR="$withval/lib"
 207       ;;
 208    esac])
 209
 210 AC_ARG_WITH([libgcrypt-libdir],
 211   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 212      [search for GNU libgcrypt's shared library in DIR])],
 213   [case "$withval" in
 214     yes|no)
 215       LIBGCRYPT="libgcrypt"
 216       LIBGCRYPT_LIBDIR="no"
 217       ;;
 218     *)
 219       LIBGCRYPT="$withval/libgcrypt"
 220       LIBGCRYPT_LIBDIR="$withval"
 221       ;;
 222    esac])
 223
 224 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 225 dnl the library directory.
 226 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 227   xnono)
 228     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 229     ;;
 230 esac
 231
 232 dnl Library name suitable for `dynamic-link'.
 233 AC_MSG_CHECKING([for libgcrypt shared library name])
 234 AC_MSG_RESULT([$LIBGCRYPT])
 235 AC_SUBST([LIBGCRYPT])
 236 AC_SUBST([LIBGCRYPT_PREFIX])
 237 AC_SUBST([LIBGCRYPT_LIBDIR])
 238
 239 dnl Library name of zlib suitable for 'dynamic-link'.
 240 GUIX_LIBZ_LIBDIR([libz_libdir])
 241 if test "x$libz_libdir" = "x"; then
 242   LIBZ="libz"
 243 else
 244   LIBZ="$libz_libdir/libz"
 245 fi
 246 AC_MSG_CHECKING([for zlib's shared library name])
 247 AC_MSG_RESULT([$LIBZ])
 248 AC_SUBST([LIBZ])
 249
 250 dnl Check for Guile-SSH, for the (guix ssh) module.
 251 GUIX_CHECK_GUILE_SSH
 252 AM_CONDITIONAL([HAVE_GUILE_SSH],
 253   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 254
 255 AC_CACHE_SAVE
 256
 257 m4_include([config-daemon.ac])
 258
 259 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 260 dnl See `Building from Git' in the manual for more info.
 261 AM_MISSING_PROG([DOT], [dot])
 262
 263 dnl Manual pages.
 264 AM_MISSING_PROG([HELP2MAN], [help2man])
 265
 266 dnl Documentation translation.
 267 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 268 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 269
 270 dnl Emacs (optional), for 'etc/indent-package.el'.
 271 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 272 AC_SUBST([EMACS])
 273
 274 case "$storedir" in
 275   /gnu/store)
 276     ;;
 277   *)
 278     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 279     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 280     ;;
 281 esac
 282
 283 AC_CONFIG_FILES([Makefile
 284                  po/guix/Makefile.in
 285                  po/packages/Makefile.in
 286                  etc/guix-daemon.cil
 287                  guix/config.scm])
 288
 289 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 290 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 291   [chmod +x pre-inst-env])
 292 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 293
 294 AC_OUTPUT