gnu/system/shadow.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Alex Griffin <a@ajgrf.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu system shadow)
  21   #:use-module (guix records)
  22   #:use-module (guix gexp)
  23   #:use-module (guix store)
  24   #:use-module (guix modules)
  25   #:use-module (guix sets)
  26   #:use-module (guix ui)
  27   #:use-module (gnu services)
  28   #:use-module (gnu services shepherd)
  29   #:use-module ((gnu system file-systems)
  30                 #:select (%tty-gid))
  31   #:use-module ((gnu packages admin)
  32                 #:select (shadow))
  33   #:use-module (gnu packages bash)
  34   #:use-module (gnu packages guile-wm)
  35   #:use-module (srfi srfi-1)
  36   #:use-module (srfi srfi-26)
  37   #:use-module (srfi srfi-34)
  38   #:use-module (srfi srfi-35)
  39   #:export (user-account
  40             user-account?
  41             user-account-name
  42             user-account-password
  43             user-account-uid
  44             user-account-group
  45             user-account-supplementary-groups
  46             user-account-comment
  47             user-account-home-directory
  48             user-account-create-home-directory?
  49             user-account-shell
  50             user-account-system?
  51
  52             user-group
  53             user-group?
  54             user-group-name
  55             user-group-password
  56             user-group-id
  57             user-group-system?
  58
  59             default-skeletons
  60             skeleton-directory
  61             %base-groups
  62             %base-user-accounts
  63
  64             account-service-type
  65             account-service))
  66
  67 ;;; Commentary:
  68 ;;;
  69 ;;; Utilities for configuring the Shadow tool suite ('login', 'passwd', etc.)
  70 ;;;
  71 ;;; Code:
  72
  73 (define-record-type* <user-account>
  74   user-account make-user-account
  75   user-account?
  76   (name           user-account-name)
  77   (password       user-account-password (default #f))
  78   (uid            user-account-uid (default #f))
  79   (group          user-account-group)             ; number | string
  80   (supplementary-groups user-account-supplementary-groups
  81                         (default '()))            ; list of strings
  82   (comment        user-account-comment (default ""))
  83   (home-directory user-account-home-directory)
  84   (create-home-directory? user-account-create-home-directory? ;Boolean
  85                           (default #t))
  86   (shell          user-account-shell              ; gexp
  87                   (default (file-append bash "/bin/bash")))
  88   (system?        user-account-system?            ; Boolean
  89                   (default #f)))
  90
  91 (define-record-type* <user-group>
  92   user-group make-user-group
  93   user-group?
  94   (name           user-group-name)
  95   (password       user-group-password (default #f))
  96   (id             user-group-id (default #f))
  97   (system?        user-group-system?              ; Boolean
  98                   (default #f)))
  99
 100
 101 (define %base-groups
 102   ;; Default set of groups.
 103   (let-syntax ((system-group (syntax-rules ()
 104                                ((_ args ...)
 105                                 (user-group (system? #t) args ...)))))
 106     (list (system-group (name "root") (id 0))
 107           (system-group (name "wheel"))           ; root-like users
 108           (system-group (name "users"))           ; normal users
 109           (system-group (name "nogroup"))         ; for daemons etc.
 110
 111           ;; The following groups are conventionally used by things like udev to
 112           ;; control access to hardware devices.
 113           (system-group (name "tty") (id %tty-gid))
 114           (system-group (name "dialout"))
 115           (system-group (name "kmem"))
 116           (system-group (name "input"))           ; input devices, from udev
 117           (system-group (name "video"))
 118           (system-group (name "audio"))
 119           (system-group (name "netdev"))          ; used in avahi-dbus.conf
 120           (system-group (name "lp"))
 121           (system-group (name "disk"))
 122           (system-group (name "floppy"))
 123           (system-group (name "cdrom"))
 124           (system-group (name "tape"))
 125           (system-group (name "kvm")))))          ; for /dev/kvm
 126
 127 (define %base-user-accounts
 128   ;; List of standard user accounts.  Note that "root" is a special case, so
 129   ;; it's not listed here.
 130   (list (user-account
 131          (name "nobody")
 132          (uid 65534)
 133          (group "nogroup")
 134          (shell (file-append shadow "/sbin/nologin"))
 135          (home-directory "/nonexistent")
 136          (create-home-directory? #f)
 137          (system? #t))))
 138
 139 (define (default-skeletons)
 140   "Return the default skeleton files for /etc/skel.  These files are copied by
 141 'useradd' in the home directory of newly created user accounts."
 142   (define copy-guile-wm
 143     (with-imported-modules '((guix build utils))
 144       #~(begin
 145           (use-modules (guix build utils))
 146           (copy-file (car (find-files #$guile-wm "wm-init-sample.scm"))
 147                      #$output))))
 148
 149   (let ((profile (plain-file "bash_profile" "\
 150 # Honor per-interactive-shell startup file
 151 if [ -f ~/.bashrc ]; then . ~/.bashrc; fi\n"))
 152         (bashrc  (plain-file "bashrc" "\
 153 # Bash initialization for interactive non-login shells and
 154 # for remote shells (info \"(bash) Bash Startup Files\").
 155
 156 # Export 'SHELL' to child processes.  Programs such as 'screen'
 157 # honor it and otherwise use /bin/sh.
 158 export SHELL
 159
 160 if [ -n \"$SSH_CLIENT\" -a -z \"`type -P cat`\" ]
 161 then
 162     # We are being invoked from a non-interactive SSH session
 163     # (as in \"ssh host command\") but 'cat' cannot be found
 164     # in $PATH.  Source /etc/profile so we get $PATH and other
 165     # essential variables.
 166     source /etc/profile
 167 fi
 168
 169 # Adjust the prompt depending on whether we're in 'guix environment'.
 170 if [ -n \"$GUIX_ENVIRONMENT\" ]
 171 then
 172     PS1='\\u@\\h \\w [env]\\$ '
 173 else
 174     PS1='\\u@\\h \\w\\$ '
 175 fi
 176 alias ls='ls -p --color'
 177 alias ll='ls -l'\n"))
 178         (zlogin    (plain-file "zlogin" "\
 179 # Honor system-wide environment variables
 180 source /etc/profile\n"))
 181         (guile-wm  (computed-file "guile-wm" copy-guile-wm))
 182         (xdefaults (plain-file "Xdefaults" "\
 183 XTerm*utf8: always
 184 XTerm*metaSendsEscape: true\n"))
 185         (gdbinit   (plain-file "gdbinit" "\
 186 # Tell GDB where to look for separate debugging files.
 187 set debug-file-directory ~/.guix-profile/lib/debug\n")))
 188     `((".bash_profile" ,profile)
 189       (".bashrc" ,bashrc)
 190       (".zlogin" ,zlogin)
 191       (".Xdefaults" ,xdefaults)
 192       (".guile-wm" ,guile-wm)
 193       (".gdbinit" ,gdbinit))))
 194
 195 (define (skeleton-directory skeletons)
 196   "Return a directory containing SKELETONS, a list of name/derivation tuples."
 197   (computed-file "skel"
 198                  (with-imported-modules '((guix build utils))
 199                    #~(begin
 200                        (use-modules (ice-9 match)
 201                                     (guix build utils))
 202
 203                        (mkdir #$output)
 204                        (chdir #$output)
 205
 206                        ;; Note: copy the skeletons instead of symlinking
 207                        ;; them like 'file-union' does, because 'useradd'
 208                        ;; would just copy the symlinks as is.
 209                        (for-each (match-lambda
 210                                    ((target source)
 211                                     (copy-recursively source target)))
 212                                  '#$skeletons)
 213                        #t))))
 214
 215 (define (assert-valid-users/groups users groups)
 216   "Raise an error if USERS refer to groups not listed in GROUPS."
 217   (let ((groups (list->set (map user-group-name groups))))
 218     (define (validate-supplementary-group user group)
 219       (unless (set-contains? groups group)
 220         (raise (condition
 221                 (&message
 222                  (message
 223                   (format #f (G_ "supplementary group '~a' \
 224 of user '~a' is undeclared")
 225                           group
 226                           (user-account-name user))))))))
 227
 228     (for-each (lambda (user)
 229                 (unless (set-contains? groups (user-account-group user))
 230                   (raise (condition
 231                           (&message
 232                            (message
 233                             (format #f (G_ "primary group '~a' \
 234 of user '~a' is undeclared")
 235                                     (user-account-group user)
 236                                     (user-account-name user)))))))
 237
 238                 (for-each (cut validate-supplementary-group user <>)
 239                           (user-account-supplementary-groups user)))
 240               users)))
 241
 242 \f
 243 ;;;
 244 ;;; Service.
 245 ;;;
 246
 247 (define (user-group->gexp group)
 248   "Turn GROUP, a <user-group> object, into a list-valued gexp suitable for
 249 'active-groups'."
 250   #~(list #$(user-group-name group)
 251           #$(user-group-password group)
 252           #$(user-group-id group)
 253           #$(user-group-system? group)))
 254
 255 (define (user-account->gexp account)
 256   "Turn ACCOUNT, a <user-account> object, into a list-valued gexp suitable for
 257 'activate-users'."
 258   #~`(#$(user-account-name account)
 259       #$(user-account-uid account)
 260       #$(user-account-group account)
 261       #$(user-account-supplementary-groups account)
 262       #$(user-account-comment account)
 263       #$(user-account-home-directory account)
 264       #$(user-account-create-home-directory? account)
 265       ,#$(user-account-shell account)             ; this one is a gexp
 266       #$(user-account-password account)
 267       #$(user-account-system? account)))
 268
 269 (define (account-activation accounts+groups)
 270   "Return a gexp that activates ACCOUNTS+GROUPS, a list of <user-account> and
 271 <user-group> objects.  Raise an error if a user account refers to a undefined
 272 group."
 273   (define accounts
 274     (filter user-account? accounts+groups))
 275
 276   (define user-specs
 277     (map user-account->gexp accounts))
 278
 279   (define groups
 280     (filter user-group? accounts+groups))
 281
 282   (define group-specs
 283     (map user-group->gexp groups))
 284
 285   (assert-valid-users/groups accounts groups)
 286
 287   ;; Add users and user groups.
 288   #~(begin
 289       (setenv "PATH"
 290               (string-append #$(@ (gnu packages admin) shadow) "/sbin"))
 291       (activate-users+groups (list #$@user-specs)
 292                              (list #$@group-specs))))
 293
 294 (define (account-shepherd-service accounts+groups)
 295   "Return a Shepherd service that creates the home directories for the user
 296 accounts among ACCOUNTS+GROUPS."
 297   (define accounts
 298     (filter user-account? accounts+groups))
 299
 300   ;; Create home directories only once 'file-systems' is up.  This makes sure
 301   ;; they are created in the right place if /home lives on a separate
 302   ;; partition.
 303   ;;
 304   ;; XXX: We arrange for this service to stop right after it's done its job so
 305   ;; that 'guix system reconfigure' knows that it can reload it fearlessly
 306   ;; (and thus create new home directories).  The cost of this hack is that
 307   ;; there's a small window during which first-time logins could happen before
 308   ;; the home directory has been created.
 309   (list (shepherd-service
 310          (requirement '(file-systems))
 311          (provision '(user-homes))
 312          (modules '((gnu build activation)))
 313          (start (with-imported-modules (source-module-closure
 314                                         '((gnu build activation)))
 315                   #~(lambda ()
 316                       (activate-user-home
 317                        (list #$@(map user-account->gexp accounts)))
 318                       #f)))                       ;stop
 319          (stop #~(const #f))
 320          (respawn? #f)
 321          (documentation "Create user home directories."))))
 322
 323 (define (shells-file shells)
 324   "Return a file-like object that builds a shell list for use as /etc/shells
 325 based on SHELLS.  /etc/shells is used by xterm, polkit, and other programs."
 326   (computed-file "shells"
 327                  #~(begin
 328                      (use-modules (srfi srfi-1))
 329
 330                      (define shells
 331                        (delete-duplicates (list #$@shells)))
 332
 333                      (call-with-output-file #$output
 334                        (lambda (port)
 335                          (display "\
 336 /bin/sh
 337 /run/current-system/profile/bin/sh
 338 /run/current-system/profile/bin/bash\n" port)
 339                          (for-each (lambda (shell)
 340                                      (display shell port)
 341                                      (newline port))
 342                                    shells))))))
 343 (define (etc-files arguments)
 344   "Filter out among ARGUMENTS things corresponding to skeletons, and return
 345 the /etc/skel directory for those."
 346   (let ((skels (filter pair? arguments))
 347         (users (filter user-account? arguments)))
 348     `(("skel" ,(skeleton-directory skels))
 349       ("shells" ,(shells-file (map user-account-shell users))))))
 350
 351 (define account-service-type
 352   (service-type (name 'account)
 353
 354                 ;; Concatenate <user-account>, <user-group>, and skeleton
 355                 ;; lists.
 356                 (compose concatenate)
 357                 (extend append)
 358
 359                 (extensions
 360                  (list (service-extension activation-service-type
 361                                           account-activation)
 362                        (service-extension shepherd-root-service-type
 363                                           account-shepherd-service)
 364                        (service-extension etc-service-type
 365                                           etc-files)))))
 366
 367 (define (account-service accounts+groups skeletons)
 368   "Return a <service> that takes care of user accounts and user groups, with
 369 ACCOUNTS+GROUPS as its initial list of accounts and groups."
 370   (service account-service-type
 371            (append skeletons accounts+groups)))
 372
 373 ;;; shadow.scm ends here