gnu/tests/base.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (gnu tests base)
  20   #:use-module (gnu tests)
  21   #:use-module (gnu system)
  22   #:use-module (gnu system shadow)
  23   #:use-module (gnu system nss)
  24   #:use-module (gnu system vm)
  25   #:use-module (gnu services)
  26   #:use-module (gnu services base)
  27   #:use-module (gnu services dbus)
  28   #:use-module (gnu services avahi)
  29   #:use-module (gnu services mcron)
  30   #:use-module (gnu services shepherd)
  31   #:use-module (gnu services networking)
  32   #:use-module (gnu packages imagemagick)
  33   #:use-module (gnu packages ocr)
  34   #:use-module (gnu packages package-management)
  35   #:use-module (gnu packages linux)
  36   #:use-module (gnu packages tmux)
  37   #:use-module (guix gexp)
  38   #:use-module (guix store)
  39   #:use-module (guix packages)
  40   #:use-module (srfi srfi-1)
  41   #:export (run-basic-test
  42             %test-basic-os
  43             %test-halt
  44             %test-mcron
  45             %test-nss-mdns))
  46
  47 (define %simple-os
  48   (simple-operating-system))
  49
  50 \f
  51 (define* (run-basic-test os command #:optional (name "basic")
  52                          #:key initialization)
  53   "Return a derivation called NAME that tests basic features of the OS started
  54 using COMMAND, a gexp that evaluates to a list of strings.  Compare some
  55 properties of running system to what's declared in OS, an <operating-system>.
  56
  57 When INITIALIZATION is true, it must be a one-argument procedure that is
  58 passed a gexp denoting the marionette, and it must return gexp that is
  59 inserted before the first test.  This is used to introduce an extra
  60 initialization step, such as entering a LUKS passphrase."
  61   (define special-files
  62     (service-value
  63      (fold-services (operating-system-services os)
  64                     #:target-type special-files-service-type)))
  65
  66   (define test
  67     (with-imported-modules '((gnu build marionette)
  68                              (guix build syscalls))
  69       #~(begin
  70           (use-modules (gnu build marionette)
  71                        (guix build syscalls)
  72                        (srfi srfi-1)
  73                        (srfi srfi-26)
  74                        (srfi srfi-64)
  75                        (ice-9 match))
  76
  77           (define marionette
  78             (make-marionette #$command))
  79
  80           (mkdir #$output)
  81           (chdir #$output)
  82
  83           (test-begin "basic")
  84
  85           #$(and initialization
  86                  (initialization #~marionette))
  87
  88           (test-assert "uname"
  89             (match (marionette-eval '(uname) marionette)
  90               (#("Linux" host-name version _ architecture)
  91                (and (string=? host-name
  92                               #$(operating-system-host-name os))
  93                     (string-prefix? #$(package-version
  94                                        (operating-system-kernel os))
  95                                     version)
  96                     (string-prefix? architecture %host-type)))))
  97
  98           (test-assert "shell and user commands"
  99             ;; Is everything in $PATH?
 100             (zero? (marionette-eval '(system "
 101 . /etc/profile
 102 set -e -x
 103 guix --version
 104 ls --version
 105 grep --version
 106 info --version")
 107                                     marionette)))
 108
 109           (test-equal "special files"
 110             '#$special-files
 111             (marionette-eval
 112              '(begin
 113                 (use-modules (ice-9 match))
 114
 115                 (map (match-lambda
 116                        ((file target)
 117                         (list file (readlink file))))
 118                      '#$special-files))
 119              marionette))
 120
 121           (test-assert "accounts"
 122             (let ((users (marionette-eval '(begin
 123                                              (use-modules (ice-9 match))
 124                                              (let loop ((result '()))
 125                                                (match (getpw)
 126                                                  (#f (reverse result))
 127                                                  (x  (loop (cons x result))))))
 128                                           marionette)))
 129               (lset= string=?
 130                      (map passwd:name users)
 131                      (list
 132                       #$@(map user-account-name
 133                               (operating-system-user-accounts os))))))
 134
 135           (test-assert "shepherd services"
 136             (let ((services (marionette-eval
 137                              '(begin
 138                                 (use-modules (gnu services herd))
 139
 140                                 (map (compose car live-service-provision)
 141                                      (current-services)))
 142                              marionette)))
 143               (lset= eq?
 144                      (pk 'services services)
 145                      '(root #$@(operating-system-shepherd-service-names os)))))
 146
 147           (test-assert "homes"
 148             (let ((homes
 149                    '#$(map user-account-home-directory
 150                            (filter user-account-create-home-directory?
 151                                    (operating-system-user-accounts os)))))
 152               (marionette-eval
 153                `(begin
 154                   (use-modules (gnu services herd) (srfi srfi-1))
 155
 156                   ;; Home directories are supposed to exist once 'user-homes'
 157                   ;; has been started.
 158                   (start-service 'user-homes)
 159
 160                   (every (lambda (home)
 161                            (and (file-exists? home)
 162                                 (file-is-directory? home)))
 163                          ',homes))
 164                marionette)))
 165
 166           (test-assert "skeletons in home directories"
 167             (let ((users+homes
 168                    '#$(filter-map (lambda (account)
 169                                     (and (user-account-create-home-directory?
 170                                           account)
 171                                          (not (user-account-system? account))
 172                                          (list (user-account-name account)
 173                                                (user-account-home-directory
 174                                                 account))))
 175                                   (operating-system-user-accounts os))))
 176               (marionette-eval
 177                `(begin
 178                   (use-modules (srfi srfi-1) (ice-9 ftw)
 179                                (ice-9 match))
 180
 181                   (every (match-lambda
 182                            ((user home)
 183                             ;; Make sure HOME has all the skeletons...
 184                             (and (null? (lset-difference string=?
 185                                                          (scandir "/etc/skel/")
 186                                                          (scandir home)))
 187
 188                                  ;; ... and that everything is user-owned.
 189                                  (let* ((pw  (getpwnam user))
 190                                         (uid (passwd:uid pw))
 191                                         (gid (passwd:gid pw))
 192                                         (st  (lstat home)))
 193                                    (define (user-owned? file)
 194                                      (= uid (stat:uid (lstat file))))
 195
 196                                    (and (= uid (stat:uid st))
 197                                         (eq? 'directory (stat:type st))
 198                                         (every user-owned?
 199                                                (find-files home
 200                                                            #:directories? #t)))))))
 201                          ',users+homes))
 202                marionette)))
 203
 204           (test-equal "permissions on /root"
 205             #o700
 206             (let ((root-home #$(any (lambda (account)
 207                                       (and (zero? (user-account-uid account))
 208                                            (user-account-home-directory
 209                                             account)))
 210                                     (operating-system-user-accounts os))))
 211               (stat:perms (marionette-eval `(stat ,root-home) marionette))))
 212
 213           (test-equal "no extra home directories"
 214             '()
 215
 216             ;; Make sure the home directories that are not supposed to be
 217             ;; created are indeed not created.
 218             (let ((nonexistent
 219                    '#$(filter-map (lambda (user)
 220                                     (and (not
 221                                           (user-account-create-home-directory?
 222                                            user))
 223                                          (user-account-home-directory user)))
 224                                   (operating-system-user-accounts os))))
 225               (marionette-eval
 226                `(begin
 227                   (use-modules (srfi srfi-1))
 228
 229                   ;; Note: Do not flag "/var/empty".
 230                   (filter file-exists?
 231                           ',(remove (cut string-prefix? "/var/" <>)
 232                                     nonexistent)))
 233                marionette)))
 234
 235           (test-equal "login on tty1"
 236             "root\n"
 237             (begin
 238               (marionette-control "sendkey ctrl-alt-f1" marionette)
 239               ;; Wait for the 'term-tty1' service to be running (using
 240               ;; 'start-service' is the simplest and most reliable way to do
 241               ;; that.)
 242               (marionette-eval
 243                '(begin
 244                   (use-modules (gnu services herd))
 245                   (start-service 'term-tty1))
 246                marionette)
 247
 248               ;; Now we can type.
 249               (marionette-type "root\n\nid -un > logged-in\n" marionette)
 250
 251               ;; It can take a while before the shell commands are executed.
 252               (marionette-eval '(use-modules (rnrs io ports)) marionette)
 253               (wait-for-file "/root/logged-in" marionette
 254                              #:read 'get-string-all)))
 255
 256           ;; There should be one utmpx entry for the user logged in on tty1.
 257           (test-equal "utmpx entry"
 258             '(("root" "tty1" #f))
 259             (marionette-eval
 260              '(begin
 261                 (use-modules (guix build syscalls)
 262                              (srfi srfi-1))
 263
 264                 (filter-map (lambda (entry)
 265                               (and (equal? (login-type USER_PROCESS)
 266                                            (utmpx-login-type entry))
 267                                    (list (utmpx-user entry) (utmpx-line entry)
 268                                          (utmpx-host entry))))
 269                             (utmpx-entries)))
 270              marionette))
 271
 272           ;; Likewise for /var/log/wtmp (used by 'last').
 273           (test-assert "wtmp entry"
 274             (match (marionette-eval
 275                     '(begin
 276                        (use-modules (guix build syscalls)
 277                                     (srfi srfi-1))
 278
 279                        (define (entry->list entry)
 280                          (list (utmpx-user entry) (utmpx-line entry)
 281                                (utmpx-host entry) (utmpx-login-type entry)))
 282
 283                        (call-with-input-file "/var/log/wtmp"
 284                          (lambda (port)
 285                            (let loop ((result '()))
 286                              (if (eof-object? (peek-char port))
 287                                  (map entry->list (reverse result))
 288                                  (loop (cons (read-utmpx port) result)))))))
 289                     marionette)
 290               (((users lines hosts types) ..1)
 291                (every (lambda (type)
 292                         (eqv? type (login-type LOGIN_PROCESS)))
 293                       types))))
 294
 295           (test-assert "host name resolution"
 296             (match (marionette-eval
 297                     '(begin
 298                        ;; Wait for nscd or our requests go through it.
 299                        (use-modules (gnu services herd))
 300                        (start-service 'nscd)
 301
 302                        (list (getaddrinfo "localhost")
 303                              (getaddrinfo #$(operating-system-host-name os))))
 304                     marionette)
 305               ((((? vector?) ..1) ((? vector?) ..1))
 306                #t)
 307               (x
 308                (pk 'failure x #f))))
 309
 310           (test-equal "host not found"
 311             #f
 312             (marionette-eval
 313              '(false-if-exception (getaddrinfo "does-not-exist"))
 314              marionette))
 315
 316           (test-equal "locale"
 317             "en_US.utf8"
 318             (marionette-eval '(let ((before (setlocale LC_ALL "en_US.utf8")))
 319                                 (setlocale LC_ALL before))
 320                              marionette))
 321
 322           (test-eq "/run/current-system is a GC root"
 323             'success!
 324             (marionette-eval '(begin
 325                                 ;; Make sure the (guix …) modules are found.
 326                                 (add-to-load-path
 327                                  #+(file-append guix "/share/guile/site/2.2"))
 328
 329                                 (use-modules (srfi srfi-34) (guix store))
 330
 331                                 (let ((system (readlink "/run/current-system")))
 332                                   (guard (c ((nix-protocol-error? c)
 333                                              (and (file-exists? system)
 334                                                   'success!)))
 335                                     (with-store store
 336                                       (delete-paths store (list system))
 337                                       #f))))
 338                              marionette))
 339
 340           ;; This symlink is currently unused, but better have it point to the
 341           ;; right place.  See
 342           ;; <https://lists.gnu.org/archive/html/guix-devel/2016-08/msg01641.html>.
 343           (test-equal "/var/guix/gcroots/profiles is a valid symlink"
 344             "/var/guix/profiles"
 345             (marionette-eval '(readlink "/var/guix/gcroots/profiles")
 346                              marionette))
 347
 348
 349           (test-assert "screendump"
 350             (begin
 351               (marionette-control (string-append "screendump " #$output
 352                                                  "/tty1.ppm")
 353                                   marionette)
 354               (file-exists? "tty1.ppm")))
 355
 356           (test-assert "screen text"
 357             (let ((text (marionette-screen-text marionette
 358                                                 #:ocrad
 359                                                 #$(file-append ocrad
 360                                                                "/bin/ocrad"))))
 361               ;; Check whether the welcome message and shell prompt are
 362               ;; displayed.  Note: OCR confuses "y" and "V" for instance, so
 363               ;; we cannot reliably match the whole text.
 364               (and (string-contains text "This is the GNU")
 365                    (string-contains text
 366                                     (string-append
 367                                      "root@"
 368                                      #$(operating-system-host-name os))))))
 369
 370           (test-end)
 371           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 372
 373   (gexp->derivation name test))
 374
 375 (define %test-basic-os
 376   (system-test
 377    (name "basic")
 378    (description
 379     "Instrument %SIMPLE-OS, run it in a VM, and run a series of basic
 380 functionality tests.")
 381    (value
 382     (let* ((os  (marionette-operating-system
 383                  %simple-os
 384                  #:imported-modules '((gnu services herd)
 385                                       (guix combinators))))
 386            (vm  (virtual-machine os)))
 387       ;; XXX: Add call to 'virtualized-operating-system' to get the exact same
 388       ;; set of services as the OS produced by
 389       ;; 'system-qemu-image/shared-store-script'.
 390       (run-basic-test (virtualized-operating-system os '())
 391                       #~(list #$vm))))))
 392
 393 \f
 394 ;;;
 395 ;;; Halt.
 396 ;;;
 397
 398 (define (run-halt-test vm)
 399   ;; As reported in <http://bugs.gnu.org/26931>, running tmux would previously
 400   ;; lead the 'stop' method of 'user-processes' to an infinite loop, with the
 401   ;; tmux server process as a zombie that remains in the list of processes.
 402   ;; This test reproduces this scenario.
 403   (define test
 404     (with-imported-modules '((gnu build marionette))
 405       #~(begin
 406           (use-modules (gnu build marionette))
 407
 408           (define marionette
 409             (make-marionette '(#$vm)))
 410
 411           (define ocrad
 412             #$(file-append ocrad "/bin/ocrad"))
 413
 414           ;; Wait for tty1 and log in.
 415           (marionette-eval '(begin
 416                               (use-modules (gnu services herd))
 417                               (start-service 'term-tty1))
 418                            marionette)
 419           (marionette-type "root\n" marionette)
 420           (wait-for-screen-text marionette
 421                                 (lambda (text)
 422                                   (string-contains text "root@komputilo"))
 423                                 #:ocrad ocrad)
 424
 425           ;; Start tmux and wait for it to be ready.
 426           (marionette-type "tmux new-session 'echo 1 > /ready; bash'\n"
 427                            marionette)
 428           (wait-for-file "/ready" marionette)
 429
 430           ;; Make sure to stop the test after a while.
 431           (sigaction SIGALRM (lambda _
 432                                (format (current-error-port)
 433                                        "FAIL: Time is up, but VM still running.\n")
 434                                (primitive-exit 1)))
 435           (alarm 10)
 436
 437           ;; Get debugging info.
 438           (marionette-eval '(current-output-port
 439                              (open-file "/dev/console" "w0"))
 440                            marionette)
 441           (marionette-eval '(system* #$(file-append procps "/bin/ps")
 442                                      "-eo" "pid,ppid,stat,comm")
 443                            marionette)
 444
 445           ;; See if 'halt' actually works.
 446           (marionette-eval '(system* "/run/current-system/profile/sbin/halt")
 447                            marionette)
 448
 449           ;; If we reach this line, that means the VM was properly stopped in
 450           ;; a timely fashion.
 451           (alarm 0)
 452           (call-with-output-file #$output
 453             (lambda (port)
 454               (display "success!" port))))))
 455
 456   (gexp->derivation "halt" test))
 457
 458 (define %test-halt
 459   (system-test
 460    (name "halt")
 461    (description
 462     "Use the 'halt' command and make sure it succeeds and does not get stuck
 463 in a loop.  See <http://bugs.gnu.org/26931>.")
 464    (value
 465     (let ((os (marionette-operating-system
 466                (operating-system
 467                  (inherit %simple-os)
 468                  (packages (cons tmux %base-packages)))
 469                #:imported-modules '((gnu services herd)
 470                                     (guix combinators)))))
 471       (run-halt-test (virtual-machine os))))))
 472
 473 \f
 474 ;;;
 475 ;;; Mcron.
 476 ;;;
 477
 478 (define %mcron-os
 479   ;; System with an mcron service, with one mcron job for "root" and one mcron
 480   ;; job for an unprivileged user.
 481   (let ((job1 #~(job next-second-from
 482                      (lambda ()
 483                        (call-with-output-file "witness"
 484                          (lambda (port)
 485                            (display (list (getuid) (getgid)) port))))))
 486         (job2 #~(job next-second-from
 487                      (lambda ()
 488                        (call-with-output-file "witness"
 489                          (lambda (port)
 490                            (display (list (getuid) (getgid)) port))))
 491                      #:user "alice"))
 492         (job3 #~(job next-second-from             ;to test $PATH
 493                      "touch witness-touch")))
 494     (simple-operating-system
 495      (mcron-service (list job1 job2 job3)))))
 496
 497 (define (run-mcron-test name)
 498   (define os
 499     (marionette-operating-system
 500      %mcron-os
 501      #:imported-modules '((gnu services herd)
 502                           (guix combinators))))
 503
 504   (define test
 505     (with-imported-modules '((gnu build marionette))
 506       #~(begin
 507           (use-modules (gnu build marionette)
 508                        (srfi srfi-64)
 509                        (ice-9 match))
 510
 511           (define marionette
 512             (make-marionette (list #$(virtual-machine os))))
 513
 514           (mkdir #$output)
 515           (chdir #$output)
 516
 517           (test-begin "mcron")
 518
 519           (test-eq "service running"
 520             'running!
 521             (marionette-eval
 522              '(begin
 523                 (use-modules (gnu services herd))
 524                 (start-service 'mcron)
 525                 'running!)
 526              marionette))
 527
 528           ;; Make sure root's mcron job runs, has its cwd set to "/root", and
 529           ;; runs with the right UID/GID.
 530           (test-equal "root's job"
 531             '(0 0)
 532             (wait-for-file "/root/witness" marionette))
 533
 534           ;; Likewise for Alice's job.  We cannot know what its GID is since
 535           ;; it's chosen by 'groupadd', but it's strictly positive.
 536           (test-assert "alice's job"
 537             (match (wait-for-file "/home/alice/witness" marionette)
 538               ((1000 gid)
 539                (>= gid 100))))
 540
 541           ;; Last, the job that uses a command; allows us to test whether
 542           ;; $PATH is sane.
 543           (test-equal "root's job with command"
 544             ""
 545             (wait-for-file "/root/witness-touch" marionette
 546                            #:read '(@ (ice-9 rdelim) read-string)))
 547
 548           (test-end)
 549           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 550
 551   (gexp->derivation name test))
 552
 553 (define %test-mcron
 554   (system-test
 555    (name "mcron")
 556    (description "Make sure the mcron service works as advertised.")
 557    (value (run-mcron-test name))))
 558
 559 \f
 560 ;;;
 561 ;;; Avahi and NSS-mDNS.
 562 ;;;
 563
 564 (define %avahi-os
 565   (operating-system
 566     (inherit %simple-os)
 567     (name-service-switch %mdns-host-lookup-nss)
 568     (services (cons* (avahi-service #:debug? #t)
 569                      (dbus-service)
 570                      (dhcp-client-service)        ;needed for multicast
 571
 572                      ;; Enable heavyweight debugging output.
 573                      (modify-services (operating-system-user-services
 574                                        %simple-os)
 575                        (nscd-service-type config
 576                                           => (nscd-configuration
 577                                               (inherit config)
 578                                               (debug-level 3)
 579                                               (log-file "/dev/console")))
 580                        (syslog-service-type config
 581                                             =>
 582                                             (syslog-configuration
 583                                              (inherit config)
 584                                              (config-file
 585                                               (plain-file
 586                                                "syslog.conf"
 587                                                "*.* /dev/console\n")))))))))
 588
 589 (define (run-nss-mdns-test)
 590   ;; Test resolution of '.local' names via libc.  Start the marionette service
 591   ;; *after* nscd.  Failing to do that, libc will try to connect to nscd,
 592   ;; fail, then never try again (see '__nss_not_use_nscd_hosts' in libc),
 593   ;; leading to '.local' resolution failures.
 594   (define os
 595     (marionette-operating-system
 596      %avahi-os
 597      #:requirements '(nscd)
 598      #:imported-modules '((gnu services herd)
 599                           (guix combinators))))
 600
 601   (define mdns-host-name
 602     (string-append (operating-system-host-name os)
 603                    ".local"))
 604
 605   (define test
 606     (with-imported-modules '((gnu build marionette))
 607       #~(begin
 608           (use-modules (gnu build marionette)
 609                        (srfi srfi-1)
 610                        (srfi srfi-64)
 611                        (ice-9 match))
 612
 613           (define marionette
 614             (make-marionette (list #$(virtual-machine os))))
 615
 616           (mkdir #$output)
 617           (chdir #$output)
 618
 619           (test-begin "avahi")
 620
 621           (test-assert "wait for services"
 622             (marionette-eval
 623              '(begin
 624                 (use-modules (gnu services herd))
 625
 626                 (start-service 'nscd)
 627
 628                 ;; XXX: Work around a race condition in nscd: nscd creates its
 629                 ;; PID file before it is listening on its socket.
 630                 (let ((sock (socket PF_UNIX SOCK_STREAM 0)))
 631                   (let try ()
 632                     (catch 'system-error
 633                       (lambda ()
 634                         (connect sock AF_UNIX "/var/run/nscd/socket")
 635                         (close-port sock)
 636                         (format #t "nscd is ready~%"))
 637                       (lambda args
 638                         (format #t "waiting for nscd...~%")
 639                         (usleep 500000)
 640                         (try)))))
 641
 642                 ;; Wait for the other useful things.
 643                 (start-service 'avahi-daemon)
 644                 (start-service 'networking)
 645
 646                 #t)
 647              marionette))
 648
 649           (test-equal "avahi-resolve-host-name"
 650             0
 651             (marionette-eval
 652              '(system*
 653                "/run/current-system/profile/bin/avahi-resolve-host-name"
 654                "-v" #$mdns-host-name)
 655              marionette))
 656
 657           (test-equal "avahi-browse"
 658             0
 659             (marionette-eval
 660              '(system* "avahi-browse" "-avt")
 661              marionette))
 662
 663           (test-assert "getaddrinfo .local"
 664             ;; Wait for the 'avahi-daemon' service and perform a resolution.
 665             (match (marionette-eval
 666                     '(getaddrinfo #$mdns-host-name)
 667                     marionette)
 668               (((? vector? addrinfos) ..1)
 669                (pk 'getaddrinfo addrinfos)
 670                (and (any (lambda (ai)
 671                            (= AF_INET (addrinfo:fam ai)))
 672                          addrinfos)
 673                     (any (lambda (ai)
 674                            (= AF_INET6 (addrinfo:fam ai)))
 675                          addrinfos)))))
 676
 677           (test-assert "gethostbyname .local"
 678             (match (pk 'gethostbyname
 679                        (marionette-eval '(gethostbyname #$mdns-host-name)
 680                                         marionette))
 681               ((? vector? result)
 682                (and (string=? (hostent:name result) #$mdns-host-name)
 683                     (= (hostent:addrtype result) AF_INET)))))
 684
 685
 686           (test-end)
 687           (exit (= (test-runner-fail-count (test-runner-current)) 0)))))
 688
 689   (gexp->derivation "nss-mdns" test))
 690
 691 (define %test-nss-mdns
 692   (system-test
 693    (name "nss-mdns")
 694    (description
 695     "Test Avahi's multicast-DNS implementation, and in particular, test its
 696 glibc name service switch (NSS) module.")
 697    (value (run-nss-mdns-test))))