gnu/packages/autotools.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012 Nikita Karetnikov <nikita@karetnikov.org>
   3 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2020 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2015 Mathieu Lirzin <mthl@openmailbox.org>
   5 ;;; Copyright © 2014 Manolis Fragkiskos Ragkousis <manolis837@gmail.com>
   6 ;;; Copyright © 2015, 2017, 2018 Mark H Weaver <mhw@netris.org>
   7 ;;; Copyright © 2016 David Thompson <davet@gnu.org>
   8 ;;; Copyright © 2017 Nikita <nikita@n0.is>
   9 ;;; Copyright © 2017, 2019 Efraim Flashner <efraim@flashner.co.il>
  10 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  11 ;;; Copyright © 2018 Ricardo Wurmus <rekado@elephly.net>
  12 ;;; Copyright © 2019 Pierre-Moana Levesque <pierre.moana.levesque@gmail.com>
  13 ;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
  14 ;;; Copyright © 2021 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  15 ;;;
  16 ;;; This file is part of GNU Guix.
  17 ;;;
  18 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  19 ;;; under the terms of the GNU General Public License as published by
  20 ;;; the Free Software Foundation; either version 3 of the License, or (at
  21 ;;; your option) any later version.
  22 ;;;
  23 ;;; GNU Guix is distributed in the hope that it will be useful, but
  24 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;;; GNU General Public License for more details.
  27 ;;;
  28 ;;; You should have received a copy of the GNU General Public License
  29 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 (define-module (gnu packages autotools)
  32   #:use-module (guix licenses)
  33   #:use-module (gnu packages)
  34   #:use-module (gnu packages perl)
  35   #:use-module (gnu packages python)
  36   #:use-module (gnu packages m4)
  37   #:use-module (gnu packages man)
  38   #:use-module (gnu packages bash)
  39   #:use-module (guix utils)
  40   #:use-module (guix packages)
  41   #:use-module (guix download)
  42   #:use-module (guix git-download)
  43   #:use-module (guix build-system gnu)
  44   #:use-module (guix build-system trivial)
  45   #:use-module (ice-9 match)
  46   #:export (autoconf-wrapper))
  47
  48 (define-public autoconf-2.69
  49   (package
  50     (name "autoconf")
  51     (version "2.69")
  52     (source
  53      (origin
  54       (method url-fetch)
  55       (uri (string-append "mirror://gnu/autoconf/autoconf-"
  56                           version ".tar.xz"))
  57       (sha256
  58        (base32
  59         "113nlmidxy9kjr45kg9x3ngar4951mvag1js2a3j8nxcz34wxsv4"))))
  60     (build-system gnu-build-system)
  61     (inputs
  62      ;; TODO: remove `if' in the next rebuild cycle.
  63      (if (%current-target-system)
  64          `(("bash" ,bash-minimal)
  65            ("perl" ,perl)
  66            ("m4" ,m4))
  67          '()))
  68     (native-inputs
  69      `(("perl" ,perl)
  70        ("m4" ,m4)))
  71     (arguments
  72      `(;; XXX: testsuite: 209 and 279 failed.  The latter is an impurity.  It
  73        ;; should use our own "cpp" instead of "/lib/cpp".
  74        #:tests? #f
  75        ,@(if (%current-target-system)
  76              `(#:phases
  77                (modify-phases %standard-phases
  78                  (add-after 'install 'patch-non-shebang-references
  79                    (lambda* (#:key build inputs outputs #:allow-other-keys)
  80                      ;; `patch-shebangs' patches shebangs only, and the Perl
  81                      ;; scripts use a re-exec feature that references the
  82                      ;; build hosts' perl.  Also, BASH and M4 store references
  83                      ;; hide in the scripts.
  84                      (let ((bash (assoc-ref inputs "bash"))
  85                            (m4 (assoc-ref inputs "m4"))
  86                            (perl (assoc-ref inputs "perl"))
  87                            (out  (assoc-ref outputs "out"))
  88                            (store-directory (%store-directory)))
  89                       (substitute* (find-files (string-append out "/bin"))
  90                         (((string-append store-directory "/[^/]*-bash-[^/]*"))
  91                          bash)
  92                         (((string-append store-directory "/[^/]*-m4-[^/]*"))
  93                          m4)
  94                         (((string-append store-directory "/[^/]*-perl-[^/]*"))
  95                          perl))
  96                       #t)))))
  97              '())))
  98     (home-page "https://www.gnu.org/software/autoconf/")
  99     (synopsis "Create source code configuration scripts")
 100     (description
 101      "Autoconf offers the developer a robust set of M4 macros which expand
 102 into shell code to test the features of Unix-like systems and to adapt
 103 automatically their software package to these systems.  The resulting shell
 104 scripts are self-contained and portable, freeing the user from needing to
 105 know anything about Autoconf or M4.")
 106     (license gpl3+))) ; some files are under GPLv2+
 107
 108 (define-public autoconf-2.70
 109   (package
 110     (inherit autoconf-2.69)
 111     (version "2.70")
 112     (source
 113      (origin
 114        (method url-fetch)
 115        (uri (string-append "mirror://gnu/autoconf/autoconf-"
 116                            version ".tar.xz"))
 117        (sha256
 118         (base32
 119          "1ipckz0wr2mvhj9n3ys54fmf2aksin6bhqvzl304bn6rc1w257ps"))))
 120     (arguments
 121      (substitute-keyword-arguments (package-arguments autoconf-2.69)
 122        ((#:tests? _ #f)
 123         ;; FIXME: To run the test suite, fix all the instances where scripts
 124         ;; generates "#! /bin/sh" shebangs.
 125         #f)
 126        ((#:phases phases '%standard-phases)
 127         `(modify-phases ,phases
 128            (add-before 'check 'prepare-tests
 129              (lambda _
 130                (for-each patch-shebang
 131                          (append (find-files "tests"
 132                                              (lambda (file stat)
 133                                                (executable-file? file)))
 134                                  (find-files "bin"
 135                                              (lambda (file stat)
 136                                                (executable-file? file)))))
 137                #t))))))))
 138
 139 (define-public autoconf autoconf-2.69)
 140
 141 (define-public autoconf-2.68
 142   (package (inherit autoconf)
 143     (version "2.68")
 144     (source
 145      (origin
 146       (method url-fetch)
 147       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 148                           version ".tar.xz"))
 149       (sha256
 150        (base32
 151         "1fjm21k2na07f3vasf288a0zx66lbv0hd3l9bvv3q8p62s3pg569"))))))
 152
 153 (define-public autoconf-2.64
 154   ;; As of GDB 7.8, GDB is still developed using this version of Autoconf.
 155   (package (inherit autoconf)
 156     (version "2.64")
 157     (source
 158      (origin
 159       (method url-fetch)
 160       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 161                           version ".tar.xz"))
 162       (sha256
 163        (base32
 164         "0j3jdjpf5ly39dlp0bg70h72nzqr059k0x8iqxvaxf106chpgn9j"))))))
 165
 166 (define-public autoconf-2.13
 167   ;; GNU IceCat 52.x requires autoconf-2.13 to build!
 168   (package (inherit autoconf)
 169     (version "2.13")
 170     (source
 171      (origin
 172       (method url-fetch)
 173       (uri (string-append "mirror://gnu/autoconf/autoconf-"
 174                           version ".tar.gz"))
 175       (sha256
 176        (base32
 177         "07krzl4czczdsgzrrw9fiqx35xcf32naf751khg821g5pqv12qgh"))))
 178     (arguments
 179      `(#:tests? #f
 180        #:phases
 181        ;; The 'configure' script in autoconf-2.13 can't cope with "SHELL=" and
 182        ;; "CONFIG_SHELL=" arguments, so we set them as environment variables
 183        ;; and pass a simplified set of arguments.
 184        (modify-phases %standard-phases
 185          (replace 'configure
 186            (lambda* (#:key build inputs outputs #:allow-other-keys)
 187              (let ((bash (which "bash"))
 188                    (out  (assoc-ref outputs "out")))
 189                (setenv "CONFIG_SHELL" bash)
 190                (setenv "SHELL" bash)
 191                (invoke bash "./configure"
 192                        (string-append "--prefix=" out)
 193                        (string-append "--build=" build))))))))))
 194
 195
 196 (define (make-autoconf-wrapper autoconf)
 197   "Return a wrapper around AUTOCONF that generates `configure' scripts that
 198 use our own Bash instead of /bin/sh in shebangs.  For that reason, it should
 199 only be used internally---users should not end up distributing `configure'
 200 files with a system-specific shebang."
 201   (package (inherit autoconf)
 202     (name (string-append (package-name autoconf) "-wrapper"))
 203     (build-system trivial-build-system)
 204     (inputs `(("guile"
 205                ;; XXX: Kludge to hide the circular dependency.
 206                ,(module-ref (resolve-interface '(gnu packages guile))
 207                             'guile-2.0))
 208               ("autoconf" ,autoconf)
 209               ("bash" ,bash)))
 210     (arguments
 211      '(#:modules ((guix build utils))
 212        #:builder
 213        (begin
 214          (use-modules (guix build utils))
 215          (let* ((out      (assoc-ref %outputs "out"))
 216                 (bin      (string-append out "/bin"))
 217                 (autoconf (string-append
 218                            (assoc-ref %build-inputs "autoconf")
 219                            "/bin/autoconf"))
 220                 (guile    (string-append
 221                            (assoc-ref %build-inputs "guile")
 222                            "/bin/guile"))
 223                 (sh       (string-append
 224                            (assoc-ref %build-inputs "bash")
 225                            "/bin/sh"))
 226                 (modules  ((compose dirname dirname dirname)
 227                            (search-path %load-path
 228                                         "guix/build/utils.scm"))))
 229            (mkdir-p bin)
 230
 231            ;; Symlink all the binaries but `autoconf'.
 232            (with-directory-excursion bin
 233              (for-each (lambda (file)
 234                          (unless (string=? (basename file) "autoconf")
 235                            (symlink file (basename file))))
 236                        (find-files (dirname autoconf) ".*")))
 237
 238            ;; Add an `autoconf' binary that wraps the real one.
 239            (call-with-output-file (string-append bin "/autoconf")
 240              (lambda (port)
 241                ;; Shamefully, Guile can be used in shebangs only if a
 242                ;; single argument is passed (-ds); otherwise it gets
 243                ;; them all as a single argument and fails to parse them.
 244                (format port "#!~a
 245 export GUILE_LOAD_PATH=\"~a\"
 246 export GUILE_LOAD_COMPILED_PATH=\"~a\"
 247 exec ~a --no-auto-compile \"$0\" \"$@\"
 248 !#~%"
 249                        sh modules modules guile)
 250                (write
 251                 `(begin
 252                    (use-modules (guix build utils))
 253                    (let ((result (apply system* ,autoconf
 254                                         (cdr (command-line)))))
 255                      (when (and (file-exists? "configure")
 256                                 (not (file-exists? "/bin/sh")))
 257                        ;; Patch regardless of RESULT, because `autoconf
 258                        ;; -Werror' can both create a `configure' file and
 259                        ;; return a non-zero exit code.
 260                        (patch-shebang "configure"))
 261                      (exit (status:exit-val result))))
 262                 port)))
 263            (chmod (string-append bin "/autoconf") #o555)
 264            #t))))
 265
 266     ;; Do not show it in the UI since it's meant for internal use.
 267     (properties '((hidden? . #t)))))
 268
 269 (define-public autoconf-wrapper
 270   (make-autoconf-wrapper autoconf))
 271
 272 (define-public autoconf-archive
 273   (package
 274     (name "autoconf-archive")
 275     (version "2019.01.06")
 276     (source
 277      (origin
 278       (method url-fetch)
 279       (uri (string-append "mirror://gnu/autoconf-archive/autoconf-archive-"
 280                           version ".tar.xz"))
 281       (sha256
 282        (base32
 283         "0gqya7nf4j5k98dkky0c3bnr0paciya91vkqazg7knlq621mq68p"))))
 284     (build-system gnu-build-system)
 285     (home-page "https://www.gnu.org/software/autoconf-archive/")
 286     (synopsis "Collection of freely reusable Autoconf macros")
 287     (description
 288      "Autoconf Archive is a collection of over 450 new macros for Autoconf,
 289 greatly expanding the domain of its functionality.  These macros have been
 290 contributed as free software by the community.")
 291     (license gpl3+)))
 292
 293 (define-public autobuild
 294   (package
 295     (name "autobuild")
 296     (version "5.3")
 297     (source (origin
 298               (method url-fetch)
 299               (uri (string-append "mirror://savannah/autobuild/autobuild-"
 300                                   version ".tar.gz"))
 301               (sha256
 302                (base32
 303                 "0gv7g61ja9q9zg1m30k4snqwwy1kq7b4df6sb7d2qra7kbdq8af1"))))
 304     (build-system gnu-build-system)
 305     (inputs `(("perl" ,perl)))
 306     (synopsis "Process generated build logs")
 307     (description "Autobuild is a package that processes build logs generated
 308 when building software.  Autobuild is primarily focused on packages using
 309 Autoconf and Automake, but can be used with other build systems too.
 310 Autobuild generates an HTML summary file, containing links to each build log.
 311 The summary includes project name, version, build hostname, host type (cross
 312 compile aware), date of build, and indication of success or failure.  The
 313 output is indexed in many ways to simplify browsing.")
 314     (home-page "https://josefsson.org/autobuild/")
 315     (license gpl3+)))
 316
 317 (define-public automake
 318   (package
 319     (name "automake")
 320     (version "1.16.2")
 321     (source (origin
 322              (method url-fetch)
 323              (uri (string-append "mirror://gnu/automake/automake-"
 324                                  version ".tar.xz"))
 325              (sha256
 326               (base32
 327                 "1l7dkqbsmbf94ax29jj1jf6a0r6ikc8jybg1p5m0c3ki7pg5ki6c"))
 328              (patches
 329               (search-patches "automake-skip-amhello-tests.patch"))))
 330     (build-system gnu-build-system)
 331     (inputs
 332      ;; TODO: remove `if' in the next rebuild cycle.
 333      (if (%current-target-system)
 334          `(("autoconf" ,autoconf-wrapper)
 335            ("bash" ,bash-minimal)
 336            ("perl" ,perl))
 337          '()))
 338     (native-inputs
 339      `(("autoconf" ,autoconf-wrapper)
 340        ("perl" ,perl)))
 341     (native-search-paths
 342      (list (search-path-specification
 343             (variable "ACLOCAL_PATH")
 344             (files '("share/aclocal")))))
 345     (arguments
 346      `(#:modules ((guix build gnu-build-system)
 347                   (guix build utils)
 348                   (srfi srfi-1)
 349                   (srfi srfi-26)
 350                   (rnrs io ports))
 351        #:phases
 352        (modify-phases %standard-phases
 353          (add-before 'patch-source-shebangs 'patch-tests-shebangs
 354            (lambda _
 355              (let ((sh (which "sh")))
 356                (substitute* (find-files "t" "\\.(sh|tap)$")
 357                  (("#![[:blank:]]?/bin/sh")
 358                   (string-append "#!" sh)))
 359
 360                ;; Set these variables for all the `configure' runs
 361                ;; that occur during the test suite.
 362                (setenv "SHELL" sh)
 363                (setenv "CONFIG_SHELL" sh)
 364                #t)))
 365
 366            (add-before 'check 'skip-test
 367              (lambda _
 368                ;; This test requires 'etags' and fails if it's missing.
 369                ;; Skip it.
 370                (substitute* "t/tags-lisp-space.sh"
 371                  (("^required.*" all)
 372                   (string-append "exit 77\n" all "\n")))
 373                #t))
 374
 375            ,@(if (%current-target-system)
 376                  `((add-after 'install 'patch-non-shebang-references
 377                      (lambda* (#:key build inputs outputs #:allow-other-keys)
 378                      ;; `patch-shebangs' patches shebangs only, and the Perl
 379                      ;; scripts use a re-exec feature that references the
 380                      ;; build hosts' perl.  Also, AUTOCONF and BASH store
 381                      ;; references hide in the scripts.
 382                        (let ((autoconf (assoc-ref inputs "autoconf"))
 383                              (bash (assoc-ref inputs "bash"))
 384                              (perl (assoc-ref inputs "perl"))
 385                              (out  (assoc-ref outputs "out"))
 386                              (store-directory (%store-directory)))
 387                          (substitute* (find-files (string-append out "/bin"))
 388                            (((string-append store-directory "/[^/]*-autoconf-[^/]*"))
 389                             autoconf)
 390                            (((string-append store-directory "/[^/]*-bash-[^/]*"))
 391                             bash)
 392                            (((string-append store-directory "/[^/]*-perl-[^/]*"))
 393                             perl))
 394                          #t))))
 395                  '())
 396
 397          ;; Files like `install-sh', `mdate.sh', etc. must use
 398          ;; #!/bin/sh, otherwise users could leak erroneous shebangs
 399          ;; in the wild.  See <http://bugs.gnu.org/14201> for an
 400          ;; example.
 401          (add-after 'install 'unpatch-shebangs
 402            (lambda* (#:key outputs #:allow-other-keys)
 403              (let* ((out (assoc-ref outputs "out"))
 404                     (dir (string-append out "/share")))
 405                (define (starts-with-shebang? file)
 406                  (equal? (call-with-input-file file
 407                            (lambda (p)
 408                              (list (get-u8 p) (get-u8 p))))
 409                          (map char->integer '(#\# #\!))))
 410
 411                (for-each (lambda (file)
 412                            (when (and (starts-with-shebang? file)
 413                                       (executable-file? file))
 414                              (format #t "restoring shebang on `~a'~%"
 415                                      file)
 416                              (substitute* file
 417                                (("^#!.*/bin/sh")
 418                                 "#!/bin/sh")
 419                                (("^#!.*/bin/env(.*)$" _ args)
 420                                 (string-append "#!/usr/bin/env"
 421                                                args)))))
 422                          (find-files dir ".*"))
 423                #t))))))
 424     (home-page "https://www.gnu.org/software/automake/")
 425     (synopsis "Making GNU standards-compliant Makefiles")
 426     (description
 427      "Automake the part of the GNU build system for producing
 428 standards-compliant Makefiles.  Build requirements are entered in an
 429 intuitive format and then Automake works with Autoconf to produce a robust
 430 Makefile, simplifying the entire process for the developer.")
 431     (license gpl2+)))                      ; some files are under GPLv3+
 432
 433 (define-public libtool
 434   (package
 435     (name "libtool")
 436     (version "2.4.6")
 437     (source (origin
 438               (method url-fetch)
 439               (uri (string-append "mirror://gnu/libtool/libtool-"
 440                                   version ".tar.xz"))
 441               (sha256
 442                (base32
 443                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))
 444               (patches (search-patches "libtool-skip-tests2.patch"))))
 445     (build-system gnu-build-system)
 446     (propagated-inputs `(("m4" ,m4)))
 447     (native-inputs `(("m4" ,m4)
 448                      ("perl" ,perl)
 449                      ;; XXX: this shouldn't be necessary, but without it test
 450                      ;; 102 fails because it cannot find ltdl/libltdl.la.
 451                      ("libltdl" ,libltdl)
 452                      ("help2man" ,help2man) ;because we modify ltmain.sh
 453                      ("automake" ,automake)      ;some tests rely on 'aclocal'
 454                      ("autoconf" ,autoconf-wrapper))) ;others on 'autom4te'
 455
 456     (arguments
 457      `(;; Libltdl is provided as a separate package, so don't install it here.
 458        #:configure-flags '("--disable-ltdl-install")
 459
 460        ;; XXX: There are test failures on mips64el-linux starting from 2.4.4:
 461        ;; <http://hydra.gnu.org/build/181662>.
 462        ;; Also, do not run tests when cross compiling
 463        #:tests? ,(not (or (%current-target-system)
 464                           (string-prefix? "mips64"
 465                                           (%current-system))))
 466
 467        #:phases
 468        (modify-phases %standard-phases
 469          (add-before 'check 'pre-check
 470            (lambda* (#:key inputs native-inputs #:allow-other-keys)
 471              ;; Run the test suite in parallel, if possible.
 472              (setenv "TESTSUITEFLAGS"
 473                      (string-append
 474                       "-j"
 475                       (number->string (parallel-job-count))))
 476            ;; Patch references to /bin/sh.
 477            (let ((bash (assoc-ref (or native-inputs inputs) "bash")))
 478              (substitute* "tests/testsuite"
 479                (("/bin/sh")
 480                 (string-append bash "/bin/sh")))
 481              #t)))
 482          (add-after 'patch-source-shebangs 'restore-ltmain-shebang
 483            (lambda* (#:key inputs #:allow-other-keys)
 484              (substitute* "build-aux/ltmain.in"
 485                (("^#!.*/bin/sh$") "#!/bin/sh"))
 486              #t)))))
 487
 488     (synopsis "Generic shared library support tools")
 489     (description
 490      "GNU Libtool helps in the creation and use of shared libraries, by
 491 presenting a single consistent, portable interface that hides the usual
 492 complexity of working with shared libraries across platforms.")
 493     (license gpl3+)
 494     (home-page "https://www.gnu.org/software/libtool/")))
 495
 496 (define-public config
 497   (let ((revision "1")
 498         (commit "c8ddc8472f8efcadafc1ef53ca1d863415fddd5f"))
 499     (package
 500       (name "config")
 501       (version (git-version "0.0.0" revision commit)) ;no release tag
 502       (source (origin
 503                 (method git-fetch)
 504                 (uri (git-reference
 505                       (url "https://git.savannah.gnu.org/git/config.git/")
 506                       (commit commit)))
 507                 (file-name (git-file-name name version))
 508                 (sha256
 509                  (base32
 510                   "0x6ycvkmmhhhag97wsf0pw8n5fvh12rjvrck90rz17my4ys16qwv"))))
 511       (build-system gnu-build-system)
 512       (arguments
 513        `(#:phases (modify-phases %standard-phases
 514                     (add-after 'unpack 'patch-/bin/sh
 515                       (lambda _
 516                         (substitute* "testsuite/config-guess.sh"
 517                           (("#!/bin/sh")
 518                            (string-append "#!" (which "sh"))))
 519                         #t))
 520                     (replace 'build
 521                       (lambda _
 522                         (invoke "make" "manpages")))
 523                     (delete 'configure)
 524                     (replace 'install
 525                       (lambda* (#:key outputs #:allow-other-keys)
 526                         (let* ((out (assoc-ref outputs "out"))
 527                                (bin (string-append out "/bin"))
 528                                (man1 (string-append out "/share/man/man1")))
 529                           (install-file "config.guess" bin)
 530                           (install-file "config.sub" bin)
 531                           (install-file "doc/config.guess.1" man1)
 532                           (install-file "doc/config.sub.1" man1)
 533                           #t))))))
 534       (native-inputs
 535        `(("help2man" ,help2man)))
 536       (home-page "https://savannah.gnu.org/projects/config")
 537       (synopsis "Ubiquitious config.guess and config.sub scripts")
 538       (description "The `config.guess' script tries to guess a canonical system triple,
 539 and `config.sub' validates and canonicalizes.  These are used as part of
 540 configuration in nearly all GNU packages (and many others).")
 541       (license gpl2+))))
 542
 543 (define-public libltdl
 544   ;; This is a libltdl package separate from the libtool package.  This is
 545   ;; useful because, unlike libtool, it has zero extra dependencies (making it
 546   ;; readily usable during bootstrap), and it builds very quickly since
 547   ;; Libtool's extensive test suite isn't run.
 548   (package
 549     (name "libltdl")
 550     (version "2.4.6")
 551     (source (origin
 552               (method url-fetch)
 553               (uri (string-append "mirror://gnu/libtool/libtool-"
 554                                   version ".tar.xz"))
 555               (sha256
 556                (base32
 557                 "0vxj52zm709125gwv9qqlw02silj8bnjnh4y07arrz60r31ai1vw"))))
 558     (build-system gnu-build-system)
 559     (arguments
 560      '(#:configure-flags '("--enable-ltdl-install") ;really install it
 561        #:phases (modify-phases %standard-phases
 562                   (add-before 'configure 'change-directory
 563                     (lambda _ (chdir "libltdl") #t)))))
 564
 565     (synopsis "System-independent dlopen wrapper of GNU libtool")
 566     (description (package-description libtool))
 567     (home-page (package-home-page libtool))
 568     (license lgpl2.1+)))
 569
 570 (define-public pyconfigure
 571   (package
 572     (name "pyconfigure")
 573     (version "0.2.3")
 574     (source (origin
 575               (method url-fetch)
 576               (uri (string-append "mirror://gnu/pyconfigure/pyconfigure-"
 577                                   version ".tar.gz"))
 578               (sha256
 579                (base32
 580                 "0kxi9bg7l6ric39vbz9ykz4a21xlihhh2zcc3297db8amvhqwhrp"))))
 581     (build-system gnu-build-system)
 582     (arguments
 583      `(#:phases
 584        (modify-phases %standard-phases
 585          (add-before 'configure 'patch-python
 586            (lambda _
 587              (substitute* "pyconf.in"
 588                (("/usr/bin/env python") (which "python3")))
 589              #t)))))
 590     (inputs
 591      `(("python" ,python-3)))
 592     (synopsis "@command{configure} interface for Python-based packages")
 593     (description
 594      "GNU pyconfigure provides template files for easily implementing
 595 standards-compliant configure scripts and Makefiles for Python-based packages.
 596 It is designed to work alongside existing Python setup scripts, making it easy
 597 to integrate into existing projects.  Powerful and flexible Autoconf macros
 598 are available, allowing you to easily make adjustments to the installation
 599 procedure based on the capabilities of the target computer.")
 600     (home-page "https://www.gnu.org/software/pyconfigure/manual/")
 601     (license
 602      (fsf-free
 603       "https://www.gnu.org/prep/maintain/html_node/License-Notices-for-Other-Files.html"))))